source: branches/2015/dev_MetOffice_merge_2015/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 6010

Last change on this file since 6010 was 6010, checked in by timgraham, 5 years ago

Tidying of DIU code

  • Property svn:keywords set to Id
File size: 41.2 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_northcomms
31   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
32   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
34   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
35   !!----------------------------------------------------------------------
36
37   !!----------------------------------------------------------------------
38   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
39   !!   nemo_init      : initialization of the NEMO system
40   !!   nemo_ctl       : initialisation of the contol print
41   !!   nemo_closefile : close remaining open files
42   !!   nemo_alloc     : dynamical allocation
43   !!   nemo_partition : calculate MPP domain decomposition
44   !!   factorise      : calculate the factors of the no. of MPI processes
45   !!----------------------------------------------------------------------
46   USE step_oce        ! module used in the ocean time stepping module (step.F90)
47   USE domcfg          ! domain configuration               (dom_cfg routine)
48   USE mppini          ! shared/distributed memory setting (mpp_init routine)
49   USE domain          ! domain initialization             (dom_init routine)
50#if defined key_nemocice_decomp
51   USE ice_domain_size, only: nx_global, ny_global
52#endif
53   USE tideini         ! tidal components initialization   (tide_ini routine)
54   USE bdyini          ! open boundary cond. setting       (bdy_init routine)
55   USE bdydta          ! open boundary cond. setting   (bdy_dta_init routine)
56   USE bdytides        ! open boundary cond. setting   (bdytide_init routine)
57   USE istate          ! initial state setting          (istate_init routine)
58   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
59   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
60   USE zdfini          ! vertical physics setting          (zdf_init routine)
61   USE phycst          ! physical constant                  (par_cst routine)
62   USE trdini          ! dyn/tra trends initialization     (trd_init routine)
63   USE asminc          ! assimilation increments     
64   USE asmbkg          ! writing out state trajectory
65   USE diaptr          ! poleward transports           (dia_ptr_init routine)
66   USE diadct          ! sections transports           (dia_dct_init routine)
67   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
68   USE diacfl          ! CFL diagnostics               (dia_cfl_init routine)
69   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
70   USE step            ! NEMO time-stepping                 (stp     routine)
71   USE icbini          ! handle bergs, initialisation
72   USE icbstp          ! handle bergs, calving, themodynamics and transport
73   USE cpl_oasis3      ! OASIS3 coupling
74   USE c1d             ! 1D configuration
75   USE step_c1d        ! Time stepping loop for the 1D configuration
76   USE dyndmp          ! Momentum damping
77#if defined key_top
78   USE trcini          ! passive tracer initialisation
79#endif
80   USE lib_mpp         ! distributed memory computing
81   USE diurnal_bulk    ! diurnal bulk SST
82   USE stp_diu         ! diurnal bulk SST timestepping if run offline
83#if defined key_iomput
84   USE xios            ! xIOserver
85#endif
86   USE sbctide, ONLY   : lk_tide
87   USE crsini          ! initialise grid coarsening utility
88   USE lbcnfd , ONLY   : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
89   USE sbc_oce, ONLY   : lk_oasis
90   USE stopar
91   USE stopts
92
93   IMPLICIT NONE
94   PRIVATE
95
96   PUBLIC   nemo_gcm    ! called by model.F90
97   PUBLIC   nemo_init   ! needed by AGRIF
98   PUBLIC   nemo_alloc  ! needed by TAM
99
100   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
101
102   !!----------------------------------------------------------------------
103   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
104   !! $Id$
105   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
106   !!----------------------------------------------------------------------
107CONTAINS
108
109   SUBROUTINE nemo_gcm
110      !!----------------------------------------------------------------------
111      !!                     ***  ROUTINE nemo_gcm  ***
112      !!
113      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
114      !!              curvilinear mesh on the sphere.
115      !!
116      !! ** Method  : - model general initialization
117      !!              - launch the time-stepping (stp routine)
118      !!              - finalize the run by closing files and communications
119      !!
120      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
121      !!              Madec, 2008, internal report, IPSL.
122      !!----------------------------------------------------------------------
123      INTEGER ::   istp       ! time step index
124      !!----------------------------------------------------------------------
125      !
126#if defined key_agrif
127      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
128#endif
129
130      !                            !-----------------------!
131      CALL nemo_init               !==  Initialisations  ==!
132      !                            !-----------------------!
133#if defined key_agrif
134      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
135      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
136# if defined key_top
137      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
138# endif
139# if defined key_lim2
140      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
141# endif
142#endif
143      ! check that all process are still there... If some process have an error,
144      ! they will never enter in step and other processes will wait until the end of the cpu time!
145      IF( lk_mpp )   CALL mpp_max( nstop )
146
147      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
148
149      !                            !-----------------------!
150      !                            !==   time stepping   ==!
151      !                            !-----------------------!
152      istp = nit000
153#if defined key_c1d
154         DO WHILE ( istp <= nitend .AND. nstop == 0 )
155            CALL stp_c1d( istp )
156            istp = istp + 1
157         END DO
158#else
159          IF( lk_asminc ) THEN
160             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
161             IF( ln_asmdin ) THEN                        ! Direct initialization
162                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
163                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
164                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
165             ENDIF
166          ENDIF
167
168#if defined key_agrif
169          CALL Agrif_Regrid()
170#endif
171
172         DO WHILE ( istp <= nitend .AND. nstop == 0 )
173#if defined key_agrif
174            CALL stp                         ! AGRIF: time stepping
175#else
176            IF ( .NOT. ln_diurnal_only ) THEN
177               CALL stp( istp )                 ! standard time stepping
178            ELSE
179               CALL stp_diurnal( istp )        ! time step only the diurnal SST
180            ENDIF 
181#endif
182            istp = istp + 1
183            IF( lk_mpp )   CALL mpp_max( nstop )
184         END DO
185#endif
186
187      IF( ln_diaobs   )   CALL dia_obs_wri
188      !
189      IF( ln_icebergs )   CALL icb_end( nitend )
190
191      !                            !------------------------!
192      !                            !==  finalize the run  ==!
193      !                            !------------------------!
194      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
195      !
196      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
197         WRITE(numout,cform_err)
198         WRITE(numout,*) nstop, ' error have been found'
199      ENDIF
200      !
201#if defined key_agrif
202      IF( .NOT. Agrif_Root() ) THEN
203                         CALL Agrif_ParentGrid_To_ChildGrid()
204         IF( ln_diaobs ) CALL dia_obs_wri
205         IF( nn_timing == 1 )   CALL timing_finalize
206                                CALL Agrif_ChildGrid_To_ParentGrid()
207      ENDIF
208#endif
209      IF( nn_timing == 1 )   CALL timing_finalize
210      !
211      CALL nemo_closefile
212      !
213#if defined key_iomput
214      CALL xios_finalize                  ! end mpp communications with xios
215      IF( lk_oasis )   CALL cpl_finalize  ! end coupling and mpp communications with OASIS
216#else
217      IF( lk_oasis ) THEN
218         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
219      ELSE
220         IF( lk_mpp )   CALL mppstop    ! end mpp communications
221      ENDIF
222#endif
223      !
224   END SUBROUTINE nemo_gcm
225
226
227   SUBROUTINE nemo_init
228      !!----------------------------------------------------------------------
229      !!                     ***  ROUTINE nemo_init  ***
230      !!
231      !! ** Purpose :   initialization of the NEMO GCM
232      !!----------------------------------------------------------------------
233      INTEGER ::   ji            ! dummy loop indices
234      INTEGER ::   ilocal_comm   ! local integer
235      INTEGER ::   ios
236      CHARACTER(len=80), DIMENSION(16) ::   cltxt
237      !
238      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
239         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
240         &             nn_bench, nn_timing, nn_diacfl
241      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
242         &             jpizoom, jpjzoom, jperio, ln_use_jattr
243      !!----------------------------------------------------------------------
244      !
245      cltxt = ''
246      cxios_context = 'nemo'
247      !
248      !                             ! Open reference namelist and configuration namelist files
249      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
250      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
251      !
252      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
253      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
254901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
255
256      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
257      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
258902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
259
260      !
261      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
262      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
263903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
264
265      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
266      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
267904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
268
269! Force values for AGRIF zoom (cf. agrif_user.F90)
270#if defined key_agrif
271   IF( .NOT. Agrif_Root() ) THEN
272      jpiglo  = nbcellsx + 2 + 2*nbghostcells
273      jpjglo  = nbcellsy + 2 + 2*nbghostcells
274      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
275      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
276      jpidta  = jpiglo
277      jpjdta  = jpjglo
278      jpizoom = 1
279      jpjzoom = 1
280      nperio  = 0
281      jperio  = 0
282      ln_use_jattr = .false.
283   ENDIF
284#endif
285      !
286      !                             !--------------------------------------------!
287      !                             !  set communicator & select the local node  !
288      !                             !  NB: mynode also opens output.namelist.dyn !
289      !                             !      on unit number numond on first proc   !
290      !                             !--------------------------------------------!
291#if defined key_iomput
292      IF( Agrif_Root() ) THEN
293         IF( lk_oasis ) THEN
294            CALL cpl_init( "oceanx", ilocal_comm )                     ! nemo local communicator given by oasis
295            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
296         ELSE
297            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
298         ENDIF
299      ENDIF
300      ! Nodes selection (control print return in cltxt)
301      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
302#else
303      IF( lk_oasis ) THEN
304         IF( Agrif_Root() ) THEN
305            CALL cpl_init( "oceanx", ilocal_comm )                      ! nemo local communicator given by oasis
306         ENDIF
307         ! Nodes selection (control print return in cltxt)
308         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
309      ELSE
310         ilocal_comm = 0
311         ! Nodes selection (control print return in cltxt)
312         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
313      ENDIF
314#endif
315      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
316
317      lwm = (narea == 1)                                    ! control of output namelists
318      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
319
320      IF(lwm) THEN
321         ! write merged namelists from earlier to output namelist now that the
322         ! file has been opened in call to mynode. nammpp has already been
323         ! written in mynode (if lk_mpp_mpi)
324         WRITE( numond, namctl )
325         WRITE( numond, namcfg )
326      ENDIF
327
328      ! If dimensions of processor grid weren't specified in the namelist file
329      ! then we calculate them here now that we have our communicator size
330      IF( jpni < 1 .OR. jpnj < 1 ) THEN
331#if   defined key_mpp_mpi
332         IF( Agrif_Root() )   CALL nemo_partition( mppsize )
333#else
334         jpni  = 1
335         jpnj  = 1
336         jpnij = jpni*jpnj
337#endif
338      ENDIF
339
340      ! Calculate domain dimensions given calculated jpni and jpnj
341      ! This used to be done in par_oce.F90 when they were parameters rather than variables
342      IF( Agrif_Root() ) THEN
343#if defined key_nemocice_decomp
344         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
345         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
346#else
347         jpi = ( jpiglo     -2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
348         jpj = ( jpjglo     -2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
349#endif
350      ENDIF         
351         jpk = jpkdta                                             ! third dim
352#if defined key_agrif
353         ! simple trick to use same vertical grid as parent but different number of levels:
354         ! Save maximum number of levels in jpkdta, then define all vertical grids with this number.
355         ! Suppress once vertical online interpolation is ok
356         IF(.NOT.Agrif_Root())   jpkdta = Agrif_Parent( jpkdta )
357#endif
358         jpim1 = jpi-1                                            ! inner domain indices
359         jpjm1 = jpj-1                                            !   "           "
360         jpkm1 = jpk-1                                            !   "           "
361         jpij  = jpi*jpj                                          !  jpi x j
362
363      IF(lwp) THEN                            ! open listing units
364         !
365         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
366         !
367         WRITE(numout,*)
368         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
369         WRITE(numout,*) '                       NEMO team'
370         WRITE(numout,*) '            Ocean General Circulation Model'
371         WRITE(numout,*) '                  version 3.7  (2015) '
372         WRITE(numout,*)
373         WRITE(numout,*)
374         DO ji = 1, SIZE(cltxt)
375            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
376         END DO
377         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
378         !
379      ENDIF
380
381      ! Now we know the dimensions of the grid and numout has been set we can
382      ! allocate arrays
383      CALL nemo_alloc()
384
385      !                             !-------------------------------!
386      !                             !  NEMO general initialization  !
387      !                             !-------------------------------!
388
389      CALL nemo_ctl                          ! Control prints & Benchmark
390
391      !                                      ! Domain decomposition
392      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
393      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
394      ENDIF
395      !
396      IF( nn_timing == 1 )  CALL timing_init
397      !
398      !                                      ! General initialization
399                            CALL     phy_cst    ! Physical constants
400                            CALL     eos_init   ! Equation of state
401      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
402                            CALL     dom_cfg    ! Domain configuration
403                            CALL     dom_init   ! Domain
404      IF( ln_crs        )   CALL     crs_init   ! coarsened grid: domain initialization
405      IF( ln_nnogather )    CALL nemo_northcomms! northfold neighbour lists (must be done after the masks are defined)
406      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
407     
408      CALL diurnal_sst_bulk_init            ! diurnal sst
409      IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init   ! cool skin   
410     
411      ! IF ln_diurnal_only, then we only want a subset of the initialisation routines
412      IF ( ln_diurnal_only ) THEN
413         CALL  istate_init   ! ocean initial state (Dynamics and tracers)
414         CALL     sbc_init   ! Forcings : surface module
415         CALL tra_qsr_init   ! penetrative solar radiation qsr
416         IF( ln_diaobs     ) THEN                  ! Observation & model comparison
417            CALL dia_obs_init            ! Initialize observational data
418            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
419         ENDIF     
420         !                                     ! Assimilation increments
421         IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
422                 
423         IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
424         RETURN
425      ENDIF
426     
427                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
428
429      !                                      ! external forcing
430!!gm to be added : creation and call of sbc_apr_init
431      IF( lk_tide       )   CALL    tide_init( nit000 )    ! tidal harmonics
432                            CALL     sbc_init   ! surface boundary conditions (including sea-ice)
433!!gm ==>> bdy_init should call bdy_dta_init and bdytide_init  NOT in nemogcm !!!
434      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
435      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
436      IF( lk_bdy .AND. lk_tide )   &
437         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
438         
439      !                                      ! Ocean physics
440      !                                         ! Vertical physics
441                            CALL     zdf_init      ! namelist read
442                            CALL zdf_bfr_init      ! bottom friction
443      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
444      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
445      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
446      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
447      IF( lk_zdfddm     )   CALL zdf_ddm_init      ! double diffusive mixing
448         
449      !                                         ! Lateral physics
450                            CALL ldf_tra_init      ! Lateral ocean tracer physics
451                            CALL ldf_eiv_init      ! eddy induced velocity param.
452                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
453
454      !                                         ! Active tracers
455                            CALL tra_qsr_init      ! penetrative solar radiation qsr
456                            CALL tra_bbc_init      ! bottom heat flux
457      IF( lk_trabbl     )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
458                            CALL tra_dmp_init      ! internal tracer damping
459                            CALL tra_adv_init      ! horizontal & vertical advection
460                            CALL tra_ldf_init      ! lateral mixing
461                            CALL tra_zdf_init      ! vertical mixing and after tracer fields
462
463      !                                         ! Dynamics
464      IF( lk_c1d        )   CALL dyn_dmp_init      ! internal momentum damping
465                            CALL dyn_adv_init      ! advection (vector or flux form)
466                            CALL dyn_vor_init      ! vorticity term including Coriolis
467                            CALL dyn_ldf_init      ! lateral mixing
468                            CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
469                            CALL dyn_zdf_init      ! vertical diffusion
470                            CALL dyn_spg_init      ! surface pressure gradient
471
472#if defined key_top
473      !                                      ! Passive tracers
474                            CALL     trc_init
475#endif
476      IF( l_ldfslp      )   CALL ldf_slp_init   ! slope of lateral mixing
477
478      !                                      ! Icebergs
479                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
480
481      !                                      ! Misc. options
482                            CALL sto_par_init   ! Stochastic parametrization
483      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
484     
485      !                                      ! Diagnostics
486      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
487                            CALL dia_cfl_init   ! Initialise CFL diagnostics
488      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
489                            CALL dia_ptr_init   ! Poleward TRansports initialization
490      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
491                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
492                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
493                            CALL dia_obs_init            ! Initialize observational data
494      IF( ln_diaobs     )   CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
495
496      !                                         ! Assimilation increments
497      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
498      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
499      !
500   END SUBROUTINE nemo_init
501
502
503   SUBROUTINE nemo_ctl
504      !!----------------------------------------------------------------------
505      !!                     ***  ROUTINE nemo_ctl  ***
506      !!
507      !! ** Purpose :   control print setting
508      !!
509      !! ** Method  : - print namctl information and check some consistencies
510      !!----------------------------------------------------------------------
511      !
512      IF(lwp) THEN                  ! control print
513         WRITE(numout,*)
514         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
515         WRITE(numout,*) '~~~~~~~ '
516         WRITE(numout,*) '   Namelist namctl'
517         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
518         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
519         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
520         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
521         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
522         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
523         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
524         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
525         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
526         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
527      ENDIF
528      !
529      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
530      nictls    = nn_ictls
531      nictle    = nn_ictle
532      njctls    = nn_jctls
533      njctle    = nn_jctle
534      isplt     = nn_isplt
535      jsplt     = nn_jsplt
536      nbench    = nn_bench
537
538      IF(lwp) THEN                  ! control print
539         WRITE(numout,*)
540         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
541         WRITE(numout,*) '~~~~~~~ '
542         WRITE(numout,*) '   Namelist namcfg'
543         WRITE(numout,*) '      configuration name                               cp_cfg  = ', TRIM(cp_cfg)
544         WRITE(numout,*) '      configuration zoom name                          cp_cfz  = ', TRIM(cp_cfz)
545         WRITE(numout,*) '      configuration resolution                         jp_cfg  = ', jp_cfg
546         WRITE(numout,*) '      1st lateral dimension ( >= jpiglo )              jpidta  = ', jpidta
547         WRITE(numout,*) '      2nd    "         "    ( >= jpjglo )              jpjdta  = ', jpjdta
548         WRITE(numout,*) '      3nd    "         "                               jpkdta  = ', jpkdta
549         WRITE(numout,*) '      1st dimension of global domain in i              jpiglo  = ', jpiglo
550         WRITE(numout,*) '      2nd    -                  -    in j              jpjglo  = ', jpjglo
551         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
552         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
553         WRITE(numout,*) '      lateral cond. type (between 0 and 6)             jperio  = ', jperio   
554         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
555      ENDIF
556      !                             ! Parameter control
557      !
558      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
559         IF( lk_mpp .AND. jpnij > 1 ) THEN
560            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
561         ELSE
562            IF( isplt == 1 .AND. jsplt == 1  ) THEN
563               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
564                  &           ' - the print control will be done over the whole domain' )
565            ENDIF
566            ijsplt = isplt * jsplt            ! total number of processors ijsplt
567         ENDIF
568         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
569         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
570         !
571         !                              ! indices used for the SUM control
572         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
573            lsp_area = .FALSE.
574         ELSE                                             ! print control done over a specific  area
575            lsp_area = .TRUE.
576            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
577               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
578               nictls = 1
579            ENDIF
580            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
581               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
582               nictle = jpiglo
583            ENDIF
584            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
585               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
586               njctls = 1
587            ENDIF
588            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
589               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
590               njctle = jpjglo
591            ENDIF
592         ENDIF
593      ENDIF
594      !
595      IF( nbench == 1 ) THEN              ! Benchmark
596         SELECT CASE ( cp_cfg )
597         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
598         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
599            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
600         END SELECT
601      ENDIF
602      !
603      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
604         &                                               'f2003 standard. '                              ,  &
605         &                                               'Compile with key_nosignedzero enabled' )
606      !
607   END SUBROUTINE nemo_ctl
608
609
610   SUBROUTINE nemo_closefile
611      !!----------------------------------------------------------------------
612      !!                     ***  ROUTINE nemo_closefile  ***
613      !!
614      !! ** Purpose :   Close the files
615      !!----------------------------------------------------------------------
616      !
617      IF( lk_mpp )   CALL mppsync
618      !
619      CALL iom_close                                 ! close all input/output files managed by iom_*
620      !
621      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
622      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
623      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
624      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
625      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
626      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
627      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
628      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
629      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
630      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
631      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
632      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
633      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
634      !
635      numout = 6                                     ! redefine numout in case it is used after this point...
636      !
637   END SUBROUTINE nemo_closefile
638
639
640   SUBROUTINE nemo_alloc
641      !!----------------------------------------------------------------------
642      !!                     ***  ROUTINE nemo_alloc  ***
643      !!
644      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
645      !!
646      !! ** Method  :
647      !!----------------------------------------------------------------------
648      USE diawri    , ONLY: dia_wri_alloc
649      USE dom_oce   , ONLY: dom_oce_alloc
650      USE trc_oce   , ONLY: trc_oce_alloc
651#if defined key_diadct 
652      USE diadct    , ONLY: diadct_alloc 
653#endif 
654#if defined key_bdy
655      USE bdy_oce   , ONLY: bdy_oce_alloc
656#endif
657      !
658      INTEGER :: ierr
659      !!----------------------------------------------------------------------
660      !
661      ierr =        oce_alloc       ()          ! ocean
662      ierr = ierr + dia_wri_alloc   ()
663      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
664      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
665      !
666      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
667      !
668#if defined key_diadct 
669      ierr = ierr + diadct_alloc    ()          !
670#endif 
671#if defined key_bdy
672      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
673#endif
674      !
675      IF( lk_mpp    )   CALL mpp_sum( ierr )
676      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
677      !
678   END SUBROUTINE nemo_alloc
679
680
681   SUBROUTINE nemo_partition( num_pes )
682      !!----------------------------------------------------------------------
683      !!                 ***  ROUTINE nemo_partition  ***
684      !!
685      !! ** Purpose :
686      !!
687      !! ** Method  :
688      !!----------------------------------------------------------------------
689      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
690      !
691      INTEGER, PARAMETER :: nfactmax = 20
692      INTEGER :: nfact ! The no. of factors returned
693      INTEGER :: ierr  ! Error flag
694      INTEGER :: ji
695      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
696      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
697      !!----------------------------------------------------------------------
698      !
699      ierr = 0
700      !
701      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
702      !
703      IF( nfact <= 1 ) THEN
704         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
705         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
706         jpnj = 1
707         jpni = num_pes
708      ELSE
709         ! Search through factors for the pair that are closest in value
710         mindiff = 1000000
711         imin    = 1
712         DO ji = 1, nfact-1, 2
713            idiff = ABS( ifact(ji) - ifact(ji+1) )
714            IF( idiff < mindiff ) THEN
715               mindiff = idiff
716               imin = ji
717            ENDIF
718         END DO
719         jpnj = ifact(imin)
720         jpni = ifact(imin + 1)
721      ENDIF
722      !
723      jpnij = jpni*jpnj
724      !
725   END SUBROUTINE nemo_partition
726
727
728   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
729      !!----------------------------------------------------------------------
730      !!                     ***  ROUTINE factorise  ***
731      !!
732      !! ** Purpose :   return the prime factors of n.
733      !!                knfax factors are returned in array kfax which is of
734      !!                maximum dimension kmaxfax.
735      !! ** Method  :
736      !!----------------------------------------------------------------------
737      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
738      INTEGER                    , INTENT(  out) ::   kerr, knfax
739      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
740      !
741      INTEGER :: ifac, jl, inu
742      INTEGER, PARAMETER :: ntest = 14
743      INTEGER, DIMENSION(ntest) ::   ilfax
744      !!----------------------------------------------------------------------
745      !
746      ! lfax contains the set of allowed factors.
747      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
748      !
749      ! Clear the error flag and initialise output vars
750      kerr  = 0
751      kfax  = 1
752      knfax = 0
753      !
754      ! Find the factors of n.
755      IF( kn == 1 )   GOTO 20
756
757      ! nu holds the unfactorised part of the number.
758      ! knfax holds the number of factors found.
759      ! l points to the allowed factor list.
760      ! ifac holds the current factor.
761      !
762      inu   = kn
763      knfax = 0
764      !
765      DO jl = ntest, 1, -1
766         !
767         ifac = ilfax(jl)
768         IF( ifac > inu )   CYCLE
769
770         ! Test whether the factor will divide.
771
772         IF( MOD(inu,ifac) == 0 ) THEN
773            !
774            knfax = knfax + 1            ! Add the factor to the list
775            IF( knfax > kmaxfax ) THEN
776               kerr = 6
777               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
778               return
779            ENDIF
780            kfax(knfax) = ifac
781            ! Store the other factor that goes with this one
782            knfax = knfax + 1
783            kfax(knfax) = inu / ifac
784            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
785         ENDIF
786         !
787      END DO
788      !
789   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
790      !
791   END SUBROUTINE factorise
792
793#if defined key_mpp_mpi
794
795   SUBROUTINE nemo_northcomms
796      !!----------------------------------------------------------------------
797      !!                     ***  ROUTINE  nemo_northcomms  ***
798      !! ** Purpose :   Setup for north fold exchanges with explicit
799      !!                point-to-point messaging
800      !!
801      !! ** Method :   Initialization of the northern neighbours lists.
802      !!----------------------------------------------------------------------
803      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
804      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
805      !!----------------------------------------------------------------------
806      INTEGER  ::   sxM, dxM, sxT, dxT, jn
807      INTEGER  ::   njmppmax
808      !!----------------------------------------------------------------------
809      !
810      njmppmax = MAXVAL( njmppt )
811      !
812      !initializes the north-fold communication variables
813      isendto(:) = 0
814      nsndto     = 0
815      !
816      !if I am a process in the north
817      IF ( njmpp == njmppmax ) THEN
818          !sxM is the first point (in the global domain) needed to compute the
819          !north-fold for the current process
820          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
821          !dxM is the last point (in the global domain) needed to compute the
822          !north-fold for the current process
823          dxM = jpiglo - nimppt(narea) + 2
824
825          !loop over the other north-fold processes to find the processes
826          !managing the points belonging to the sxT-dxT range
827 
828          DO jn = 1, jpni
829                !sxT is the first point (in the global domain) of the jn
830                !process
831                sxT = nfiimpp(jn, jpnj)
832                !dxT is the last point (in the global domain) of the jn
833                !process
834                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
835                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
836                   nsndto = nsndto + 1
837                     isendto(nsndto) = jn
838                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
839                   nsndto = nsndto + 1
840                     isendto(nsndto) = jn
841                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
842                   nsndto = nsndto + 1
843                     isendto(nsndto) = jn
844                END IF
845          END DO
846          nfsloop = 1
847          nfeloop = nlci
848          DO jn = 2,jpni-1
849           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
850              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
851                 nfsloop = nldi
852              ENDIF
853              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
854                 nfeloop = nlei
855              ENDIF
856           ENDIF
857        END DO
858
859      ENDIF
860      l_north_nogather = .TRUE.
861   END SUBROUTINE nemo_northcomms
862
863#else
864   SUBROUTINE nemo_northcomms      ! Dummy routine
865      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
866   END SUBROUTINE nemo_northcomms
867#endif
868
869   !!======================================================================
870END MODULE nemogcm
871
Note: See TracBrowser for help on using the repository browser.