New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 4616

Last change on this file since 4616 was 4616, checked in by gm, 10 years ago

#1260 : see the associated wiki page for explanation
  • Property svn:keywords set to Id
File size: 52.3 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   dyn_hpg      : update the momentum trend with the now horizontal
22   !!                  gradient of the hydrostatic pressure
23   !!   dyn_hpg_init : initialisation and control of options
24   !!       hpg_zco  : z-coordinate scheme
25   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
26   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
27   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
28   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
29   !!----------------------------------------------------------------------
30   USE oce             ! ocean dynamics and tracers
31   USE dom_oce         ! ocean space and time domain
32   USE phycst          ! physical constants
33   USE trdmod          ! ocean dynamics trends
34   USE trdmod_oce      ! ocean variables trends
35   USE in_out_manager  ! I/O manager
36   USE prtctl          ! Print control
37   USE lbclnk          ! lateral boundary condition
38   USE lib_mpp         ! MPP library
39   USE wrk_nemo        ! Memory Allocation
40   USE timing          ! Timing
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   dyn_hpg        ! routine called by step module
46   PUBLIC   dyn_hpg_init   ! routine called by opa module
47
48   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
49   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
50   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
51   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
52   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
53   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
54   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
55
56   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
57
58   !! * Substitutions
59#  include "domzgr_substitute.h90"
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE dyn_hpg( kt )
69      !!---------------------------------------------------------------------
70      !!                  ***  ROUTINE dyn_hpg  ***
71      !!
72      !! ** Method  :   Call the hydrostatic pressure gradient routine
73      !!              using the scheme defined in the namelist
74      !!
75      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
76      !!             - Save the trend (l_trddyn=T)
77      !!----------------------------------------------------------------------
78      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
79      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
80      !!----------------------------------------------------------------------
81      !
82      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
83      !
84      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
85         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
86         ztrdu(:,:,:) = ua(:,:,:)
87         ztrdv(:,:,:) = va(:,:,:)
88      ENDIF
89      !
90      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
91      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
92      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
93      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
94      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
95      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
96      END SELECT
97      !
98      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
99         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
100         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
101         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_hpg, 'DYN', kt )
102         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
103      ENDIF
104      !
105      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
106         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
107      !
108      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
109      !
110   END SUBROUTINE dyn_hpg
111
112
113   SUBROUTINE dyn_hpg_init
114      !!----------------------------------------------------------------------
115      !!                 ***  ROUTINE dyn_hpg_init  ***
116      !!
117      !! ** Purpose :   initializations for the hydrostatic pressure gradient
118      !!              computation and consistency control
119      !!
120      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
121      !!      with the type of vertical coordinate used (zco, zps, sco)
122      !!----------------------------------------------------------------------
123      INTEGER ::   ioptio = 0      ! temporary integer
124      INTEGER ::   ios             ! Local integer output status for namelist read
125      !!
126      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco   ,     &
127         &                 ln_hpg_djc, ln_hpg_prj, ln_dynhpg_imp
128      !!----------------------------------------------------------------------
129      !
130      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
131      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
132901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
133
134      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
135      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
136902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
137      WRITE ( numond, namdyn_hpg )
138      !
139      IF(lwp) THEN                   ! Control print
140         WRITE(numout,*)
141         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
142         WRITE(numout,*) '~~~~~~~~~~~~'
143         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
144         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
145         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
146         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
147         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
148         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
149         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
150      ENDIF
151      !
152      IF( ln_hpg_djc )   &
153         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
154                           & currently disabled (bugs under investigation). Please select &
155                           & either  ln_hpg_sco or  ln_hpg_prj instead')
156      !
157      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj) )   &
158         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
159                           & the standard jacobian formulation hpg_sco or &
160                           & the pressure jacobian formulation hpg_prj')
161      !
162      !                               ! Set nhpg from ln_hpg_... flags
163      IF( ln_hpg_zco )   nhpg = 0
164      IF( ln_hpg_zps )   nhpg = 1
165      IF( ln_hpg_sco )   nhpg = 2
166      IF( ln_hpg_djc )   nhpg = 3
167      IF( ln_hpg_prj )   nhpg = 4
168      !
169      !                               ! Consistency check
170      ioptio = 0
171      IF( ln_hpg_zco )   ioptio = ioptio + 1
172      IF( ln_hpg_zps )   ioptio = ioptio + 1
173      IF( ln_hpg_sco )   ioptio = ioptio + 1
174      IF( ln_hpg_djc )   ioptio = ioptio + 1
175      IF( ln_hpg_prj )   ioptio = ioptio + 1
176      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
177      !
178   END SUBROUTINE dyn_hpg_init
179
180
181   SUBROUTINE hpg_zco( kt )
182      !!---------------------------------------------------------------------
183      !!                  ***  ROUTINE hpg_zco  ***
184      !!
185      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
186      !!      The now hydrostatic pressure gradient at a given level, jk,
187      !!      is computed by taking the vertical integral of the in-situ
188      !!      density gradient along the model level from the suface to that
189      !!      level:    zhpi = grav .....
190      !!                zhpj = grav .....
191      !!      add it to the general momentum trend (ua,va).
192      !!            ua = ua - 1/e1u * zhpi
193      !!            va = va - 1/e2v * zhpj
194      !!
195      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
196      !!----------------------------------------------------------------------
197      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
198      !!
199      INTEGER  ::   ji, jj, jk       ! dummy loop indices
200      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
201      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
202      !!----------------------------------------------------------------------
203      !
204      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
205      !
206      IF( kt == nit000 ) THEN
207         IF(lwp) WRITE(numout,*)
208         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
209         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
210      ENDIF
211
212      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
213
214      ! Surface value
215      DO jj = 2, jpjm1
216         DO ji = fs_2, fs_jpim1   ! vector opt.
217            zcoef1 = zcoef0 * fse3w(ji,jj,1)
218            ! hydrostatic pressure gradient
219            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
220            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
221            ! add to the general momentum trend
222            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
223            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
224         END DO
225      END DO
226
227      !
228      ! interior value (2=<jk=<jpkm1)
229      DO jk = 2, jpkm1
230         DO jj = 2, jpjm1
231            DO ji = fs_2, fs_jpim1   ! vector opt.
232               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
233               ! hydrostatic pressure gradient
234               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
235                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
236                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
237
238               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
239                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
240                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
241               ! add to the general momentum trend
242               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
243               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
244            END DO
245         END DO
246      END DO
247      !
248      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
249      !
250   END SUBROUTINE hpg_zco
251
252
253   SUBROUTINE hpg_zps( kt )
254      !!---------------------------------------------------------------------
255      !!                 ***  ROUTINE hpg_zps  ***
256      !!
257      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
258      !!
259      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
260      !!----------------------------------------------------------------------
261      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
262      !!
263      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
264      INTEGER  ::   iku, ikv                         ! temporary integers
265      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
266      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
267      !!----------------------------------------------------------------------
268      !
269      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
270      !
271      IF( kt == nit000 ) THEN
272         IF(lwp) WRITE(numout,*)
273         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
274         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
275      ENDIF
276
277
278      ! Local constant initialization
279      zcoef0 = - grav * 0.5_wp
280
281      !  Surface value (also valid in partial step case)
282      DO jj = 2, jpjm1
283         DO ji = fs_2, fs_jpim1   ! vector opt.
284            zcoef1 = zcoef0 * fse3w(ji,jj,1)
285            ! hydrostatic pressure gradient
286            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
287            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
288            ! add to the general momentum trend
289            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
290            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
291         END DO
292      END DO
293
294
295      ! interior value (2=<jk=<jpkm1)
296      DO jk = 2, jpkm1
297         DO jj = 2, jpjm1
298            DO ji = fs_2, fs_jpim1   ! vector opt.
299               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
300               ! hydrostatic pressure gradient
301               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
302                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )    &
303                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
304
305               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
306                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )    &
307                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
308               ! add to the general momentum trend
309               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
310               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
311            END DO
312         END DO
313      END DO
314
315
316      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
317      DO jj = 2, jpjm1
318         DO ji = 2, jpim1
319            iku = mbku(ji,jj)
320            ikv = mbkv(ji,jj)
321            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
322            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
323            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
324               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
325               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
326                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) * r1_e1u(ji,jj)
327               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
328            ENDIF
329            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
330               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
331               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
332                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) * r1_e2v(ji,jj)
333               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
334            ENDIF
335         END DO
336      END DO
337      !
338      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
339      !
340   END SUBROUTINE hpg_zps
341
342
343   SUBROUTINE hpg_sco( kt )
344      !!---------------------------------------------------------------------
345      !!                  ***  ROUTINE hpg_sco  ***
346      !!
347      !! ** Method  :   s-coordinate case. Jacobian scheme.
348      !!      The now hydrostatic pressure gradient at a given level, jk,
349      !!      is computed by taking the vertical integral of the in-situ
350      !!      density gradient along the model level from the suface to that
351      !!      level. s-coordinates (ln_sco): a corrective term is added
352      !!      to the horizontal pressure gradient :
353      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
354      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
355      !!      add it to the general momentum trend (ua,va).
356      !!         ua = ua - 1/e1u * zhpi
357      !!         va = va - 1/e2v * zhpj
358      !!
359      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
360      !!----------------------------------------------------------------------
361      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
362      !!
363      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
364      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
365      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
366      !!----------------------------------------------------------------------
367      !
368      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
369      !
370      IF( kt == nit000 ) THEN
371         IF(lwp) WRITE(numout,*)
372         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
373         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
374      ENDIF
375
376      ! Local constant initialization
377      zcoef0 = - grav * 0.5_wp
378      ! To use density and not density anomaly
379      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
380      ELSE                 ;     znad = 0._wp         ! Fixed volume
381      ENDIF
382
383      ! Surface value
384      DO jj = 2, jpjm1
385         DO ji = fs_2, fs_jpim1   ! vector opt.
386            ! hydrostatic pressure gradient along s-surfaces
387            zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
388               &                                     - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
389            zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
390               &                                     - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
391            ! s-coordinate pressure gradient correction
392            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
393               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) * r1_e1u(ji,jj)
394            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
395               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) * r1_e2v(ji,jj)
396            ! add to the general momentum trend
397            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
398            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
399         END DO
400      END DO
401
402!!gm
403!!gm Idea of optimization here : only divide by e1u and e2v  when apply to ua, va ....
404!!gm
405
406      ! interior value (2=<jk=<jpkm1)
407      DO jk = 2, jpkm1
408         DO jj = 2, jpjm1
409            DO ji = fs_2, fs_jpim1   ! vector opt.
410               ! hydrostatic pressure gradient along s-surfaces
411               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
412                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
413                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
414               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
415                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
416                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
417               ! s-coordinate pressure gradient correction
418               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
419                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) * r1_e1u(ji,jj)
420               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
421                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) * r1_e2v(ji,jj)
422               ! add to the general momentum trend
423               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
424               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
425            END DO
426         END DO
427      END DO
428      !
429      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
430      !
431   END SUBROUTINE hpg_sco
432
433
434   SUBROUTINE hpg_djc( kt )
435      !!---------------------------------------------------------------------
436      !!                  ***  ROUTINE hpg_djc  ***
437      !!
438      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
439      !!
440      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
441      !!----------------------------------------------------------------------
442      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
443      !!
444      INTEGER  ::   ji, jj, jk          ! dummy loop indices
445      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
446      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
447      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
448      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
449      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
450      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
451      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
452      !!----------------------------------------------------------------------
453      !
454      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
455      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
456      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
457      !
458
459      IF( kt == nit000 ) THEN
460         IF(lwp) WRITE(numout,*)
461         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
462         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
463      ENDIF
464
465      ! Local constant initialization
466      zcoef0 = - grav * 0.5_wp
467      z1_10  = 1._wp / 10._wp
468      z1_12  = 1._wp / 12._wp
469
470      !----------------------------------------------------------------------------------------
471      !  compute and store in provisional arrays elementary vertical and horizontal differences
472      !----------------------------------------------------------------------------------------
473
474!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
475
476      DO jk = 2, jpkm1
477         DO jj = 2, jpjm1
478            DO ji = fs_2, fs_jpim1   ! vector opt.
479               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
480               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
481               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
482               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
483               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
484               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
485            END DO
486         END DO
487      END DO
488
489      !-------------------------------------------------------------------------
490      ! compute harmonic averages using eq. 5.18
491      !-------------------------------------------------------------------------
492      zep = 1.e-15
493
494!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
495!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
496
497      DO jk = 2, jpkm1
498         DO jj = 2, jpjm1
499            DO ji = fs_2, fs_jpim1   ! vector opt.
500               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
501
502               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
503               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
504
505               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
506               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
507
508               IF( cffw > zep) THEN
509                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
510                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
511               ELSE
512                  drhow(ji,jj,jk) = 0._wp
513               ENDIF
514
515               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
516                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
517
518               IF( cffu > zep ) THEN
519                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
520                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
521               ELSE
522                  drhou(ji,jj,jk ) = 0._wp
523               ENDIF
524
525               IF( cffx > zep ) THEN
526                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
527                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
528               ELSE
529                  dzu(ji,jj,jk) = 0._wp
530               ENDIF
531
532               IF( cffv > zep ) THEN
533                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
534                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
535               ELSE
536                  drhov(ji,jj,jk) = 0._wp
537               ENDIF
538
539               IF( cffy > zep ) THEN
540                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
541                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
542               ELSE
543                  dzv(ji,jj,jk) = 0._wp
544               ENDIF
545
546            END DO
547         END DO
548      END DO
549
550      !----------------------------------------------------------------------------------
551      ! apply boundary conditions at top and bottom using 5.36-5.37
552      !----------------------------------------------------------------------------------
553      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
554      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
555      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
556
557      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
558      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
559      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
560
561
562      !--------------------------------------------------------------
563      ! Upper half of top-most grid box, compute and store
564      !-------------------------------------------------------------
565
566!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
567!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
568
569      DO jj = 2, jpjm1
570         DO ji = fs_2, fs_jpim1   ! vector opt.
571            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
572               &                   * (  rhd(ji,jj,1)                                    &
573               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
574               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
575               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
576         END DO
577      END DO
578
579!!bug gm    : here also, simplification is possible
580
581      DO jk = 2, jpkm1
582         DO jj = 2, jpjm1
583            DO ji = fs_2, fs_jpim1   ! vector opt.
584               !
585               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
586                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
587                  &            - grav * z1_10 * (                                                                     &
588                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
589                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
590                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
591                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
592                  &                             )
593                  !
594               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
595                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
596                  &            - grav* z1_10 * (                                                                      &
597                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
598                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
599                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
600                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
601                  &                            )
602                  !
603               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
604                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
605                  &            - grav* z1_10 * (                                                                      &
606                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
607                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
608                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
609                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
610                  &                            )
611            END DO
612         END DO
613      END DO
614      CALL lbc_lnk(rho_k,'W',1.)
615      CALL lbc_lnk(rho_i,'U',1.)
616      CALL lbc_lnk(rho_j,'V',1.)
617
618
619      ! ---------------
620      !  Surface value
621      ! ---------------
622      DO jj = 2, jpjm1
623         DO ji = fs_2, fs_jpim1   ! vector opt.
624            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
625            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
626            ! add to the general momentum trend
627            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
628            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
629         END DO
630      END DO
631
632      ! ----------------
633      !  interior value   (2=<jk=<jpkm1)
634      ! ----------------
635      DO jk = 2, jpkm1
636         DO jj = 2, jpjm1
637            DO ji = fs_2, fs_jpim1   ! vector opt.
638               ! hydrostatic pressure gradient along s-surfaces
639               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
640                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
641                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
642               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
643                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
644                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
645               ! add to the general momentum trend
646               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
647               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
648            END DO
649         END DO
650      END DO
651      !
652      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
653      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
654      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
655      !
656   END SUBROUTINE hpg_djc
657
658
659   SUBROUTINE hpg_prj( kt )
660      !!---------------------------------------------------------------------
661      !!                  ***  ROUTINE hpg_prj  ***
662      !!
663      !! ** Method  :   s-coordinate case.
664      !!      A Pressure-Jacobian horizontal pressure gradient method
665      !!      based on the constrained cubic-spline interpolation for
666      !!      all vertical coordinate systems
667      !!
668      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
669      !!             - Save the trend (l_trddyn=T)
670      !!
671      !!----------------------------------------------------------------------
672      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
673      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
674      !!
675      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
676      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
677      !!
678      !! The local variables for the correction term
679      INTEGER  :: jk1, jis, jid, jjs, jjd
680      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
681      REAL(wp) :: zrhdt1
682      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
683      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
684      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
685      !!----------------------------------------------------------------------
686      !
687      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
688      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
689      !
690      IF( kt == nit000 ) THEN
691         IF(lwp) WRITE(numout,*)
692         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
693         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
694      ENDIF
695
696      !!----------------------------------------------------------------------
697      ! Local constant initialization
698      zcoef0 = - grav
699      znad = 0.0_wp
700      IF( lk_vvl ) znad = 1._wp
701
702      ! Clean 3-D work arrays
703      zhpi(:,:,:) = 0._wp
704      zrhh(:,:,:) = rhd(:,:,:)
705
706      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
707      DO jj = 1, jpj
708        DO ji = 1, jpi
709          jk = mbathy(ji,jj)
710          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
711          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
712          ELSE IF(jk < jpkm1) THEN
713             DO jkk = jk+1, jpk
714                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
715                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
716             END DO
717          ENDIF
718        END DO
719      END DO
720
721      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
722      DO jj = 1, jpj;   DO ji = 1, jpi
723          zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
724      END DO        ;   END DO
725
726      DO jk = 2, jpk;   DO jj = 1, jpj;   DO ji = 1, jpi
727          zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
728      END DO        ;   END DO        ;   END DO
729
730      fsp(:,:,:) = zrhh(:,:,:)
731      xsp(:,:,:) = zdept(:,:,:)
732
733      ! Construct the vertical density profile with the
734      ! constrained cubic spline interpolation
735      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
736      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
737
738      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
739      DO jj = 2, jpj
740        DO ji = 2, jpi
741          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
742                                         bsp(ji,jj,1),   csp(ji,jj,1), &
743                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
744
745          ! assuming linear profile across the top half surface layer
746          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
747        END DO
748      END DO
749
750      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
751      DO jk = 2, jpkm1
752        DO jj = 2, jpj
753          DO ji = 2, jpi
754            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
755                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
756                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
757                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
758          END DO
759        END DO
760      END DO
761
762      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
763      DO jj = 2, jpjm1
764        DO ji = 2, jpim1
765          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshu_n for ztilde compilation
766          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshv_n for ztilde compilation
767        END DO
768      END DO
769
770      DO jk = 2, jpkm1
771        DO jj = 2, jpjm1
772          DO ji = 2, jpim1
773            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
774            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
775          END DO
776        END DO
777      END DO
778
779      DO jk = 1, jpkm1
780        DO jj = 2, jpjm1
781          DO ji = 2, jpim1
782            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
783            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
784          END DO
785        END DO
786      END DO
787
788      DO jk = 1, jpkm1
789        DO jj = 2, jpjm1
790          DO ji = 2, jpim1
791            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
792            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
793            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
794            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
795          END DO
796        END DO
797      END DO
798
799
800      DO jk = 1, jpkm1
801        DO jj = 2, jpjm1
802          DO ji = 2, jpim1
803            zpwes = 0._wp; zpwed = 0._wp
804            zpnss = 0._wp; zpnsd = 0._wp
805            zuijk = zu(ji,jj,jk)
806            zvijk = zv(ji,jj,jk)
807
808            !!!!!     for u equation
809            IF( jk <= mbku(ji,jj) ) THEN
810               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
811                 jis = ji + 1; jid = ji
812               ELSE
813                 jis = ji;     jid = ji +1
814               ENDIF
815
816               ! integrate the pressure on the shallow side
817               jk1 = jk
818               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
819                 IF( jk1 == mbku(ji,jj) ) THEN
820                   zuijk = -zdept(jis,jj,jk1)
821                   EXIT
822                 ENDIF
823                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
824                 zpwes = zpwes +                                    &
825                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
826                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
827                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
828                 jk1 = jk1 + 1
829               END DO
830
831               ! integrate the pressure on the deep side
832               jk1 = jk
833               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
834                 IF( jk1 == 1 ) THEN
835                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
836                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
837                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
838                                                     dsp(jid,jj,1)) * zdeps
839                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
840                   EXIT
841                 ENDIF
842                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
843                 zpwed = zpwed +                                        &
844                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
845                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
846                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
847                 jk1 = jk1 - 1
848               END DO
849
850               ! update the momentum trends in u direction
851
852               zdpdx1 = zcoef0 * r1_e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
853               IF( lk_vvl ) THEN
854                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
855                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
856                ELSE
857                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
858               ENDIF
859
860               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
861               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
862!!gm above it is stupid:   umask is equal to the product of the 2 tmask that follows...
863            ENDIF
864
865            !!!!!     for v equation
866            IF( jk <= mbkv(ji,jj) ) THEN
867               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
868                 jjs = jj + 1; jjd = jj
869               ELSE
870                 jjs = jj    ; jjd = jj + 1
871               ENDIF
872
873               ! integrate the pressure on the shallow side
874               jk1 = jk
875               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
876                 IF( jk1 == mbkv(ji,jj) ) THEN
877                   zvijk = -zdept(ji,jjs,jk1)
878                   EXIT
879                 ENDIF
880                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
881                 zpnss = zpnss +                                      &
882                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
883                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
884                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
885                 jk1 = jk1 + 1
886               END DO
887
888               ! integrate the pressure on the deep side
889               jk1 = jk
890               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
891                 IF( jk1 == 1 ) THEN
892                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
893                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
894                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
895                                                     dsp(ji,jjd,1) ) * zdeps
896                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
897                   EXIT
898                 ENDIF
899                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
900                 zpnsd = zpnsd +                                        &
901                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
902                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
903                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
904                 jk1 = jk1 - 1
905               END DO
906
907
908               ! update the momentum trends in v direction
909
910               zdpdy1 = zcoef0 * r1_e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
911               IF( lk_vvl ) THEN
912                   zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
913                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
914               ELSE
915                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
916               ENDIF
917
918               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
919               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
920!!gm above it is stupid:   vmask is equal to the product of the 2 tmask that follows...
921            ENDIF
922
923
924           END DO
925        END DO
926      END DO
927      !
928      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
929      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
930      !
931   END SUBROUTINE hpg_prj
932
933
934   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
935      !!----------------------------------------------------------------------
936      !!                 ***  ROUTINE cspline  ***
937      !!
938      !! ** Purpose :   constrained cubic spline interpolation
939      !!
940      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
941      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
942      !!----------------------------------------------------------------------
943      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
944      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of the interpolated function
945      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
946      !                                                             ! 2: Linear
947      !
948      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
949      INTEGER  ::   jpi, jpj, jpkm1
950      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
951      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
952      REAL(wp) ::   zdf(size(fsp,3))
953      !!----------------------------------------------------------------------
954
955      jpi   = size(fsp,1)
956      jpj   = size(fsp,2)
957      jpkm1 = size(fsp,3) - 1
958
959
960      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
961         DO ji = 1, jpi
962            DO jj = 1, jpj
963           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
964           !    DO jk = 2, jpkm1-1
965           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
966           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
967           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
968           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
969           !
970           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
971           !
972           !       IF(zdf1 * zdf2 <= 0._wp) THEN
973           !           zdf(jk) = 0._wp
974           !       ELSE
975           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
976           !       ENDIF
977           !    END DO
978
979           !!Simply geometric average
980               DO jk = 2, jpkm1-1
981                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
982                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
983
984                  IF(zdf1 * zdf2 <= 0._wp) THEN
985                     zdf(jk) = 0._wp
986                  ELSE
987                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
988                  ENDIF
989               END DO
990
991               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
992                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
993               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
994                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
995                          & 0.5_wp * zdf(jpkm1 - 1)
996
997               DO jk = 1, jpkm1 - 1
998                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
999                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1000                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1001                 zddf1  = -2._wp * ztmp1 + ztmp2
1002                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1003                 zddf2  =  2._wp * ztmp1 - ztmp2
1004
1005                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1006                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1007                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1008                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1009                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1010                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1011                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1012                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1013                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1014               END DO
1015            END DO
1016         END DO
1017
1018      ELSE IF (polynomial_type == 2) THEN     ! Linear
1019         DO ji = 1, jpi
1020            DO jj = 1, jpj
1021               DO jk = 1, jpkm1-1
1022                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1023                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1024
1025                  dsp(ji,jj,jk) = 0._wp
1026                  csp(ji,jj,jk) = 0._wp
1027                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1028                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1029               END DO
1030            END DO
1031         END DO
1032
1033      ELSE
1034           CALL ctl_stop( 'invalid polynomial type in cspline' )
1035      ENDIF
1036      !
1037   END SUBROUTINE cspline
1038
1039
1040   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1041      !!----------------------------------------------------------------------
1042      !!                 ***  ROUTINE interp1  ***
1043      !!
1044      !! ** Purpose :   1-d linear interpolation
1045      !!
1046      !! ** Method  :
1047      !!                interpolation is straight forward
1048      !!                extrapolation is also permitted (no value limit)
1049      !!
1050      !!----------------------------------------------------------------------
1051      IMPLICIT NONE
1052      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1053      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1054      REAL(wp)             ::  zdeltx
1055      !!----------------------------------------------------------------------
1056
1057      zdeltx = xr - xl
1058      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1059        f = 0.5_wp * (fl + fr)
1060      ELSE
1061        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1062      ENDIF
1063
1064   END FUNCTION interp1
1065
1066
1067   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1068      !!----------------------------------------------------------------------
1069      !!                 ***  ROUTINE interp1  ***
1070      !!
1071      !! ** Purpose :   1-d constrained cubic spline interpolation
1072      !!
1073      !! ** Method  :  cubic spline interpolation
1074      !!
1075      !!----------------------------------------------------------------------
1076      IMPLICIT NONE
1077      REAL(wp), INTENT(in) ::  x, a, b, c, d
1078      REAL(wp)             ::  f ! value from the interpolation
1079      !!----------------------------------------------------------------------
1080
1081      f = a + x* ( b + x * ( c + d * x ) )
1082
1083   END FUNCTION interp2
1084
1085
1086   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1087      !!----------------------------------------------------------------------
1088      !!                 ***  ROUTINE interp1  ***
1089      !!
1090      !! ** Purpose :   Calculate the first order of deriavtive of
1091      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1092      !!
1093      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1094      !!
1095      !!----------------------------------------------------------------------
1096      IMPLICIT NONE
1097      REAL(wp), INTENT(in) ::  x, a, b, c, d
1098      REAL(wp)             ::  f ! value from the interpolation
1099      !!----------------------------------------------------------------------
1100
1101      f = b + x * ( 2._wp * c + 3._wp * d * x)
1102
1103   END FUNCTION interp3
1104
1105
1106   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1107      !!----------------------------------------------------------------------
1108      !!                 ***  ROUTINE interp1  ***
1109      !!
1110      !! ** Purpose :   1-d constrained cubic spline integration
1111      !!
1112      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1113      !!
1114      !!----------------------------------------------------------------------
1115      IMPLICIT NONE
1116      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1117      REAL(wp)             ::  za1, za2, za3
1118      REAL(wp)             ::  f                   ! integration result
1119      !!----------------------------------------------------------------------
1120
1121      za1 = 0.5_wp * b
1122      za2 = c / 3.0_wp
1123      za3 = 0.25_wp * d
1124
1125      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1126         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1127
1128   END FUNCTION integ_spline
1129
1130
1131   !!======================================================================
1132END MODULE dynhpg
1133
Note: See TracBrowser for help on using the repository browser.