New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 5621

Last change on this file since 5621 was 5621, checked in by mathiot, 9 years ago

UKMO_ISF: upgrade to NEMO_3.6_STABLE (r5554)
  • Property svn:keywords set to Id
File size: 63.0 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38   !
39   USE in_out_manager  ! I/O manager
40   USE prtctl          ! Print control
41   USE lbclnk          ! lateral boundary condition
42   USE lib_mpp         ! MPP library
43   USE eosbn2          ! compute density
44   USE wrk_nemo        ! Memory Allocation
45   USE timing          ! Timing
46   USE iom
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   dyn_hpg        ! routine called by step module
52   PUBLIC   dyn_hpg_init   ! routine called by opa module
53
54   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
56   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
57   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
58   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
59   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
60   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
61   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
62
63   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE dyn_hpg( kt )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE dyn_hpg  ***
78      !!
79      !! ** Method  :   Call the hydrostatic pressure gradient routine
80      !!              using the scheme defined in the namelist
81      !!
82      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
90      !
91      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
92         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
93         ztrdu(:,:,:) = ua(:,:,:)
94         ztrdv(:,:,:) = va(:,:,:)
95      ENDIF
96      !
97      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
98      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
99      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
100      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
101      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
102      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
103      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
104      END SELECT
105      !
106      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
107         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
108         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
109         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
110         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
111      ENDIF
112      !
113      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
114         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
115      !
116      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
117      !
118   END SUBROUTINE dyn_hpg
119
120
121   SUBROUTINE dyn_hpg_init
122      !!----------------------------------------------------------------------
123      !!                 ***  ROUTINE dyn_hpg_init  ***
124      !!
125      !! ** Purpose :   initializations for the hydrostatic pressure gradient
126      !!              computation and consistency control
127      !!
128      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
129      !!      with the type of vertical coordinate used (zco, zps, sco)
130      !!----------------------------------------------------------------------
131      INTEGER ::   ioptio = 0      ! temporary integer
132      INTEGER ::   ios             ! Local integer output status for namelist read
133      !!
134      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
135      REAL(wp) ::   znad
136      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop, zrhd ! hypothesys on isf density
137      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_isf  ! density at bottom of ISF
138      REAL(wp), POINTER, DIMENSION(:,:)     ::  ziceload     ! density at bottom of ISF
139      !!
140      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
141         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
142      !!----------------------------------------------------------------------
143      !
144      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
145      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
146901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
147
148      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
149      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
150902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
151      IF(lwm) WRITE ( numond, namdyn_hpg )
152      !
153      IF(lwp) THEN                   ! Control print
154         WRITE(numout,*)
155         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
156         WRITE(numout,*) '~~~~~~~~~~~~'
157         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
158         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
159         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
160         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
161         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
162         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
163         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
164         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
165      ENDIF
166      !
167      IF( ln_hpg_djc )   &
168         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
169                           & currently disabled (bugs under investigation). Please select &
170                           & either  ln_hpg_sco or  ln_hpg_prj instead')
171      !
172      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
173         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
174                           & the standard jacobian formulation hpg_sco or &
175                           & the pressure jacobian formulation hpg_prj')
176
177      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
178         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
179      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
180         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
181      !
182      !                               ! Set nhpg from ln_hpg_... flags
183      IF( ln_hpg_zco )   nhpg = 0
184      IF( ln_hpg_zps )   nhpg = 1
185      IF( ln_hpg_sco )   nhpg = 2
186      IF( ln_hpg_djc )   nhpg = 3
187      IF( ln_hpg_prj )   nhpg = 4
188      IF( ln_hpg_isf )   nhpg = 5
189      !
190      !                               ! Consistency check
191      ioptio = 0
192      IF( ln_hpg_zco )   ioptio = ioptio + 1
193      IF( ln_hpg_zps )   ioptio = ioptio + 1
194      IF( ln_hpg_sco )   ioptio = ioptio + 1
195      IF( ln_hpg_djc )   ioptio = ioptio + 1
196      IF( ln_hpg_prj )   ioptio = ioptio + 1
197      IF( ln_hpg_isf )   ioptio = ioptio + 1
198      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
199      !
200      ! initialisation of ice shelf load
201      IF ( .NOT. ln_isfcav ) riceload(:,:)=0.0
202      IF (       ln_isfcav ) THEN
203         CALL wrk_alloc( jpi,jpj, 2,  ztstop) 
204         CALL wrk_alloc( jpi,jpj,jpk, zrhd  )
205         CALL wrk_alloc( jpi,jpj,     zrhdtop_isf, ziceload) 
206         !
207         IF(lwp) WRITE(numout,*)
208         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
209         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' 
210
211         ! To use density and not density anomaly
212         znad=1._wp
213         
214         ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
215         ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
216
217         ! compute density of the water displaced by the ice shelf
218         DO jk = 1, jpk
219            CALL eos(ztstop(:,:,:),fsdept_n(:,:,jk),zrhd(:,:,jk))
220         END DO
221     
222         ! compute rhd at the ice/oce interface (ice shelf side)
223         CALL eos(ztstop,risfdep,zrhdtop_isf)
224
225         ! Surface value + ice shelf gradient
226         ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
227         ziceload = 0._wp
228         DO jj = 1, jpj
229            DO ji = 1, jpi   ! vector opt.
230               ikt=mikt(ji,jj)
231               ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
232               DO jk=2,ikt-1
233                  ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
234                     &                              * (1._wp - tmask(ji,jj,jk))
235               END DO
236               IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
237                                  &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
238            END DO
239         END DO
240         riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
241
242         CALL wrk_dealloc( jpi,jpj, 2,  ztstop) 
243         CALL wrk_dealloc( jpi,jpj,jpk, zrhd  )
244         CALL wrk_dealloc( jpi,jpj,     zrhdtop_isf, ziceload) 
245      END IF
246      !
247   END SUBROUTINE dyn_hpg_init
248
249
250   SUBROUTINE hpg_zco( kt )
251      !!---------------------------------------------------------------------
252      !!                  ***  ROUTINE hpg_zco  ***
253      !!
254      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
255      !!      The now hydrostatic pressure gradient at a given level, jk,
256      !!      is computed by taking the vertical integral of the in-situ
257      !!      density gradient along the model level from the suface to that
258      !!      level:    zhpi = grav .....
259      !!                zhpj = grav .....
260      !!      add it to the general momentum trend (ua,va).
261      !!            ua = ua - 1/e1u * zhpi
262      !!            va = va - 1/e2v * zhpj
263      !!
264      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
265      !!----------------------------------------------------------------------
266      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
267      !!
268      INTEGER  ::   ji, jj, jk       ! dummy loop indices
269      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
270      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
271      !!----------------------------------------------------------------------
272      !
273      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
274      !
275      IF( kt == nit000 ) THEN
276         IF(lwp) WRITE(numout,*)
277         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
278         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
279      ENDIF
280
281      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
282
283      ! Surface value
284      DO jj = 2, jpjm1
285         DO ji = fs_2, fs_jpim1   ! vector opt.
286            zcoef1 = zcoef0 * fse3w(ji,jj,1)
287            ! hydrostatic pressure gradient
288            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
289            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
290            ! add to the general momentum trend
291            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
292            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
293         END DO
294      END DO
295
296      !
297      ! interior value (2=<jk=<jpkm1)
298      DO jk = 2, jpkm1
299         DO jj = 2, jpjm1
300            DO ji = fs_2, fs_jpim1   ! vector opt.
301               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
302               ! hydrostatic pressure gradient
303               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
304                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
305                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
306
307               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
308                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
309                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
310               ! add to the general momentum trend
311               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
312               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
313            END DO
314         END DO
315      END DO
316      !
317      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
318      !
319   END SUBROUTINE hpg_zco
320
321
322   SUBROUTINE hpg_zps( kt )
323      !!---------------------------------------------------------------------
324      !!                 ***  ROUTINE hpg_zps  ***
325      !!
326      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
327      !!
328      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
329      !!----------------------------------------------------------------------
330      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
331      !!
332      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
333      INTEGER  ::   iku, ikv                         ! temporary integers
334      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
335      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
336      !!----------------------------------------------------------------------
337      !
338      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
339      !
340      IF( kt == nit000 ) THEN
341         IF(lwp) WRITE(numout,*)
342         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
343         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
344      ENDIF
345
346
347      ! Local constant initialization
348      zcoef0 = - grav * 0.5_wp
349
350      !  Surface value (also valid in partial step case)
351      DO jj = 2, jpjm1
352         DO ji = fs_2, fs_jpim1   ! vector opt.
353            zcoef1 = zcoef0 * fse3w(ji,jj,1)
354            ! hydrostatic pressure gradient
355            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
356            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
357            ! add to the general momentum trend
358            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
359            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
360         END DO
361      END DO
362
363
364      ! interior value (2=<jk=<jpkm1)
365      DO jk = 2, jpkm1
366         DO jj = 2, jpjm1
367            DO ji = fs_2, fs_jpim1   ! vector opt.
368               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
369               ! hydrostatic pressure gradient
370               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
371                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
372                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
373
374               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
375                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
376                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
377               ! add to the general momentum trend
378               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
379               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
380            END DO
381         END DO
382      END DO
383
384
385      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
386      DO jj = 2, jpjm1
387         DO ji = 2, jpim1
388            iku = mbku(ji,jj)
389            ikv = mbkv(ji,jj)
390            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
391            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
392            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
393               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
394               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
395                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
396               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
397            ENDIF
398            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
399               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
400               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
401                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
402               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
403            ENDIF
404         END DO
405      END DO
406      !
407      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
408      !
409   END SUBROUTINE hpg_zps
410
411   SUBROUTINE hpg_sco( kt )
412      !!---------------------------------------------------------------------
413      !!                  ***  ROUTINE hpg_sco  ***
414      !!
415      !! ** Method  :   s-coordinate case. Jacobian scheme.
416      !!      The now hydrostatic pressure gradient at a given level, jk,
417      !!      is computed by taking the vertical integral of the in-situ
418      !!      density gradient along the model level from the suface to that
419      !!      level. s-coordinates (ln_sco): a corrective term is added
420      !!      to the horizontal pressure gradient :
421      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
422      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
423      !!      add it to the general momentum trend (ua,va).
424      !!         ua = ua - 1/e1u * zhpi
425      !!         va = va - 1/e2v * zhpj
426      !!
427      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
428      !!----------------------------------------------------------------------
429      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
430      !!
431      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
432      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
433      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
434      !!----------------------------------------------------------------------
435      !
436      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
437      !
438      IF( kt == nit000 ) THEN
439         IF(lwp) WRITE(numout,*)
440         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
441         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
442      ENDIF
443
444      ! Local constant initialization
445      zcoef0 = - grav * 0.5_wp
446      ! To use density and not density anomaly
447      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
448      ELSE                 ;     znad = 0._wp         ! Fixed volume
449      ENDIF
450
451      ! Surface value
452      DO jj = 2, jpjm1
453         DO ji = fs_2, fs_jpim1   ! vector opt.
454            ! hydrostatic pressure gradient along s-surfaces
455            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
456               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
457            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
458               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
459            ! s-coordinate pressure gradient correction
460            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
461               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
462            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
463               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
464            ! add to the general momentum trend
465            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
466            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
467         END DO
468      END DO
469
470      ! interior value (2=<jk=<jpkm1)
471      DO jk = 2, jpkm1
472         DO jj = 2, jpjm1
473            DO ji = fs_2, fs_jpim1   ! vector opt.
474               ! hydrostatic pressure gradient along s-surfaces
475               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
476                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
477                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
478               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
479                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
480                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
481               ! s-coordinate pressure gradient correction
482               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
483                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
484               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
485                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
486               ! add to the general momentum trend
487               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
488               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
489            END DO
490         END DO
491      END DO
492      !
493      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
494      !
495   END SUBROUTINE hpg_sco
496
497   SUBROUTINE hpg_isf( kt )
498      !!---------------------------------------------------------------------
499      !!                  ***  ROUTINE hpg_sco  ***
500      !!
501      !! ** Method  :   s-coordinate case. Jacobian scheme.
502      !!      The now hydrostatic pressure gradient at a given level, jk,
503      !!      is computed by taking the vertical integral of the in-situ
504      !!      density gradient along the model level from the suface to that
505      !!      level. s-coordinates (ln_sco): a corrective term is added
506      !!      to the horizontal pressure gradient :
507      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
508      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
509      !!      add it to the general momentum trend (ua,va).
510      !!         ua = ua - 1/e1u * zhpi
511      !!         va = va - 1/e2v * zhpj
512      !!      iceload is added and partial cell case are added to the top and bottom
513      !!     
514      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
515      !!----------------------------------------------------------------------
516      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
517      !!
518      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
519      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
520      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj
521      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
522      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_oce, zpshpi, zpshpj
523      !!----------------------------------------------------------------------
524      !
525      CALL wrk_alloc( jpi,jpj,  2, ztstop) 
526      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj)
527      CALL wrk_alloc( jpi,jpj,     zrhdtop_oce, zpshpi, zpshpj) 
528      !
529      ! Local constant initialization
530      zcoef0 = - grav * 0.5_wp
531   
532      ! To use density and not density anomaly
533      znad=1._wp
534
535      ! iniitialised to 0. zhpi zhpi
536      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
537
538      ! compute rhd at the ice/oce interface (ocean side) usefull to reduce unrealistic water current if homogene water
539!  TO BE DISCUSS do we compute density at w point for the ocean/ice atmosphere
540!      DO ji=1,jpi
541!        DO jj=1,jpj
542!          ikt=mikt(ji,jj)
543!          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
544!          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
545!        END DO
546!      END DO
547!      CALL eos(ztstop,risfdep,zrhdtop_oce)
548
549      DO jj = 2, jpjm1
550         DO ji = fs_2, fs_jpim1   ! vector opt.
551            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
552            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
553            ! we assume ISF is in isostatic equilibrium
554            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,iktp1i) * ( znad + rhd(ji+1,jj  ,iktp1i) )   &
555               &                                  - fse3w(ji  ,jj  ,ikt   ) * ( znad + rhd(ji  ,jj  ,ikt   ) )   &
556               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                       ) 
557            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,iktp1j) * ( znad + rhd(ji  ,jj+1,iktp1j) )   &
558               &                                  - fse3w(ji  ,jj  ,ikt   ) * ( znad + rhd(ji  ,jj  ,ikt   ) )   &
559               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj) )                      ) 
560!            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
561!               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
562!               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
563!               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
564!               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                              )
565!            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
566!               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
567!               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
568!               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
569!               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj) )                             )
570            ! s-coordinate pressure gradient correction (=0 if z coordinate)
571            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
572               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
573            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
574               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
575            ! add to the general momentum trend
576            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
577            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
578         END DO
579      END DO
580
581!==================================================================================     
582!===== Compute interior value =====================================================
583!==================================================================================
584      ! interior value (2=<jk=<jpkm1)
585      DO jk = 2, jpkm1
586         DO jj = 2, jpjm1
587            DO ji = fs_2, fs_jpim1   ! vector opt.
588               ! hydrostatic pressure gradient along s-surfaces
589               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
590                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
591                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
592               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
593                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
594                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
595               ! s-coordinate pressure gradient correction
596               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
597                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
598               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
599                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
600               ! add to the general momentum trend
601               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
602               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
603            END DO
604         END DO
605      END DO
606      !
607      CALL wrk_dealloc( jpi,jpj,2  , ztstop)
608      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj)
609      CALL wrk_dealloc( jpi,jpj    , zrhdtop_oce, zpshpi, zpshpj)
610      !
611   END SUBROUTINE hpg_isf
612
613
614   SUBROUTINE hpg_djc( kt )
615      !!---------------------------------------------------------------------
616      !!                  ***  ROUTINE hpg_djc  ***
617      !!
618      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
619      !!
620      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
621      !!----------------------------------------------------------------------
622      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
623      !!
624      INTEGER  ::   ji, jj, jk          ! dummy loop indices
625      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
626      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
627      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
628      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
629      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
630      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
631      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
632      !!----------------------------------------------------------------------
633      !
634      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
635      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
636      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
637      !
638
639      IF( kt == nit000 ) THEN
640         IF(lwp) WRITE(numout,*)
641         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
642         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
643      ENDIF
644
645      ! Local constant initialization
646      zcoef0 = - grav * 0.5_wp
647      z1_10  = 1._wp / 10._wp
648      z1_12  = 1._wp / 12._wp
649
650      !----------------------------------------------------------------------------------------
651      !  compute and store in provisional arrays elementary vertical and horizontal differences
652      !----------------------------------------------------------------------------------------
653
654!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
655
656      DO jk = 2, jpkm1
657         DO jj = 2, jpjm1
658            DO ji = fs_2, fs_jpim1   ! vector opt.
659               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
660               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
661               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
662               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
663               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
664               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
665            END DO
666         END DO
667      END DO
668
669      !-------------------------------------------------------------------------
670      ! compute harmonic averages using eq. 5.18
671      !-------------------------------------------------------------------------
672      zep = 1.e-15
673
674!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
675!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
676
677      DO jk = 2, jpkm1
678         DO jj = 2, jpjm1
679            DO ji = fs_2, fs_jpim1   ! vector opt.
680               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
681
682               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
683               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
684
685               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
686               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
687
688               IF( cffw > zep) THEN
689                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
690                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
691               ELSE
692                  drhow(ji,jj,jk) = 0._wp
693               ENDIF
694
695               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
696                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
697
698               IF( cffu > zep ) THEN
699                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
700                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
701               ELSE
702                  drhou(ji,jj,jk ) = 0._wp
703               ENDIF
704
705               IF( cffx > zep ) THEN
706                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
707                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
708               ELSE
709                  dzu(ji,jj,jk) = 0._wp
710               ENDIF
711
712               IF( cffv > zep ) THEN
713                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
714                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
715               ELSE
716                  drhov(ji,jj,jk) = 0._wp
717               ENDIF
718
719               IF( cffy > zep ) THEN
720                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
721                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
722               ELSE
723                  dzv(ji,jj,jk) = 0._wp
724               ENDIF
725
726            END DO
727         END DO
728      END DO
729
730      !----------------------------------------------------------------------------------
731      ! apply boundary conditions at top and bottom using 5.36-5.37
732      !----------------------------------------------------------------------------------
733      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
734      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
735      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
736
737      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
738      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
739      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
740
741
742      !--------------------------------------------------------------
743      ! Upper half of top-most grid box, compute and store
744      !-------------------------------------------------------------
745
746!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
747!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
748
749      DO jj = 2, jpjm1
750         DO ji = fs_2, fs_jpim1   ! vector opt.
751            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
752               &                   * (  rhd(ji,jj,1)                                    &
753               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
754               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
755               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
756         END DO
757      END DO
758
759!!bug gm    : here also, simplification is possible
760!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
761
762      DO jk = 2, jpkm1
763         DO jj = 2, jpjm1
764            DO ji = fs_2, fs_jpim1   ! vector opt.
765
766               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
767                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
768                  &            - grav * z1_10 * (                                                                     &
769                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
770                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
771                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
772                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
773                  &                             )
774
775               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
776                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
777                  &            - grav* z1_10 * (                                                                      &
778                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
779                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
780                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
781                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
782                  &                            )
783
784               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
785                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
786                  &            - grav* z1_10 * (                                                                      &
787                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
788                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
789                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
790                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
791                  &                            )
792
793            END DO
794         END DO
795      END DO
796      CALL lbc_lnk(rho_k,'W',1.)
797      CALL lbc_lnk(rho_i,'U',1.)
798      CALL lbc_lnk(rho_j,'V',1.)
799
800
801      ! ---------------
802      !  Surface value
803      ! ---------------
804      DO jj = 2, jpjm1
805         DO ji = fs_2, fs_jpim1   ! vector opt.
806            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
807            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
808            ! add to the general momentum trend
809            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
810            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
811         END DO
812      END DO
813
814      ! ----------------
815      !  interior value   (2=<jk=<jpkm1)
816      ! ----------------
817      DO jk = 2, jpkm1
818         DO jj = 2, jpjm1
819            DO ji = fs_2, fs_jpim1   ! vector opt.
820               ! hydrostatic pressure gradient along s-surfaces
821               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
822                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
823                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
824               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
825                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
826                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
827               ! add to the general momentum trend
828               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
829               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
830            END DO
831         END DO
832      END DO
833      !
834      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
835      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
836      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
837      !
838   END SUBROUTINE hpg_djc
839
840
841   SUBROUTINE hpg_prj( kt )
842      !!---------------------------------------------------------------------
843      !!                  ***  ROUTINE hpg_prj  ***
844      !!
845      !! ** Method  :   s-coordinate case.
846      !!      A Pressure-Jacobian horizontal pressure gradient method
847      !!      based on the constrained cubic-spline interpolation for
848      !!      all vertical coordinate systems
849      !!
850      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
851      !!----------------------------------------------------------------------
852      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
853      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
854      !!
855      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
856      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
857      !!
858      !! The local variables for the correction term
859      INTEGER  :: jk1, jis, jid, jjs, jjd
860      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
861      REAL(wp) :: zrhdt1
862      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
863      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
864      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
865      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
866      !!----------------------------------------------------------------------
867      !
868      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
869      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
870      CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
871      !
872      IF( kt == nit000 ) THEN
873         IF(lwp) WRITE(numout,*)
874         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
875         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
876      ENDIF
877
878      !!----------------------------------------------------------------------
879      ! Local constant initialization
880      zcoef0 = - grav
881      znad = 0.0_wp
882      IF( lk_vvl ) znad = 1._wp
883
884      ! Clean 3-D work arrays
885      zhpi(:,:,:) = 0._wp
886      zrhh(:,:,:) = rhd(:,:,:)
887
888      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
889      DO jj = 1, jpj
890        DO ji = 1, jpi
891          jk = mbathy(ji,jj)
892          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
893          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
894          ELSE IF(jk < jpkm1) THEN
895             DO jkk = jk+1, jpk
896                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
897                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
898             END DO
899          ENDIF
900        END DO
901      END DO
902
903      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
904      DO jj = 1, jpj
905         DO ji = 1, jpi
906            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
907         END DO
908      END DO
909
910      DO jk = 2, jpk
911         DO jj = 1, jpj
912            DO ji = 1, jpi
913               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
914            END DO
915         END DO
916      END DO
917
918      fsp(:,:,:) = zrhh (:,:,:)
919      xsp(:,:,:) = zdept(:,:,:)
920
921      ! Construct the vertical density profile with the
922      ! constrained cubic spline interpolation
923      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
924      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
925
926      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
927      DO jj = 2, jpj
928        DO ji = 2, jpi
929          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
930                                         bsp(ji,jj,1),   csp(ji,jj,1), &
931                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
932
933          ! assuming linear profile across the top half surface layer
934          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
935        END DO
936      END DO
937
938      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
939      DO jk = 2, jpkm1
940        DO jj = 2, jpj
941          DO ji = 2, jpi
942            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
943                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
944                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
945                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
946          END DO
947        END DO
948      END DO
949
950      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
951
952      ! Prepare zsshu_n and zsshv_n
953      DO jj = 2, jpjm1
954        DO ji = 2, jpim1
955          zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
956                         & r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
957          zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
958                         & r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
959        END DO
960      END DO
961
962      DO jj = 2, jpjm1
963        DO ji = 2, jpim1
964          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad) 
965          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
966        END DO
967      END DO
968
969      DO jk = 2, jpkm1
970        DO jj = 2, jpjm1
971          DO ji = 2, jpim1
972            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
973            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
974          END DO
975        END DO
976      END DO
977
978      DO jk = 1, jpkm1
979        DO jj = 2, jpjm1
980          DO ji = 2, jpim1
981            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
982            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
983          END DO
984        END DO
985      END DO
986
987      DO jk = 1, jpkm1
988        DO jj = 2, jpjm1
989          DO ji = 2, jpim1
990            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
991            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
992            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
993            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
994          END DO
995        END DO
996      END DO
997
998
999      DO jk = 1, jpkm1
1000        DO jj = 2, jpjm1
1001          DO ji = 2, jpim1
1002            zpwes = 0._wp; zpwed = 0._wp
1003            zpnss = 0._wp; zpnsd = 0._wp
1004            zuijk = zu(ji,jj,jk)
1005            zvijk = zv(ji,jj,jk)
1006
1007            !!!!!     for u equation
1008            IF( jk <= mbku(ji,jj) ) THEN
1009               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1010                 jis = ji + 1; jid = ji
1011               ELSE
1012                 jis = ji;     jid = ji +1
1013               ENDIF
1014
1015               ! integrate the pressure on the shallow side
1016               jk1 = jk
1017               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1018                 IF( jk1 == mbku(ji,jj) ) THEN
1019                   zuijk = -zdept(jis,jj,jk1)
1020                   EXIT
1021                 ENDIF
1022                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1023                 zpwes = zpwes +                                    &
1024                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1025                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1026                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1027                 jk1 = jk1 + 1
1028               END DO
1029
1030               ! integrate the pressure on the deep side
1031               jk1 = jk
1032               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1033                 IF( jk1 == 1 ) THEN
1034                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1035                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1036                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1037                                                     dsp(jid,jj,1)) * zdeps
1038                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1039                   EXIT
1040                 ENDIF
1041                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1042                 zpwed = zpwed +                                        &
1043                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1044                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1045                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1046                 jk1 = jk1 - 1
1047               END DO
1048
1049               ! update the momentum trends in u direction
1050
1051               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1052               IF( lk_vvl ) THEN
1053                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1054                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1055                ELSE
1056                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1057               ENDIF
1058
1059               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1060               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1061            ENDIF
1062
1063            !!!!!     for v equation
1064            IF( jk <= mbkv(ji,jj) ) THEN
1065               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1066                 jjs = jj + 1; jjd = jj
1067               ELSE
1068                 jjs = jj    ; jjd = jj + 1
1069               ENDIF
1070
1071               ! integrate the pressure on the shallow side
1072               jk1 = jk
1073               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1074                 IF( jk1 == mbkv(ji,jj) ) THEN
1075                   zvijk = -zdept(ji,jjs,jk1)
1076                   EXIT
1077                 ENDIF
1078                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1079                 zpnss = zpnss +                                      &
1080                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1081                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1082                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1083                 jk1 = jk1 + 1
1084               END DO
1085
1086               ! integrate the pressure on the deep side
1087               jk1 = jk
1088               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1089                 IF( jk1 == 1 ) THEN
1090                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1091                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1092                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1093                                                     dsp(ji,jjd,1) ) * zdeps
1094                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1095                   EXIT
1096                 ENDIF
1097                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1098                 zpnsd = zpnsd +                                        &
1099                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1100                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1101                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1102                 jk1 = jk1 - 1
1103               END DO
1104
1105
1106               ! update the momentum trends in v direction
1107
1108               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1109               IF( lk_vvl ) THEN
1110                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1111                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1112               ELSE
1113                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1114               ENDIF
1115
1116               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1117               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1118            ENDIF
1119
1120
1121           END DO
1122        END DO
1123      END DO
1124      !
1125      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1126      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1127      CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1128      !
1129   END SUBROUTINE hpg_prj
1130
1131
1132   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1133      !!----------------------------------------------------------------------
1134      !!                 ***  ROUTINE cspline  ***
1135      !!
1136      !! ** Purpose :   constrained cubic spline interpolation
1137      !!
1138      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1139      !!
1140      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1141      !!----------------------------------------------------------------------
1142      IMPLICIT NONE
1143      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1144      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1145                                                                    ! the interpoated function
1146      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1147                                                                    ! 2: Linear
1148      !
1149      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1150      INTEGER  ::   jpi, jpj, jpkm1
1151      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1152      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1153      REAL(wp) ::   zdf(size(fsp,3))
1154      !!----------------------------------------------------------------------
1155
1156      jpi   = size(fsp,1)
1157      jpj   = size(fsp,2)
1158      jpkm1 = size(fsp,3) - 1
1159
1160
1161      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1162         DO ji = 1, jpi
1163            DO jj = 1, jpj
1164           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1165           !    DO jk = 2, jpkm1-1
1166           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1167           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1168           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1169           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1170           !
1171           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1172           !
1173           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1174           !           zdf(jk) = 0._wp
1175           !       ELSE
1176           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1177           !       ENDIF
1178           !    END DO
1179
1180           !!Simply geometric average
1181               DO jk = 2, jpkm1-1
1182                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1183                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1184
1185                  IF(zdf1 * zdf2 <= 0._wp) THEN
1186                     zdf(jk) = 0._wp
1187                  ELSE
1188                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1189                  ENDIF
1190               END DO
1191
1192               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1193                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1194               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1195                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1196                          & 0.5_wp * zdf(jpkm1 - 1)
1197
1198               DO jk = 1, jpkm1 - 1
1199                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1200                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1201                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1202                 zddf1  = -2._wp * ztmp1 + ztmp2
1203                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1204                 zddf2  =  2._wp * ztmp1 - ztmp2
1205
1206                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1207                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1208                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1209                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1210                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1211                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1212                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1213                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1214                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1215               END DO
1216            END DO
1217         END DO
1218
1219      ELSE IF (polynomial_type == 2) THEN     ! Linear
1220         DO ji = 1, jpi
1221            DO jj = 1, jpj
1222               DO jk = 1, jpkm1-1
1223                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1224                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1225
1226                  dsp(ji,jj,jk) = 0._wp
1227                  csp(ji,jj,jk) = 0._wp
1228                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1229                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1230               END DO
1231            END DO
1232         END DO
1233
1234      ELSE
1235           CALL ctl_stop( 'invalid polynomial type in cspline' )
1236      ENDIF
1237
1238   END SUBROUTINE cspline
1239
1240
1241   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1242      !!----------------------------------------------------------------------
1243      !!                 ***  ROUTINE interp1  ***
1244      !!
1245      !! ** Purpose :   1-d linear interpolation
1246      !!
1247      !! ** Method  :   interpolation is straight forward
1248      !!                extrapolation is also permitted (no value limit)
1249      !!----------------------------------------------------------------------
1250      IMPLICIT NONE
1251      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1252      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1253      REAL(wp)             ::  zdeltx
1254      !!----------------------------------------------------------------------
1255
1256      zdeltx = xr - xl
1257      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1258        f = 0.5_wp * (fl + fr)
1259      ELSE
1260        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1261      ENDIF
1262
1263   END FUNCTION interp1
1264
1265
1266   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1267      !!----------------------------------------------------------------------
1268      !!                 ***  ROUTINE interp1  ***
1269      !!
1270      !! ** Purpose :   1-d constrained cubic spline interpolation
1271      !!
1272      !! ** Method  :  cubic spline interpolation
1273      !!
1274      !!----------------------------------------------------------------------
1275      IMPLICIT NONE
1276      REAL(wp), INTENT(in) ::  x, a, b, c, d
1277      REAL(wp)             ::  f ! value from the interpolation
1278      !!----------------------------------------------------------------------
1279
1280      f = a + x* ( b + x * ( c + d * x ) )
1281
1282   END FUNCTION interp2
1283
1284
1285   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1286      !!----------------------------------------------------------------------
1287      !!                 ***  ROUTINE interp1  ***
1288      !!
1289      !! ** Purpose :   Calculate the first order of deriavtive of
1290      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1291      !!
1292      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1293      !!
1294      !!----------------------------------------------------------------------
1295      IMPLICIT NONE
1296      REAL(wp), INTENT(in) ::  x, a, b, c, d
1297      REAL(wp)             ::  f ! value from the interpolation
1298      !!----------------------------------------------------------------------
1299
1300      f = b + x * ( 2._wp * c + 3._wp * d * x)
1301
1302   END FUNCTION interp3
1303
1304
1305   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1306      !!----------------------------------------------------------------------
1307      !!                 ***  ROUTINE interp1  ***
1308      !!
1309      !! ** Purpose :   1-d constrained cubic spline integration
1310      !!
1311      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1312      !!
1313      !!----------------------------------------------------------------------
1314      IMPLICIT NONE
1315      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1316      REAL(wp)             ::  za1, za2, za3
1317      REAL(wp)             ::  f                   ! integration result
1318      !!----------------------------------------------------------------------
1319
1320      za1 = 0.5_wp * b
1321      za2 = c / 3.0_wp
1322      za3 = 0.25_wp * d
1323
1324      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1325         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1326
1327   END FUNCTION integ_spline
1328
1329   !!======================================================================
1330END MODULE dynhpg
1331
Note: See TracBrowser for help on using the repository browser.