New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 4596

Last change on this file since 4596 was 4596, checked in by gm, 10 years ago

#1260: LDF simplification + bilap iso-neutral for TRA and GYRE
  • Property svn:keywords set to Id
File size: 52.2 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   dyn_hpg      : update the momentum trend with the now horizontal
22   !!                  gradient of the hydrostatic pressure
23   !!   dyn_hpg_init : initialisation and control of options
24   !!       hpg_zco  : z-coordinate scheme
25   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
26   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
27   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
28   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
29   !!----------------------------------------------------------------------
30   USE oce             ! ocean dynamics and tracers
31   USE dom_oce         ! ocean space and time domain
32   USE phycst          ! physical constants
33   USE trdmod          ! ocean dynamics trends
34   USE trdmod_oce      ! ocean variables trends
35   USE in_out_manager  ! I/O manager
36   USE prtctl          ! Print control
37   USE lbclnk          ! lateral boundary condition
38   USE lib_mpp         ! MPP library
39   USE wrk_nemo        ! Memory Allocation
40   USE timing          ! Timing
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   dyn_hpg        ! routine called by step module
46   PUBLIC   dyn_hpg_init   ! routine called by opa module
47
48   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
49   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
50   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
51   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
52   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
53   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
54   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
55
56   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
57
58   !! * Substitutions
59#  include "domzgr_substitute.h90"
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE dyn_hpg( kt )
69      !!---------------------------------------------------------------------
70      !!                  ***  ROUTINE dyn_hpg  ***
71      !!
72      !! ** Method  :   Call the hydrostatic pressure gradient routine
73      !!              using the scheme defined in the namelist
74      !!
75      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
76      !!             - Save the trend (l_trddyn=T)
77      !!----------------------------------------------------------------------
78      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
79      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
80      !!----------------------------------------------------------------------
81      !
82      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
83      !
84      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
85         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
86         ztrdu(:,:,:) = ua(:,:,:)
87         ztrdv(:,:,:) = va(:,:,:)
88      ENDIF
89      !
90      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
91      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
92      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
93      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
94      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
95      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
96      END SELECT
97      !
98      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
99         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
100         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
101         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_hpg, 'DYN', kt )
102         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
103      ENDIF
104      !
105      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
106         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
107      !
108      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
109      !
110   END SUBROUTINE dyn_hpg
111
112
113   SUBROUTINE dyn_hpg_init
114      !!----------------------------------------------------------------------
115      !!                 ***  ROUTINE dyn_hpg_init  ***
116      !!
117      !! ** Purpose :   initializations for the hydrostatic pressure gradient
118      !!              computation and consistency control
119      !!
120      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
121      !!      with the type of vertical coordinate used (zco, zps, sco)
122      !!----------------------------------------------------------------------
123      INTEGER ::   ioptio = 0      ! temporary integer
124      INTEGER ::   ios             ! Local integer output status for namelist read
125      !!
126      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco   ,     &
127         &                 ln_hpg_djc, ln_hpg_prj, ln_dynhpg_imp
128      !!----------------------------------------------------------------------
129      !
130      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
131      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
132901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
133
134      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
135      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
136902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
137      WRITE ( numond, namdyn_hpg )
138      !
139      IF(lwp) THEN                   ! Control print
140         WRITE(numout,*)
141         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
142         WRITE(numout,*) '~~~~~~~~~~~~'
143         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
144         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
145         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
146         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
147         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
148         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
149         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
150      ENDIF
151      !
152      IF( ln_hpg_djc )   &
153         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
154                           & currently disabled (bugs under investigation). Please select &
155                           & either  ln_hpg_sco or  ln_hpg_prj instead')
156      !
157      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj) )   &
158         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
159                           & the standard jacobian formulation hpg_sco or &
160                           & the pressure jacobian formulation hpg_prj')
161      !
162      !                               ! Set nhpg from ln_hpg_... flags
163      IF( ln_hpg_zco )   nhpg = 0
164      IF( ln_hpg_zps )   nhpg = 1
165      IF( ln_hpg_sco )   nhpg = 2
166      IF( ln_hpg_djc )   nhpg = 3
167      IF( ln_hpg_prj )   nhpg = 4
168      !
169      !                               ! Consistency check
170      ioptio = 0
171      IF( ln_hpg_zco )   ioptio = ioptio + 1
172      IF( ln_hpg_zps )   ioptio = ioptio + 1
173      IF( ln_hpg_sco )   ioptio = ioptio + 1
174      IF( ln_hpg_djc )   ioptio = ioptio + 1
175      IF( ln_hpg_prj )   ioptio = ioptio + 1
176      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
177      !
178   END SUBROUTINE dyn_hpg_init
179
180
181   SUBROUTINE hpg_zco( kt )
182      !!---------------------------------------------------------------------
183      !!                  ***  ROUTINE hpg_zco  ***
184      !!
185      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
186      !!      The now hydrostatic pressure gradient at a given level, jk,
187      !!      is computed by taking the vertical integral of the in-situ
188      !!      density gradient along the model level from the suface to that
189      !!      level:    zhpi = grav .....
190      !!                zhpj = grav .....
191      !!      add it to the general momentum trend (ua,va).
192      !!            ua = ua - 1/e1u * zhpi
193      !!            va = va - 1/e2v * zhpj
194      !!
195      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
196      !!----------------------------------------------------------------------
197      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
198      !!
199      INTEGER  ::   ji, jj, jk       ! dummy loop indices
200      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
201      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
202      !!----------------------------------------------------------------------
203      !
204      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
205      !
206      IF( kt == nit000 ) THEN
207         IF(lwp) WRITE(numout,*)
208         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
209         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
210      ENDIF
211
212      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
213
214      ! Surface value
215      DO jj = 2, jpjm1
216         DO ji = fs_2, fs_jpim1   ! vector opt.
217            zcoef1 = zcoef0 * fse3w(ji,jj,1)
218            ! hydrostatic pressure gradient
219            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
220            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
221            ! add to the general momentum trend
222            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
223            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
224         END DO
225      END DO
226
227      !
228      ! interior value (2=<jk=<jpkm1)
229      DO jk = 2, jpkm1
230         DO jj = 2, jpjm1
231            DO ji = fs_2, fs_jpim1   ! vector opt.
232               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
233               ! hydrostatic pressure gradient
234               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
235                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
236                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
237
238               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
239                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
240                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
241               ! add to the general momentum trend
242               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
243               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
244            END DO
245         END DO
246      END DO
247      !
248      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
249      !
250   END SUBROUTINE hpg_zco
251
252
253   SUBROUTINE hpg_zps( kt )
254      !!---------------------------------------------------------------------
255      !!                 ***  ROUTINE hpg_zps  ***
256      !!
257      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
258      !!
259      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
260      !!----------------------------------------------------------------------
261      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
262      !!
263      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
264      INTEGER  ::   iku, ikv                         ! temporary integers
265      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
266      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
267      !!----------------------------------------------------------------------
268      !
269      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
270      !
271      IF( kt == nit000 ) THEN
272         IF(lwp) WRITE(numout,*)
273         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
274         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
275      ENDIF
276
277
278      ! Local constant initialization
279      zcoef0 = - grav * 0.5_wp
280
281      !  Surface value (also valid in partial step case)
282      DO jj = 2, jpjm1
283         DO ji = fs_2, fs_jpim1   ! vector opt.
284            zcoef1 = zcoef0 * fse3w(ji,jj,1)
285            ! hydrostatic pressure gradient
286            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
287            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
288            ! add to the general momentum trend
289            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
290            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
291         END DO
292      END DO
293
294
295      ! interior value (2=<jk=<jpkm1)
296      DO jk = 2, jpkm1
297         DO jj = 2, jpjm1
298            DO ji = fs_2, fs_jpim1   ! vector opt.
299               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
300               ! hydrostatic pressure gradient
301               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
302                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
303                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
304
305               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
306                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
307                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
308               ! add to the general momentum trend
309               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
310               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
311            END DO
312         END DO
313      END DO
314
315
316      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
317# if defined key_vectopt_loop
318         jj = 1
319         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
320# else
321      DO jj = 2, jpjm1
322         DO ji = 2, jpim1
323# endif
324            iku = mbku(ji,jj)
325            ikv = mbkv(ji,jj)
326            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
327            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
328            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
329               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
330               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
331                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
332               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
333            ENDIF
334            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
335               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
336               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
337                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
338               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
339            ENDIF
340# if ! defined key_vectopt_loop
341         END DO
342# endif
343      END DO
344      !
345      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
346      !
347   END SUBROUTINE hpg_zps
348
349
350   SUBROUTINE hpg_sco( kt )
351      !!---------------------------------------------------------------------
352      !!                  ***  ROUTINE hpg_sco  ***
353      !!
354      !! ** Method  :   s-coordinate case. Jacobian scheme.
355      !!      The now hydrostatic pressure gradient at a given level, jk,
356      !!      is computed by taking the vertical integral of the in-situ
357      !!      density gradient along the model level from the suface to that
358      !!      level. s-coordinates (ln_sco): a corrective term is added
359      !!      to the horizontal pressure gradient :
360      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
361      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
362      !!      add it to the general momentum trend (ua,va).
363      !!         ua = ua - 1/e1u * zhpi
364      !!         va = va - 1/e2v * zhpj
365      !!
366      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
367      !!----------------------------------------------------------------------
368      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
369      !!
370      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
371      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
372      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
373      !!----------------------------------------------------------------------
374      !
375      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
376      !
377      IF( kt == nit000 ) THEN
378         IF(lwp) WRITE(numout,*)
379         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
380         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
381      ENDIF
382
383      ! Local constant initialization
384      zcoef0 = - grav * 0.5_wp
385      ! To use density and not density anomaly
386      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
387      ELSE                 ;     znad = 0._wp         ! Fixed volume
388      ENDIF
389
390      ! Surface value
391      DO jj = 2, jpjm1
392         DO ji = fs_2, fs_jpim1   ! vector opt.
393            ! hydrostatic pressure gradient along s-surfaces
394            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
395               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
396            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
397               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
398            ! s-coordinate pressure gradient correction
399            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
400               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
401            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
402               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
403            ! add to the general momentum trend
404            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
405            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
406         END DO
407      END DO
408
409      ! interior value (2=<jk=<jpkm1)
410      DO jk = 2, jpkm1
411         DO jj = 2, jpjm1
412            DO ji = fs_2, fs_jpim1   ! vector opt.
413               ! hydrostatic pressure gradient along s-surfaces
414               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
415                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
416                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
417               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
418                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
419                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
420               ! s-coordinate pressure gradient correction
421               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
422                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
423               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
424                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
425               ! add to the general momentum trend
426               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
427               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
428            END DO
429         END DO
430      END DO
431      !
432      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
433      !
434   END SUBROUTINE hpg_sco
435
436
437   SUBROUTINE hpg_djc( kt )
438      !!---------------------------------------------------------------------
439      !!                  ***  ROUTINE hpg_djc  ***
440      !!
441      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
442      !!
443      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
444      !!----------------------------------------------------------------------
445      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
446      !!
447      INTEGER  ::   ji, jj, jk          ! dummy loop indices
448      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
449      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
450      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
451      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
452      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
453      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
454      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
455      !!----------------------------------------------------------------------
456      !
457      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
458      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
459      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
460      !
461
462      IF( kt == nit000 ) THEN
463         IF(lwp) WRITE(numout,*)
464         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
465         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
466      ENDIF
467
468      ! Local constant initialization
469      zcoef0 = - grav * 0.5_wp
470      z1_10  = 1._wp / 10._wp
471      z1_12  = 1._wp / 12._wp
472
473      !----------------------------------------------------------------------------------------
474      !  compute and store in provisional arrays elementary vertical and horizontal differences
475      !----------------------------------------------------------------------------------------
476
477!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
478
479      DO jk = 2, jpkm1
480         DO jj = 2, jpjm1
481            DO ji = fs_2, fs_jpim1   ! vector opt.
482               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
483               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
484               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
485               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
486               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
487               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
488            END DO
489         END DO
490      END DO
491
492      !-------------------------------------------------------------------------
493      ! compute harmonic averages using eq. 5.18
494      !-------------------------------------------------------------------------
495      zep = 1.e-15
496
497!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
498!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
499
500      DO jk = 2, jpkm1
501         DO jj = 2, jpjm1
502            DO ji = fs_2, fs_jpim1   ! vector opt.
503               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
504
505               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
506               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
507
508               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
509               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
510
511               IF( cffw > zep) THEN
512                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
513                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
514               ELSE
515                  drhow(ji,jj,jk) = 0._wp
516               ENDIF
517
518               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
519                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
520
521               IF( cffu > zep ) THEN
522                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
523                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
524               ELSE
525                  drhou(ji,jj,jk ) = 0._wp
526               ENDIF
527
528               IF( cffx > zep ) THEN
529                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
530                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
531               ELSE
532                  dzu(ji,jj,jk) = 0._wp
533               ENDIF
534
535               IF( cffv > zep ) THEN
536                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
537                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
538               ELSE
539                  drhov(ji,jj,jk) = 0._wp
540               ENDIF
541
542               IF( cffy > zep ) THEN
543                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
544                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
545               ELSE
546                  dzv(ji,jj,jk) = 0._wp
547               ENDIF
548
549            END DO
550         END DO
551      END DO
552
553      !----------------------------------------------------------------------------------
554      ! apply boundary conditions at top and bottom using 5.36-5.37
555      !----------------------------------------------------------------------------------
556      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
557      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
558      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
559
560      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
561      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
562      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
563
564
565      !--------------------------------------------------------------
566      ! Upper half of top-most grid box, compute and store
567      !-------------------------------------------------------------
568
569!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
570!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
571
572      DO jj = 2, jpjm1
573         DO ji = fs_2, fs_jpim1   ! vector opt.
574            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
575               &                   * (  rhd(ji,jj,1)                                    &
576               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
577               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
578               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
579         END DO
580      END DO
581
582!!bug gm    : here also, simplification is possible
583
584      DO jk = 2, jpkm1
585         DO jj = 2, jpjm1
586            DO ji = fs_2, fs_jpim1   ! vector opt.
587               !
588               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
589                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
590                  &            - grav * z1_10 * (                                                                     &
591                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
592                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
593                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
594                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
595                  &                             )
596                  !
597               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
598                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
599                  &            - grav* z1_10 * (                                                                      &
600                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
601                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
602                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
603                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
604                  &                            )
605                  !
606               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
607                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
608                  &            - grav* z1_10 * (                                                                      &
609                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
610                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
611                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
612                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
613                  &                            )
614            END DO
615         END DO
616      END DO
617      CALL lbc_lnk(rho_k,'W',1.)
618      CALL lbc_lnk(rho_i,'U',1.)
619      CALL lbc_lnk(rho_j,'V',1.)
620
621
622      ! ---------------
623      !  Surface value
624      ! ---------------
625      DO jj = 2, jpjm1
626         DO ji = fs_2, fs_jpim1   ! vector opt.
627            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
628            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
629            ! add to the general momentum trend
630            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
631            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
632         END DO
633      END DO
634
635      ! ----------------
636      !  interior value   (2=<jk=<jpkm1)
637      ! ----------------
638      DO jk = 2, jpkm1
639         DO jj = 2, jpjm1
640            DO ji = fs_2, fs_jpim1   ! vector opt.
641               ! hydrostatic pressure gradient along s-surfaces
642               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
643                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
644                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
645               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
646                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
647                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
648               ! add to the general momentum trend
649               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
650               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
651            END DO
652         END DO
653      END DO
654      !
655      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
656      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
657      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
658      !
659   END SUBROUTINE hpg_djc
660
661
662   SUBROUTINE hpg_prj( kt )
663      !!---------------------------------------------------------------------
664      !!                  ***  ROUTINE hpg_prj  ***
665      !!
666      !! ** Method  :   s-coordinate case.
667      !!      A Pressure-Jacobian horizontal pressure gradient method
668      !!      based on the constrained cubic-spline interpolation for
669      !!      all vertical coordinate systems
670      !!
671      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
672      !!             - Save the trend (l_trddyn=T)
673      !!
674      !!----------------------------------------------------------------------
675      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
676      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
677      !!
678      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
679      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
680      !!
681      !! The local variables for the correction term
682      INTEGER  :: jk1, jis, jid, jjs, jjd
683      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
684      REAL(wp) :: zrhdt1
685      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
686      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
687      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
688      !!----------------------------------------------------------------------
689      !
690      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
691      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
692      !
693      IF( kt == nit000 ) THEN
694         IF(lwp) WRITE(numout,*)
695         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
696         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
697      ENDIF
698
699      !!----------------------------------------------------------------------
700      ! Local constant initialization
701      zcoef0 = - grav
702      znad = 0.0_wp
703      IF( lk_vvl ) znad = 1._wp
704
705      ! Clean 3-D work arrays
706      zhpi(:,:,:) = 0._wp
707      zrhh(:,:,:) = rhd(:,:,:)
708
709      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
710      DO jj = 1, jpj
711        DO ji = 1, jpi
712          jk = mbathy(ji,jj)
713          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
714          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
715          ELSE IF(jk < jpkm1) THEN
716             DO jkk = jk+1, jpk
717                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
718                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
719             END DO
720          ENDIF
721        END DO
722      END DO
723
724      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
725      DO jj = 1, jpj;   DO ji = 1, jpi
726          zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
727      END DO        ;   END DO
728
729      DO jk = 2, jpk;   DO jj = 1, jpj;   DO ji = 1, jpi
730          zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
731      END DO        ;   END DO        ;   END DO
732
733      fsp(:,:,:) = zrhh(:,:,:)
734      xsp(:,:,:) = zdept(:,:,:)
735
736      ! Construct the vertical density profile with the
737      ! constrained cubic spline interpolation
738      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
739      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
740
741      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
742      DO jj = 2, jpj
743        DO ji = 2, jpi
744          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
745                                         bsp(ji,jj,1),   csp(ji,jj,1), &
746                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
747
748          ! assuming linear profile across the top half surface layer
749          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
750        END DO
751      END DO
752
753      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
754      DO jk = 2, jpkm1
755        DO jj = 2, jpj
756          DO ji = 2, jpi
757            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
758                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
759                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
760                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
761          END DO
762        END DO
763      END DO
764
765      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
766      DO jj = 2, jpjm1
767        DO ji = 2, jpim1
768          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshu_n for ztilde compilation
769          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshv_n for ztilde compilation
770        END DO
771      END DO
772
773      DO jk = 2, jpkm1
774        DO jj = 2, jpjm1
775          DO ji = 2, jpim1
776            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
777            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
778          END DO
779        END DO
780      END DO
781
782      DO jk = 1, jpkm1
783        DO jj = 2, jpjm1
784          DO ji = 2, jpim1
785            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
786            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
787          END DO
788        END DO
789      END DO
790
791      DO jk = 1, jpkm1
792        DO jj = 2, jpjm1
793          DO ji = 2, jpim1
794            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
795            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
796            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
797            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
798          END DO
799        END DO
800      END DO
801
802
803      DO jk = 1, jpkm1
804        DO jj = 2, jpjm1
805          DO ji = 2, jpim1
806            zpwes = 0._wp; zpwed = 0._wp
807            zpnss = 0._wp; zpnsd = 0._wp
808            zuijk = zu(ji,jj,jk)
809            zvijk = zv(ji,jj,jk)
810
811            !!!!!     for u equation
812            IF( jk <= mbku(ji,jj) ) THEN
813               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
814                 jis = ji + 1; jid = ji
815               ELSE
816                 jis = ji;     jid = ji +1
817               ENDIF
818
819               ! integrate the pressure on the shallow side
820               jk1 = jk
821               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
822                 IF( jk1 == mbku(ji,jj) ) THEN
823                   zuijk = -zdept(jis,jj,jk1)
824                   EXIT
825                 ENDIF
826                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
827                 zpwes = zpwes +                                    &
828                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
829                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
830                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
831                 jk1 = jk1 + 1
832               END DO
833
834               ! integrate the pressure on the deep side
835               jk1 = jk
836               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
837                 IF( jk1 == 1 ) THEN
838                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
839                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
840                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
841                                                     dsp(jid,jj,1)) * zdeps
842                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
843                   EXIT
844                 ENDIF
845                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
846                 zpwed = zpwed +                                        &
847                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
848                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
849                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
850                 jk1 = jk1 - 1
851               END DO
852
853               ! update the momentum trends in u direction
854
855               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
856               IF( lk_vvl ) THEN
857                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
858                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
859                ELSE
860                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
861               ENDIF
862
863               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
864               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
865            ENDIF
866
867            !!!!!     for v equation
868            IF( jk <= mbkv(ji,jj) ) THEN
869               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
870                 jjs = jj + 1; jjd = jj
871               ELSE
872                 jjs = jj    ; jjd = jj + 1
873               ENDIF
874
875               ! integrate the pressure on the shallow side
876               jk1 = jk
877               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
878                 IF( jk1 == mbkv(ji,jj) ) THEN
879                   zvijk = -zdept(ji,jjs,jk1)
880                   EXIT
881                 ENDIF
882                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
883                 zpnss = zpnss +                                      &
884                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
885                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
886                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
887                 jk1 = jk1 + 1
888               END DO
889
890               ! integrate the pressure on the deep side
891               jk1 = jk
892               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
893                 IF( jk1 == 1 ) THEN
894                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
895                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
896                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
897                                                     dsp(ji,jjd,1) ) * zdeps
898                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
899                   EXIT
900                 ENDIF
901                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
902                 zpnsd = zpnsd +                                        &
903                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
904                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
905                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
906                 jk1 = jk1 - 1
907               END DO
908
909
910               ! update the momentum trends in v direction
911
912               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
913               IF( lk_vvl ) THEN
914                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
915                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
916               ELSE
917                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
918               ENDIF
919
920               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
921               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
922            ENDIF
923
924
925           END DO
926        END DO
927      END DO
928      !
929      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
930      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
931      !
932   END SUBROUTINE hpg_prj
933
934   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
935      !!----------------------------------------------------------------------
936      !!                 ***  ROUTINE cspline  ***
937      !!
938      !! ** Purpose :   constrained cubic spline interpolation
939      !!
940      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
941      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
942      !!
943      !!----------------------------------------------------------------------
944      IMPLICIT NONE
945      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
946      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
947                                                                    ! the interpoated function
948      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
949                                                                    ! 2: Linear
950
951      ! Local Variables
952      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
953      INTEGER  ::   jpi, jpj, jpkm1
954      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
955      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
956      REAL(wp) ::   zdf(size(fsp,3))
957      !!----------------------------------------------------------------------
958
959      jpi   = size(fsp,1)
960      jpj   = size(fsp,2)
961      jpkm1 = size(fsp,3) - 1
962
963
964      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
965         DO ji = 1, jpi
966            DO jj = 1, jpj
967           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
968           !    DO jk = 2, jpkm1-1
969           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
970           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
971           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
972           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
973           !
974           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
975           !
976           !       IF(zdf1 * zdf2 <= 0._wp) THEN
977           !           zdf(jk) = 0._wp
978           !       ELSE
979           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
980           !       ENDIF
981           !    END DO
982
983           !!Simply geometric average
984               DO jk = 2, jpkm1-1
985                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
986                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
987
988                  IF(zdf1 * zdf2 <= 0._wp) THEN
989                     zdf(jk) = 0._wp
990                  ELSE
991                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
992                  ENDIF
993               END DO
994
995               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
996                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
997               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
998                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
999                          & 0.5_wp * zdf(jpkm1 - 1)
1000
1001               DO jk = 1, jpkm1 - 1
1002                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1003                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1004                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1005                 zddf1  = -2._wp * ztmp1 + ztmp2
1006                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1007                 zddf2  =  2._wp * ztmp1 - ztmp2
1008
1009                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1010                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1011                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1012                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1013                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1014                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1015                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1016                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1017                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1018               END DO
1019            END DO
1020         END DO
1021
1022      ELSE IF (polynomial_type == 2) THEN     ! Linear
1023         DO ji = 1, jpi
1024            DO jj = 1, jpj
1025               DO jk = 1, jpkm1-1
1026                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1027                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1028
1029                  dsp(ji,jj,jk) = 0._wp
1030                  csp(ji,jj,jk) = 0._wp
1031                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1032                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1033               END DO
1034            END DO
1035         END DO
1036
1037      ELSE
1038           CALL ctl_stop( 'invalid polynomial type in cspline' )
1039      ENDIF
1040
1041
1042   END SUBROUTINE cspline
1043
1044
1045   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1046      !!----------------------------------------------------------------------
1047      !!                 ***  ROUTINE interp1  ***
1048      !!
1049      !! ** Purpose :   1-d linear interpolation
1050      !!
1051      !! ** Method  :
1052      !!                interpolation is straight forward
1053      !!                extrapolation is also permitted (no value limit)
1054      !!
1055      !!----------------------------------------------------------------------
1056      IMPLICIT NONE
1057      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1058      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1059      REAL(wp)             ::  zdeltx
1060      !!----------------------------------------------------------------------
1061
1062      zdeltx = xr - xl
1063      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1064        f = 0.5_wp * (fl + fr)
1065      ELSE
1066        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1067      ENDIF
1068
1069   END FUNCTION interp1
1070
1071   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1072      !!----------------------------------------------------------------------
1073      !!                 ***  ROUTINE interp1  ***
1074      !!
1075      !! ** Purpose :   1-d constrained cubic spline interpolation
1076      !!
1077      !! ** Method  :  cubic spline interpolation
1078      !!
1079      !!----------------------------------------------------------------------
1080      IMPLICIT NONE
1081      REAL(wp), INTENT(in) ::  x, a, b, c, d
1082      REAL(wp)             ::  f ! value from the interpolation
1083      !!----------------------------------------------------------------------
1084
1085      f = a + x* ( b + x * ( c + d * x ) )
1086
1087   END FUNCTION interp2
1088
1089
1090   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1091      !!----------------------------------------------------------------------
1092      !!                 ***  ROUTINE interp1  ***
1093      !!
1094      !! ** Purpose :   Calculate the first order of deriavtive of
1095      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1096      !!
1097      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1098      !!
1099      !!----------------------------------------------------------------------
1100      IMPLICIT NONE
1101      REAL(wp), INTENT(in) ::  x, a, b, c, d
1102      REAL(wp)             ::  f ! value from the interpolation
1103      !!----------------------------------------------------------------------
1104
1105      f = b + x * ( 2._wp * c + 3._wp * d * x)
1106
1107   END FUNCTION interp3
1108
1109
1110   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1111      !!----------------------------------------------------------------------
1112      !!                 ***  ROUTINE interp1  ***
1113      !!
1114      !! ** Purpose :   1-d constrained cubic spline integration
1115      !!
1116      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1117      !!
1118      !!----------------------------------------------------------------------
1119      IMPLICIT NONE
1120      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1121      REAL(wp)             ::  za1, za2, za3
1122      REAL(wp)             ::  f                   ! integration result
1123      !!----------------------------------------------------------------------
1124
1125      za1 = 0.5_wp * b
1126      za2 = c / 3.0_wp
1127      za3 = 0.25_wp * d
1128
1129      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1130         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1131
1132   END FUNCTION integ_spline
1133
1134
1135   !!======================================================================
1136END MODULE dynhpg
1137
Note: See TracBrowser for help on using the repository browser.