source: branches/2015/nemo_v3_6_STABLE/NEMOGCM/NEMO/OPA_SRC/DIA/diaar5.F90 @ 8187

Last change on this file since 8187 was 8187, checked in by nicolasmartin, 3 years ago

Fix for typos in diaar5.F90 [close #1913]

  • Property svn:keywords set to Id
File size: 14.0 KB
Line 
1MODULE diaar5
2   !!======================================================================
3   !!                       ***  MODULE  diaar5  ***
4   !! AR5 diagnostics
5   !!======================================================================
6   !! History :  3.2  !  2009-11  (S. Masson)  Original code
7   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_diaar5   || defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_diaar5'  :                           activate ar5 diagnotics
12   !!----------------------------------------------------------------------
13   !!   dia_ar5       : AR5 diagnostics
14   !!   dia_ar5_init  : initialisation of AR5 diagnostics
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE eosbn2         ! equation of state                (eos_bn2 routine)
19   USE lib_mpp        ! distribued memory computing library
20   USE iom            ! I/O manager library
21   USE timing         ! preformance summary
22   USE wrk_nemo       ! working arrays
23   USE fldread        ! type FLD_N
24   USE phycst         ! physical constant
25   USE in_out_manager  ! I/O manager
26   USE zdfddm
27   USE zdf_oce
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   dia_ar5        ! routine called in step.F90 module
33   PUBLIC   dia_ar5_init   ! routine called in opa.F90 module
34   PUBLIC   dia_ar5_alloc  ! routine called in nemogcm.F90 module
35
36   LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .TRUE.   ! coupled flag
37
38   REAL(wp)                         ::   vol0         ! ocean volume (interior domain)
39   REAL(wp)                         ::   area_tot     ! total ocean surface (interior domain)
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:  ) ::   area         ! cell surface (interior domain)
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:  ) ::   thick0       ! ocean thickness (interior domain)
42   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sn0          ! initial salinity
43     
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46#  include "zdfddm_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   FUNCTION dia_ar5_alloc()
55      !!----------------------------------------------------------------------
56      !!                    ***  ROUTINE dia_ar5_alloc  ***
57      !!----------------------------------------------------------------------
58      INTEGER :: dia_ar5_alloc
59      !!----------------------------------------------------------------------
60      !
61      ALLOCATE( area(jpi,jpj), thick0(jpi,jpj) , sn0(jpi,jpj,jpk) , STAT=dia_ar5_alloc )
62      !
63      IF( lk_mpp             )   CALL mpp_sum ( dia_ar5_alloc )
64      IF( dia_ar5_alloc /= 0 )   CALL ctl_warn('dia_ar5_alloc: failed to allocate arrays')
65      !
66   END FUNCTION dia_ar5_alloc
67
68
69   SUBROUTINE dia_ar5( kt )
70      !!----------------------------------------------------------------------
71      !!                    ***  ROUTINE dia_ar5  ***
72      !!
73      !! ** Purpose :   compute and output some AR5 diagnostics
74      !!----------------------------------------------------------------------
75      !
76      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
77      !
78      INTEGER  ::   ji, jj, jk                      ! dummy loop arguments
79      REAL(wp) ::   zvolssh, zvol, zssh_steric, zztmp, zarho, ztemp, zsal, zmass
80      REAL(wp) ::   zaw, zbw, zrw
81      !
82      REAL(wp), POINTER, DIMENSION(:,:)     :: zarea_ssh , zbotpres       ! 2D workspace
83      REAL(wp), POINTER, DIMENSION(:,:)     :: zpe                        ! 2D workspace
84      REAL(wp), POINTER, DIMENSION(:,:,:)   :: zrhd , zrhop               ! 3D workspace
85      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztsn                       ! 4D workspace
86      !!--------------------------------------------------------------------
87      IF( nn_timing == 1 )   CALL timing_start('dia_ar5')
88
89      !Call to init moved to here so that we can call iom_use in the
90      !initialisation
91      IF( kt == nit000 )     CALL dia_ar5_init
92 
93      CALL wrk_alloc( jpi , jpj              , zarea_ssh , zbotpres, zpe )
94      CALL wrk_alloc( jpi , jpj , jpk        , zrhd      , zrhop         )
95      CALL wrk_alloc( jpi , jpj , jpk , jpts , ztsn                      )
96
97      zarea_ssh(:,:) = area(:,:) * sshn(:,:)
98
99      !                                         ! total volume of liquid seawater
100      zvolssh = SUM( zarea_ssh(:,:) ) 
101      IF( lk_mpp )   CALL mpp_sum( zvolssh )
102      zvol = vol0 + zvolssh
103     
104      CALL iom_put( 'voltot', zvol               )
105      CALL iom_put( 'sshtot', zvolssh / area_tot )
106      CALL iom_put( 'sshdyn', sshn(:,:) - (zvolssh / area_tot) )
107
108      !                     
109      IF( iom_use('sshthster')) THEN
110         ztsn(:,:,:,jp_tem) = tsn(:,:,:,jp_tem)                    ! thermosteric ssh
111         ztsn(:,:,:,jp_sal) = sn0(:,:,:)
112         CALL eos( ztsn, zrhd, fsdept_n(:,:,:) )                       ! now in situ density using initial salinity
113         !
114         zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
115         DO jk = 1, jpkm1
116            zbotpres(:,:) = zbotpres(:,:) + fse3t(:,:,jk) * zrhd(:,:,jk)
117         END DO
118         IF( .NOT.lk_vvl ) THEN
119            IF ( ln_isfcav ) THEN
120               DO ji=1,jpi
121                  DO jj=1,jpj
122                     zbotpres(ji,jj) = zbotpres(ji,jj) + sshn(ji,jj) * zrhd(ji,jj,mikt(ji,jj)) + riceload(ji,jj)
123                  END DO
124               END DO
125            ELSE
126               zbotpres(:,:) = zbotpres(:,:) + sshn(:,:) * zrhd(:,:,1)
127            END IF
128         END IF
129      !                                         
130         zarho = SUM( area(:,:) * zbotpres(:,:) ) 
131         IF( lk_mpp )   CALL mpp_sum( zarho )
132         zssh_steric = - zarho / area_tot
133         CALL iom_put( 'sshthster', zssh_steric )
134      ENDIF
135      !                                         ! steric sea surface height
136      CALL eos( tsn, zrhd, zrhop, fsdept_n(:,:,:) )                 ! now in situ and potential density
137      zrhop(:,:,jpk) = 0._wp
138      CALL iom_put( 'rhop', zrhop )
139      !
140      zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
141      DO jk = 1, jpkm1
142         zbotpres(:,:) = zbotpres(:,:) + fse3t(:,:,jk) * zrhd(:,:,jk)
143      END DO
144      IF( .NOT.lk_vvl ) THEN
145         IF ( ln_isfcav ) THEN
146            DO ji=1,jpi
147               DO jj=1,jpj
148                  zbotpres(ji,jj) = zbotpres(ji,jj) + sshn(ji,jj) * zrhd(ji,jj,mikt(ji,jj)) + riceload(ji,jj)
149               END DO
150            END DO
151         ELSE
152            zbotpres(:,:) = zbotpres(:,:) + sshn(:,:) * zrhd(:,:,1)
153         END IF
154      END IF
155      !   
156      zarho = SUM( area(:,:) * zbotpres(:,:) ) 
157      IF( lk_mpp )   CALL mpp_sum( zarho )
158      zssh_steric = - zarho / area_tot
159      CALL iom_put( 'sshsteric', zssh_steric )
160     
161      !                                         ! ocean bottom pressure
162      zztmp = rau0 * grav * 1.e-4_wp               ! recover pressure from pressure anomaly and cover to dbar = 1.e4 Pa
163      zbotpres(:,:) = zztmp * ( zbotpres(:,:) + sshn(:,:) + thick0(:,:) )
164      CALL iom_put( 'botpres', zbotpres )
165
166      !                                         ! Mean density anomalie, temperature and salinity
167      ztemp = 0._wp
168      zsal  = 0._wp
169      DO jk = 1, jpkm1
170         DO jj = 1, jpj
171            DO ji = 1, jpi
172               zztmp = area(ji,jj) * fse3t(ji,jj,jk)
173               ztemp = ztemp + zztmp * tsn(ji,jj,jk,jp_tem)
174               zsal  = zsal  + zztmp * tsn(ji,jj,jk,jp_sal)
175            END DO
176         END DO
177      END DO
178      IF( .NOT.lk_vvl ) THEN
179         IF ( ln_isfcav ) THEN
180            DO ji=1,jpi
181               DO jj=1,jpj
182                  ztemp = ztemp + zarea_ssh(ji,jj) * tsn(ji,jj,mikt(ji,jj),jp_tem) 
183                  zsal  = zsal  + zarea_ssh(ji,jj) * tsn(ji,jj,mikt(ji,jj),jp_sal) 
184               END DO
185            END DO
186         ELSE
187            ztemp = ztemp + SUM( zarea_ssh(:,:) * tsn(:,:,1,jp_tem) )
188            zsal  = zsal  + SUM( zarea_ssh(:,:) * tsn(:,:,1,jp_sal) )
189         END IF
190      ENDIF
191      IF( lk_mpp ) THEN 
192         CALL mpp_sum( ztemp )
193         CALL mpp_sum( zsal  )
194      END IF
195      !
196      zmass = rau0 * ( zarho + zvol )                 ! total mass of liquid seawater
197      ztemp = ztemp / zvol                            ! potential temperature in liquid seawater
198      zsal  = zsal  / zvol                            ! Salinity of liquid seawater
199      !
200      CALL iom_put( 'masstot', zmass )
201      CALL iom_put( 'temptot', ztemp )
202      CALL iom_put( 'saltot' , zsal  )
203
204      IF( iom_use( 'tnpeo' )) THEN   
205      ! Work done against stratification by vertical mixing
206      ! Exclude points where rn2 is negative as convection kicks in here and
207      ! work is not being done against stratification
208         zpe(:,:) = 0._wp
209         IF( lk_zdfddm ) THEN
210            DO jk = 2, jpk
211               DO jj = 1, jpj
212                  DO ji = 1, jpi
213                     IF( rn2(ji,jj,jk) > 0._wp ) THEN
214                        zrw =   ( gdepw_n(ji,jj,jk  ) - gdept_n(ji,jj,jk) )   &
215                           &  / ( gdept_n(ji,jj,jk-1) - gdept_n(ji,jj,jk) )
216                        !
217                        zaw = rab_n(ji,jj,jk,jp_tem) * (1. - zrw) + rab_n(ji,jj,jk-1,jp_tem)* zrw
218                        zbw = rab_n(ji,jj,jk,jp_sal) * (1. - zrw) + rab_n(ji,jj,jk-1,jp_sal)* zrw
219                        !
220                        zpe(ji, jj) = zpe(ji, jj)            &
221                           &        -  grav * (    avt(ji,jj,jk) * zaw * (tsn(ji,jj,jk-1,jp_tem) - tsn(ji,jj,jk,jp_tem) )  &
222                           &                   - fsavs(ji,jj,jk) * zbw * (tsn(ji,jj,jk-1,jp_sal) - tsn(ji,jj,jk,jp_sal) ) )
223                     ENDIF
224                  END DO
225               END DO
226             END DO
227          ELSE
228            DO jk = 1, jpk
229               DO ji = 1, jpi
230                  DO jj = 1, jpj
231                     zpe(ji,jj) = zpe(ji,jj) + avt(ji, jj, jk) * MIN(0._wp,rn2(ji, jj, jk)) * rau0 * e3w_n(ji, jj, jk)
232                  END DO
233               END DO
234            END DO
235         ENDIF
236         CALL lbc_lnk(zpe, 'T', 1._wp)         
237         CALL iom_put( 'tnpeo', zpe  )
238      ENDIF
239      !
240      CALL wrk_dealloc( jpi , jpj              , zarea_ssh , zbotpres, zpe )
241      CALL wrk_dealloc( jpi , jpj , jpk        , zrhd      , zrhop         )
242      CALL wrk_dealloc( jpi , jpj , jpk , jpts , ztsn                      )
243      !
244      IF( nn_timing == 1 )   CALL timing_stop('dia_ar5')
245      !
246   END SUBROUTINE dia_ar5
247
248
249   SUBROUTINE dia_ar5_init
250      !!----------------------------------------------------------------------
251      !!                  ***  ROUTINE dia_ar5_init  ***
252      !!                   
253      !! ** Purpose :   initialization for AR5 diagnostic computation
254      !!----------------------------------------------------------------------
255      INTEGER  ::   inum
256      INTEGER  ::   ik
257      INTEGER  ::   ji, jj, jk  ! dummy loop indices
258      REAL(wp) ::   zztmp 
259      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   zsaldta   ! Jan/Dec levitus salinity
260      !
261      !!----------------------------------------------------------------------
262      !
263      IF( nn_timing == 1 )   CALL timing_start('dia_ar5_init')
264      !
265      CALL wrk_alloc( jpi, jpj, jpk, 2, zsaldta )
266      !                                      ! allocate dia_ar5 arrays
267      IF( dia_ar5_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'dia_ar5_init : unable to allocate arrays' )
268
269      area(:,:) = e1t(:,:) * e2t(:,:) * tmask_i(:,:)
270
271      area_tot = SUM( area(:,:) )   ;   IF( lk_mpp )   CALL mpp_sum( area_tot )
272
273      vol0        = 0._wp
274      thick0(:,:) = 0._wp
275      DO jk = 1, jpkm1
276         vol0        = vol0        + SUM( area (:,:) * tmask(:,:,jk) * e3t_0(:,:,jk) )
277         thick0(:,:) = thick0(:,:) +    tmask_i(:,:) * tmask(:,:,jk) * e3t_0(:,:,jk)
278      END DO
279      IF( lk_mpp )   CALL mpp_sum( vol0 )
280
281      IF( iom_use('sshthster')) THEN
282         CALL iom_open ( 'sali_ref_clim_monthly', inum )
283         CALL iom_get  ( inum, jpdom_data, 'vosaline' , zsaldta(:,:,:,1), 1  )
284         CALL iom_get  ( inum, jpdom_data, 'vosaline' , zsaldta(:,:,:,2), 12 )
285         CALL iom_close( inum )
286
287         sn0(:,:,:) = 0.5_wp * ( zsaldta(:,:,:,1) + zsaldta(:,:,:,2) )       
288         sn0(:,:,:) = sn0(:,:,:) * tmask(:,:,:)
289         IF( ln_zps ) THEN               ! z-coord. partial steps
290            DO jj = 1, jpj               ! interpolation of salinity at the last ocean level (i.e. the partial step)
291               DO ji = 1, jpi
292                  ik = mbkt(ji,jj)
293                  IF( ik > 1 ) THEN
294                     zztmp = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
295                     sn0(ji,jj,ik) = ( 1._wp - zztmp ) * sn0(ji,jj,ik) + zztmp * sn0(ji,jj,ik-1)
296                  ENDIF
297               END DO
298            END DO
299         ENDIF
300      ENDIF
301      !
302      CALL wrk_dealloc( jpi, jpj, jpk, 2, zsaldta )
303      !
304      IF( nn_timing == 1 )   CALL timing_stop('dia_ar5_init')
305      !
306   END SUBROUTINE dia_ar5_init
307
308#else
309   !!----------------------------------------------------------------------
310   !!   Default option :                                         NO diaar5
311   !!----------------------------------------------------------------------
312   LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .FALSE.   ! coupled flag
313CONTAINS
314   SUBROUTINE dia_ar5_init    ! Dummy routine
315   END SUBROUTINE dia_ar5_init
316   SUBROUTINE dia_ar5( kt )   ! Empty routine
317      INTEGER ::   kt
318      WRITE(*,*) 'dia_ar5: You should not have seen this print! error?', kt
319   END SUBROUTINE dia_ar5
320#endif
321
322   !!======================================================================
323END MODULE diaar5
Note: See TracBrowser for help on using the repository browser.