| 1 | MODULE traldf_triad |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traldf_triad *** |
|---|
| 4 | !! Ocean tracers: horizontal component of the lateral tracer mixing trend |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.3 ! 2010-10 (G. Nurser, C. Harris, G. Madec) Griffies operator (original code) |
|---|
| 7 | !! 3.7 ! 2013-12 (F. Lemarie, G. Madec) triad operator (Griffies) + Method of Stabilizing Correction |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! tra_ldf_triad : update the tracer trend with the iso-neutral laplacian triad-operator |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce ! ocean dynamics and active tracers |
|---|
| 14 | USE dom_oce ! ocean space and time domain |
|---|
| 15 | USE phycst ! physical constants |
|---|
| 16 | USE trc_oce ! share passive tracers/Ocean variables |
|---|
| 17 | USE zdf_oce ! ocean vertical physics |
|---|
| 18 | USE ldftra ! lateral physics: eddy diffusivity |
|---|
| 19 | USE ldfslp ! lateral physics: iso-neutral slopes |
|---|
| 20 | USE traldf_iso ! lateral diffusion (Madec operator) (tra_ldf_iso routine) |
|---|
| 21 | USE diaptr ! poleward transport diagnostics |
|---|
| 22 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
|---|
| 23 | ! |
|---|
| 24 | USE in_out_manager ! I/O manager |
|---|
| 25 | USE iom ! I/O library |
|---|
| 26 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 27 | USE lib_mpp ! MPP library |
|---|
| 28 | USE wrk_nemo ! Memory Allocation |
|---|
| 29 | USE timing ! Timing |
|---|
| 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| 34 | PUBLIC tra_ldf_triad ! routine called by traldf.F90 |
|---|
| 35 | |
|---|
| 36 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE :: zdkt3d !: vertical tracer gradient at 2 levels |
|---|
| 37 | |
|---|
| 38 | !! * Substitutions |
|---|
| 39 | # include "vectopt_loop_substitute.h90" |
|---|
| 40 | !!---------------------------------------------------------------------- |
|---|
| 41 | !! NEMO/OPA 3.7 , NEMO Consortium (2015) |
|---|
| 42 | !! $Id$ |
|---|
| 43 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | CONTAINS |
|---|
| 46 | |
|---|
| 47 | SUBROUTINE tra_ldf_triad( kt, kit000, cdtype, pahu, pahv, pgu , pgv , & |
|---|
| 48 | & pgui, pgvi, & |
|---|
| 49 | & ptb , ptbb, pta , kjpt, kpass ) |
|---|
| 50 | !!---------------------------------------------------------------------- |
|---|
| 51 | !! *** ROUTINE tra_ldf_triad *** |
|---|
| 52 | !! |
|---|
| 53 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
|---|
| 54 | !! trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and |
|---|
| 55 | !! add it to the general trend of tracer equation. |
|---|
| 56 | !! |
|---|
| 57 | !! ** Method : The horizontal component of the lateral diffusive trends |
|---|
| 58 | !! is provided by a 2nd order operator rotated along neural or geopo- |
|---|
| 59 | !! tential surfaces to which an eddy induced advection can be added |
|---|
| 60 | !! It is computed using before fields (forward in time) and isopyc- |
|---|
| 61 | !! nal or geopotential slopes computed in routine ldfslp. |
|---|
| 62 | !! |
|---|
| 63 | !! see documentation for the desciption |
|---|
| 64 | !! |
|---|
| 65 | !! ** Action : pta updated with the before rotated diffusion |
|---|
| 66 | !! ah_wslp2 .... |
|---|
| 67 | !! akz stabilizing vertical diffusivity coefficient (used in trazdf_imp) |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 70 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
|---|
| 71 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
|---|
| 72 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 73 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
|---|
| 74 | REAL(wp), DIMENSION(jpi,jpj,jpk) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
|---|
| 75 | REAL(wp), DIMENSION(jpi,jpj ,kjpt), INTENT(in ) :: pgu , pgv ! tracer gradient at pstep levels |
|---|
| 76 | REAL(wp), DIMENSION(jpi,jpj, kjpt), INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
|---|
| 77 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptb ! tracer (kpass=1) or laplacian of tracer (kpass=2) |
|---|
| 78 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptbb ! tracer (only used in kpass=2) |
|---|
| 79 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) :: pta ! tracer trend |
|---|
| 80 | ! |
|---|
| 81 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 82 | INTEGER :: ip,jp,kp ! dummy loop indices |
|---|
| 83 | INTEGER :: ierr ! local integer |
|---|
| 84 | REAL(wp) :: zmsku, zabe1, zcof1, zcoef3 ! local scalars |
|---|
| 85 | REAL(wp) :: zmskv, zabe2, zcof2, zcoef4 ! - - |
|---|
| 86 | REAL(wp) :: zcoef0, ze3w_2, zsign, z2dt, z1_2dt ! - - |
|---|
| 87 | ! |
|---|
| 88 | REAL(wp) :: zslope_skew, zslope_iso, zslope2, zbu, zbv |
|---|
| 89 | REAL(wp) :: ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt |
|---|
| 90 | REAL(wp) :: zah, zah_slp, zaei_slp |
|---|
| 91 | #if defined key_diaar5 |
|---|
| 92 | REAL(wp) :: zztmp ! local scalar |
|---|
| 93 | #endif |
|---|
| 94 | REAL(wp), POINTER, DIMENSION(:,: ) :: z2d ! 2D workspace |
|---|
| 95 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw ! 3D - |
|---|
| 96 | !!---------------------------------------------------------------------- |
|---|
| 97 | ! |
|---|
| 98 | IF( nn_timing == 1 ) CALL timing_start('tra_ldf_triad') |
|---|
| 99 | ! |
|---|
| 100 | CALL wrk_alloc( jpi,jpj, z2d ) |
|---|
| 101 | CALL wrk_alloc( jpi,jpj,jpk, zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw ) |
|---|
| 102 | ! |
|---|
| 103 | IF( .NOT.ALLOCATED(zdkt3d) ) THEN |
|---|
| 104 | ALLOCATE( zdkt3d(jpi,jpj,0:1) , STAT=ierr ) |
|---|
| 105 | IF( lk_mpp ) CALL mpp_sum ( ierr ) |
|---|
| 106 | IF( ierr > 0 ) CALL ctl_stop('STOP', 'tra_ldf_triad: unable to allocate arrays') |
|---|
| 107 | ENDIF |
|---|
| 108 | ! |
|---|
| 109 | IF( kpass == 1 .AND. kt == kit000 ) THEN |
|---|
| 110 | IF(lwp) WRITE(numout,*) |
|---|
| 111 | IF(lwp) WRITE(numout,*) 'tra_ldf_triad : rotated laplacian diffusion operator on ', cdtype |
|---|
| 112 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~' |
|---|
| 113 | ENDIF |
|---|
| 114 | ! |
|---|
| 115 | ! ! set time step size (Euler/Leapfrog) |
|---|
| 116 | IF( neuler == 0 .AND. kt == kit000 ) THEN ; z2dt = rdttra(1) ! at nit000 (Euler) |
|---|
| 117 | ELSE ; z2dt = 2.* rdttra(1) ! (Leapfrog) |
|---|
| 118 | ENDIF |
|---|
| 119 | z1_2dt = 1._wp / z2dt |
|---|
| 120 | ! |
|---|
| 121 | IF( kpass == 1 ) THEN ; zsign = 1._wp ! bilaplacian operator require a minus sign (eddy diffusivity >0) |
|---|
| 122 | ELSE ; zsign = -1._wp |
|---|
| 123 | ENDIF |
|---|
| 124 | |
|---|
| 125 | !!---------------------------------------------------------------------- |
|---|
| 126 | !! 0 - calculate ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw |
|---|
| 127 | !!---------------------------------------------------------------------- |
|---|
| 128 | ! |
|---|
| 129 | IF( kpass == 1 ) THEN !== first pass only and whatever the tracer is ==! |
|---|
| 130 | ! |
|---|
| 131 | akz (:,:,:) = 0._wp |
|---|
| 132 | ah_wslp2(:,:,:) = 0._wp |
|---|
| 133 | IF( ln_ldfeiv_dia ) THEN |
|---|
| 134 | zpsi_uw(:,:,:) = 0._wp |
|---|
| 135 | zpsi_vw(:,:,:) = 0._wp |
|---|
| 136 | ENDIF |
|---|
| 137 | ! |
|---|
| 138 | DO ip = 0, 1 ! i-k triads |
|---|
| 139 | DO kp = 0, 1 |
|---|
| 140 | DO jk = 1, jpkm1 |
|---|
| 141 | DO jj = 1, jpjm1 |
|---|
| 142 | DO ji = 1, fs_jpim1 |
|---|
| 143 | ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp) |
|---|
| 144 | zbu = e1e2u(ji,jj) * e3u_n(ji,jj,jk) |
|---|
| 145 | zah = 0.25_wp * pahu(ji,jj,jk) |
|---|
| 146 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 147 | ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth) |
|---|
| 148 | zslope2 = zslope_skew + ( gdept_n(ji+1,jj,jk) - gdept_n(ji,jj,jk) ) * r1_e1u(ji,jj) * umask(ji,jj,jk+kp) |
|---|
| 149 | zslope2 = zslope2 *zslope2 |
|---|
| 150 | ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp) + zah * zbu * ze3wr * r1_e1e2t(ji+ip,jj) * zslope2 |
|---|
| 151 | akz (ji+ip,jj,jk+kp) = akz (ji+ip,jj,jk+kp) + zah * r1_e1u(ji,jj) & |
|---|
| 152 | & * r1_e1u(ji,jj) * umask(ji,jj,jk+kp) |
|---|
| 153 | ! |
|---|
| 154 | IF( ln_ldfeiv_dia ) zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp) & |
|---|
| 155 | & + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * zslope_skew |
|---|
| 156 | END DO |
|---|
| 157 | END DO |
|---|
| 158 | END DO |
|---|
| 159 | END DO |
|---|
| 160 | END DO |
|---|
| 161 | ! |
|---|
| 162 | DO jp = 0, 1 ! j-k triads |
|---|
| 163 | DO kp = 0, 1 |
|---|
| 164 | DO jk = 1, jpkm1 |
|---|
| 165 | DO jj = 1, jpjm1 |
|---|
| 166 | DO ji = 1, fs_jpim1 |
|---|
| 167 | ze3wr = 1.0_wp / e3w_n(ji,jj+jp,jk+kp) |
|---|
| 168 | zbv = e1e2v(ji,jj) * e3v_n(ji,jj,jk) |
|---|
| 169 | zah = 0.25_wp * pahv(ji,jj,jk) |
|---|
| 170 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 171 | ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces |
|---|
| 172 | ! (do this by *adding* gradient of depth) |
|---|
| 173 | zslope2 = zslope_skew + ( gdept_n(ji,jj+1,jk) - gdept_n(ji,jj,jk) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp) |
|---|
| 174 | zslope2 = zslope2 * zslope2 |
|---|
| 175 | ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp) + zah * zbv * ze3wr * r1_e1e2t(ji,jj+jp) * zslope2 |
|---|
| 176 | akz (ji,jj+jp,jk+kp) = akz (ji,jj+jp,jk+kp) + zah * r1_e2v(ji,jj) & |
|---|
| 177 | & * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp) |
|---|
| 178 | ! |
|---|
| 179 | IF( ln_ldfeiv_dia ) zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp) & |
|---|
| 180 | & + 0.25 * aeiv(ji,jj,jk) * e1v(ji,jj) * zslope_skew |
|---|
| 181 | END DO |
|---|
| 182 | END DO |
|---|
| 183 | END DO |
|---|
| 184 | END DO |
|---|
| 185 | END DO |
|---|
| 186 | ! |
|---|
| 187 | IF( ln_traldf_msc ) THEN ! stabilizing vertical diffusivity coefficient |
|---|
| 188 | ! |
|---|
| 189 | IF( ln_traldf_blp ) THEN ! bilaplacian operator |
|---|
| 190 | DO jk = 2, jpkm1 |
|---|
| 191 | DO jj = 1, jpjm1 |
|---|
| 192 | DO ji = 1, fs_jpim1 |
|---|
| 193 | akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk) & |
|---|
| 194 | & * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk) ) ) |
|---|
| 195 | END DO |
|---|
| 196 | END DO |
|---|
| 197 | END DO |
|---|
| 198 | ELSEIF( ln_traldf_lap ) THEN ! laplacian operator |
|---|
| 199 | DO jk = 2, jpkm1 |
|---|
| 200 | DO jj = 1, jpjm1 |
|---|
| 201 | DO ji = 1, fs_jpim1 |
|---|
| 202 | ze3w_2 = e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk) |
|---|
| 203 | zcoef0 = z2dt * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2 ) |
|---|
| 204 | akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * z1_2dt |
|---|
| 205 | END DO |
|---|
| 206 | END DO |
|---|
| 207 | END DO |
|---|
| 208 | ENDIF |
|---|
| 209 | ! |
|---|
| 210 | ELSE ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit |
|---|
| 211 | akz(:,:,:) = ah_wslp2(:,:,:) |
|---|
| 212 | ENDIF |
|---|
| 213 | ! |
|---|
| 214 | IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' ) CALL ldf_eiv_dia( zpsi_uw, zpsi_vw ) |
|---|
| 215 | ! |
|---|
| 216 | ENDIF !== end 1st pass only ==! |
|---|
| 217 | ! |
|---|
| 218 | ! ! =========== |
|---|
| 219 | DO jn = 1, kjpt ! tracer loop |
|---|
| 220 | ! ! =========== |
|---|
| 221 | ! Zero fluxes for each tracer |
|---|
| 222 | !!gm this should probably be done outside the jn loop |
|---|
| 223 | ztfw(:,:,:) = 0._wp |
|---|
| 224 | zftu(:,:,:) = 0._wp |
|---|
| 225 | zftv(:,:,:) = 0._wp |
|---|
| 226 | ! |
|---|
| 227 | DO jk = 1, jpkm1 !== before lateral T & S gradients at T-level jk ==! |
|---|
| 228 | DO jj = 1, jpjm1 |
|---|
| 229 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 230 | zdit(ji,jj,jk) = ( ptb(ji+1,jj ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk) |
|---|
| 231 | zdjt(ji,jj,jk) = ( ptb(ji ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk) |
|---|
| 232 | END DO |
|---|
| 233 | END DO |
|---|
| 234 | END DO |
|---|
| 235 | IF( ln_zps .AND. l_grad_zps ) THEN ! partial steps: correction at top/bottom ocean level |
|---|
| 236 | DO jj = 1, jpjm1 ! bottom level |
|---|
| 237 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 238 | zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn) |
|---|
| 239 | zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn) |
|---|
| 240 | END DO |
|---|
| 241 | END DO |
|---|
| 242 | IF( ln_isfcav ) THEN ! top level (ocean cavities only) |
|---|
| 243 | DO jj = 1, jpjm1 |
|---|
| 244 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 245 | IF( miku(ji,jj) > 1 ) zdit(ji,jj,miku(ji,jj) ) = pgui(ji,jj,jn) |
|---|
| 246 | IF( mikv(ji,jj) > 1 ) zdjt(ji,jj,mikv(ji,jj) ) = pgvi(ji,jj,jn) |
|---|
| 247 | END DO |
|---|
| 248 | END DO |
|---|
| 249 | ENDIF |
|---|
| 250 | ENDIF |
|---|
| 251 | |
|---|
| 252 | !!---------------------------------------------------------------------- |
|---|
| 253 | !! II - horizontal trend (full) |
|---|
| 254 | !!---------------------------------------------------------------------- |
|---|
| 255 | ! |
|---|
| 256 | DO jk = 1, jpkm1 |
|---|
| 257 | ! |
|---|
| 258 | ! !== Vertical tracer gradient at level jk and jk+1 |
|---|
| 259 | zdkt3d(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1) |
|---|
| 260 | ! |
|---|
| 261 | ! ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1) |
|---|
| 262 | IF( jk == 1 ) THEN ; zdkt3d(:,:,0) = zdkt3d(:,:,1) |
|---|
| 263 | ELSE ; zdkt3d(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk) |
|---|
| 264 | ENDIF |
|---|
| 265 | ! |
|---|
| 266 | zaei_slp = 0._wp |
|---|
| 267 | ! |
|---|
| 268 | IF( ln_botmix_triad ) THEN |
|---|
| 269 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 270 | DO kp = 0, 1 |
|---|
| 271 | DO jj = 1, jpjm1 |
|---|
| 272 | DO ji = 1, fs_jpim1 |
|---|
| 273 | ze1ur = r1_e1u(ji,jj) |
|---|
| 274 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 275 | ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp) |
|---|
| 276 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
|---|
| 277 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 278 | zslope_iso = triadi (ji+ip,jj,jk,1-ip,kp) |
|---|
| 279 | |
|---|
| 280 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u_n(ji,jj,jk) |
|---|
| 281 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahu is masked.... |
|---|
| 282 | zah = pahu(ji,jj,jk) |
|---|
| 283 | zah_slp = zah * zslope_iso |
|---|
| 284 | IF( ln_ldfeiv ) zaei_slp = aeiu(ji,jj,jk) * zslope_skew |
|---|
| 285 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
|---|
| 286 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - ( zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
|---|
| 287 | END DO |
|---|
| 288 | END DO |
|---|
| 289 | END DO |
|---|
| 290 | END DO |
|---|
| 291 | |
|---|
| 292 | DO jp = 0, 1 |
|---|
| 293 | DO kp = 0, 1 |
|---|
| 294 | DO jj = 1, jpjm1 |
|---|
| 295 | DO ji = 1, fs_jpim1 |
|---|
| 296 | ze2vr = r1_e2v(ji,jj) |
|---|
| 297 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 298 | ze3wr = 1._wp / e3w_n(ji,jj+jp,jk+kp) |
|---|
| 299 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
|---|
| 300 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 301 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
|---|
| 302 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v_n(ji,jj,jk) |
|---|
| 303 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahv is masked... |
|---|
| 304 | zah = pahv(ji,jj,jk) |
|---|
| 305 | zah_slp = zah * zslope_iso |
|---|
| 306 | IF( ln_ldfeiv ) zaei_slp = aeiv(ji,jj,jk) * zslope_skew |
|---|
| 307 | zftv(ji,jj ,jk ) = zftv(ji,jj ,jk ) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
|---|
| 308 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - ( zah_slp + zaei_slp ) * zdyt * zbv * ze3wr |
|---|
| 309 | END DO |
|---|
| 310 | END DO |
|---|
| 311 | END DO |
|---|
| 312 | END DO |
|---|
| 313 | |
|---|
| 314 | ELSE |
|---|
| 315 | |
|---|
| 316 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 317 | DO kp = 0, 1 |
|---|
| 318 | DO jj = 1, jpjm1 |
|---|
| 319 | DO ji = 1, fs_jpim1 |
|---|
| 320 | ze1ur = r1_e1u(ji,jj) |
|---|
| 321 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 322 | ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp) |
|---|
| 323 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
|---|
| 324 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 325 | zslope_iso = triadi(ji+ip,jj,jk,1-ip,kp) |
|---|
| 326 | |
|---|
| 327 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u_n(ji,jj,jk) |
|---|
| 328 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 329 | zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp) ! pahu(ji+ip,jj,jk) ===>> ???? |
|---|
| 330 | zah_slp = zah * zslope_iso |
|---|
| 331 | IF( ln_ldfeiv ) zaei_slp = aeiu(ji,jj,jk) * zslope_skew ! aeit(ji+ip,jj,jk)*zslope_skew |
|---|
| 332 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
|---|
| 333 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
|---|
| 334 | END DO |
|---|
| 335 | END DO |
|---|
| 336 | END DO |
|---|
| 337 | END DO |
|---|
| 338 | |
|---|
| 339 | DO jp = 0, 1 |
|---|
| 340 | DO kp = 0, 1 |
|---|
| 341 | DO jj = 1, jpjm1 |
|---|
| 342 | DO ji = 1, fs_jpim1 |
|---|
| 343 | ze2vr = r1_e2v(ji,jj) |
|---|
| 344 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 345 | ze3wr = 1._wp / e3w_n(ji,jj+jp,jk+kp) |
|---|
| 346 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
|---|
| 347 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 348 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
|---|
| 349 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v_n(ji,jj,jk) |
|---|
| 350 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 351 | zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp) ! pahv(ji,jj+jp,jk) ???? |
|---|
| 352 | zah_slp = zah * zslope_iso |
|---|
| 353 | IF( ln_ldfeiv ) zaei_slp = aeiv(ji,jj,jk) * zslope_skew ! aeit(ji,jj+jp,jk)*zslope_skew |
|---|
| 354 | zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
|---|
| 355 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr |
|---|
| 356 | END DO |
|---|
| 357 | END DO |
|---|
| 358 | END DO |
|---|
| 359 | END DO |
|---|
| 360 | ENDIF |
|---|
| 361 | ! !== horizontal divergence and add to the general trend ==! |
|---|
| 362 | DO jj = 2 , jpjm1 |
|---|
| 363 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 364 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * ( zftu(ji-1,jj,jk) - zftu(ji,jj,jk) & |
|---|
| 365 | & + zftv(ji,jj-1,jk) - zftv(ji,jj,jk) ) & |
|---|
| 366 | & / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) ) |
|---|
| 367 | END DO |
|---|
| 368 | END DO |
|---|
| 369 | ! |
|---|
| 370 | END DO |
|---|
| 371 | ! |
|---|
| 372 | ! !== add the vertical 33 flux ==! |
|---|
| 373 | IF( ln_traldf_lap ) THEN ! laplacian case: eddy coef = ah_wslp2 - akz |
|---|
| 374 | DO jk = 2, jpkm1 |
|---|
| 375 | DO jj = 1, jpjm1 |
|---|
| 376 | DO ji = fs_2, fs_jpim1 |
|---|
| 377 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 378 | & * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) ) & |
|---|
| 379 | & * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) |
|---|
| 380 | END DO |
|---|
| 381 | END DO |
|---|
| 382 | END DO |
|---|
| 383 | ELSE ! bilaplacian |
|---|
| 384 | SELECT CASE( kpass ) |
|---|
| 385 | CASE( 1 ) ! 1st pass : eddy coef = ah_wslp2 |
|---|
| 386 | DO jk = 2, jpkm1 |
|---|
| 387 | DO jj = 1, jpjm1 |
|---|
| 388 | DO ji = fs_2, fs_jpim1 |
|---|
| 389 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 390 | & * ah_wslp2(ji,jj,jk) * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) |
|---|
| 391 | END DO |
|---|
| 392 | END DO |
|---|
| 393 | END DO |
|---|
| 394 | CASE( 2 ) ! 2nd pass : eddy flux = ah_wslp2 and akz applied on ptb and ptbb gradients, resp. |
|---|
| 395 | DO jk = 2, jpkm1 |
|---|
| 396 | DO jj = 1, jpjm1 |
|---|
| 397 | DO ji = fs_2, fs_jpim1 |
|---|
| 398 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 399 | & * ( ah_wslp2(ji,jj,jk) * ( ptb (ji,jj,jk-1,jn) - ptb (ji,jj,jk,jn) ) & |
|---|
| 400 | & + akz (ji,jj,jk) * ( ptbb(ji,jj,jk-1,jn) - ptbb(ji,jj,jk,jn) ) ) |
|---|
| 401 | END DO |
|---|
| 402 | END DO |
|---|
| 403 | END DO |
|---|
| 404 | END SELECT |
|---|
| 405 | ENDIF |
|---|
| 406 | ! |
|---|
| 407 | DO jk = 1, jpkm1 !== Divergence of vertical fluxes added to pta ==! |
|---|
| 408 | DO jj = 2, jpjm1 |
|---|
| 409 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 410 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * ( ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk) ) & |
|---|
| 411 | & / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) ) |
|---|
| 412 | END DO |
|---|
| 413 | END DO |
|---|
| 414 | END DO |
|---|
| 415 | ! |
|---|
| 416 | IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR. & !== first pass only ( laplacian) ==! |
|---|
| 417 | ( kpass == 2 .AND. ln_traldf_blp ) ) THEN !== 2nd pass (bilaplacian) ==! |
|---|
| 418 | ! |
|---|
| 419 | ! ! "Poleward" diffusive heat or salt transports (T-S case only) |
|---|
| 420 | IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN |
|---|
| 421 | IF( jn == jp_tem) htr_ldf(:) = ptr_sj( zftv(:,:,:) ) ! 3.3 names |
|---|
| 422 | IF( jn == jp_sal) str_ldf(:) = ptr_sj( zftv(:,:,:) ) |
|---|
| 423 | ENDIF |
|---|
| 424 | ! |
|---|
| 425 | IF( iom_use("udiff_heattr") .OR. iom_use("vdiff_heattr") ) THEN |
|---|
| 426 | ! |
|---|
| 427 | IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN |
|---|
| 428 | z2d(:,:) = zftu(ji,jj,1) |
|---|
| 429 | DO jk = 2, jpkm1 |
|---|
| 430 | DO jj = 2, jpjm1 |
|---|
| 431 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 432 | z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) |
|---|
| 433 | END DO |
|---|
| 434 | END DO |
|---|
| 435 | END DO |
|---|
| 436 | z2d(:,:) = rau0_rcp * z2d(:,:) |
|---|
| 437 | CALL lbc_lnk( z2d, 'U', -1. ) |
|---|
| 438 | CALL iom_put( "udiff_heattr", z2d ) ! heat i-transport |
|---|
| 439 | ! |
|---|
| 440 | z2d(:,:) = zftv(ji,jj,1) |
|---|
| 441 | DO jk = 2, jpkm1 |
|---|
| 442 | DO jj = 2, jpjm1 |
|---|
| 443 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 444 | z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) |
|---|
| 445 | END DO |
|---|
| 446 | END DO |
|---|
| 447 | END DO |
|---|
| 448 | z2d(:,:) = rau0_rcp * z2d(:,:) |
|---|
| 449 | CALL lbc_lnk( z2d, 'V', -1. ) |
|---|
| 450 | CALL iom_put( "vdiff_heattr", z2d ) ! heat j-transport |
|---|
| 451 | ENDIF |
|---|
| 452 | ! |
|---|
| 453 | ENDIF |
|---|
| 454 | ! |
|---|
| 455 | ENDIF !== end pass selection ==! |
|---|
| 456 | ! |
|---|
| 457 | ! ! =============== |
|---|
| 458 | END DO ! end tracer loop |
|---|
| 459 | ! ! =============== |
|---|
| 460 | ! |
|---|
| 461 | CALL wrk_dealloc( jpi,jpj, z2d ) |
|---|
| 462 | CALL wrk_dealloc( jpi,jpj,jpk, zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw ) |
|---|
| 463 | ! |
|---|
| 464 | IF( nn_timing == 1 ) CALL timing_stop('tra_ldf_triad') |
|---|
| 465 | ! |
|---|
| 466 | END SUBROUTINE tra_ldf_triad |
|---|
| 467 | |
|---|
| 468 | !!============================================================================== |
|---|
| 469 | END MODULE traldf_triad |
|---|
