New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/TRA/zpshde.F90 @ 5921

Last change on this file since 5921 was 5921, checked in by mathiot, 8 years ago

ISF: modification of how we compute contribution to hpg of the first half wet cell beneath an ice shelf
  • Property svn:keywords set to Id
File size: 24.6 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!            3.6  !  2014-11  (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
11   !!======================================================================
12   
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean: dynamics and tracers variables
18   USE dom_oce         ! domain: ocean variables
19   USE phycst          ! physical constants
20   USE eosbn2          ! ocean equation of state
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! MPP library
24   USE wrk_nemo        ! Memory allocation
25   USE timing          ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   zps_hde     ! routine called by step.F90
31   PUBLIC   zps_hde_isf ! routine called by step.F90
32
33   !! * Substitutions
34#  include "domzgr_substitute.h90"
35#  include "vectopt_loop_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
38   !! $Id$
39   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE zps_hde( kt, kjpt, pta, pgtu, pgtv,   &
44      &                          prd, pgru, pgrv    )
45      !!----------------------------------------------------------------------
46      !!                     ***  ROUTINE zps_hde  ***
47      !!                   
48      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
49      !!      at u- and v-points with a linear interpolation for z-coordinate
50      !!      with partial steps.
51      !!
52      !! ** Method  :   In z-coord with partial steps, scale factors on last
53      !!      levels are different for each grid point, so that T, S and rd
54      !!      points are not at the same depth as in z-coord. To have horizontal
55      !!      gradients again, we interpolate T and S at the good depth :
56      !!      Linear interpolation of T, S   
57      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
58      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
59      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
60      !!         This formulation computes the two cases:
61      !!                 CASE 1                   CASE 2 
62      !!         k-1  ___ ___________   k-1   ___ ___________
63      !!                    Ti  T~                  T~  Ti+1
64      !!                  _____                        _____
65      !!         k        |   |Ti+1     k           Ti |   |
66      !!                  |   |____                ____|   |
67      !!              ___ |   |   |           ___  |   |   |
68      !!                 
69      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
70      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
71      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
72      !!          or
73      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
74      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
75      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
76      !!          Idem for di(s) and dj(s)         
77      !!
78      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
79      !!      depth zh from interpolated T and S for the different formulations
80      !!      of the equation of state (eos).
81      !!      Gradient formulation for rho :
82      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
83      !!
84      !! ** Action  : compute for top interfaces
85      !!              - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
86      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
87      !!----------------------------------------------------------------------
88      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
89      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
90      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
91      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
92      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
93      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
94      !
95      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
96      INTEGER  ::   iku, ikv, ikum1, ikvm1   ! partial step level (ocean bottom level) at u- and v-points
97      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv  ! temporary scalars
98      REAL(wp), DIMENSION(jpi,jpj)      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
99      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::  zti, ztj             !
100      !!----------------------------------------------------------------------
101      !
102      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde')
103      !
104      pgtu(:,:,:)=0.0_wp ; pgtv(:,:,:)=0.0_wp ;
105      zti (:,:,:)=0.0_wp ; ztj (:,:,:)=0.0_wp ;
106      zhi (:,:  )=0.0_wp ; zhj (:,:  )=0.0_wp ;
107      !
108      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
109         !
110         DO jj = 1, jpjm1
111            DO ji = 1, jpim1
112               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
113               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
114               ze3wu = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
115               ze3wv = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
116               !
117               ! i- direction
118               IF( ze3wu >= 0._wp ) THEN      ! case 1
119                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
120                  ! interpolated values of tracers
121                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
122                  ! gradient of  tracers
123                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
124               ELSE                           ! case 2
125                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
126                  ! interpolated values of tracers
127                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
128                  ! gradient of tracers
129                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
130               ENDIF
131               !
132               ! j- direction
133               IF( ze3wv >= 0._wp ) THEN      ! case 1
134                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
135                  ! interpolated values of tracers
136                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
137                  ! gradient of tracers
138                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
139               ELSE                           ! case 2
140                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
141                  ! interpolated values of tracers
142                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
143                  ! gradient of tracers
144                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
145               ENDIF
146            END DO
147         END DO
148         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
149         !
150      END DO
151
152      ! horizontal derivative of density anomalies (rd)
153      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
154         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
155         DO jj = 1, jpjm1
156            DO ji = 1, jpim1
157               iku = mbku(ji,jj)
158               ikv = mbkv(ji,jj)
159               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
160               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
161               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji  ,jj,iku)     ! i-direction: case 1
162               ELSE                        ;   zhi(ji,jj) = fsdept(ji+1,jj,iku)     ! -     -      case 2
163               ENDIF
164               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv)     ! j-direction: case 1
165               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv)     ! -     -      case 2
166               ENDIF
167            END DO
168         END DO
169
170         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
171         ! step and store it in  zri, zrj for each  case
172         CALL eos( zti, zhi, zri ) 
173         CALL eos( ztj, zhj, zrj )
174
175         ! Gradient of density at the last level
176         DO jj = 1, jpjm1
177            DO ji = 1, jpim1
178               iku = mbku(ji,jj)
179               ikv = mbkv(ji,jj)
180               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
181               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
182               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
183               ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
184               ENDIF
185               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
186               ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
187               ENDIF
188            END DO
189         END DO
190         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
191         !
192      END IF
193      !
194      IF( nn_timing == 1 )  CALL timing_stop( 'zps_hde')
195      !
196   END SUBROUTINE zps_hde
197   !
198   SUBROUTINE zps_hde_isf( kt, kjpt, pta, pgtu, pgtv, pgtui, pgtvi,  &
199      &                          prd, pgru, pgrv, pgrui, pgrvi )
200      !!----------------------------------------------------------------------
201      !!                     ***  ROUTINE zps_hde_isf  ***
202      !!                   
203      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
204      !!      at u- and v-points with a linear interpolation for z-coordinate
205      !!      with partial steps for top (ice shelf) and bottom.
206      !!
207      !! ** Method  :   In z-coord with partial steps, scale factors on last
208      !!      levels are different for each grid point, so that T, S and rd
209      !!      points are not at the same depth as in z-coord. To have horizontal
210      !!      gradients again, we interpolate T and S at the good depth :
211      !!      For the bottom case:
212      !!      Linear interpolation of T, S   
213      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
214      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
215      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
216      !!         This formulation computes the two cases:
217      !!                 CASE 1                   CASE 2 
218      !!         k-1  ___ ___________   k-1   ___ ___________
219      !!                    Ti  T~                  T~  Ti+1
220      !!                  _____                        _____
221      !!         k        |   |Ti+1     k           Ti |   |
222      !!                  |   |____                ____|   |
223      !!              ___ |   |   |           ___  |   |   |
224      !!                 
225      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
226      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
227      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
228      !!          or
229      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
230      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
231      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
232      !!          Idem for di(s) and dj(s)         
233      !!
234      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
235      !!      depth zh from interpolated T and S for the different formulations
236      !!      of the equation of state (eos).
237      !!      Gradient formulation for rho :
238      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
239      !!
240      !!      For the top case (ice shelf): As for the bottom case but upside down
241      !!
242      !! ** Action  : compute for top and bottom interfaces
243      !!              - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
244      !!              - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
245      !!----------------------------------------------------------------------
246      INTEGER                              , INTENT(in   )           ::  kt           ! ocean time-step index
247      INTEGER                              , INTENT(in   )           ::  kjpt         ! number of tracers
248      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta          ! 4D tracers fields
249      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
250      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
251      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd          ! 3D density anomaly fields
252      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
253      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
254      !
255      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
256      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
257      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv             ! temporary scalars
258      REAL(wp), DIMENSION(jpi,jpj)      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
259      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::  zti, ztj             !
260      !!----------------------------------------------------------------------
261      !
262      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde_isf')
263      !
264      pgtu (:,:,:)=0.0_wp ; pgtv(:,:,:) =0.0_wp ;
265      pgtui(:,:,:)=0.0_wp ; pgtvi(:,:,:)=0.0_wp ;
266      zti  (:,:,:)=0.0_wp ; ztj  (:,:,:)=0.0_wp ;
267      zhi  (:,:  )=0.0_wp ; zhj  (:,:  )=0.0_wp ;
268      !
269      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
270         !
271         DO jj = 1, jpjm1
272            DO ji = 1, jpim1
273
274               iku = mbku(ji,jj); ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
275               ikv = mbkv(ji,jj); ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
276               ze3wu = fsdept_n(ji+1,jj,iku) - fsdept_n(ji,jj,iku)
277               ze3wv = fsdept_n(ji,jj+1,ikv) - fsdept_n(ji,jj,ikv)
278               !
279               ! i- direction
280               IF( ze3wu >= 0._wp ) THEN      ! case 1
281                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
282                  ! interpolated values of tracers
283                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
284                  ! gradient of  tracers
285                  pgtu(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
286               ELSE                           ! case 2
287                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
288                  ! interpolated values of tracers
289                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
290                  ! gradient of tracers
291                  pgtu(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
292               ENDIF
293               !
294               ! j- direction
295               IF( ze3wv >= 0._wp ) THEN      ! case 1
296                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
297                  ! interpolated values of tracers
298                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
299                  ! gradient of tracers
300                  pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
301               ELSE                           ! case 2
302                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
303                  ! interpolated values of tracers
304                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
305                  ! gradient of tracers
306                  pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
307               ENDIF
308
309            END DO
310         END DO
311         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
312         !
313      END DO
314
315      ! horizontal derivative of density anomalies (rd)
316      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
317         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
318         !
319         DO jj = 1, jpjm1
320            DO ji = 1, jpim1
321
322               iku = mbku(ji,jj)
323               ikv = mbkv(ji,jj)
324               ze3wu = fsdept_n(ji+1,jj,iku) - fsdept_n(ji,jj,iku)
325               ze3wv = fsdept_n(ji,jj+1,ikv) - fsdept_n(ji,jj,ikv)
326
327               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji  ,jj,iku)    ! i-direction: case 1
328               ELSE                        ;   zhi(ji,jj) = fsdept(ji+1,jj,iku)    ! -     -      case 2
329               ENDIF
330               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv)    ! j-direction: case 1
331               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv)    ! -     -      case 2
332               ENDIF
333
334            END DO
335         END DO
336
337         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
338         ! step and store it in  zri, zrj for each  case
339         CALL eos( zti, zhi, zri )
340         CALL eos( ztj, zhj, zrj )
341
342         ! Gradient of density at the last level
343         DO jj = 1, jpjm1
344            DO ji = 1, jpim1
345
346               iku = mbku(ji,jj)
347               ikv = mbkv(ji,jj)
348               ze3wu = fsdept_n(ji+1,jj,iku) - fsdept_n(ji,jj,iku)
349               ze3wv = fsdept_n(ji,jj+1,ikv) - fsdept_n(ji,jj,ikv)
350
351               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
352               ELSE                        ;   pgru(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
353               ENDIF
354               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
355               ELSE                        ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
356               ENDIF
357
358            END DO
359         END DO
360
361         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
362         !
363      END IF
364         ! (ISH)  compute grui and gruvi
365      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
366         DO jj = 1, jpjm1
367            DO ji = 1, jpim1
368               iku = miku(ji,jj); ikup1 = miku(ji,jj) + 1
369               ikv = mikv(ji,jj); ikvp1 = mikv(ji,jj) + 1
370               !
371               ! (ISF) case partial step top and bottom in adjacent cell in vertical
372               ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
373               ! in this case e3w(i,j) - e3w(i,j+1) is not the distance between Tj~ and Tj
374               ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
375               ze3wu  =  fsdept_n(ji,jj,iku) - fsdept_n(ji+1,jj,iku)
376               ze3wv  =  fsdept_n(ji,jj,ikv) - fsdept_n(ji,jj+1,ikv) 
377
378               ! i- direction
379               IF( ze3wu >= 0._wp ) THEN      ! case 1
380                  zmaxu = ze3wu / fse3w(ji+1,jj,ikup1)
381                  ! interpolated values of tracers
382                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikup1,jn) - pta(ji+1,jj,iku,jn) )
383                  ! gradient of tracers
384                  pgtui(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
385               ELSE                           ! case 2
386                  zmaxu = - ze3wu / fse3w(ji,jj,ikup1)
387                  ! interpolated values of tracers
388                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikup1,jn) - pta(ji,jj,iku,jn) )
389                  ! gradient of  tracers
390                  pgtui(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
391               ENDIF
392               !
393               ! j- direction
394               IF( ze3wv >= 0._wp ) THEN      ! case 1
395                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikvp1)
396                  ! interpolated values of tracers
397                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvp1,jn) - pta(ji,jj+1,ikv,jn) )
398                  ! gradient of tracers
399                  pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
400               ELSE                           ! case 2
401                  zmaxv =  - ze3wv / fse3w(ji,jj,ikvp1)
402                  ! interpolated values of tracers
403                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvp1,jn) - pta(ji,jj,ikv,jn) )
404                  ! gradient of tracers
405                  pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
406               ENDIF
407
408            END DO
409         END DO
410         CALL lbc_lnk( pgtui(:,:,jn), 'U', -1. ); CALL lbc_lnk( pgtvi(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
411         !
412      END DO
413
414      ! horizontal derivative of density anomalies (rd)
415      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
416         pgrui(:,:)  =0.0_wp; pgrvi(:,:)  =0.0_wp;
417         DO jj = 1, jpjm1
418            DO ji = 1, jpim1
419
420               iku = miku(ji,jj)
421               ikv = mikv(ji,jj)
422               ze3wu  =  fsdept_n(ji,jj,iku) - fsdept_n(ji+1,jj,iku)
423               ze3wv  =  fsdept_n(ji,jj,ikv) - fsdept_n(ji,jj+1,ikv) 
424
425               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji  ,jj,iku)    ! i-direction: case 1
426               ELSE                        ;   zhi(ji,jj) = fsdept(ji+1,jj,iku)    ! -     -      case 2
427               ENDIF
428
429               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv)    ! j-direction: case 1
430               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv)    ! -     -      case 2
431               ENDIF
432
433            END DO
434         END DO
435
436         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
437         ! step and store it in  zri, zrj for each  case
438         CALL eos( zti, zhi, zri ) 
439         CALL eos( ztj, zhj, zrj )
440
441         ! Gradient of density at the last level
442         DO jj = 1, jpjm1
443            DO ji = 1, jpim1
444
445               iku = miku(ji,jj) 
446               ikv = mikv(ji,jj) 
447               ze3wu  =  fsdept_n(ji,jj,iku) - fsdept_n(ji+1,jj,iku)
448               ze3wv  =  fsdept_n(ji,jj,ikv) - fsdept_n(ji,jj+1,ikv) 
449
450               IF( ze3wu >= 0._wp ) THEN ; pgrui(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj      ) - prd(ji,jj,iku) ) ! i: 1
451               ELSE                      ; pgrui(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj  ,iku) - zri(ji,jj    ) ) ! i: 2
452               ENDIF
453
454               IF( ze3wv >= 0._wp ) THEN ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( zrj(ji  ,jj      ) - prd(ji,jj,ikv) ) ! j: 1
455               ELSE                      ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( prd(ji  ,jj+1,ikv) - zrj(ji,jj    ) ) ! j: 2
456               ENDIF
457
458            END DO
459         END DO
460         CALL lbc_lnk( pgrui   , 'U', -1. ); CALL lbc_lnk( pgrvi   , 'V', -1. )   ! Lateral boundary conditions
461         !
462      END IF 
463      !
464      IF( nn_timing == 1 )  CALL timing_stop( 'zps_hde_isf')
465      !
466   END SUBROUTINE zps_hde_isf
467   !!======================================================================
468END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.