New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_crs.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso_crs.F90 @ 6101

Last change on this file since 6101 was 6101, checked in by cbricaud, 8 years ago

correction of bugs from last update and improvments for CRS
  • Property svn:executable set to *
File size: 16.3 KB
Line 
1MODULE traldf_iso_crs
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!            8.0  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!            1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!----------------------------------------------------------------------
12#if   defined key_ldfslp   ||   defined key_esopa
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
20   !!----------------------------------------------------------------------
21!   USE oce             ! ocean dynamics and active tracers
22!   USE dom_oce         ! ocean space and time domain
23!   USE trc_oce         ! share passive tracers/Ocean variables
24!   USE zdf_oce         ! ocean vertical physics
25!   USE ldftra_oce      ! ocean active tracers: lateral physics
26!   USE ldfslp          ! iso-neutral slopes
27   USE ldfslp_crs          ! iso-neutral slopes
28   USE diaptr          ! poleward transport diagnostics
29   USE in_out_manager  ! I/O manager
30   USE iom             ! I/O library
31#if defined key_diaar5
32   USE phycst          ! physical constants
33   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
34#endif
35   USE wrk_nemo        ! Memory Allocation
36   USE timing          ! Timing
37!   USE crs
38   USE oce_trc
39   USE iom, ONLY : iom_put,iom_swap
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   tra_ldf_iso_crs   ! routine called by step.F90
45
46   !! * Substitutions
47#  include "domzgr_substitute.h90"
48#  include "ldftra_substitute.h90"
49#  include "vectopt_loop_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
52   !! $Id: traldf_iso.F90 3294 2012-01-28 16:44:18Z rblod $
53   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
54   !!----------------------------------------------------------------------
55CONTAINS
56
57   SUBROUTINE tra_ldf_iso_crs( kt, kit000, cdtype, pgu, pgv,              &
58      &                                ptb, pta, kjpt, pahtb0 )
59      !!----------------------------------------------------------------------
60      !!                  ***  ROUTINE tra_ldf_iso  ***
61      !!
62      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
63      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
64      !!      add it to the general trend of tracer equation.
65      !!
66      !! ** Method  :   The horizontal component of the lateral diffusive trends
67      !!      is provided by a 2nd order operator rotated along neural or geopo-
68      !!      tential surfaces to which an eddy induced advection can be added
69      !!      It is computed using before fields (forward in time) and isopyc-
70      !!      nal or geopotential slopes computed in routine ldfslp.
71      !!
72      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
73      !!      ========    with partial cell update if ln_zps=T.
74      !!
75      !!      2nd part :  horizontal fluxes of the lateral mixing operator
76      !!      ========   
77      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
78      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
79      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
80      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
81      !!      take the horizontal divergence of the fluxes:
82      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
83      !!      Add this trend to the general trend (ta,sa):
84      !!         ta = ta + difft
85      !!
86      !!      3rd part: vertical trends of the lateral mixing operator
87      !!      ========  (excluding the vertical flux proportional to dk[t] )
88      !!      vertical fluxes associated with the rotated lateral mixing:
89      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
90      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
91      !!      take the horizontal divergence of the fluxes:
92      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
93      !!      Add this trend to the general trend (ta,sa):
94      !!         pta = pta + difft
95      !!
96      !! ** Action :   Update pta arrays with the before rotated diffusion
97      !!----------------------------------------------------------------------
98      !
99      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
100      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
101      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
102      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
103      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
104      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
105      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
106      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
107      !
108      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
109      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
110      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
111      REAL(wp) ::  zcoef0, zbtr, ztra            !   -      -
112#if defined key_diaar5
113      REAL(wp)                         ::   zztmp               ! local scalar
114#endif
115      REAL(wp), POINTER, DIMENSION(:,:  ) ::  zdkt, zdk1t, z2d
116      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zdit, zdjt, ztfw , zftu,  zftv 
117      !!----------------------------------------------------------------------
118      !
119      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso')
120      !
121      CALL wrk_alloc( jpi, jpj,      zdkt, zdk1t, z2d ) 
122      CALL wrk_alloc( jpi, jpj, jpk, zdit, zdjt, ztfw , zftu, zftv ) 
123      !
124
125      IF( kt == kit000 )  THEN
126         IF(lwp) WRITE(numout,*)
127         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
128         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
129      ENDIF
130      !
131      !                                                          ! ===========
132      DO jn = 1, kjpt                                            ! tracer loop
133         !                                                       ! ===========
134         !                                               
135         !!----------------------------------------------------------------------
136         !!   I - masked horizontal derivative
137         !!----------------------------------------------------------------------
138         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
139         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
140         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
141         !!end
142
143         ! Horizontal tracer gradient
144         DO jk = 1, jpkm1
145            DO jj = 1, jpjm1
146               DO ji = 1, fs_jpim1   ! vector opt.
147                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask_crs(ji,jj,jk)
148                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask_crs(ji,jj,jk)
149               END DO
150            END DO
151         END DO
152         IF( ln_zps ) THEN      ! partial steps correction at the last ocean level
153            DO jj = 1, jpjm1
154               DO ji = 1, fs_jpim1   ! vector opt.
155                  zdit(ji,jj,mbku_crs(ji,jj)) = pgu(ji,jj,jn)         
156                  zdjt(ji,jj,mbkv_crs(ji,jj)) = pgv(ji,jj,jn)     
157               END DO
158            END DO
159         ENDIF
160
161         !!----------------------------------------------------------------------
162         !!   II - horizontal trend  (full)
163         !!----------------------------------------------------------------------
164!CDIR PARALLEL DO PRIVATE( zdk1t )
165         !                                                ! ===============
166         DO jk = 1, jpkm1                                 ! Horizontal slab
167            !                                             ! ===============
168            ! 1. Vertical tracer gradient at level jk and jk+1
169            ! ------------------------------------------------
170            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
171            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask_crs(:,:,jk+1)
172            !
173            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)
174            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask_crs(:,:,jk)
175            ENDIF
176
177            ! 2. Horizontal fluxes
178            ! --------------------   
179            DO jj = 1 , jpjm1
180               DO ji = 1, fs_jpim1   ! vector opt.
181                  zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * e2e3u_msk(ji,jj,jk) / e1u_crs(ji,jj)
182                  zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * e1e3v_msk(ji,jj,jk) / e2v_crs(ji,jj)
183
184                  zmsku = 1. / MAX(  tmask_crs(ji+1,jj,jk  ) + tmask_crs(ji,jj,jk+1)   &
185                     &             + tmask_crs(ji+1,jj,jk+1) + tmask_crs(ji,jj,jk  ), 1. )
186                  !
187                  zmskv = 1. / MAX(  tmask_crs(ji,jj+1,jk  ) + tmask_crs(ji,jj,jk+1)   &
188                     &             + tmask_crs(ji,jj+1,jk+1) + tmask_crs(ji,jj,jk  ), 1. )
189                  !
190                  zcof1 = - fsahtu(ji,jj,jk) * e2e3u_msk(ji,jj,jk) * uslp_crs(ji,jj,jk) * zmsku / MAX( 1._wp , e3u_max_crs(ji,jj,jk))
191                  zcof2 = - fsahtv(ji,jj,jk) * e1e3v_msk(ji,jj,jk) * vslp_crs(ji,jj,jk) * zmskv / MAX( 1._wp , e3v_max_crs(ji,jj,jk))
192                  !
193                  zftu(ji,jj,jk ) = ( zabe1 * zdit(ji,jj,jk)   &
194                     &              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
195                     &                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask_crs(ji,jj,jk)
196                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
197                     &              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
198                     &                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask_crs(ji,jj,jk)                 
199               END DO
200            END DO
201            CALL iom_swap( "nemo_crs"  )
202            CALL iom_put( "zftu" , zftu )
203            CALL iom_put( "zftv" , zftv )
204            CALL iom_swap( "nemo" )
205
206            ! II.4 Second derivative (divergence) and add to the general trend
207            ! ----------------------------------------------------------------
208            DO jj = 2 , jpjm1
209               DO ji = fs_2, fs_jpim1   ! vector opt.
210                  zbtr = r1_bt_crs(ji,jj,jk)
211                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
212                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
213
214               END DO
215            END DO
216            !                                          ! ===============
217         END DO                                        !   End of slab 
218         !                                             ! ===============
219         !
220         ! "Poleward" diffusive heat or salt transports (T-S case only)
221         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN
222            IF( jn == jp_tem)   htr_ldf(:) = ptr_sj( zftv(:,:,:) )
223            IF( jn == jp_sal)   str_ldf(:) = ptr_sj( zftv(:,:,:) )
224         ENDIF
225 
226#if defined key_diaar5
227         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
228            z2d(:,:) = 0._wp 
229            zztmp = rau0 * rcp 
230            DO jk = 1, jpkm1
231               DO jj = 2, jpjm1
232                  DO ji = fs_2, fs_jpim1   ! vector opt.
233                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
234                  END DO
235               END DO
236            END DO
237            z2d(:,:) = zztmp * z2d(:,:)
238            CALL crs_lbc_lnk( z2d, 'U', -1. )
239         !   CALL crs_iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
240            z2d(:,:) = 0._wp 
241            DO jk = 1, jpkm1
242               DO jj = 2, jpjm1
243                  DO ji = fs_2, fs_jpim1   ! vector opt.
244                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
245                  END DO
246               END DO
247            END DO
248            z2d(:,:) = zztmp * z2d(:,:)
249            CALL crs_lbc_lnk( z2d, 'V', -1. )
250            ! CALL crs_iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
251         END IF
252#endif
253
254         !!----------------------------------------------------------------------
255         !!   III - vertical trend of T & S (extra diagonal terms only)
256         !!----------------------------------------------------------------------
257         
258         ! Local constant initialization
259         ! -----------------------------
260         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
261         
262         ! Vertical fluxes
263         ! ---------------
264         
265         ! Surface and bottom vertical fluxes set to zero
266         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
267         
268         ! interior (2=<jk=<jpk-1)
269         DO jk = 2, jpkm1
270            DO jj = 2, jpjm1
271               DO ji = fs_2, fs_jpim1   ! vector opt.
272                  zcoef0 = - fsahtw(ji,jj,jk) * tmask_crs(ji,jj,jk)
273                  !
274                  zmsku = 1./MAX(   umask_crs(ji  ,jj,jk-1) + umask_crs(ji-1,jj,jk)      &
275                     &            + umask_crs(ji-1,jj,jk-1) + umask_crs(ji  ,jj,jk), 1.  )
276                  zmskv = 1./MAX(   vmask_crs(ji,jj  ,jk-1) + vmask_crs(ji,jj-1,jk)      &
277                     &            + vmask_crs(ji,jj-1,jk-1) + vmask_crs(ji,jj  ,jk), 1.  )
278                  !
279                  zcoef3 = zcoef0 * e1e2w_crs(ji,jj,jk) * zmsku * wslpi_crs(ji,jj,jk) / e1t_crs(ji,jj)
280                  zcoef4 = zcoef0 * e1e2w_crs(ji,jj,jk) * zmskv * wslpj_crs(ji,jj,jk) / e2t_crs(ji,jj)
281                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
282                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
283                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
284                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
285               END DO
286            END DO
287         END DO
288         
289         
290         ! I.5 Divergence of vertical fluxes added to the general tracer trend
291         ! -------------------------------------------------------------------
292         DO jk = 1, jpkm1
293            DO jj = 2, jpjm1
294               DO ji = fs_2, fs_jpim1   ! vector opt.
295                  zbtr = r1_bt_crs(ji,jj,jk)
296                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
297                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
298
299               END DO
300            END DO
301         END DO
302         !
303      END DO
304      !
305      CALL wrk_dealloc( jpi, jpj,      zdkt, zdk1t, z2d ) 
306      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt, ztfw , zftu, zftv ) 
307      !
308      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso')
309      !
310   END SUBROUTINE tra_ldf_iso_crs
311
312#else
313   !!----------------------------------------------------------------------
314   !!   default option :   Dummy code   NO rotation of the diffusive tensor
315   !!----------------------------------------------------------------------
316CONTAINS
317   SUBROUTINE tra_ldf_iso_crs( kt, kit000,cdtype, pgu, pgv, ptb, pta, kjpt, pahtb0 )      ! Empty routine
318      INTEGER:: kt, kit000
319      CHARACTER(len=3) ::   cdtype
320      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
321      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
322      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt, kit000, cdtype,   &
323         &                       pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
324   END SUBROUTINE tra_ldf_iso_crs
325#endif
326
327   !!==============================================================================
328END MODULE traldf_iso_crs
Note: See TracBrowser for help on using the repository browser.