New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 5059

Last change on this file since 5059 was 5055, checked in by clem, 9 years ago

LIM3: removing par_ice and put jpl, nlay_i and nlay_s as namelist parameters
  • Property svn:keywords set to Id
File size: 38.8 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE oce     , ONLY : fraqsr_1lev 
25   USE ice            ! LIM: sea-ice variables
26   USE sbc_oce        ! Surface boundary condition: ocean fields
27   USE sbc_ice        ! Surface boundary condition: ice fields
28   USE thd_ice        ! LIM thermodynamic sea-ice variables
29   USE dom_ice        ! LIM sea-ice domain
30   USE domvvl         ! domain: variable volume level
31   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
32   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
33   USE limthd_sal     ! LIM: thermodynamics, ice salinity
34   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
35   USE limthd_lac     ! LIM-3 lateral accretion
36   USE limitd_th      ! remapping thickness distribution
37   USE limtab         ! LIM: 1D <==> 2D transformation
38   USE limvar         ! LIM: sea-ice variables
39   USE lbclnk         ! lateral boundary condition - MPP links
40   USE lib_mpp        ! MPP library
41   USE wrk_nemo       ! work arrays
42   USE in_out_manager ! I/O manager
43   USE prtctl         ! Print control
44   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
45   USE timing         ! Timing
46   USE limcons        ! conservation tests
47   USE limctl
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   lim_thd        ! called by limstp module
53   PUBLIC   lim_thd_init   ! called by sbc_lim_init
54
55   !! * Substitutions
56#  include "domzgr_substitute.h90"
57#  include "vectopt_loop_substitute.h90"
58   !!----------------------------------------------------------------------
59   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
60   !! $Id$
61   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   SUBROUTINE lim_thd( kt )
66      !!-------------------------------------------------------------------
67      !!                ***  ROUTINE lim_thd  ***       
68      !! 
69      !! ** Purpose : This routine manages ice thermodynamics
70      !!         
71      !! ** Action : - Initialisation of some variables
72      !!             - Some preliminary computation (oceanic heat flux
73      !!               at the ice base, snow acc.,heat budget of the leads)
74      !!             - selection of the icy points and put them in an array
75      !!             - call lim_thd_dif  for vertical heat diffusion
76      !!             - call lim_thd_dh   for vertical ice growth and melt
77      !!             - call lim_thd_ent  for enthalpy remapping
78      !!             - call lim_thd_sal  for ice desalination
79      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
80      !!             - back to the geographic grid
81      !!     
82      !! ** References :
83      !!---------------------------------------------------------------------
84      INTEGER, INTENT(in) :: kt    ! number of iteration
85      !!
86      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
87      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
88      INTEGER  :: ii, ij           ! temporary dummy loop index
89      REAL(wp) :: zfric_u, zqld, zqfr
90      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
91      REAL(wp), PARAMETER :: zfric_umin = 0._wp        ! lower bound for the friction velocity (cice value=5.e-04)
92      REAL(wp), PARAMETER :: zch        = 0.0057_wp    ! heat transfer coefficient
93      !
94      REAL(wp), POINTER, DIMENSION(:,:) ::  zqsr, zqns
95      !!-------------------------------------------------------------------
96      CALL wrk_alloc( jpi, jpj, zqsr, zqns )
97
98      IF( nn_timing == 1 )  CALL timing_start('limthd')
99
100      ! conservation test
101      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
102
103      !------------------------------------------------------------------------!
104      ! 1) Initialization of some variables                                    !
105      !------------------------------------------------------------------------!
106      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
107
108      !--------------------
109      ! 1.2) Heat content   
110      !--------------------
111      ! Change the units of heat content; from global units to J.m3
112      DO jl = 1, jpl
113         DO jk = 1, nlay_i
114            DO jj = 1, jpj
115               DO ji = 1, jpi
116                  !0 if no ice and 1 if yes
117                  rswitch = 1.0 - MAX(  0.0 , SIGN( 1.0 , - v_i(ji,jj,jl) + epsi10 )  )
118                  !Energy of melting q(S,T) [J.m-3]
119                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_i(ji,jj,jl) , epsi10 ) ) * REAL( nlay_i )
120                  !convert units ! very important that this line is here       
121                  e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) * unit_fac 
122               END DO
123            END DO
124         END DO
125         DO jk = 1, nlay_s
126            DO jj = 1, jpj
127               DO ji = 1, jpi
128                  !0 if no ice and 1 if yes
129                  rswitch = 1.0 - MAX(  0.0 , SIGN( 1.0 , - v_s(ji,jj,jl) + epsi10 )  )
130                  !Energy of melting q(S,T) [J.m-3]
131                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_s(ji,jj,jl) , epsi10 ) ) * REAL( nlay_s )
132                  !convert units ! very important that this line is here
133                  e_s(ji,jj,jk,jl) = e_s(ji,jj,jk,jl) * unit_fac 
134               END DO
135            END DO
136         END DO
137      END DO
138
139      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
140      !-----------------------------------------------------------------------------!
141
142      !--- Ocean solar and non solar fluxes to be used in zqld
143      IF ( .NOT. lk_cpl ) THEN   ! --- forced case, fluxes to the lead are the same as over the ocean
144         !
145         zqsr(:,:) = qsr(:,:)      ; zqns(:,:) = qns(:,:)
146         !
147      ELSE                       ! --- coupled case, fluxes to the lead are total - intercepted
148         !
149         zqsr(:,:) = qsr_tot(:,:)  ; zqns(:,:) = qns_tot(:,:)
150         !
151         DO jl = 1, jpl
152            DO jj = 1, jpj
153               DO ji = 1, jpi
154                  zqsr(ji,jj) = zqsr(ji,jj) - qsr_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
155                  zqns(ji,jj) = zqns(ji,jj) - qns_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
156               END DO
157            END DO
158         END DO
159         !
160      ENDIF
161
162      DO jj = 1, jpj
163         DO ji = 1, jpi
164            rswitch  = tms(ji,jj) * ( 1._wp - MAX( 0._wp , SIGN( 1._wp , - at_i(ji,jj) + epsi10 ) ) ) ! 0 if no ice
165            !
166            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
167            !           !  practically no "direct lateral ablation"
168            !           
169            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
170            !           !  temperature and turbulent mixing (McPhee, 1992)
171            !
172
173            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
174            ! REMARK valid at least in forced mode from clem
175            ! precip is included in qns but not in qns_ice
176            IF ( lk_cpl ) THEN
177               zqld =  tms(ji,jj) * rdt_ice *  &
178                  &    (   zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj)               &   ! pfrld already included in coupled mode
179                  &    + ( pfrld(ji,jj)**betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *     &   ! heat content of precip
180                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )   &
181                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt ) )
182            ELSE
183               zqld =  tms(ji,jj) * rdt_ice *  &
184                  &      ( pfrld(ji,jj) * ( zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj) )    &
185                  &    + ( pfrld(ji,jj)**betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *             &  ! heat content of precip
186                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )           &
187                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt ) )
188            ENDIF
189
190            !-- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
191            zqfr = tms(ji,jj) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
192
193            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
194            qlead(ji,jj) = MIN( 0._wp , zqld - zqfr ) 
195
196            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
197            IF( at_i(ji,jj) > epsi10 .AND. zqld > 0._wp ) THEN
198               fhld (ji,jj) = zqld * r1_rdtice / at_i(ji,jj) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
199               qlead(ji,jj) = 0._wp
200            ELSE
201               fhld (ji,jj) = 0._wp
202            ENDIF
203            !
204            !-- Energy from the turbulent oceanic heat flux --- !
205            !clem zfric_u        = MAX ( MIN( SQRT( ust2s(ji,jj) ) , zfric_umax ) , zfric_umin )
206            zfric_u      = MAX( SQRT( ust2s(ji,jj) ), zfric_umin ) 
207            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
208            ! upper bound for fhtur: we do not want SST to drop below Tfreeze.
209            ! So we say that the heat retrieved from the ocean (fhtur+fhld) must be < to the heat necessary to reach Tfreeze (zqfr)   
210            ! This is not a clean budget, so that should be corrected at some point
211            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - fhld(ji,jj) - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
212
213            ! -----------------------------------------
214            ! Net heat flux on top of ice-ocean [W.m-2]
215            ! -----------------------------------------
216            !     First  step here      : heat flux at the ocean surface + precip
217            !     Second step below     : heat flux at the ice   surface (after limthd_dif)
218            hfx_in(ji,jj) = hfx_in(ji,jj)                                                                                         & 
219               ! heat flux above the ocean
220               &    +             pfrld(ji,jj)   * ( zqns(ji,jj) + zqsr(ji,jj) )                                                  &
221               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
222               &    +   ( 1._wp - pfrld(ji,jj) ) * sprecip(ji,jj) * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )  &
223               &    +   ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt )
224
225            ! -----------------------------------------------------------------------------
226            ! Net heat flux that is retroceded to the ocean or taken from the ocean [W.m-2]
227            ! -----------------------------------------------------------------------------
228            !     First  step here              :  non solar + precip - qlead - qturb
229            !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
230            !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
231            hfx_out(ji,jj) = hfx_out(ji,jj)                                                                                       & 
232               ! Non solar heat flux received by the ocean
233               &    +        pfrld(ji,jj) * qns(ji,jj)                                                                            &
234               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
235               &    +      ( pfrld(ji,jj)**betas - pfrld(ji,jj) ) * sprecip(ji,jj)       &
236               &         * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )  &
237               &    +      ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt )       &
238               ! heat flux taken from the ocean where there is open water ice formation
239               &    -      qlead(ji,jj) * r1_rdtice                                                                               &
240               ! heat flux taken from the ocean during bottom growth/melt (fhld should be 0 while bott growth)
241               &    -      at_i(ji,jj) * fhtur(ji,jj)                                                                             &
242               &    -      at_i(ji,jj) *  fhld(ji,jj)
243
244         END DO
245      END DO
246
247      !------------------------------------------------------------------------------!
248      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
249      !------------------------------------------------------------------------------!
250
251      DO jl = 1, jpl      !loop over ice categories
252
253         IF( kt == nit000 .AND. lwp ) THEN
254            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
255            WRITE(numout,*) ' ~~~~~~~~'
256         ENDIF
257
258         nbpb = 0
259         DO jj = 1, jpj
260            DO ji = 1, jpi
261               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
262                  nbpb      = nbpb  + 1
263                  npb(nbpb) = (jj - 1) * jpi + ji
264               ENDIF
265            END DO
266         END DO
267
268         ! debug point to follow
269         jiindex_1d = 0
270         IF( ln_nicep ) THEN
271            DO ji = mi0(jiindx), mi1(jiindx)
272               DO jj = mj0(jjindx), mj1(jjindx)
273                  jiindex_1d = (jj - 1) * jpi + ji
274                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
275               END DO
276            END DO
277         ENDIF
278
279         !------------------------------------------------------------------------------!
280         ! 4) Thermodynamic computation
281         !------------------------------------------------------------------------------!
282
283         IF( lk_mpp )   CALL mpp_ini_ice( nbpb , numout )
284
285         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
286
287            !-------------------------
288            ! 4.1 Move to 1D arrays
289            !-------------------------
290
291            CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
292            CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
293            CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
294            CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
295
296            CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
297            CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
298            DO jk = 1, nlay_s
299               CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
300               CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
301            END DO
302            DO jk = 1, nlay_i
303               CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
304               CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
305               CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
306            END DO
307
308            CALL tab_2d_1d( nbpb, tatm_ice_1d(1:nbpb), tatm_ice(:,:)   , jpi, jpj, npb(1:nbpb) )
309            CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
310            CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
311            CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
312            CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
313            CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
314            IF( .NOT. lk_cpl ) THEN
315               CALL tab_2d_1d( nbpb, qla_ice_1d (1:nbpb), qla_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
316               CALL tab_2d_1d( nbpb, dqla_ice_1d(1:nbpb), dqla_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
317            ENDIF
318            CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
319            CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
320            CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
321            CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
322            CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
323            CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
324
325            CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
326            CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
327
328            CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
329            CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
330            CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
331            CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
332            CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
333            CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
334
335            CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
336            CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
337            CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
338            CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
339            CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
340            CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
341
342            CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
343            CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
344            CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
345            CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
346            CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
347            CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
348            CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
349            CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
350            CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
351            CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
352            CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
353            CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
354
355            !--------------------------------
356            ! 4.3) Thermodynamic processes
357            !--------------------------------
358
359            !--------------------------------------!
360            ! --- Ice/Snow Temperature profile --- !
361            !--------------------------------------!
362            CALL lim_thd_dif( 1, nbpb )
363
364            !---------------------------------!
365            ! --- Ice/Snow thickness ---      !
366            !---------------------------------!
367            CALL lim_thd_dh( 1, nbpb )   
368
369            ! --- Ice enthalpy remapping --- !
370            CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) ) 
371                                           
372            !---------------------------------!
373            ! --- Ice salinity ---            !
374            !---------------------------------!
375            CALL lim_thd_sal( 1, nbpb )   
376
377            !---------------------------------!
378            ! --- temperature update ---      !
379            !---------------------------------!
380            CALL lim_thd_temp( 1, nbpb )
381
382            !------------------------------------!
383            ! --- lateral melting if monocat --- !
384            !------------------------------------!
385            IF ( ( ( nn_monocat == 1 ) .OR. ( nn_monocat == 4 ) ) .AND. ( jpl == 1 ) ) THEN
386               CALL lim_thd_lam( 1, nbpb )
387            END IF
388
389            !--------------------------------
390            ! 4.4) Move 1D to 2D vectors
391            !--------------------------------
392
393               CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
394               CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
395               CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
396               CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
397               CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
398               CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
399            DO jk = 1, nlay_s
400               CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
401               CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
402            END DO
403            DO jk = 1, nlay_i
404               CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
405               CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
406               CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
407            END DO
408               CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
409
410               CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
411               CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
412
413               CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
414               CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
415               CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
416               CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
417               CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
418               CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
419
420               CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
421               CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
422               CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
423               CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
424               CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
425               CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
426
427              CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
428              CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
429              CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
430              CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
431              CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
432              CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
433              CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
434              CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
435              CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
436              CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
437              CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
438              CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
439            !
440              CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
441              CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
442            !
443            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
444         ENDIF
445         !
446      END DO
447
448      !------------------------------------------------------------------------------!
449      ! 5) Global variables, diagnostics
450      !------------------------------------------------------------------------------!
451
452      !------------------------
453      ! Ice heat content             
454      !------------------------
455      ! Enthalpies are global variables we have to readjust the units (heat content in Joules)
456      DO jl = 1, jpl
457         DO jk = 1, nlay_i
458            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * area(:,:) * a_i(:,:,jl) * ht_i(:,:,jl) / ( unit_fac * REAL( nlay_i ) )
459         END DO
460      END DO
461
462      !------------------------
463      ! Snow heat content             
464      !------------------------
465      ! Enthalpies are global variables we have to readjust the units (heat content in Joules)
466      DO jl = 1, jpl
467         DO jk = 1, nlay_s
468            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * area(:,:) * a_i(:,:,jl) * ht_s(:,:,jl) / ( unit_fac * REAL( nlay_s ) )
469         END DO
470      END DO
471 
472      !------------------------
473      ! Ice natural aging             
474      !------------------------
475      oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * rdt_ice /rday
476
477      !----------------------------------
478      ! Change thickness to volume
479      !----------------------------------
480      CALL lim_var_eqv2glo
481
482      !--------------------------------------------
483      ! 5.4) Diagnostic thermodynamic growth rates
484      !--------------------------------------------
485      IF( ln_nicep )   CALL lim_prt( kt, jiindx, jjindx, 1, ' - ice thermodyn. - ' )   ! control print
486
487      IF(ln_ctl) THEN            ! Control print
488         CALL prt_ctl_info(' ')
489         CALL prt_ctl_info(' - Cell values : ')
490         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
491         CALL prt_ctl(tab2d_1=area , clinfo1=' lim_thd  : cell area :')
492         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
493         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
494         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
495         DO jl = 1, jpl
496            CALL prt_ctl_info(' ')
497            CALL prt_ctl_info(' - Category : ', ivar1=jl)
498            CALL prt_ctl_info('   ~~~~~~~~~~')
499            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
500            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
501            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
502            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
503            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
504            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
505            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
506            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
507            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
508            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
509            DO jk = 1, nlay_i
510               CALL prt_ctl_info(' ')
511               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
512               CALL prt_ctl_info('   ~~~~~~~')
513               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
514               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
515            END DO
516         END DO
517      ENDIF
518      !
519      !
520      CALL wrk_dealloc( jpi, jpj, zqsr, zqns )
521
522      !------------------------------------------------------------------------------|
523      !  1) Transport of ice between thickness categories.                           |
524      !------------------------------------------------------------------------------|
525      ! Given thermodynamic growth rates, transport ice between
526      ! thickness categories.
527      IF( jpl > 1 )   CALL lim_itd_th_rem( 1, jpl, kt )
528      !
529      CALL lim_var_glo2eqv    ! only for info
530      CALL lim_var_agg(1)
531
532      !------------------------------------------------------------------------------|
533      !  3) Add frazil ice growing in leads.
534      !------------------------------------------------------------------------------|
535      CALL lim_thd_lac
536      CALL lim_var_glo2eqv    ! only for info
537     
538      IF(ln_ctl) THEN   ! Control print
539         CALL prt_ctl_info(' ')
540         CALL prt_ctl_info(' - Cell values : ')
541         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
542         CALL prt_ctl(tab2d_1=area , clinfo1=' lim_itd_th  : cell area :')
543         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
544         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
545         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
546         DO jl = 1, jpl
547            CALL prt_ctl_info(' ')
548            CALL prt_ctl_info(' - Category : ', ivar1=jl)
549            CALL prt_ctl_info('   ~~~~~~~~~~')
550            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
551            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
552            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
553            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
554            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
555            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
556            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
557            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
558            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
559            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
560            DO jk = 1, nlay_i
561               CALL prt_ctl_info(' ')
562               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
563               CALL prt_ctl_info('   ~~~~~~~')
564               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
565               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
566            END DO
567         END DO
568      ENDIF
569      !
570      ! conservation test
571      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
572
573      IF( nn_timing == 1 )  CALL timing_stop('limthd')
574
575   END SUBROUTINE lim_thd 
576
577   SUBROUTINE lim_thd_temp( kideb, kiut )
578      !!-----------------------------------------------------------------------
579      !!                   ***  ROUTINE lim_thd_temp ***
580      !!                 
581      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
582      !!
583      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
584      !!-------------------------------------------------------------------
585      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
586      !!
587      INTEGER  ::   ji, jk   ! dummy loop indices
588      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
589      !!-------------------------------------------------------------------
590      ! Recover ice temperature
591      DO jk = 1, nlay_i
592         DO ji = kideb, kiut
593            ztmelts       =  -tmut * s_i_1d(ji,jk) + rtt
594            ! Conversion q(S,T) -> T (second order equation)
595            zaaa          =  cpic
596            zbbb          =  ( rcp - cpic ) * ( ztmelts - rtt ) + q_i_1d(ji,jk) / rhoic - lfus
597            zccc          =  lfus * ( ztmelts - rtt )
598            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
599            t_i_1d(ji,jk) =  rtt - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
600           
601            ! mask temperature
602            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
603            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rtt
604         END DO
605      END DO
606
607   END SUBROUTINE lim_thd_temp
608
609   SUBROUTINE lim_thd_lam( kideb, kiut )
610      !!-----------------------------------------------------------------------
611      !!                   ***  ROUTINE lim_thd_lam ***
612      !!                 
613      !! ** Purpose :   Lateral melting in case monocategory
614      !!                          ( dA = A/2h dh )
615      !!-----------------------------------------------------------------------
616      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
617      INTEGER             ::   ji            ! dummy loop indices
618      REAL(wp)            ::   zhi_bef       ! ice thickness before thermo
619      REAL(wp)            ::   zdh_mel       ! net melting
620
621      DO ji = kideb, kiut
622         zhi_bef = ht_i_1d(ji) - ( dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) )
623         zdh_mel = MIN( 0._wp,     dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) )
624         IF( zdh_mel < 0._wp )   &
625            &   a_i_1d(ji) = MAX( 0._wp, a_i_1d(ji) + a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi10 ) ) ) 
626      END DO
627      at_i_1d(:) = a_i_1d(:)
628     
629   END SUBROUTINE lim_thd_lam
630
631   SUBROUTINE lim_thd_init
632      !!-----------------------------------------------------------------------
633      !!                   ***  ROUTINE lim_thd_init ***
634      !!                 
635      !! ** Purpose :   Physical constants and parameters linked to the ice
636      !!              thermodynamics
637      !!
638      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
639      !!              parameter values called at the first timestep (nit000)
640      !!
641      !! ** input   :   Namelist namicether
642      !!-------------------------------------------------------------------
643      INTEGER  ::   ios                 ! Local integer output status for namelist read
644      NAMELIST/namicethd/ hiccrit, fraz_swi, maxfrazb, vfrazb, Cfrazb,    &
645         &                hiclim, parsub, betas,                          & 
646         &                kappa_i, nconv_i_thd, maxer_i_thd, thcon_i_swi, &
647         &                nn_monocat
648      !!-------------------------------------------------------------------
649      !
650      IF(lwp) THEN
651         WRITE(numout,*)
652         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
653         WRITE(numout,*) '~~~~~~~'
654      ENDIF
655      !
656      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
657      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
658901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
659
660      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
661      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
662902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
663      IF(lwm) WRITE ( numoni, namicethd )
664      !
665      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
666         nn_monocat = 0
667         WRITE(numout, *) ' nn_monocat must be 0 in multi-category case '
668      ENDIF
669
670      IF( lk_cpl .AND. parsub /= 0.0 )   CALL ctl_stop( 'In coupled mode, use parsub = 0. or send dqla' )
671      !
672      IF(lwp) THEN                          ! control print
673         WRITE(numout,*)
674         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
675         WRITE(numout,*)'      ice thick. for lateral accretion                        hiccrit      = ', hiccrit
676         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       fraz_swi     = ', fraz_swi
677         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   maxfrazb     = ', maxfrazb
678         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  vfrazb       = ', vfrazb
679         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          Cfrazb       = ', Cfrazb
680         WRITE(numout,*)'      minimum ice thickness                                   hiclim       = ', hiclim 
681         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
682         WRITE(numout,*)'      switch for snow sublimation  (=1) or not (=0)           parsub       = ', parsub 
683         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          betas        = ', betas
684         WRITE(numout,*)'      extinction radiation parameter in sea ice               kappa_i      = ', kappa_i
685         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nconv_i_thd  = ', nconv_i_thd
686         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        maxer_i_thd  = ', maxer_i_thd
687         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     thcon_i_swi  = ', thcon_i_swi
688         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
689         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
690      ENDIF
691      !
692   END SUBROUTINE lim_thd_init
693
694#else
695   !!----------------------------------------------------------------------
696   !!   Default option         Dummy module          NO  LIM3 sea-ice model
697   !!----------------------------------------------------------------------
698#endif
699
700   !!======================================================================
701END MODULE limthd
Note: See TracBrowser for help on using the repository browser.