| 1 | MODULE p4zche |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p4zche *** |
|---|
| 4 | !! TOP : PISCES Sea water chemistry computed following OCMIP protocol |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1988 (E. Maier-Reimer) Original code |
|---|
| 7 | !! - ! 1998 (O. Aumont) addition |
|---|
| 8 | !! - ! 1999 (C. Le Quere) modification |
|---|
| 9 | !! NEMO 1.0 ! 2004 (O. Aumont) modification |
|---|
| 10 | !! - ! 2006 (R. Gangsto) modification |
|---|
| 11 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 12 | !! ! 2011-02 (J. Simeon, J.Orr ) update O2 solubility constants |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | #if defined key_pisces |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! 'key_pisces' PISCES bio-model |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! p4z_che : Sea water chemistry computed following OCMIP protocol |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | USE oce_trc ! shared variables between ocean and passive tracers |
|---|
| 21 | USE sms_pisces ! PISCES Source Minus Sink variables |
|---|
| 22 | USE lib_mpp ! MPP library |
|---|
| 23 | |
|---|
| 24 | IMPLICIT NONE |
|---|
| 25 | PRIVATE |
|---|
| 26 | |
|---|
| 27 | PUBLIC p4z_che ! |
|---|
| 28 | PUBLIC p4z_che_alloc ! |
|---|
| 29 | |
|---|
| 30 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: sio3eq ! chemistry of Si |
|---|
| 31 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: fekeq ! chemistry of Fe |
|---|
| 32 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: chemc ! Solubilities of O2 and CO2 |
|---|
| 33 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: chemo2 ! Solubilities of O2 and CO2 |
|---|
| 34 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: tempis ! In situ temperature |
|---|
| 35 | |
|---|
| 36 | REAL(wp), PUBLIC :: atcox = 0.20946 ! units atm |
|---|
| 37 | |
|---|
| 38 | REAL(wp) :: salchl = 1. / 1.80655 ! conversion factor for salinity --> chlorinity (Wooster et al. 1969) |
|---|
| 39 | REAL(wp) :: o2atm = 1. / ( 1000. * 0.20946 ) |
|---|
| 40 | |
|---|
| 41 | REAL(wp) :: rgas = 83.14472 ! universal gas constants |
|---|
| 42 | REAL(wp) :: oxyco = 1. / 22.4144 ! converts from liters of an ideal gas to moles |
|---|
| 43 | |
|---|
| 44 | REAL(wp) :: bor1 = 0.00023 ! borat constants |
|---|
| 45 | REAL(wp) :: bor2 = 1. / 10.82 |
|---|
| 46 | |
|---|
| 47 | REAL(wp) :: st1 = 0.14 ! constants for calculate concentrations for sulfate |
|---|
| 48 | REAL(wp) :: st2 = 1./96.062 ! (Morris & Riley 1966) |
|---|
| 49 | |
|---|
| 50 | REAL(wp) :: ft1 = 0.000067 ! constants for calculate concentrations for fluorides |
|---|
| 51 | REAL(wp) :: ft2 = 1./18.9984 ! (Dickson & Riley 1979 ) |
|---|
| 52 | |
|---|
| 53 | ! ! volumetric solubility constants for o2 in ml/L |
|---|
| 54 | REAL(wp) :: ox0 = 2.00856 ! from Table 1 for Eq 8 of Garcia and Gordon, 1992. |
|---|
| 55 | REAL(wp) :: ox1 = 3.22400 ! corrects for moisture and fugacity, but not total atmospheric pressure |
|---|
| 56 | REAL(wp) :: ox2 = 3.99063 ! Original PISCES code noted this was a solubility, but |
|---|
| 57 | REAL(wp) :: ox3 = 4.80299 ! was in fact a bunsen coefficient with units L-O2/(Lsw atm-O2) |
|---|
| 58 | REAL(wp) :: ox4 = 9.78188e-1 ! Hence, need to divide EXP( zoxy ) by 1000, ml-O2 => L-O2 |
|---|
| 59 | REAL(wp) :: ox5 = 1.71069 ! and atcox = 0.20946 to add the 1/atm dimension. |
|---|
| 60 | REAL(wp) :: ox6 = -6.24097e-3 |
|---|
| 61 | REAL(wp) :: ox7 = -6.93498e-3 |
|---|
| 62 | REAL(wp) :: ox8 = -6.90358e-3 |
|---|
| 63 | REAL(wp) :: ox9 = -4.29155e-3 |
|---|
| 64 | REAL(wp) :: ox10 = -3.11680e-7 |
|---|
| 65 | |
|---|
| 66 | ! ! coeff. for seawater pressure correction : millero 95 |
|---|
| 67 | ! ! AGRIF doesn't like the DATA instruction |
|---|
| 68 | REAL(wp) :: devk11 = -25.5 |
|---|
| 69 | REAL(wp) :: devk12 = -15.82 |
|---|
| 70 | REAL(wp) :: devk13 = -29.48 |
|---|
| 71 | REAL(wp) :: devk14 = -25.60 |
|---|
| 72 | REAL(wp) :: devk15 = -48.76 |
|---|
| 73 | ! |
|---|
| 74 | REAL(wp) :: devk21 = 0.1271 |
|---|
| 75 | REAL(wp) :: devk22 = -0.0219 |
|---|
| 76 | REAL(wp) :: devk23 = 0.1622 |
|---|
| 77 | REAL(wp) :: devk24 = 0.2324 |
|---|
| 78 | REAL(wp) :: devk25 = 0.5304 |
|---|
| 79 | ! |
|---|
| 80 | REAL(wp) :: devk31 = 0. |
|---|
| 81 | REAL(wp) :: devk32 = 0. |
|---|
| 82 | REAL(wp) :: devk33 = 2.608E-3 |
|---|
| 83 | REAL(wp) :: devk34 = -3.6246E-3 |
|---|
| 84 | REAL(wp) :: devk35 = 0. |
|---|
| 85 | ! |
|---|
| 86 | REAL(wp) :: devk41 = -3.08E-3 |
|---|
| 87 | REAL(wp) :: devk42 = 1.13E-3 |
|---|
| 88 | REAL(wp) :: devk43 = -2.84E-3 |
|---|
| 89 | REAL(wp) :: devk44 = -5.13E-3 |
|---|
| 90 | REAL(wp) :: devk45 = -11.76E-3 |
|---|
| 91 | ! |
|---|
| 92 | REAL(wp) :: devk51 = 0.0877E-3 |
|---|
| 93 | REAL(wp) :: devk52 = -0.1475E-3 |
|---|
| 94 | REAL(wp) :: devk53 = 0. |
|---|
| 95 | REAL(wp) :: devk54 = 0.0794E-3 |
|---|
| 96 | REAL(wp) :: devk55 = 0.3692E-3 |
|---|
| 97 | |
|---|
| 98 | !!* Substitution |
|---|
| 99 | #include "top_substitute.h90" |
|---|
| 100 | !!---------------------------------------------------------------------- |
|---|
| 101 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 102 | !! $Id$ |
|---|
| 103 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 104 | !!---------------------------------------------------------------------- |
|---|
| 105 | CONTAINS |
|---|
| 106 | |
|---|
| 107 | SUBROUTINE p4z_che |
|---|
| 108 | !!--------------------------------------------------------------------- |
|---|
| 109 | !! *** ROUTINE p4z_che *** |
|---|
| 110 | !! |
|---|
| 111 | !! ** Purpose : Sea water chemistry computed following OCMIP protocol |
|---|
| 112 | !! |
|---|
| 113 | !! ** Method : - ... |
|---|
| 114 | !!--------------------------------------------------------------------- |
|---|
| 115 | INTEGER :: ji, jj, jk |
|---|
| 116 | REAL(wp) :: ztkel, zt , zt2 , zsal , zsal2 , zbuf1 , zbuf2 |
|---|
| 117 | REAL(wp) :: ztgg , ztgg2, ztgg3 , ztgg4 , ztgg5 |
|---|
| 118 | REAL(wp) :: zpres, ztc , zcl , zcpexp, zoxy , zcpexp2 |
|---|
| 119 | REAL(wp) :: zsqrt, ztr , zlogt , zcek1, zc1, zplat |
|---|
| 120 | REAL(wp) :: zis , zis2 , zsal15, zisqrt, za1 , za2 |
|---|
| 121 | REAL(wp) :: zckb , zck1 , zck2 , zckw , zak1 , zak2 , zakb , zaksp0, zakw |
|---|
| 122 | REAL(wp) :: zst , zft , zcks , zckf , zaksp1 |
|---|
| 123 | !!--------------------------------------------------------------------- |
|---|
| 124 | ! |
|---|
| 125 | IF( nn_timing == 1 ) CALL timing_start('p4z_che') |
|---|
| 126 | ! |
|---|
| 127 | ! Computations of chemical constants require in situ temperature |
|---|
| 128 | ! Here a quite simple formulation is used to convert |
|---|
| 129 | ! potential temperature to in situ temperature. The errors is less than |
|---|
| 130 | ! 0.04°C relative to an exact computation |
|---|
| 131 | ! --------------------------------------------------------------------- |
|---|
| 132 | DO jk = 1, jpk |
|---|
| 133 | DO jj = 1, jpj |
|---|
| 134 | DO ji = 1, jpi |
|---|
| 135 | zpres = fsdept(ji,jj,jk) / 1000. |
|---|
| 136 | za1 = 0.04 * ( 1.0 + 0.185 * tsn(ji,jj,jk,jp_tem) + 0.035 * (tsn(ji,jj,jk,jp_sal) - 35.0) ) |
|---|
| 137 | za2 = 0.0075 * ( 1.0 - tsn(ji,jj,jk,jp_tem) / 30.0 ) |
|---|
| 138 | tempis(ji,jj,jk) = tsn(ji,jj,jk,jp_tem) - za1 * zpres + za2 * zpres**2 |
|---|
| 139 | END DO |
|---|
| 140 | END DO |
|---|
| 141 | END DO |
|---|
| 142 | ! |
|---|
| 143 | ! CHEMICAL CONSTANTS - SURFACE LAYER |
|---|
| 144 | ! ---------------------------------- |
|---|
| 145 | !CDIR NOVERRCHK |
|---|
| 146 | DO jj = 1, jpj |
|---|
| 147 | !CDIR NOVERRCHK |
|---|
| 148 | DO ji = 1, jpi |
|---|
| 149 | ! ! SET ABSOLUTE TEMPERATURE |
|---|
| 150 | ztkel = tempis(ji,jj,1) + 273.15 |
|---|
| 151 | zt = ztkel * 0.01 |
|---|
| 152 | zt2 = zt * zt |
|---|
| 153 | zsal = tsn(ji,jj,1,jp_sal) + ( 1.- tmask(ji,jj,1) ) * 35. |
|---|
| 154 | zsal2 = zsal * zsal |
|---|
| 155 | zlogt = LOG( zt ) |
|---|
| 156 | ! ! LN(K0) OF SOLUBILITY OF CO2 (EQ. 12, WEISS, 1980) |
|---|
| 157 | ! ! AND FOR THE ATMOSPHERE FOR NON IDEAL GAS |
|---|
| 158 | zcek1 = 9345.17/ztkel - 60.2409 + 23.3585 * LOG(zt) + zsal*(0.023517 - 0.00023656*ztkel & |
|---|
| 159 | & + 0.0047036e-4*ztkel**2) |
|---|
| 160 | ! ! SET SOLUBILITIES OF O2 AND CO2 |
|---|
| 161 | chemc(ji,jj,1) = EXP( zcek1 ) * 1.e-6 * rhop(ji,jj,1) / 1000. ! mol/(kg uatm) |
|---|
| 162 | chemc(ji,jj,2) = -1636.75 + 12.0408*ztkel - 0.0327957*ztkel**2 + 0.0000316528*ztkel**3 |
|---|
| 163 | chemc(ji,jj,3) = 57.7 - 0.118*ztkel |
|---|
| 164 | ! |
|---|
| 165 | END DO |
|---|
| 166 | END DO |
|---|
| 167 | |
|---|
| 168 | ! OXYGEN SOLUBILITY - DEEP OCEAN |
|---|
| 169 | ! ------------------------------- |
|---|
| 170 | !CDIR NOVERRCHK |
|---|
| 171 | DO jk = 1, jpk |
|---|
| 172 | !CDIR NOVERRCHK |
|---|
| 173 | DO jj = 1, jpj |
|---|
| 174 | !CDIR NOVERRCHK |
|---|
| 175 | DO ji = 1, jpi |
|---|
| 176 | ztkel = tempis(ji,jj,jk) + 273.15 |
|---|
| 177 | zsal = tsn(ji,jj,jk,jp_sal) + ( 1.- tmask(ji,jj,jk) ) * 35. |
|---|
| 178 | zsal2 = zsal * zsal |
|---|
| 179 | ztgg = LOG( ( 298.15 - tempis(ji,jj,jk) ) / ztkel ) ! Set the GORDON & GARCIA scaled temperature |
|---|
| 180 | ztgg2 = ztgg * ztgg |
|---|
| 181 | ztgg3 = ztgg2 * ztgg |
|---|
| 182 | ztgg4 = ztgg3 * ztgg |
|---|
| 183 | ztgg5 = ztgg4 * ztgg |
|---|
| 184 | zoxy = ox0 + ox1 * ztgg + ox2 * ztgg2 + ox3 * ztgg3 + ox4 * ztgg4 + ox5 * ztgg5 & |
|---|
| 185 | + zsal * ( ox6 + ox7 * ztgg + ox8 * ztgg2 + ox9 * ztgg3 ) + ox10 * zsal2 |
|---|
| 186 | chemo2(ji,jj,jk) = ( EXP( zoxy ) * o2atm ) * oxyco * atcox ! mol/(L atm) |
|---|
| 187 | END DO |
|---|
| 188 | END DO |
|---|
| 189 | END DO |
|---|
| 190 | |
|---|
| 191 | |
|---|
| 192 | |
|---|
| 193 | ! CHEMICAL CONSTANTS - DEEP OCEAN |
|---|
| 194 | ! ------------------------------- |
|---|
| 195 | !CDIR NOVERRCHK |
|---|
| 196 | DO jk = 1, jpk |
|---|
| 197 | !CDIR NOVERRCHK |
|---|
| 198 | DO jj = 1, jpj |
|---|
| 199 | !CDIR NOVERRCHK |
|---|
| 200 | DO ji = 1, jpi |
|---|
| 201 | |
|---|
| 202 | ! SET PRESSION ACCORDING TO SAUNDER (1980) |
|---|
| 203 | zplat = SIN ( ABS(gphit(ji,jj)*3.141592654/180.) ) |
|---|
| 204 | zc1 = 5.92E-3 + zplat**2 * 5.25E-3 |
|---|
| 205 | zpres = ((1-zc1)-SQRT(((1-zc1)**2)-(8.84E-6*fsdept(ji,jj,jk)))) / 4.42E-6 |
|---|
| 206 | zpres = zpres / 10.0 |
|---|
| 207 | |
|---|
| 208 | ! SET ABSOLUTE TEMPERATURE |
|---|
| 209 | ztkel = tempis(ji,jj,jk) + 273.15 |
|---|
| 210 | zsal = tsn(ji,jj,jk,jp_sal) + ( 1.-tmask(ji,jj,jk) ) * 35. |
|---|
| 211 | zsqrt = SQRT( zsal ) |
|---|
| 212 | zsal15 = zsqrt * zsal |
|---|
| 213 | zlogt = LOG( ztkel ) |
|---|
| 214 | ztr = 1. / ztkel |
|---|
| 215 | zis = 19.924 * zsal / ( 1000.- 1.005 * zsal ) |
|---|
| 216 | zis2 = zis * zis |
|---|
| 217 | zisqrt = SQRT( zis ) |
|---|
| 218 | ztc = tempis(ji,jj,jk) + ( 1.- tmask(ji,jj,jk) ) * 20. |
|---|
| 219 | |
|---|
| 220 | ! CHLORINITY (WOOSTER ET AL., 1969) |
|---|
| 221 | zcl = zsal * salchl |
|---|
| 222 | |
|---|
| 223 | ! TOTAL SULFATE CONCENTR. [MOLES/kg soln] |
|---|
| 224 | zst = st1 * zcl * st2 |
|---|
| 225 | |
|---|
| 226 | ! TOTAL FLUORIDE CONCENTR. [MOLES/kg soln] |
|---|
| 227 | zft = ft1 * zcl * ft2 |
|---|
| 228 | |
|---|
| 229 | ! DISSOCIATION CONSTANT FOR SULFATES on free H scale (Dickson 1990) |
|---|
| 230 | zcks = EXP(-4276.1 * ztr + 141.328 - 23.093 * zlogt & |
|---|
| 231 | & + (-13856. * ztr + 324.57 - 47.986 * zlogt) * zisqrt & |
|---|
| 232 | & + (35474. * ztr - 771.54 + 114.723 * zlogt) * zis & |
|---|
| 233 | & - 2698. * ztr * zis**1.5 + 1776.* ztr * zis2 & |
|---|
| 234 | & + LOG(1.0 - 0.001005 * zsal)) |
|---|
| 235 | ! |
|---|
| 236 | aphscale(ji,jj,jk) = ( 1. + zst / zcks ) |
|---|
| 237 | |
|---|
| 238 | ! DISSOCIATION CONSTANT FOR FLUORIDES on free H scale (Dickson and Riley 79) |
|---|
| 239 | zckf = EXP( 1590.2*ztr - 12.641 + 1.525*zisqrt & |
|---|
| 240 | & + LOG(1.0d0 - 0.001005d0*zsal) & |
|---|
| 241 | & + LOG(1.0d0 + zst/zcks)) |
|---|
| 242 | |
|---|
| 243 | ! DISSOCIATION CONSTANT FOR CARBONATE AND BORATE |
|---|
| 244 | zckb= (-8966.90 - 2890.53*zsqrt - 77.942*zsal & |
|---|
| 245 | & + 1.728*zsal15 - 0.0996*zsal*zsal)*ztr & |
|---|
| 246 | & + (148.0248 + 137.1942*zsqrt + 1.62142*zsal) & |
|---|
| 247 | & + (-24.4344 - 25.085*zsqrt - 0.2474*zsal) & |
|---|
| 248 | & * zlogt + 0.053105*zsqrt*ztkel |
|---|
| 249 | |
|---|
| 250 | |
|---|
| 251 | ! DISSOCIATION COEFFICIENT FOR CARBONATE ACCORDING TO |
|---|
| 252 | ! MEHRBACH (1973) REFIT BY MILLERO (1995), seawater scale |
|---|
| 253 | zck1 = -1.0*(3633.86*ztr - 61.2172 + 9.6777*zlogt & |
|---|
| 254 | - 0.011555*zsal + 0.0001152*zsal*zsal) |
|---|
| 255 | zck2 = -1.0*(471.78*ztr + 25.9290 - 3.16967*zlogt & |
|---|
| 256 | - 0.01781*zsal + 0.0001122*zsal*zsal) |
|---|
| 257 | |
|---|
| 258 | ! PKW (H2O) (DICKSON AND RILEY, 1979) |
|---|
| 259 | zckw = -13847.26*ztr + 148.9652 - 23.6521 * zlogt & |
|---|
| 260 | & + (118.67*ztr - 5.977 + 1.0495 * zlogt) & |
|---|
| 261 | & * zsqrt - 0.01615 * zsal |
|---|
| 262 | |
|---|
| 263 | ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE IN SEAWATER |
|---|
| 264 | ! (S=27-43, T=2-25 DEG C) at pres =0 (atmos. pressure) (MUCCI 1983) |
|---|
| 265 | zaksp0 = -171.9065 -0.077993*ztkel + 2839.319*ztr + 71.595*LOG10( ztkel ) & |
|---|
| 266 | & + (-0.77712 + 0.00284263*ztkel + 178.34*ztr) * zsqrt & |
|---|
| 267 | & - 0.07711*zsal + 0.0041249*zsal15 |
|---|
| 268 | |
|---|
| 269 | ! K1, K2 OF CARBONIC ACID, KB OF BORIC ACID, KW (H2O) (LIT.?) |
|---|
| 270 | zak1 = 10**(zck1) |
|---|
| 271 | zak2 = 10**(zck2) |
|---|
| 272 | zakb = EXP( zckb ) |
|---|
| 273 | zakw = EXP( zckw ) |
|---|
| 274 | zaksp1 = 10**(zaksp0) |
|---|
| 275 | |
|---|
| 276 | ! FORMULA FOR CPEXP AFTER EDMOND & GIESKES (1970) |
|---|
| 277 | ! (REFERENCE TO CULBERSON & PYTKOQICZ (1968) AS MADE |
|---|
| 278 | ! IN BROECKER ET AL. (1982) IS INCORRECT; HERE RGAS IS |
|---|
| 279 | ! TAKEN TENFOLD TO CORRECT FOR THE NOTATION OF pres IN |
|---|
| 280 | ! DBAR INSTEAD OF BAR AND THE EXPRESSION FOR CPEXP IS |
|---|
| 281 | ! MULTIPLIED BY LN(10.) TO ALLOW USE OF EXP-FUNCTION |
|---|
| 282 | ! WITH BASIS E IN THE FORMULA FOR AKSPP (CF. EDMOND |
|---|
| 283 | ! & GIESKES (1970), P. 1285-1286 (THE SMALL |
|---|
| 284 | ! FORMULA ON P. 1286 IS RIGHT AND CONSISTENT WITH THE |
|---|
| 285 | ! SIGN IN PARTIAL MOLAR VOLUME CHANGE AS SHOWN ON P. 1285)) |
|---|
| 286 | zcpexp = zpres /(rgas*ztkel) |
|---|
| 287 | zcpexp2 = zpres * zpres/(rgas*ztkel) |
|---|
| 288 | |
|---|
| 289 | ! KB OF BORIC ACID, K1,K2 OF CARBONIC ACID PRESSURE |
|---|
| 290 | ! CORRECTION AFTER CULBERSON AND PYTKOWICZ (1968) |
|---|
| 291 | ! (CF. BROECKER ET AL., 1982) |
|---|
| 292 | |
|---|
| 293 | zbuf1 = - ( devk11 + devk21 * ztc + devk31 * ztc * ztc ) |
|---|
| 294 | zbuf2 = 0.5 * ( devk41 + devk51 * ztc ) |
|---|
| 295 | ak13(ji,jj,jk) = zak1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 296 | |
|---|
| 297 | zbuf1 = - ( devk12 + devk22 * ztc + devk32 * ztc * ztc ) |
|---|
| 298 | zbuf2 = 0.5 * ( devk42 + devk52 * ztc ) |
|---|
| 299 | ak23(ji,jj,jk) = zak2 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 300 | |
|---|
| 301 | zbuf1 = - ( devk13 + devk23 * ztc + devk33 * ztc * ztc ) |
|---|
| 302 | zbuf2 = 0.5 * ( devk43 + devk53 * ztc ) |
|---|
| 303 | akb3(ji,jj,jk) = zakb * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 304 | |
|---|
| 305 | zbuf1 = - ( devk14 + devk24 * ztc + devk34 * ztc * ztc ) |
|---|
| 306 | zbuf2 = 0.5 * ( devk44 + devk54 * ztc ) |
|---|
| 307 | akw3(ji,jj,jk) = zakw * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 308 | |
|---|
| 309 | |
|---|
| 310 | ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE |
|---|
| 311 | ! AS FUNCTION OF PRESSURE FOLLOWING MILLERO |
|---|
| 312 | ! (P. 1285) AND BERNER (1976) |
|---|
| 313 | zbuf1 = - ( devk15 + devk25 * ztc + devk35 * ztc * ztc ) |
|---|
| 314 | zbuf2 = 0.5 * ( devk45 + devk55 * ztc ) |
|---|
| 315 | aksp(ji,jj,jk) = zaksp1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 316 | |
|---|
| 317 | ! TOTAL BORATE CONCENTR. [MOLES/L] |
|---|
| 318 | borat(ji,jj,jk) = bor1 * zcl * bor2 |
|---|
| 319 | |
|---|
| 320 | ! Iron and SIO3 saturation concentration from ... |
|---|
| 321 | sio3eq(ji,jj,jk) = EXP( LOG( 10.) * ( 6.44 - 968. / ztkel ) ) * 1.e-6 |
|---|
| 322 | fekeq (ji,jj,jk) = 10**( 17.27 - 1565.7 / ( 273.15 + ztc ) ) |
|---|
| 323 | |
|---|
| 324 | END DO |
|---|
| 325 | END DO |
|---|
| 326 | END DO |
|---|
| 327 | ! |
|---|
| 328 | IF( nn_timing == 1 ) CALL timing_stop('p4z_che') |
|---|
| 329 | ! |
|---|
| 330 | END SUBROUTINE p4z_che |
|---|
| 331 | |
|---|
| 332 | |
|---|
| 333 | INTEGER FUNCTION p4z_che_alloc() |
|---|
| 334 | !!---------------------------------------------------------------------- |
|---|
| 335 | !! *** ROUTINE p4z_che_alloc *** |
|---|
| 336 | !!---------------------------------------------------------------------- |
|---|
| 337 | ALLOCATE( sio3eq(jpi,jpj,jpk), fekeq(jpi,jpj,jpk), chemc(jpi,jpj,3), chemo2(jpi,jpj,jpk), & |
|---|
| 338 | & tempis(jpi,jpj,jpk), STAT=p4z_che_alloc ) |
|---|
| 339 | ! |
|---|
| 340 | IF( p4z_che_alloc /= 0 ) CALL ctl_warn('p4z_che_alloc : failed to allocate arrays.') |
|---|
| 341 | ! |
|---|
| 342 | END FUNCTION p4z_che_alloc |
|---|
| 343 | |
|---|
| 344 | #else |
|---|
| 345 | !!====================================================================== |
|---|
| 346 | !! Dummy module : No PISCES bio-model |
|---|
| 347 | !!====================================================================== |
|---|
| 348 | CONTAINS |
|---|
| 349 | SUBROUTINE p4z_che( kt ) ! Empty routine |
|---|
| 350 | INTEGER, INTENT(in) :: kt |
|---|
| 351 | WRITE(*,*) 'p4z_che: You should not have seen this print! error?', kt |
|---|
| 352 | END SUBROUTINE p4z_che |
|---|
| 353 | #endif |
|---|
| 354 | |
|---|
| 355 | !!====================================================================== |
|---|
| 356 | END MODULE p4zche |
|---|
