| 1 | MODULE step |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE step *** |
|---|
| 4 | !! Time-stepping : manager of the ocean, tracer and ice time stepping |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1991-03 (G. Madec) Original code |
|---|
| 7 | !! - ! 1991-11 (G. Madec) |
|---|
| 8 | !! - ! 1992-06 (M. Imbard) add a first output record |
|---|
| 9 | !! - ! 1996-04 (G. Madec) introduction of dynspg |
|---|
| 10 | !! - ! 1996-04 (M.A. Foujols) introduction of passive tracer |
|---|
| 11 | !! 8.0 ! 1997-06 (G. Madec) new architecture of call |
|---|
| 12 | !! 8.2 ! 1997-06 (G. Madec, M. Imbard, G. Roullet) free surface |
|---|
| 13 | !! - ! 1999-02 (G. Madec, N. Grima) hpg implicit |
|---|
| 14 | !! - ! 2000-07 (J-M Molines, M. Imbard) Open Bondary Conditions |
|---|
| 15 | !! NEMO 1.0 ! 2002-06 (G. Madec) free form, suppress macro-tasking |
|---|
| 16 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 17 | !! - ! 2005-01 (C. Ethe) Add the KPP closure scheme |
|---|
| 18 | !! - ! 2005-11 (G. Madec) Reorganisation of tra and dyn calls |
|---|
| 19 | !! - ! 2006-01 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 20 | !! - ! 2006-07 (S. Masson) restart using iom |
|---|
| 21 | !! 3.2 ! 2009-02 (G. Madec, R. Benshila) reintroduicing z*-coordinate |
|---|
| 22 | !! - ! 2009-06 (S. Masson, G. Madec) TKE restart compatible with key_cpl |
|---|
| 23 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 24 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA |
|---|
| 25 | !! 3.4 ! 2011-04 (G. Madec, C. Ethe) Merge of dtatem and dtasal |
|---|
| 26 | !! ! 2012-07 (J. Simeon, G. Madec, C. Ethe) Online coarsening of outputs |
|---|
| 27 | !! 3.7 ! 2014-04 (F. Roquet, G. Madec) New equations of state |
|---|
| 28 | !!---------------------------------------------------------------------- |
|---|
| 29 | |
|---|
| 30 | !!---------------------------------------------------------------------- |
|---|
| 31 | !! stp : OPA system time-stepping |
|---|
| 32 | !!---------------------------------------------------------------------- |
|---|
| 33 | USE step_oce ! time stepping definition modules |
|---|
| 34 | USE iom |
|---|
| 35 | USE crs |
|---|
| 36 | |
|---|
| 37 | IMPLICIT NONE |
|---|
| 38 | PRIVATE |
|---|
| 39 | |
|---|
| 40 | PUBLIC stp ! called by opa.F90 |
|---|
| 41 | |
|---|
| 42 | !! * Substitutions |
|---|
| 43 | # include "domzgr_substitute.h90" |
|---|
| 44 | !!gm # include "zdfddm_substitute.h90" |
|---|
| 45 | !!---------------------------------------------------------------------- |
|---|
| 46 | !! NEMO/OPA 3.7 , NEMO Consortium (2014) |
|---|
| 47 | !! $Id$ |
|---|
| 48 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | CONTAINS |
|---|
| 51 | |
|---|
| 52 | #if defined key_agrif |
|---|
| 53 | SUBROUTINE stp( ) |
|---|
| 54 | INTEGER :: kstp ! ocean time-step index |
|---|
| 55 | #else |
|---|
| 56 | SUBROUTINE stp( kstp ) |
|---|
| 57 | INTEGER, INTENT(in) :: kstp ! ocean time-step index |
|---|
| 58 | #endif |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | !! *** ROUTINE stp *** |
|---|
| 61 | !! |
|---|
| 62 | !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.) |
|---|
| 63 | !! - Time stepping of LIM (dynamic and thermodynamic eqs.) |
|---|
| 64 | !! - Tme stepping of TRC (passive tracer eqs.) |
|---|
| 65 | !! |
|---|
| 66 | !! ** Method : -1- Update forcings and data |
|---|
| 67 | !! -2- Update ocean physics |
|---|
| 68 | !! -3- Compute the t and s trends |
|---|
| 69 | !! -4- Update t and s |
|---|
| 70 | !! -5- Compute the momentum trends |
|---|
| 71 | !! -6- Update the horizontal velocity |
|---|
| 72 | !! -7- Compute the diagnostics variables (rd,N2, div,cur,w) |
|---|
| 73 | !! -8- Outputs and diagnostics |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | INTEGER :: jk ! dummy loop indice |
|---|
| 76 | INTEGER :: indic ! error indicator if < 0 |
|---|
| 77 | INTEGER :: kcall ! optional integer argument (dom_vvl_sf_nxt) |
|---|
| 78 | !! --------------------------------------------------------------------- |
|---|
| 79 | |
|---|
| 80 | #if defined key_agrif |
|---|
| 81 | kstp = nit000 + Agrif_Nb_Step() |
|---|
| 82 | ! IF ( Agrif_Root() .and. lwp) Write(*,*) '---' |
|---|
| 83 | ! IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp |
|---|
| 84 | IF ( kstp == (nit000 + 1) ) lk_agrif_fstep = .FALSE. |
|---|
| 85 | # if defined key_iomput |
|---|
| 86 | IF( Agrif_Nbstepint() == 0 ) CALL iom_swap( cxios_context ) |
|---|
| 87 | # endif |
|---|
| 88 | #endif |
|---|
| 89 | indic = 0 ! reset to no error condition |
|---|
| 90 | IF( kstp == nit000 ) THEN |
|---|
| 91 | ! must be done after nemo_init for AGRIF+XIOS+OASIS |
|---|
| 92 | CALL iom_init( cxios_context ) ! iom_put initialization |
|---|
| 93 | IF( ln_crs ) CALL iom_init( TRIM(cxios_context)//"_crs" ) ! initialize context for coarse grid |
|---|
| 94 | ENDIF |
|---|
| 95 | |
|---|
| 96 | IF( kstp /= nit000 ) CALL day( kstp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 97 | CALL iom_setkt( kstp - nit000 + 1, cxios_context ) ! tell iom we are at time step kstp |
|---|
| 98 | IF( ln_crs ) CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" ) ! tell iom we are at time step kstp |
|---|
| 99 | |
|---|
| 100 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 101 | ! Update data, open boundaries, surface boundary condition (including sea-ice) |
|---|
| 102 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 103 | IF( lk_tide ) CALL sbc_tide( kstp ) |
|---|
| 104 | IF( lk_bdy ) THEN |
|---|
| 105 | IF( ln_apr_dyn) CALL sbc_apr( kstp ) ! bdy_dta needs ssh_ib |
|---|
| 106 | CALL bdy_dta ( kstp, time_offset=+1 ) ! update dynamic & tracer data at open boundaries |
|---|
| 107 | ENDIF |
|---|
| 108 | CALL sbc ( kstp ) ! Sea Boundary Condition (including sea-ice) |
|---|
| 109 | ! clem: moved here for bdy ice purpose |
|---|
| 110 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 111 | ! Update stochastic parameters and random T/S fluctuations |
|---|
| 112 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 113 | CALL sto_par( kstp ) ! Stochastic parameters |
|---|
| 114 | |
|---|
| 115 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 116 | ! Ocean physics update (ua, va, tsa used as workspace) |
|---|
| 117 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 118 | ! THERMODYNAMICS |
|---|
| 119 | !cbr not used CALL eos_rab( tsb, rab_b ) ! before local thermal/haline expension ratio at T-points |
|---|
| 120 | !cbr not used CALL eos_rab( tsn, rab_n ) ! now local thermal/haline expension ratio at T-points |
|---|
| 121 | CALL bn2 ( tsb, rab_b, rn2b ) ! before Brunt-Vaisala frequency |
|---|
| 122 | CALL bn2 ( tsn, rab_n, rn2 ) ! now Brunt-Vaisala frequency |
|---|
| 123 | ! |
|---|
| 124 | ! VERTICAL PHYSICS |
|---|
| 125 | CALL zdf_bfr( kstp ) ! bottom friction (if quadratic) |
|---|
| 126 | ! ! Vertical eddy viscosity and diffusivity coefficients |
|---|
| 127 | IF( lk_zdfric ) CALL zdf_ric( kstp ) ! Richardson number dependent Kz |
|---|
| 128 | IF( lk_zdftke ) CALL zdf_tke( kstp ) ! TKE closure scheme for Kz |
|---|
| 129 | IF( lk_zdfgls ) CALL zdf_gls( kstp ) ! GLS closure scheme for Kz |
|---|
| 130 | IF( lk_zdfkpp ) CALL zdf_kpp( kstp ) ! KPP closure scheme for Kz |
|---|
| 131 | IF( lk_zdfcst ) THEN ! Constant Kz (reset avt, avm[uv] to the background value) |
|---|
| 132 | avt (:,:,:) = rn_avt0 * wmask (:,:,:) |
|---|
| 133 | avmu(:,:,:) = rn_avm0 * wumask(:,:,:) |
|---|
| 134 | avmv(:,:,:) = rn_avm0 * wvmask(:,:,:) |
|---|
| 135 | ENDIF |
|---|
| 136 | IF( ln_rnf_mouth ) THEN ! increase diffusivity at rivers mouths |
|---|
| 137 | DO jk = 2, nkrnf ; avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk) ; END DO |
|---|
| 138 | ENDIF |
|---|
| 139 | IF( ln_zdfevd ) CALL zdf_evd( kstp ) ! enhanced vertical eddy diffusivity |
|---|
| 140 | |
|---|
| 141 | IF( lk_zdftmx ) CALL zdf_tmx( kstp ) ! tidal vertical mixing |
|---|
| 142 | |
|---|
| 143 | IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) & |
|---|
| 144 | & CALL zdf_ddm( kstp ) ! double diffusive mixing |
|---|
| 145 | |
|---|
| 146 | CALL zdf_mxl( kstp ) ! mixed layer depth |
|---|
| 147 | |
|---|
| 148 | ! write TKE or GLS information in the restart file |
|---|
| 149 | IF( lrst_oce .AND. lk_zdftke ) CALL tke_rst( kstp, 'WRITE' ) |
|---|
| 150 | IF( lrst_oce .AND. lk_zdfgls ) CALL gls_rst( kstp, 'WRITE' ) |
|---|
| 151 | ! |
|---|
| 152 | ! LATERAL PHYSICS |
|---|
| 153 | ! |
|---|
| 154 | IF( lk_ldfslp ) THEN ! slope of lateral mixing |
|---|
| 155 | IF(ln_sto_eos ) CALL sto_pts( tsn ) ! Random T/S fluctuations |
|---|
| 156 | CALL eos( tsb, rhd, gdept_0(:,:,:) ) ! before in situ density |
|---|
| 157 | IF( ln_zps .AND. .NOT. ln_isfcav) & |
|---|
| 158 | & CALL zps_hde ( kstp, jpts, tsb, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 159 | & rhd, gru , grv ) ! of t, s, rd at the last ocean level |
|---|
| 160 | IF( ln_zps .AND. ln_isfcav) & |
|---|
| 161 | & CALL zps_hde_isf( kstp, jpts, tsb, gtsu, gtsv, & ! Partial steps for top cell (ISF) |
|---|
| 162 | & rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv , & |
|---|
| 163 | & gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi ) ! of t, s, rd at the first ocean level |
|---|
| 164 | IF( ln_traldf_grif ) THEN ! before slope for Griffies operator |
|---|
| 165 | CALL ldf_slp_grif( kstp ) |
|---|
| 166 | ELSE |
|---|
| 167 | CALL iom_put("rabt",rab_n(:,:,:,jp_tem)) |
|---|
| 168 | CALL iom_put("rabs",rab_n(:,:,:,jp_sal)) |
|---|
| 169 | CALL iom_put("rhd",rhd) |
|---|
| 170 | CALL iom_put("rn2b",rn2b) |
|---|
| 171 | CALL ldf_slp( kstp, rhd, rn2b ) ! before slope for Madec operator |
|---|
| 172 | ENDIF |
|---|
| 173 | ENDIF |
|---|
| 174 | #if defined key_traldf_c2d |
|---|
| 175 | IF( lk_traldf_eiv ) CALL ldf_eiv( kstp ) ! eddy induced velocity coefficient |
|---|
| 176 | #endif |
|---|
| 177 | #if defined key_traldf_c3d && defined key_traldf_smag |
|---|
| 178 | CALL ldf_tra_smag( kstp ) ! eddy induced velocity coefficient |
|---|
| 179 | # endif |
|---|
| 180 | #if defined key_dynldf_c3d && defined key_dynldf_smag |
|---|
| 181 | CALL ldf_dyn_smag( kstp ) ! eddy induced velocity coefficient |
|---|
| 182 | # endif |
|---|
| 183 | |
|---|
| 184 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 185 | ! Ocean dynamics : hdiv, rot, ssh, e3, wn |
|---|
| 186 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 187 | CALL ssh_nxt ( kstp ) ! after ssh (includes call to div_cur) |
|---|
| 188 | IF( lk_vvl ) CALL dom_vvl_sf_nxt( kstp ) ! after vertical scale factors |
|---|
| 189 | CALL wzv ( kstp ) ! now cross-level velocity |
|---|
| 190 | |
|---|
| 191 | IF( lk_dynspg_ts ) THEN |
|---|
| 192 | ! In case the time splitting case, update almost all momentum trends here: |
|---|
| 193 | ! Note that the computation of vertical velocity above, hence "after" sea level |
|---|
| 194 | ! is necessary to compute momentum advection for the rhs of barotropic loop: |
|---|
| 195 | IF(ln_sto_eos ) CALL sto_pts( tsn ) ! Random T/S fluctuations |
|---|
| 196 | CALL eos ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation |
|---|
| 197 | IF( ln_zps .AND. .NOT. ln_isfcav) & |
|---|
| 198 | & CALL zps_hde ( kstp, jpts, tsn, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 199 | & rhd, gru , grv ) ! of t, s, rd at the last ocean level |
|---|
| 200 | IF( ln_zps .AND. ln_isfcav) & |
|---|
| 201 | & CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv, & ! Partial steps for top cell (ISF) |
|---|
| 202 | & rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv , & |
|---|
| 203 | & gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi ) ! of t, s, rd at the last ocean level |
|---|
| 204 | |
|---|
| 205 | ua(:,:,:) = 0.e0 ! set dynamics trends to zero |
|---|
| 206 | va(:,:,:) = 0.e0 |
|---|
| 207 | IF( ln_asmiau .AND. & |
|---|
| 208 | & ln_dyninc ) CALL dyn_asm_inc ( kstp ) ! apply dynamics assimilation increment |
|---|
| 209 | IF( ln_neptsimp ) CALL dyn_nept_cor ( kstp ) ! subtract Neptune velocities (simplified) |
|---|
| 210 | IF( lk_bdy ) CALL bdy_dyn3d_dmp( kstp ) ! bdy damping trends |
|---|
| 211 | CALL dyn_adv ( kstp ) ! advection (vector or flux form) |
|---|
| 212 | CALL dyn_vor ( kstp ) ! vorticity term including Coriolis |
|---|
| 213 | CALL dyn_ldf ( kstp ) ! lateral mixing |
|---|
| 214 | IF( ln_neptsimp ) CALL dyn_nept_cor ( kstp ) ! add Neptune velocities (simplified) |
|---|
| 215 | #if defined key_agrif |
|---|
| 216 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn ! momentum sponge |
|---|
| 217 | #endif |
|---|
| 218 | CALL dyn_hpg( kstp ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 219 | CALL dyn_spg( kstp, indic ) ! surface pressure gradient |
|---|
| 220 | |
|---|
| 221 | ua_sv(:,:,:) = ua(:,:,:) ! Save trends (barotropic trend has been fully updated at this stage) |
|---|
| 222 | va_sv(:,:,:) = va(:,:,:) |
|---|
| 223 | |
|---|
| 224 | CALL div_cur( kstp ) ! Horizontal divergence & Relative vorticity (2nd call in time-split case) |
|---|
| 225 | IF( lk_vvl ) CALL dom_vvl_sf_nxt( kstp, kcall=2 ) ! after vertical scale factors (update depth average component) |
|---|
| 226 | CALL wzv ( kstp ) ! now cross-level velocity |
|---|
| 227 | ENDIF |
|---|
| 228 | |
|---|
| 229 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 230 | ! diagnostics and outputs (ua, va, tsa used as workspace) |
|---|
| 231 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 232 | IF( lk_floats ) CALL flo_stp( kstp ) ! drifting Floats |
|---|
| 233 | IF( lk_diahth ) CALL dia_hth( kstp ) ! Thermocline depth (20 degres isotherm depth) |
|---|
| 234 | IF( .NOT. ln_cpl ) CALL dia_fwb( kstp ) ! Fresh water budget diagnostics |
|---|
| 235 | IF( lk_diadct ) CALL dia_dct( kstp ) ! Transports |
|---|
| 236 | IF( lk_diaar5 ) CALL dia_ar5( kstp ) ! ar5 diag |
|---|
| 237 | IF( lk_diaharm ) CALL dia_harm( kstp ) ! Tidal harmonic analysis |
|---|
| 238 | CALL dia_wri( kstp ) ! ocean model: outputs |
|---|
| 239 | ! |
|---|
| 240 | IF( ln_crs ) CALL crs_fld( kstp ) ! ocean model: online field coarsening & output |
|---|
| 241 | |
|---|
| 242 | #if defined key_top |
|---|
| 243 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 244 | ! Passive Tracer Model |
|---|
| 245 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 246 | IF( ln_crs ) THEN |
|---|
| 247 | CALL dom_grid_crs |
|---|
| 248 | |
|---|
| 249 | CALL eos_rab_crs( tsn_crs, rab_crs_n ) ! now local thermal/haline expension ratio at T-points |
|---|
| 250 | CALL bn2_crs ( tsn_crs, rab_crs_n, rb2_crs ) ! now Brunt-Vaisala frequency |
|---|
| 251 | CALL eos_crs ( tsn_crs, rhd_crs, rhop_crs, gdept_crs(:,:,:) ) ! now in situ density for hpg computation |
|---|
| 252 | |
|---|
| 253 | IF( ln_zps ) CALL zps_hde_crs( kstp, jpts, tsb_crs, gtsu_crs, gtsv_crs, rhd_crs, gru_crs, grv_crs ) |
|---|
| 254 | |
|---|
| 255 | IF( lk_ldfslp .AND. .NOT. ln_traldf_grif ) & |
|---|
| 256 | CALL ldf_slp_crs( kstp, rhd_crs, rb2_crs ) |
|---|
| 257 | CALL dom_grid_glo |
|---|
| 258 | |
|---|
| 259 | ENDIF |
|---|
| 260 | CALL zdf_mxl_crs(kstp) |
|---|
| 261 | |
|---|
| 262 | IF( ln_crs_top ) CALL dom_grid_crs |
|---|
| 263 | |
|---|
| 264 | CALL trc_stp( kstp ) ! time-stepping |
|---|
| 265 | |
|---|
| 266 | IF( ln_crs_top ) CALL dom_grid_glo |
|---|
| 267 | #endif |
|---|
| 268 | |
|---|
| 269 | |
|---|
| 270 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 271 | ! Active tracers (ua, va used as workspace) |
|---|
| 272 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 273 | tsa(:,:,:,:) = 0.e0 ! set tracer trends to zero |
|---|
| 274 | |
|---|
| 275 | IF( ln_asmiau .AND. & |
|---|
| 276 | & ln_trainc ) CALL tra_asm_inc( kstp ) ! apply tracer assimilation increment |
|---|
| 277 | CALL tra_sbc ( kstp ) ! surface boundary condition |
|---|
| 278 | IF( ln_traqsr ) CALL tra_qsr ( kstp ) ! penetrative solar radiation qsr |
|---|
| 279 | IF( ln_trabbc ) CALL tra_bbc ( kstp ) ! bottom heat flux |
|---|
| 280 | IF( lk_trabbl ) CALL tra_bbl ( kstp ) ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 281 | IF( ln_tradmp ) CALL tra_dmp ( kstp ) ! internal damping trends |
|---|
| 282 | IF( lk_bdy ) CALL bdy_tra_dmp( kstp ) ! bdy damping trends |
|---|
| 283 | CALL tra_adv ( kstp ) ! horizontal & vertical advection |
|---|
| 284 | IF( lk_zdfkpp ) CALL tra_kpp ( kstp ) ! KPP non-local tracer fluxes |
|---|
| 285 | CALL tra_ldf ( kstp ) ! lateral mixing |
|---|
| 286 | |
|---|
| 287 | IF( ln_diaptr ) CALL dia_ptr ! Poleward adv/ldf TRansports diagnostics |
|---|
| 288 | |
|---|
| 289 | #if defined key_agrif |
|---|
| 290 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra ! tracers sponge |
|---|
| 291 | #endif |
|---|
| 292 | CALL tra_zdf ( kstp ) ! vertical mixing and after tracer fields |
|---|
| 293 | |
|---|
| 294 | IF( ln_dynhpg_imp ) THEN ! semi-implicit hpg (time stepping then eos) |
|---|
| 295 | IF( ln_zdfnpc ) CALL tra_npc( kstp ) ! update after fields by non-penetrative convection |
|---|
| 296 | CALL tra_nxt( kstp ) ! tracer fields at next time step |
|---|
| 297 | IF( ln_sto_eos ) CALL sto_pts( tsn ) ! Random T/S fluctuations |
|---|
| 298 | CALL eos ( tsa, rhd, rhop, fsdept_n(:,:,:) ) ! Time-filtered in situ density for hpg computation |
|---|
| 299 | IF( ln_zps .AND. .NOT. ln_isfcav) & |
|---|
| 300 | & CALL zps_hde ( kstp, jpts, tsa, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 301 | & rhd, gru , grv ) ! of t, s, rd at the last ocean level |
|---|
| 302 | IF( ln_zps .AND. ln_isfcav) & |
|---|
| 303 | & CALL zps_hde_isf( kstp, jpts, tsa, gtsu, gtsv, & ! Partial steps for top cell (ISF) |
|---|
| 304 | & rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv , & |
|---|
| 305 | & gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi ) ! of t, s, rd at the last ocean level |
|---|
| 306 | ELSE ! centered hpg (eos then time stepping) |
|---|
| 307 | IF ( .NOT. lk_dynspg_ts ) THEN ! eos already called in time-split case |
|---|
| 308 | IF( ln_sto_eos ) CALL sto_pts( tsn ) ! Random T/S fluctuations |
|---|
| 309 | CALL eos ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation |
|---|
| 310 | IF( ln_zps .AND. .NOT. ln_isfcav) & |
|---|
| 311 | & CALL zps_hde ( kstp, jpts, tsn, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 312 | & rhd, gru , grv ) ! of t, s, rd at the last ocean level |
|---|
| 313 | IF( ln_zps .AND. ln_isfcav) & |
|---|
| 314 | & CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv, & ! Partial steps for top cell (ISF) |
|---|
| 315 | & rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv , & |
|---|
| 316 | & gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi ) ! of t, s, rd at the last ocean level |
|---|
| 317 | ENDIF |
|---|
| 318 | IF( ln_zdfnpc ) CALL tra_npc( kstp ) ! update after fields by non-penetrative convection |
|---|
| 319 | CALL tra_nxt( kstp ) ! tracer fields at next time step |
|---|
| 320 | ENDIF |
|---|
| 321 | |
|---|
| 322 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 323 | ! Dynamics (tsa used as workspace) |
|---|
| 324 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 325 | IF( lk_dynspg_ts ) THEN |
|---|
| 326 | ! revert to previously computed momentum tendencies |
|---|
| 327 | ! (not using ua, va as temporary arrays during tracers' update could avoid that) |
|---|
| 328 | ua(:,:,:) = ua_sv(:,:,:) |
|---|
| 329 | va(:,:,:) = va_sv(:,:,:) |
|---|
| 330 | ! Revert now divergence and rotational to previously computed ones |
|---|
| 331 | !(needed because of the time swap in div_cur, at the beginning of each time step) |
|---|
| 332 | hdivn(:,:,:) = hdivb(:,:,:) |
|---|
| 333 | rotn(:,:,:) = rotb(:,:,:) |
|---|
| 334 | |
|---|
| 335 | CALL dyn_bfr( kstp ) ! bottom friction |
|---|
| 336 | CALL dyn_zdf( kstp ) ! vertical diffusion |
|---|
| 337 | ELSE |
|---|
| 338 | ua(:,:,:) = 0.e0 ! set dynamics trends to zero |
|---|
| 339 | va(:,:,:) = 0.e0 |
|---|
| 340 | |
|---|
| 341 | IF( ln_asmiau .AND. & |
|---|
| 342 | & ln_dyninc ) CALL dyn_asm_inc( kstp ) ! apply dynamics assimilation increment |
|---|
| 343 | IF( ln_bkgwri ) CALL asm_bkg_wri( kstp ) ! output background fields |
|---|
| 344 | IF( ln_neptsimp ) CALL dyn_nept_cor( kstp ) ! subtract Neptune velocities (simplified) |
|---|
| 345 | IF( lk_bdy ) CALL bdy_dyn3d_dmp(kstp ) ! bdy damping trends |
|---|
| 346 | CALL dyn_adv( kstp ) ! advection (vector or flux form) |
|---|
| 347 | CALL dyn_vor( kstp ) ! vorticity term including Coriolis |
|---|
| 348 | CALL dyn_ldf( kstp ) ! lateral mixing |
|---|
| 349 | IF( ln_neptsimp ) CALL dyn_nept_cor( kstp ) ! add Neptune velocities (simplified) |
|---|
| 350 | #if defined key_agrif |
|---|
| 351 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn ! momemtum sponge |
|---|
| 352 | #endif |
|---|
| 353 | CALL dyn_hpg( kstp ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 354 | CALL dyn_bfr( kstp ) ! bottom friction |
|---|
| 355 | CALL dyn_zdf( kstp ) ! vertical diffusion |
|---|
| 356 | CALL dyn_spg( kstp, indic ) ! surface pressure gradient |
|---|
| 357 | ENDIF |
|---|
| 358 | CALL dyn_nxt( kstp ) ! lateral velocity at next time step |
|---|
| 359 | |
|---|
| 360 | CALL ssh_swp( kstp ) ! swap of sea surface height |
|---|
| 361 | IF( lk_vvl ) CALL dom_vvl_sf_swp( kstp ) ! swap of vertical scale factors |
|---|
| 362 | |
|---|
| 363 | IF( ln_diahsb ) CALL dia_hsb( kstp ) ! - ML - global conservation diagnostics |
|---|
| 364 | IF( lk_diaobs ) CALL dia_obs( kstp ) ! obs-minus-model (assimilation) diagnostics (call after dynamics update) |
|---|
| 365 | |
|---|
| 366 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 367 | ! Control and restarts |
|---|
| 368 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 369 | CALL stp_ctl( kstp, indic ) |
|---|
| 370 | IF( indic < 0 ) THEN |
|---|
| 371 | CALL ctl_stop( 'step: indic < 0' ) |
|---|
| 372 | CALL dia_wri_state( 'output.abort', kstp ) |
|---|
| 373 | ENDIF |
|---|
| 374 | IF( kstp == nit000 ) THEN |
|---|
| 375 | CALL iom_close( numror ) ! close input ocean restart file |
|---|
| 376 | IF(lwm) CALL FLUSH ( numond ) ! flush output namelist oce |
|---|
| 377 | IF( lwm.AND.numoni /= -1 ) CALL FLUSH ( numoni ) ! flush output namelist ice |
|---|
| 378 | ENDIF |
|---|
| 379 | IF( lrst_oce ) CALL rst_write ( kstp ) ! write output ocean restart file |
|---|
| 380 | |
|---|
| 381 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 382 | ! Coupled mode |
|---|
| 383 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 384 | IF( lk_oasis ) CALL sbc_cpl_snd( kstp ) ! coupled mode : field exchanges |
|---|
| 385 | ! |
|---|
| 386 | #if defined key_iomput |
|---|
| 387 | IF( kstp == nitend .OR. indic < 0 ) THEN |
|---|
| 388 | CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF |
|---|
| 389 | IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) ! |
|---|
| 390 | ENDIF |
|---|
| 391 | #endif |
|---|
| 392 | ! |
|---|
| 393 | IF( nn_timing == 1 .AND. kstp == nit000 ) CALL timing_reset |
|---|
| 394 | ! |
|---|
| 395 | END SUBROUTINE stp |
|---|
| 396 | |
|---|
| 397 | !!====================================================================== |
|---|
| 398 | END MODULE step |
|---|
