source: branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 5352

Last change on this file since 5352 was 5352, checked in by smasson, 5 years ago

dev_r5218_CNRS17_coupling: update for fraqsr

  • Property svn:keywords set to Id
File size: 40.1 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! LIM: sea-ice variables
25   USE sbc_oce        ! Surface boundary condition: ocean fields
26   USE sbc_ice        ! Surface boundary condition: ice fields
27   USE thd_ice        ! LIM thermodynamic sea-ice variables
28   USE dom_ice        ! LIM sea-ice domain
29   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
30   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
31   USE limthd_sal     ! LIM: thermodynamics, ice salinity
32   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
33   USE limthd_lac     ! LIM-3 lateral accretion
34   USE limitd_th      ! remapping thickness distribution
35   USE limtab         ! LIM: 1D <==> 2D transformation
36   USE limvar         ! LIM: sea-ice variables
37   USE lbclnk         ! lateral boundary condition - MPP links
38   USE lib_mpp        ! MPP library
39   USE wrk_nemo       ! work arrays
40   USE in_out_manager ! I/O manager
41   USE prtctl         ! Print control
42   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
43   USE timing         ! Timing
44   USE limcons        ! conservation tests
45   USE limctl
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   lim_thd        ! called by limstp module
51   PUBLIC   lim_thd_init   ! called by sbc_lim_init
52
53   !! * Substitutions
54#  include "domzgr_substitute.h90"
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE lim_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE lim_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - Initialisation of some variables
70      !!             - Some preliminary computation (oceanic heat flux
71      !!               at the ice base, snow acc.,heat budget of the leads)
72      !!             - selection of the icy points and put them in an array
73      !!             - call lim_thd_dif  for vertical heat diffusion
74      !!             - call lim_thd_dh   for vertical ice growth and melt
75      !!             - call lim_thd_ent  for enthalpy remapping
76      !!             - call lim_thd_sal  for ice desalination
77      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
78      !!             - back to the geographic grid
79      !!     
80      !! ** References :
81      !!---------------------------------------------------------------------
82      INTEGER, INTENT(in) :: kt    ! number of iteration
83      !!
84      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
85      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
86      INTEGER  :: ii, ij           ! temporary dummy loop index
87      REAL(wp) :: zfric_u, zqld, zqfr
88      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
89      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
90      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
91      !
92      REAL(wp), POINTER, DIMENSION(:,:) ::  zqsr, zqns
93      !!-------------------------------------------------------------------
94      CALL wrk_alloc( jpi,jpj, zqsr, zqns )
95
96      IF( nn_timing == 1 )  CALL timing_start('limthd')
97
98      ! conservation test
99      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
100
101      CALL lim_var_glo2eqv
102      !------------------------------------------------------------------------!
103      ! 1) Initialization of some variables                                    !
104      !------------------------------------------------------------------------!
105      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
106
107      !--------------------
108      ! 1.2) Heat content   
109      !--------------------
110      ! Change the units of heat content; from J/m2 to J/m3
111      DO jl = 1, jpl
112         DO jk = 1, nlay_i
113            DO jj = 1, jpj
114               DO ji = 1, jpi
115                  !0 if no ice and 1 if yes
116                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
117                  !Energy of melting q(S,T) [J.m-3]
118                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
119               END DO
120            END DO
121         END DO
122         DO jk = 1, nlay_s
123            DO jj = 1, jpj
124               DO ji = 1, jpi
125                  !0 if no ice and 1 if yes
126                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
127                  !Energy of melting q(S,T) [J.m-3]
128                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
129               END DO
130            END DO
131         END DO
132      END DO
133
134      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
135      !-----------------------------------------------------------------------------!
136
137      !--- Ocean solar and non solar fluxes to be used in zqld
138      IF ( .NOT. ln_cpl ) THEN   ! --- forced case, fluxes to the lead are the same as over the ocean
139         !
140         zqsr(:,:) = qsr(:,:)      ; zqns(:,:) = qns(:,:)
141         !
142      ELSE                       ! --- coupled case, fluxes to the lead are total - intercepted
143         !
144         zqsr(:,:) = qsr_tot(:,:)  ; zqns(:,:) = qns_tot(:,:)
145         !
146         DO jl = 1, jpl
147            DO jj = 1, jpj
148               DO ji = 1, jpi
149                  zqsr(ji,jj) = zqsr(ji,jj) - qsr_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
150                  zqns(ji,jj) = zqns(ji,jj) - qns_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
151               END DO
152            END DO
153         END DO
154         !
155      ENDIF
156
157      DO jj = 1, jpj
158         DO ji = 1, jpi
159            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
160            !
161            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
162            !           !  practically no "direct lateral ablation"
163            !           
164            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
165            !           !  temperature and turbulent mixing (McPhee, 1992)
166            !
167
168            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
169            ! REMARK valid at least in forced mode from clem
170            ! precip is included in qns but not in qns_ice
171            IF ( ln_cpl ) THEN
172               zqld =  tmask(ji,jj,1) * rdt_ice *  &
173                  &    (   zqsr(ji,jj) * frq_m(ji,jj) + zqns(ji,jj)                     &   ! pfrld already included in coupled mode
174                  &    + ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj) *   &   ! heat content of precip
175                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )   &
176                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 ) )
177            ELSE
178               zqld =  tmask(ji,jj,1) * rdt_ice *  &
179                  &      ( pfrld(ji,jj) * ( zqsr(ji,jj) * frq_m(ji,jj) + zqns(ji,jj) )   &
180                  &    + ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj) *    &  ! heat content of precip
181                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )    &
182                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 ) )
183            ENDIF
184
185            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
186            zqfr = tmask(ji,jj,1) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
187
188            ! --- Energy from the turbulent oceanic heat flux (W/m2) --- !
189            zfric_u      = MAX( SQRT( ust2s(ji,jj) ), zfric_umin ) 
190            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
191            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
192            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
193            !                        the freezing point, so that we do not have SST < T_freeze
194            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
195
196            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
197            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
198
199            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
200            IF( zqld > 0._wp ) THEN
201               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
202               qlead(ji,jj) = 0._wp
203            ELSE
204               fhld (ji,jj) = 0._wp
205            ENDIF
206            !
207            ! -----------------------------------------
208            ! Net heat flux on top of ice-ocean [W.m-2]
209            ! -----------------------------------------
210            !     heat flux at the ocean surface + precip
211            !   + heat flux at the ice   surface
212            hfx_in(ji,jj) = hfx_in(ji,jj)                                                                                         & 
213               ! heat flux above the ocean
214               &    +             pfrld(ji,jj)   * ( zqns(ji,jj) + zqsr(ji,jj) )                                                  &
215               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
216               &    +   ( 1._wp - pfrld(ji,jj) ) * sprecip(ji,jj) * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )  &
217               &    +   ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 )          &
218               ! heat flux above the ice
219               &    +   SUM(    a_i_b(ji,jj,:)   * ( qns_ice(ji,jj,:) + qsr_ice(ji,jj,:) ) )
220
221            ! -----------------------------------------------------------------------------
222            ! Net heat flux that is retroceded to the ocean or taken from the ocean [W.m-2]
223            ! -----------------------------------------------------------------------------
224            !     First  step here              :  non solar + precip - qlead - qturb
225            !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
226            !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
227            hfx_out(ji,jj) = hfx_out(ji,jj)                                                                                       & 
228               ! Non solar heat flux received by the ocean
229               &    +        pfrld(ji,jj) * zqns(ji,jj)                                                                            &
230               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
231               &    +      ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)       &
232               &         * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )  &
233               &    +      ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 )       &
234               ! heat flux taken from the ocean where there is open water ice formation
235               &    -      qlead(ji,jj) * r1_rdtice                                                                               &
236               ! heat flux taken from the ocean during bottom growth/melt (fhld should be 0 while bott growth)
237               &    -      at_i(ji,jj) * fhtur(ji,jj)                                                                             &
238               &    -      at_i(ji,jj) *  fhld(ji,jj)
239
240         END DO
241      END DO
242
243      !------------------------------------------------------------------------------!
244      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
245      !------------------------------------------------------------------------------!
246
247      DO jl = 1, jpl      !loop over ice categories
248
249         IF( kt == nit000 .AND. lwp ) THEN
250            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
251            WRITE(numout,*) ' ~~~~~~~~'
252         ENDIF
253
254         nbpb = 0
255         DO jj = 1, jpj
256            DO ji = 1, jpi
257               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
258                  nbpb      = nbpb  + 1
259                  npb(nbpb) = (jj - 1) * jpi + ji
260               ENDIF
261            END DO
262         END DO
263
264         ! debug point to follow
265         jiindex_1d = 0
266         IF( ln_icectl ) THEN
267            DO ji = mi0(iiceprt), mi1(iiceprt)
268               DO jj = mj0(jiceprt), mj1(jiceprt)
269                  jiindex_1d = (jj - 1) * jpi + ji
270                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
271               END DO
272            END DO
273         ENDIF
274
275         !------------------------------------------------------------------------------!
276         ! 4) Thermodynamic computation
277         !------------------------------------------------------------------------------!
278
279         IF( lk_mpp )   CALL mpp_ini_ice( nbpb , numout )
280
281         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
282
283            !-------------------------!
284            ! --- Move to 1D arrays ---
285            !-------------------------!
286            CALL lim_thd_1d2d( nbpb, jl, 1 )
287
288            !--------------------------------------!
289            ! --- Ice/Snow Temperature profile --- !
290            !--------------------------------------!
291            CALL lim_thd_dif( 1, nbpb )
292
293            !---------------------------------!
294            ! --- Ice/Snow thickness ---      !
295            !---------------------------------!
296            CALL lim_thd_dh( 1, nbpb )   
297
298            ! --- Ice enthalpy remapping --- !
299            CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) ) 
300                                           
301            !---------------------------------!
302            ! --- Ice salinity ---            !
303            !---------------------------------!
304            CALL lim_thd_sal( 1, nbpb )   
305
306            !---------------------------------!
307            ! --- temperature update ---      !
308            !---------------------------------!
309            CALL lim_thd_temp( 1, nbpb )
310
311            !------------------------------------!
312            ! --- lateral melting if monocat --- !
313            !------------------------------------!
314            IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
315               CALL lim_thd_lam( 1, nbpb )
316            END IF
317
318            !-------------------------!
319            ! --- Move to 2D arrays ---
320            !-------------------------!
321            CALL lim_thd_1d2d( nbpb, jl, 2 )
322
323            !
324            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
325         ENDIF
326         !
327      END DO !jl
328
329      !------------------------------------------------------------------------------!
330      ! 5) Global variables, diagnostics
331      !------------------------------------------------------------------------------!
332
333      !------------------------
334      ! Ice heat content             
335      !------------------------
336      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
337      DO jl = 1, jpl
338         DO jk = 1, nlay_i
339            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
340         END DO
341      END DO
342
343      !------------------------
344      ! Snow heat content             
345      !------------------------
346      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
347      DO jl = 1, jpl
348         DO jk = 1, nlay_s
349            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
350         END DO
351      END DO
352 
353      !----------------------------------
354      ! Change thickness to volume
355      !----------------------------------
356      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
357      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
358      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
359
360      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting in monocat)
361      DO jl  = 1, jpl
362         DO jj = 1, jpj
363            DO ji = 1, jpi
364               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
365               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
366            END DO
367         END DO
368      END DO
369
370      CALL lim_var_zapsmall
371
372      !--------------------------------------------
373      ! Diagnostic thermodynamic growth rates
374      !--------------------------------------------
375      IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
376
377      IF(ln_ctl) THEN            ! Control print
378         CALL prt_ctl_info(' ')
379         CALL prt_ctl_info(' - Cell values : ')
380         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
381         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_thd  : cell area :')
382         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
383         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
384         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
385         DO jl = 1, jpl
386            CALL prt_ctl_info(' ')
387            CALL prt_ctl_info(' - Category : ', ivar1=jl)
388            CALL prt_ctl_info('   ~~~~~~~~~~')
389            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
390            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
391            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
392            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
393            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
394            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
395            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
396            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
397            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
398            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
399            DO jk = 1, nlay_i
400               CALL prt_ctl_info(' ')
401               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
402               CALL prt_ctl_info('   ~~~~~~~')
403               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
404               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
405            END DO
406         END DO
407      ENDIF
408      !
409      !
410      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
411
412      CALL wrk_dealloc( jpi,jpj, zqsr, zqns )
413
414      !------------------------------------------------------------------------------|
415      !  6) Transport of ice between thickness categories.                           |
416      !------------------------------------------------------------------------------|
417      ! Given thermodynamic growth rates, transport ice between thickness categories.
418      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
419
420      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
421
422      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
423
424      !------------------------------------------------------------------------------|
425      !  7) Add frazil ice growing in leads.
426      !------------------------------------------------------------------------------|
427      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
428
429      CALL lim_thd_lac
430     
431      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
432
433      ! Control print
434      IF(ln_ctl) THEN
435         CALL lim_var_glo2eqv
436
437         CALL prt_ctl_info(' ')
438         CALL prt_ctl_info(' - Cell values : ')
439         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
440         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_itd_th  : cell area :')
441         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
442         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
443         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
444         DO jl = 1, jpl
445            CALL prt_ctl_info(' ')
446            CALL prt_ctl_info(' - Category : ', ivar1=jl)
447            CALL prt_ctl_info('   ~~~~~~~~~~')
448            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
449            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
450            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
451            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
452            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
453            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
454            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
455            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
456            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
457            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
458            DO jk = 1, nlay_i
459               CALL prt_ctl_info(' ')
460               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
461               CALL prt_ctl_info('   ~~~~~~~')
462               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
463               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
464            END DO
465         END DO
466      ENDIF
467      !
468      IF( nn_timing == 1 )  CALL timing_stop('limthd')
469
470   END SUBROUTINE lim_thd 
471
472   SUBROUTINE lim_thd_temp( kideb, kiut )
473      !!-----------------------------------------------------------------------
474      !!                   ***  ROUTINE lim_thd_temp ***
475      !!                 
476      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
477      !!
478      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
479      !!-------------------------------------------------------------------
480      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
481      !!
482      INTEGER  ::   ji, jk   ! dummy loop indices
483      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
484      !!-------------------------------------------------------------------
485      ! Recover ice temperature
486      DO jk = 1, nlay_i
487         DO ji = kideb, kiut
488            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
489            ! Conversion q(S,T) -> T (second order equation)
490            zaaa          =  cpic
491            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
492            zccc          =  lfus * ( ztmelts - rt0 )
493            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
494            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
495           
496            ! mask temperature
497            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
498            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
499         END DO
500      END DO
501
502   END SUBROUTINE lim_thd_temp
503
504   SUBROUTINE lim_thd_lam( kideb, kiut )
505      !!-----------------------------------------------------------------------
506      !!                   ***  ROUTINE lim_thd_lam ***
507      !!                 
508      !! ** Purpose :   Lateral melting in case monocategory
509      !!                          ( dA = A/2h dh )
510      !!-----------------------------------------------------------------------
511      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
512      INTEGER             ::   ji                 ! dummy loop indices
513      REAL(wp)            ::   zhi_bef            ! ice thickness before thermo
514      REAL(wp)            ::   zdh_mel, zda_mel   ! net melting
515      REAL(wp)            ::   zvi, zvs           ! ice/snow volumes
516
517      DO ji = kideb, kiut
518         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) )
519         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
520            zvi          = a_i_1d(ji) * ht_i_1d(ji)
521            zvs          = a_i_1d(ji) * ht_s_1d(ji)
522            ! lateral melting = concentration change
523            zhi_bef     = ht_i_1d(ji) - zdh_mel
524            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
525            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
526            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
527             ! adjust thickness
528            ht_i_1d(ji) = zvi / a_i_1d(ji)           
529            ht_s_1d(ji) = zvs / a_i_1d(ji)           
530            ! retrieve total concentration
531            at_i_1d(ji) = a_i_1d(ji)
532         END IF
533      END DO
534     
535   END SUBROUTINE lim_thd_lam
536
537   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
538      !!-----------------------------------------------------------------------
539      !!                   ***  ROUTINE lim_thd_1d2d ***
540      !!                 
541      !! ** Purpose :   move arrays from 1d to 2d and the reverse
542      !!-----------------------------------------------------------------------
543      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D
544                                        ! 2= from 1D to 2D
545      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
546      INTEGER, INTENT(in) ::   jl       ! ice cat
547      INTEGER             ::   jk       ! dummy loop indices
548
549      SELECT CASE( kn )
550
551      CASE( 1 )
552
553         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
554         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
555         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
556         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
557         
558         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
559         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
560         DO jk = 1, nlay_s
561            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
562            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
563         END DO
564         DO jk = 1, nlay_i
565            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
566            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
567            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
568         END DO
569         
570         CALL tab_2d_1d( nbpb, tatm_ice_1d(1:nbpb), tatm_ice(:,:)   , jpi, jpj, npb(1:nbpb) )
571         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
572         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
573         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
574         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
575         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
576         IF( .NOT. ln_cpl ) THEN
577            CALL tab_2d_1d( nbpb, qla_ice_1d (1:nbpb), qla_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
578            CALL tab_2d_1d( nbpb, dqla_ice_1d(1:nbpb), dqla_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
579         ENDIF
580         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
581         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
582         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
583         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
584         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
585         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
586         
587         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
588         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
589         
590         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
591         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
592         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
593         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
594         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
595         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
596         
597         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
598         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
599         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
600         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
601         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
602         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
603         
604         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
605         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
606         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
607         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
608         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
609         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
610         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
611         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
612         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
613         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
614         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
615         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
616         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
617
618      CASE( 2 )
619
620         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
621         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
622         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
623         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
624         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
625         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
626         DO jk = 1, nlay_s
627            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
628            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
629         END DO
630         DO jk = 1, nlay_i
631            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
632            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
633            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
634         END DO
635         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
636         
637         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
638         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
639         
640         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
641         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
642         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
643         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
644         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
645         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
646         
647         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
648         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
649         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
650         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
651         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
652         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
653         
654         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
655         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
656         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
657         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
658         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
659         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
660         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
661         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
662         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
663         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
664         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
665         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
666         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
667         !
668         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
669         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
670                 
671      END SELECT
672
673   END SUBROUTINE lim_thd_1d2d
674
675
676   SUBROUTINE lim_thd_init
677      !!-----------------------------------------------------------------------
678      !!                   ***  ROUTINE lim_thd_init ***
679      !!                 
680      !! ** Purpose :   Physical constants and parameters linked to the ice
681      !!              thermodynamics
682      !!
683      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
684      !!              parameter values called at the first timestep (nit000)
685      !!
686      !! ** input   :   Namelist namicether
687      !!-------------------------------------------------------------------
688      INTEGER  ::   ios                 ! Local integer output status for namelist read
689      NAMELIST/namicethd/ rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb,                       &
690         &                rn_himin, rn_betas, rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon, &
691         &                nn_monocat, ln_it_qnsice
692      !!-------------------------------------------------------------------
693      !
694      IF(lwp) THEN
695         WRITE(numout,*)
696         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
697         WRITE(numout,*) '~~~~~~~'
698      ENDIF
699      !
700      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
701      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
702901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
703
704      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
705      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
706902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
707      IF(lwm) WRITE ( numoni, namicethd )
708      !
709      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
710         nn_monocat = 0
711         IF(lwp) WRITE(numout, *) '   nn_monocat must be 0 in multi-category case '
712      ENDIF
713
714      !
715      IF(lwp) THEN                          ! control print
716         WRITE(numout,*)
717         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
718         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
719         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
720         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
721         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
722         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
723         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
724         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
725         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
726         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
727         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
728         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
729         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
730         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
731         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
732         WRITE(numout,*)'      iterate the surface non-solar flux (T) or not (F)       ln_it_qnsice = ', ln_it_qnsice
733      ENDIF
734      !
735   END SUBROUTINE lim_thd_init
736
737#else
738   !!----------------------------------------------------------------------
739   !!   Default option         Dummy module          NO  LIM3 sea-ice model
740   !!----------------------------------------------------------------------
741#endif
742
743   !!======================================================================
744END MODULE limthd
Note: See TracBrowser for help on using the repository browser.