New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynzdf_imp.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/DYN/dynzdf_imp.F90 @ 7037

Last change on this file since 7037 was 7037, checked in by mocavero, 8 years ago

ORCA2_LIM_PISCES hybrid version update
  • Property svn:keywords set to Id
File size: 17.4 KB
Line 
1MODULE dynzdf_imp
2   !!======================================================================
3   !!                    ***  MODULE  dynzdf_imp  ***
4   !! Ocean dynamics:  vertical component(s) of the momentum mixing trend, implicit scheme
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            8.0  !  1997-05  (G. Madec)  vertical component of isopycnal
8   !!   NEMO     0.5  !  2002-08  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!            3.4  !  2012-01  (H. Liu) Semi-implicit bottom friction
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   dyn_zdf_imp   : compute the vertical diffusion using a implicit scheme
15   !!                   together with the Leap-Frog time integration.
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and tracers
18   USE phycst         ! physical constants
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! variable volume
21   USE sbc_oce        ! surface boundary condition: ocean
22   USE dynadv   , ONLY: ln_dynadv_vec ! Momentum advection form
23   USE zdf_oce        ! ocean vertical physics
24   USE zdfbfr         ! Bottom friction setup
25   !
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! MPP library
28   USE wrk_nemo       ! Memory Allocation
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   dyn_zdf_imp   ! called by step.F90
35
36   REAL(wp) ::  r_vvl     ! non-linear free surface indicator: =0 if ln_linssh=T, =1 otherwise
37
38   !! * Substitutions
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE dyn_zdf_imp( kt, p2dt )
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE dyn_zdf_imp  ***
50      !!                   
51      !! ** Purpose :   Compute the trend due to the vert. momentum diffusion
52      !!              together with the Leap-Frog time stepping using an
53      !!              implicit scheme.
54      !!
55      !! ** Method  :  - Leap-Frog time stepping on all trends but the vertical mixing
56      !!         ua =         ub + 2*dt *       ua             vector form or linear free surf.
57      !!         ua = ( e3u_b*ub + 2*dt * e3u_n*ua ) / e3u_a   otherwise
58      !!               - update the after velocity with the implicit vertical mixing.
59      !!      This requires to solver the following system:
60      !!         ua = ua + 1/e3u_a dk+1[ avmu / e3uw_a dk[ua] ]
61      !!      with the following surface/top/bottom boundary condition:
62      !!      surface: wind stress input (averaged over kt-1/2 & kt+1/2)
63      !!      top & bottom : top stress (iceshelf-ocean) & bottom stress (cf zdfbfr.F)
64      !!
65      !! ** Action :   (ua,va) after velocity
66      !!---------------------------------------------------------------------
67      INTEGER , INTENT(in) ::  kt     ! ocean time-step index
68      REAL(wp), INTENT(in) ::  p2dt   ! vertical profile of tracer time-step
69      !
70      INTEGER  ::   ji, jj, jk    ! dummy loop indices
71      INTEGER  ::   ikbu, ikbv    ! local integers
72      REAL(wp) ::   zzwi, ze3ua   ! local scalars
73      REAL(wp) ::   zzws, ze3va   !   -      -
74      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zwi, zwd, zws
75      !!----------------------------------------------------------------------
76      !
77      IF( nn_timing == 1 )  CALL timing_start('dyn_zdf_imp')
78      !
79      CALL wrk_alloc( jpi,jpj,jpk, zwi, zwd, zws ) 
80      !
81      IF( kt == nit000 ) THEN
82         IF(lwp) WRITE(numout,*)
83         IF(lwp) WRITE(numout,*) 'dyn_zdf_imp : vertical momentum diffusion implicit operator'
84         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
85         !
86         If( ln_linssh ) THEN   ;    r_vvl = 0._wp    ! non-linear free surface indicator
87         ELSE                   ;    r_vvl = 1._wp
88         ENDIF
89      ENDIF
90      !
91      !              !==  Time step dynamics  ==!
92      !
93      IF( ln_dynadv_vec .OR. ln_linssh ) THEN      ! applied on velocity
94!$OMP PARALLEL DO schedule(static) private(jk)
95         DO jk = 1, jpkm1
96            ua(:,:,jk) = ( ub(:,:,jk) + p2dt * ua(:,:,jk) ) * umask(:,:,jk)
97            va(:,:,jk) = ( vb(:,:,jk) + p2dt * va(:,:,jk) ) * vmask(:,:,jk)
98         END DO
99      ELSE                                         ! applied on thickness weighted velocity
100!$OMP PARALLEL DO schedule(static) private(jk)
101         DO jk = 1, jpkm1
102            ua(:,:,jk) = (         e3u_b(:,:,jk) * ub(:,:,jk)  &
103               &          + p2dt * e3u_n(:,:,jk) * ua(:,:,jk)  ) / e3u_a(:,:,jk) * umask(:,:,jk)
104            va(:,:,jk) = (         e3v_b(:,:,jk) * vb(:,:,jk)  &
105               &          + p2dt * e3v_n(:,:,jk) * va(:,:,jk)  ) / e3v_a(:,:,jk) * vmask(:,:,jk)
106         END DO
107      ENDIF
108      !
109      !              !==  Apply semi-implicit bottom friction  ==!
110      !
111      ! Only needed for semi-implicit bottom friction setup. The explicit
112      ! bottom friction has been included in "u(v)a" which act as the R.H.S
113      ! column vector of the tri-diagonal matrix equation
114      !
115      IF( ln_bfrimp ) THEN
116!$OMP PARALLEL DO schedule(static) private(jj, ji, ikbu, ikbv)
117         DO jj = 2, jpjm1
118            DO ji = 2, jpim1
119               ikbu = mbku(ji,jj)       ! ocean bottom level at u- and v-points
120               ikbv = mbkv(ji,jj)       ! (deepest ocean u- and v-points)
121               avmu(ji,jj,ikbu+1) = -bfrua(ji,jj) * e3uw_n(ji,jj,ikbu+1)
122               avmv(ji,jj,ikbv+1) = -bfrva(ji,jj) * e3vw_n(ji,jj,ikbv+1)
123            END DO
124         END DO
125         IF ( ln_isfcav ) THEN
126!$OMP PARALLEL DO schedule(static) private(jj, ji, ikbu, ikbv)
127            DO jj = 2, jpjm1
128               DO ji = 2, jpim1
129                  ikbu = miku(ji,jj)       ! ocean top level at u- and v-points
130                  ikbv = mikv(ji,jj)       ! (first wet ocean u- and v-points)
131                  IF( ikbu >= 2 )   avmu(ji,jj,ikbu) = -tfrua(ji,jj) * e3uw_n(ji,jj,ikbu)
132                  IF( ikbv >= 2 )   avmv(ji,jj,ikbv) = -tfrva(ji,jj) * e3vw_n(ji,jj,ikbv)
133               END DO
134            END DO
135         END IF
136      ENDIF
137      !
138      ! With split-explicit free surface, barotropic stress is treated explicitly
139      ! Update velocities at the bottom.
140      ! J. Chanut: The bottom stress is computed considering after barotropic velocities, which does
141      !            not lead to the effective stress seen over the whole barotropic loop.
142      ! G. Madec : in linear free surface, e3u_a = e3u_n = e3u_0, so systematic use of e3u_a
143      IF( ln_bfrimp .AND. ln_dynspg_ts ) THEN
144!$OMP PARALLEL
145!$OMP DO schedule(static) private(jk)
146         DO jk = 1, jpkm1        ! remove barotropic velocities
147            ua(:,:,jk) = ( ua(:,:,jk) - ua_b(:,:) ) * umask(:,:,jk)
148            va(:,:,jk) = ( va(:,:,jk) - va_b(:,:) ) * vmask(:,:,jk)
149         END DO
150!$OMP DO schedule(static) private(jj, ji, ikbu, ikbv, ze3ua, ze3va)
151         DO jj = 2, jpjm1        ! Add bottom/top stress due to barotropic component only
152            DO ji = fs_2, fs_jpim1   ! vector opt.
153               ikbu = mbku(ji,jj)         ! ocean bottom level at u- and v-points
154               ikbv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
155               ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,ikbu) + r_vvl * e3u_a(ji,jj,ikbu)
156               ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,ikbv) + r_vvl * e3v_a(ji,jj,ikbv)
157               ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + p2dt * bfrua(ji,jj) * ua_b(ji,jj) / ze3ua
158               va(ji,jj,ikbv) = va(ji,jj,ikbv) + p2dt * bfrva(ji,jj) * va_b(ji,jj) / ze3va
159            END DO
160         END DO
161!$OMP END DO NOWAIT
162!$OMP END PARALLEL
163         IF( ln_isfcav ) THEN    ! Ocean cavities (ISF)
164!$OMP PARALLEL DO schedule(static) private(jj, ji, ikbu, ikbv, ze3ua, ze3va)
165            DO jj = 2, jpjm1       
166               DO ji = fs_2, fs_jpim1   ! vector opt.
167                  ikbu = miku(ji,jj)         ! top ocean level at u- and v-points
168                  ikbv = mikv(ji,jj)         ! (first wet ocean u- and v-points)
169                  ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,ikbu) + r_vvl * e3u_a(ji,jj,ikbu)
170                  ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,ikbv) + r_vvl * e3v_a(ji,jj,ikbv)
171                  ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + p2dt * tfrua(ji,jj) * ua_b(ji,jj) / ze3ua
172                  va(ji,jj,ikbv) = va(ji,jj,ikbv) + p2dt * tfrva(ji,jj) * va_b(ji,jj) / ze3va
173               END DO
174            END DO
175         END IF
176      ENDIF
177      !
178      !              !==  Vertical diffusion on u  ==!
179      !
180      ! Matrix and second member construction
181      ! bottom boundary condition: both zwi and zws must be masked as avmu can take
182      ! non zero value at the ocean bottom depending on the bottom friction used.
183      !
184!$OMP PARALLEL
185!$OMP DO schedule(static) private(jk, jj, ji, ze3ua, zzwi, zzws)
186      DO jk = 1, jpkm1        ! Matrix
187         DO jj = 2, jpjm1 
188            DO ji = fs_2, fs_jpim1   ! vector opt.
189               ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,jk) + r_vvl * e3u_a(ji,jj,jk)   ! after scale factor at T-point
190               zzwi = - p2dt * avmu(ji,jj,jk  ) / ( ze3ua * e3uw_n(ji,jj,jk  ) )
191               zzws = - p2dt * avmu(ji,jj,jk+1) / ( ze3ua * e3uw_n(ji,jj,jk+1) )
192               zwi(ji,jj,jk) = zzwi * wumask(ji,jj,jk  )
193               zws(ji,jj,jk) = zzws * wumask(ji,jj,jk+1)
194               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
195            END DO
196         END DO
197      END DO
198!$OMP DO schedule(static) private(jj, ji)
199      DO jj = 2, jpjm1        ! Surface boundary conditions
200         DO ji = fs_2, fs_jpim1   ! vector opt.
201            zwi(ji,jj,1) = 0._wp
202            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
203         END DO
204      END DO
205
206      ! Matrix inversion starting from the first level
207      !-----------------------------------------------------------------------
208      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
209      !
210      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
211      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
212      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
213      !        (        ...               )( ...  ) ( ...  )
214      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
215      !
216      !   m is decomposed in the product of an upper and a lower triangular matrix
217      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
218      !   The solution (the after velocity) is in ua
219      !-----------------------------------------------------------------------
220      !
221      DO jk = 2, jpkm1        !==  First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1   (increasing k)  ==
222!$OMP DO schedule(static) private(jj, ji)
223         DO jj = 2, jpjm1   
224            DO ji = fs_2, fs_jpim1   ! vector opt.
225               zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
226            END DO
227         END DO
228!$OMP END DO NOWAIT
229      END DO
230      !
231!$OMP DO schedule(static) private(jj, ji, ze3ua)
232      DO jj = 2, jpjm1        !==  second recurrence:    SOLk = RHSk - Lk / Dk-1  Lk-1  ==!
233         DO ji = fs_2, fs_jpim1   ! vector opt.
234            ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,1) + r_vvl * e3u_a(ji,jj,1) 
235            ua(ji,jj,1) = ua(ji,jj,1) + p2dt * 0.5_wp * ( utau_b(ji,jj) + utau(ji,jj) )   &
236               &                                      / ( ze3ua * rau0 ) * umask(ji,jj,1) 
237         END DO
238      END DO
239      DO jk = 2, jpkm1
240!$OMP DO schedule(static) private(jj, ji)
241         DO jj = 2, jpjm1
242            DO ji = fs_2, fs_jpim1
243               ua(ji,jj,jk) = ua(ji,jj,jk) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * ua(ji,jj,jk-1)
244            END DO
245         END DO
246      END DO
247      !
248!$OMP DO schedule(static) private(jj, ji)
249        DO jj = 2, jpjm1        !==  thrid recurrence : SOLk = ( Lk - Uk * Ek+1 ) / Dk  ==!
250         DO ji = fs_2, fs_jpim1   ! vector opt.
251            ua(ji,jj,jpkm1) = ua(ji,jj,jpkm1) / zwd(ji,jj,jpkm1)
252         END DO
253      END DO
254      DO jk = jpk-2, 1, -1
255!$OMP DO schedule(static) private(jj, ji)
256        DO jj = 2, jpjm1
257            DO ji = fs_2, fs_jpim1
258               ua(ji,jj,jk) = ( ua(ji,jj,jk) - zws(ji,jj,jk) * ua(ji,jj,jk+1) ) / zwd(ji,jj,jk)
259            END DO
260         END DO
261      END DO
262      !
263      !              !==  Vertical diffusion on v  ==!
264      !
265      ! Matrix and second member construction
266      ! bottom boundary condition: both zwi and zws must be masked as avmv can take
267      ! non zero value at the ocean bottom depending on the bottom friction used
268      !
269!$OMP DO schedule(static) private(jk, jj, ji, ze3va, zzwi, zzws)
270      DO jk = 1, jpkm1        ! Matrix
271         DO jj = 2, jpjm1   
272            DO ji = fs_2, fs_jpim1   ! vector opt.
273               ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,jk) + r_vvl * e3v_a(ji,jj,jk)   ! after scale factor at T-point
274               zzwi = - p2dt * avmv (ji,jj,jk  ) / ( ze3va * e3vw_n(ji,jj,jk  ) )
275               zzws = - p2dt * avmv (ji,jj,jk+1) / ( ze3va * e3vw_n(ji,jj,jk+1) )
276               zwi(ji,jj,jk) = zzwi * wvmask(ji,jj,jk  )
277               zws(ji,jj,jk) = zzws * wvmask(ji,jj,jk+1)
278               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
279            END DO
280         END DO
281      END DO
282!$OMP DO schedule(static) private(jj, ji)
283      DO jj = 2, jpjm1        ! Surface boundary conditions
284         DO ji = fs_2, fs_jpim1   ! vector opt.
285            zwi(ji,jj,1) = 0._wp
286            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
287         END DO
288      END DO
289
290      ! Matrix inversion
291      !-----------------------------------------------------------------------
292      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
293      !
294      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
295      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
296      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
297      !        (        ...               )( ...  ) ( ...  )
298      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
299      !
300      !   m is decomposed in the product of an upper and lower triangular matrix
301      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
302      !   The solution (after velocity) is in 2d array va
303      !-----------------------------------------------------------------------
304      !
305      DO jk = 2, jpkm1        !==  First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1   (increasing k)  ==
306!$OMP DO schedule(static) private(jj, ji)
307         DO jj = 2, jpjm1   
308            DO ji = fs_2, fs_jpim1   ! vector opt.
309               zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
310            END DO
311         END DO
312!$OMP END DO NOWAIT
313      END DO
314      !
315!$OMP DO schedule(static) private(jj, ji, ze3va)
316      DO jj = 2, jpjm1        !==  second recurrence:    SOLk = RHSk - Lk / Dk-1  Lk-1  ==!
317         DO ji = fs_2, fs_jpim1   ! vector opt.         
318            ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,1) + r_vvl * e3v_a(ji,jj,1) 
319            va(ji,jj,1) = va(ji,jj,1) + p2dt * 0.5_wp * ( vtau_b(ji,jj) + vtau(ji,jj) )   &
320               &                                      / ( ze3va * rau0 ) 
321         END DO
322      END DO
323      DO jk = 2, jpkm1
324!$OMP DO schedule(static) private(jj, ji)
325         DO jj = 2, jpjm1
326            DO ji = fs_2, fs_jpim1   ! vector opt.
327               va(ji,jj,jk) = va(ji,jj,jk) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * va(ji,jj,jk-1)
328            END DO
329         END DO
330      END DO
331      !
332!$OMP DO schedule(static) private(jj, ji)
333      DO jj = 2, jpjm1        !==  third recurrence : SOLk = ( Lk - Uk * SOLk+1 ) / Dk  ==!
334         DO ji = fs_2, fs_jpim1   ! vector opt.
335            va(ji,jj,jpkm1) = va(ji,jj,jpkm1) / zwd(ji,jj,jpkm1)
336         END DO
337      END DO
338      DO jk = jpk-2, 1, -1
339!$OMP DO schedule(static) private(jj, ji)
340         DO jj = 2, jpjm1
341            DO ji = fs_2, fs_jpim1
342               va(ji,jj,jk) = ( va(ji,jj,jk) - zws(ji,jj,jk) * va(ji,jj,jk+1) ) / zwd(ji,jj,jk)
343            END DO
344         END DO
345!$OMP END DO NOWAIT
346      END DO
347!$OMP END PARALLEL     
348      ! J. Chanut: Lines below are useless ?
349      !! restore bottom layer avmu(v)
350      !!gm  I almost sure it is !!!!
351      IF( ln_bfrimp ) THEN
352!$OMP PARALLEL DO schedule(static) private(jj, ji, ikbu, ikbv)
353        DO jj = 2, jpjm1
354           DO ji = 2, jpim1
355              ikbu = mbku(ji,jj)         ! ocean bottom level at u- and v-points
356              ikbv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
357              avmu(ji,jj,ikbu+1) = 0._wp
358              avmv(ji,jj,ikbv+1) = 0._wp
359           END DO
360        END DO
361        IF (ln_isfcav) THEN
362!$OMP PARALLEL DO schedule(static) private(jj, ji, ikbu, ikbv)
363           DO jj = 2, jpjm1
364              DO ji = 2, jpim1
365                 ikbu = miku(ji,jj)         ! ocean top level at u- and v-points
366                 ikbv = mikv(ji,jj)         ! (first wet ocean u- and v-points)
367                 IF( ikbu > 1 )   avmu(ji,jj,ikbu) = 0._wp
368                 IF( ikbv > 1 )   avmv(ji,jj,ikbv) = 0._wp
369              END DO
370           END DO
371        ENDIF
372      ENDIF
373      !
374      CALL wrk_dealloc( jpi,jpj,jpk,   zwi, zwd, zws) 
375      !
376      IF( nn_timing == 1 )   CALL timing_stop('dyn_zdf_imp')
377      !
378   END SUBROUTINE dyn_zdf_imp
379
380   !!==============================================================================
381END MODULE dynzdf_imp
Note: See TracBrowser for help on using the repository browser.