New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldftra.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/LDF – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/LDF/ldftra.F90 @ 7512

Last change on this file since 7512 was 7508, checked in by mocavero, 7 years ago

changes on code duplication and workshare construct
  • Property svn:keywords set to Id
File size: 44.5 KB
Line 
1MODULE ldftra
2   !!======================================================================
3   !!                       ***  MODULE  ldftra  ***
4   !! Ocean physics:  lateral diffusivity coefficients
5   !!=====================================================================
6   !! History :       ! 1997-07  (G. Madec)  from inimix.F split in 2 routines
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            2.0  ! 2005-11  (G. Madec) 
9   !!            3.7  ! 2013-12  (F. Lemarie, G. Madec)  restructuration/simplification of aht/aeiv specification,
10   !!                 !                                  add velocity dependent coefficient and optional read in file
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   ldf_tra_init : initialization, namelist read, and parameters control
15   !!   ldf_tra      : update lateral eddy diffusivity coefficients at each time step
16   !!   ldf_eiv_init : initialization of the eiv coeff. from namelist choices
17   !!   ldf_eiv      : time evolution of the eiv coefficients (function of the growth rate of baroclinic instability)
18   !!   ldf_eiv_trp  : add to the input ocean transport the contribution of the EIV parametrization
19   !!   ldf_eiv_dia  : diagnose the eddy induced velocity from the eiv streamfunction
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and tracers
22   USE dom_oce         ! ocean space and time domain
23   USE phycst          ! physical constants
24   USE ldfslp          ! lateral diffusion: slope of iso-neutral surfaces
25   USE ldfc1d_c2d      ! lateral diffusion: 1D & 2D cases
26   USE diaar5, ONLY:   lk_diaar5
27   !
28   USE trc_oce, ONLY: lk_offline ! offline flag
29   USE in_out_manager  ! I/O manager
30   USE iom             ! I/O module for ehanced bottom friction file
31   USE lib_mpp         ! distribued memory computing library
32   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
33   USE wrk_nemo        ! work arrays
34   USE timing          ! timing
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   ldf_tra_init   ! called by nemogcm.F90
40   PUBLIC   ldf_tra        ! called by step.F90
41   PUBLIC   ldf_eiv_init   ! called by nemogcm.F90
42   PUBLIC   ldf_eiv        ! called by step.F90
43   PUBLIC   ldf_eiv_trp    ! called by traadv.F90
44   PUBLIC   ldf_eiv_dia    ! called by traldf_iso and traldf_iso_triad.F90
45   
46   !                                   !!* Namelist namtra_ldf : lateral mixing on tracers *
47   !                                    != Operator type =!
48   LOGICAL , PUBLIC ::   ln_traldf_lap       !: laplacian operator
49   LOGICAL , PUBLIC ::   ln_traldf_blp       !: bilaplacian operator
50   !                                    != Direction of action =!
51   LOGICAL , PUBLIC ::   ln_traldf_lev       !: iso-level direction
52   LOGICAL , PUBLIC ::   ln_traldf_hor       !: horizontal (geopotential) direction
53!  LOGICAL , PUBLIC ::   ln_traldf_iso       !: iso-neutral direction                    (see ldfslp)
54!  LOGICAL , PUBLIC ::   ln_traldf_triad     !: griffies triad scheme                    (see ldfslp)
55   LOGICAL , PUBLIC ::   ln_traldf_msc       !: Method of Stabilizing Correction
56!  LOGICAL , PUBLIC ::   ln_triad_iso        !: pure horizontal mixing in ML             (see ldfslp)
57!  LOGICAL , PUBLIC ::   ln_botmix_triad     !: mixing on bottom                         (see ldfslp)
58!  REAL(wp), PUBLIC ::   rn_sw_triad         !: =1/0 switching triad / all 4 triads used (see ldfslp)
59!  REAL(wp), PUBLIC ::   rn_slpmax           !: slope limit                              (see ldfslp)
60   !                                    !=  Coefficients =!
61   INTEGER , PUBLIC ::   nn_aht_ijk_t        !: choice of time & space variations of the lateral eddy diffusivity coef.
62   REAL(wp), PUBLIC ::   rn_aht_0            !:   laplacian lateral eddy diffusivity [m2/s]
63   REAL(wp), PUBLIC ::   rn_bht_0            !: bilaplacian lateral eddy diffusivity [m4/s]
64
65   !                                   !!* Namelist namtra_ldfeiv : eddy induced velocity param. *
66   !                                    != Use/diagnose eiv =!
67   LOGICAL , PUBLIC ::   ln_ldfeiv           !: eddy induced velocity flag
68   LOGICAL , PUBLIC ::   ln_ldfeiv_dia       !: diagnose & output eiv streamfunction and velocity (IOM)
69   !                                    != Coefficients =!
70   INTEGER , PUBLIC ::   nn_aei_ijk_t        !: choice of time/space variation of the eiv coeff.
71   REAL(wp), PUBLIC ::   rn_aeiv_0           !: eddy induced velocity coefficient [m2/s]
72   
73   LOGICAL , PUBLIC ::   l_ldftra_time = .FALSE.   !: flag for time variation of the lateral eddy diffusivity coef.
74   LOGICAL , PUBLIC ::   l_ldfeiv_time = .FALSE.   ! flag for time variation of the eiv coef.
75
76   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ahtu, ahtv   !: eddy diffusivity coef. at U- and V-points   [m2/s]
77   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   aeiu, aeiv   !: eddy induced velocity coeff.                [m2/s]
78
79   REAL(wp) ::   r1_4  = 0.25_wp          ! =1/4
80   REAL(wp) ::   r1_12 = 1._wp / 12._wp   ! =1/12
81
82   !! * Substitutions
83#  include "vectopt_loop_substitute.h90"
84   !!----------------------------------------------------------------------
85   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
86   !! $Id$
87   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
88   !!----------------------------------------------------------------------
89CONTAINS
90
91   SUBROUTINE ldf_tra_init
92      !!----------------------------------------------------------------------
93      !!                  ***  ROUTINE ldf_tra_init  ***
94      !!
95      !! ** Purpose :   initializations of the tracer lateral mixing coeff.
96      !!
97      !! ** Method  : * the eddy diffusivity coef. specification depends on:
98      !!
99      !!    ln_traldf_lap = T     laplacian operator
100      !!    ln_traldf_blp = T   bilaplacian operator
101      !!
102      !!    nn_aht_ijk_t  =  0 => = constant
103      !!                  !
104      !!                  = 10 => = F(z) : constant with a reduction of 1/4 with depth
105      !!                  !
106      !!                  =-20 => = F(i,j)   = shape read in 'eddy_diffusivity.nc' file
107      !!                  = 20    = F(i,j)   = F(e1,e2) or F(e1^3,e2^3) (lap or bilap case)
108      !!                  = 21    = F(i,j,t) = F(growth rate of baroclinic instability)
109      !!                  !
110      !!                  =-30 => = F(i,j,k)   = shape read in 'eddy_diffusivity.nc' file
111      !!                  = 30    = F(i,j,k)   = 2D (case 20) + decrease with depth (case 10)
112      !!                  = 31    = F(i,j,k,t) = F(local velocity) (  |u|e  /12   laplacian operator
113      !!                                                          or |u|e^3/12 bilaplacian operator )
114      !!              * initialisation of the eddy induced velocity coefficient by a call to ldf_eiv_init
115      !!           
116      !! ** action  : ahtu, ahtv initialized once for all or l_ldftra_time set to true
117      !!              aeiu, aeiv initialized once for all or l_ldfeiv_time set to true
118      !!----------------------------------------------------------------------
119      INTEGER  ::   jk, jj, ji        ! dummy loop indices
120      INTEGER  ::   ierr, inum, ios   ! local integer
121      REAL(wp) ::   zah0              ! local scalar
122      !
123      NAMELIST/namtra_ldf/ ln_traldf_lap, ln_traldf_blp  ,                   &   ! type of operator
124         &                 ln_traldf_lev, ln_traldf_hor  , ln_traldf_triad,  &   ! acting direction of the operator
125         &                 ln_traldf_iso, ln_traldf_msc  ,  rn_slpmax     ,  &   ! option for iso-neutral operator
126         &                 ln_triad_iso , ln_botmix_triad, rn_sw_triad    ,  &   ! option for triad operator
127         &                 rn_aht_0     , rn_bht_0       , nn_aht_ijk_t          ! lateral eddy coefficient
128      !!----------------------------------------------------------------------
129      !
130      !  Choice of lateral tracer physics
131      ! =================================
132      !
133      REWIND( numnam_ref )              ! Namelist namtra_ldf in reference namelist : Lateral physics on tracers
134      READ  ( numnam_ref, namtra_ldf, IOSTAT = ios, ERR = 901)
135901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_ldf in reference namelist', lwp )
136      !
137      REWIND( numnam_cfg )              ! Namelist namtra_ldf in configuration namelist : Lateral physics on tracers
138      READ  ( numnam_cfg, namtra_ldf, IOSTAT = ios, ERR = 902 )
139902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_ldf in configuration namelist', lwp )
140      IF(lwm) WRITE ( numond, namtra_ldf )
141      !
142      IF(lwp) THEN                      ! control print
143         WRITE(numout,*)
144         WRITE(numout,*) 'ldf_tra_init : lateral tracer physics'
145         WRITE(numout,*) '~~~~~~~~~~~~ '
146         WRITE(numout,*) '   Namelist namtra_ldf : lateral mixing parameters (type, direction, coefficients)'
147         !
148         WRITE(numout,*) '      type :'
149         WRITE(numout,*) '         laplacian operator                      ln_traldf_lap   = ', ln_traldf_lap
150         WRITE(numout,*) '         bilaplacian operator                    ln_traldf_blp   = ', ln_traldf_blp
151         !
152         WRITE(numout,*) '      direction of action :'
153         WRITE(numout,*) '         iso-level                               ln_traldf_lev   = ', ln_traldf_lev
154         WRITE(numout,*) '         horizontal (geopotential)               ln_traldf_hor   = ', ln_traldf_hor
155         WRITE(numout,*) '         iso-neutral Madec operator              ln_traldf_iso   = ', ln_traldf_iso
156         WRITE(numout,*) '         iso-neutral triad operator              ln_traldf_triad = ', ln_traldf_triad
157         WRITE(numout,*) '            iso-neutral (Method of Stab. Corr.)  ln_traldf_msc   = ', ln_traldf_msc
158         WRITE(numout,*) '            maximum isoppycnal slope             rn_slpmax       = ', rn_slpmax
159         WRITE(numout,*) '            pure lateral mixing in ML            ln_triad_iso    = ', ln_triad_iso
160         WRITE(numout,*) '            switching triad or not               rn_sw_triad     = ', rn_sw_triad
161         WRITE(numout,*) '            lateral mixing on bottom             ln_botmix_triad = ', ln_botmix_triad
162         !
163         WRITE(numout,*) '      coefficients :'
164         WRITE(numout,*) '         lateral eddy diffusivity   (lap case)   rn_aht_0        = ', rn_aht_0
165         WRITE(numout,*) '         lateral eddy diffusivity (bilap case)   rn_bht_0        = ', rn_bht_0
166         WRITE(numout,*) '         type of time-space variation            nn_aht_ijk_t    = ', nn_aht_ijk_t
167      ENDIF
168      !
169      !                                ! Parameter control
170      !
171      IF( .NOT.ln_traldf_lap .AND. .NOT.ln_traldf_blp ) THEN
172         IF(lwp) WRITE(numout,*) '   No diffusive operator selected. ahtu and ahtv are not allocated'
173         l_ldftra_time = .FALSE.
174         RETURN
175      ENDIF
176      !
177      IF( ln_traldf_blp .AND. ( ln_traldf_iso .OR. ln_traldf_triad) ) THEN     ! iso-neutral bilaplacian need MSC
178         IF( .NOT.ln_traldf_msc )   CALL ctl_stop( 'tra_ldf_init: iso-neutral bilaplacian requires ln_traldf_msc=.true.' )
179      ENDIF
180      !
181      !  Space/time variation of eddy coefficients
182      ! ===========================================
183      !                                               ! allocate the aht arrays
184      ALLOCATE( ahtu(jpi,jpj,jpk) , ahtv(jpi,jpj,jpk) , STAT=ierr )
185      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'ldf_tra_init: failed to allocate arrays')
186      !
187!$OMP PARALLEL DO schedule(static) private(jj, ji)
188      DO jj = 1, jpj
189         DO ji = 1, jpi
190            ahtu(ji,jj,jpk) = 0._wp                           ! last level always 0 
191            ahtv(ji,jj,jpk) = 0._wp
192         END DO
193      END DO
194      !
195      !                                               ! value of eddy mixing coef.
196      IF    ( ln_traldf_lap ) THEN   ;   zah0 =      rn_aht_0        !   laplacian operator
197      ELSEIF( ln_traldf_blp ) THEN   ;   zah0 = ABS( rn_bht_0 )      ! bilaplacian operator
198      ENDIF
199      !
200      l_ldftra_time = .FALSE.                         ! no time variation except in case defined below
201      !
202      IF( ln_traldf_lap .OR. ln_traldf_blp ) THEN     ! only if a lateral diffusion operator is used
203         !
204         SELECT CASE(  nn_aht_ijk_t  )                   ! Specification of space time variations of ehtu, ahtv
205         !
206         CASE(   0  )      !==  constant  ==!
207            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = constant = ', rn_aht_0
208!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
209            DO jk = 1, jpk
210               DO jj = 1, jpj
211                  DO ji = 1, jpi
212                     ahtu(ji,jj,jk) = zah0 * umask(ji,jj,jk)
213                     ahtv(ji,jj,jk) = zah0 * vmask(ji,jj,jk)
214                  END DO
215               END DO
216            END DO
217            !
218         CASE(  10  )      !==  fixed profile  ==!
219            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( depth )'
220!$OMP PARALLEL DO schedule(static) private(jj, ji)
221            DO jj = 1, jpj
222               DO ji = 1, jpi
223                  ahtu(ji,jj,1) = zah0 * umask(ji,jj,1)                      ! constant surface value
224                  ahtv(ji,jj,1) = zah0 * vmask(ji,jj,1)
225               END DO
226            END DO
227            CALL ldf_c1d( 'TRA', r1_4, ahtu(:,:,1), ahtv(:,:,1), ahtu, ahtv )
228            !
229         CASE ( -20 )      !== fixed horizontal shape read in file  ==!
230            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F(i,j) read in eddy_diffusivity.nc file'
231            CALL iom_open( 'eddy_diffusivity_2D.nc', inum )
232            CALL iom_get ( inum, jpdom_data, 'ahtu_2D', ahtu(:,:,1) )
233            CALL iom_get ( inum, jpdom_data, 'ahtv_2D', ahtv(:,:,1) )
234            CALL iom_close( inum )
235!$OMP PARALLEL DO schedule(static) private(jk)
236            DO jk = 2, jpkm1
237               ahtu(:,:,jk) = ahtu(:,:,1) * umask(:,:,jk)
238               ahtv(:,:,jk) = ahtv(:,:,1) * vmask(:,:,jk)
239            END DO
240            !
241         CASE(  20  )      !== fixed horizontal shape  ==!
242            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( e1, e2 ) or F( e1^3, e2^3 ) (lap or blp case)'
243            IF( ln_traldf_lap )   CALL ldf_c2d( 'TRA', 'LAP', zah0, ahtu, ahtv )    ! surface value proportional to scale factor
244            IF( ln_traldf_blp )   CALL ldf_c2d( 'TRA', 'BLP', zah0, ahtu, ahtv )    ! surface value proportional to scale factor
245            !
246         CASE(  21  )      !==  time varying 2D field  ==!
247            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( latitude, longitude, time )'
248            IF(lwp) WRITE(numout,*) '                              = F( growth rate of baroclinic instability )'
249            IF(lwp) WRITE(numout,*) '                              min value = 0.1 * rn_aht_0'
250            IF(lwp) WRITE(numout,*) '                              max value = rn_aht_0 (rn_aeiv_0 if nn_aei_ijk_t=21)'
251            IF(lwp) WRITE(numout,*) '                              increased to rn_aht_0 within 20N-20S'
252            !
253            l_ldftra_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
254            !
255            IF( ln_traldf_blp ) THEN
256               CALL ctl_stop( 'ldf_tra_init: aht=F(growth rate of baroc. insta.) incompatible with bilaplacian operator' )
257            ENDIF
258            !
259         CASE( -30  )      !== fixed 3D shape read in file  ==!
260            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F(i,j,k) read in eddy_diffusivity.nc file'
261            CALL iom_open( 'eddy_diffusivity_3D.nc', inum )
262            CALL iom_get ( inum, jpdom_data, 'ahtu_3D', ahtu )
263            CALL iom_get ( inum, jpdom_data, 'ahtv_3D', ahtv )
264            CALL iom_close( inum )
265!$OMP PARALLEL DO schedule(static) private(jk)
266            DO jk = 1, jpkm1
267               ahtu(:,:,jk) = ahtu(:,:,jk) * umask(:,:,jk)
268               ahtv(:,:,jk) = ahtv(:,:,jk) * vmask(:,:,jk)
269            END DO
270            !
271         CASE(  30  )      !==  fixed 3D shape  ==!
272            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( latitude, longitude, depth )'
273            IF( ln_traldf_lap )   CALL ldf_c2d( 'TRA', 'LAP', zah0, ahtu, ahtv )    ! surface value proportional to scale factor
274            IF( ln_traldf_blp )   CALL ldf_c2d( 'TRA', 'BLP', zah0, ahtu, ahtv )    ! surface value proportional to scale factor
275            !                                                    ! reduction with depth
276            CALL ldf_c1d( 'TRA', r1_4, ahtu(:,:,1), ahtv(:,:,1), ahtu, ahtv )
277            !
278         CASE(  31  )      !==  time varying 3D field  ==!
279            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( latitude, longitude, depth , time )'
280            IF(lwp) WRITE(numout,*) '                                proportional to the velocity : |u|e/12 or |u|e^3/12'
281            !
282            l_ldftra_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
283            !
284         CASE DEFAULT
285            CALL ctl_stop('ldf_tra_init: wrong choice for nn_aht_ijk_t, the type of space-time variation of aht')
286         END SELECT
287         !
288         IF( ln_traldf_blp .AND. .NOT. l_ldftra_time ) THEN
289!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
290            DO jk = 1, jpk
291               DO jj = 1, jpj
292                  DO ji = 1, jpi
293                     ahtu(ji,jj,jk) = SQRT( ahtu(ji,jj,jk) )
294                     ahtv(ji,jj,jk) = SQRT( ahtv(ji,jj,jk) )
295                  END DO
296               END DO
297            END DO
298         ENDIF
299         !
300      ENDIF
301      !
302   END SUBROUTINE ldf_tra_init
303
304
305   SUBROUTINE ldf_tra( kt )
306      !!----------------------------------------------------------------------
307      !!                  ***  ROUTINE ldf_tra  ***
308      !!
309      !! ** Purpose :   update at kt the tracer lateral mixing coeff. (aht and aeiv)
310      !!
311      !! ** Method  :   time varying eddy diffusivity coefficients:
312      !!
313      !!    nn_aei_ijk_t = 21    aeiu, aeiv = F(i,j,  t) = F(growth rate of baroclinic instability)
314      !!                                                   with a reduction to 0 in vicinity of the Equator
315      !!    nn_aht_ijk_t = 21    ahtu, ahtv = F(i,j,  t) = F(growth rate of baroclinic instability)
316      !!
317      !!                 = 31    ahtu, ahtv = F(i,j,k,t) = F(local velocity) (  |u|e  /12   laplacian operator
318      !!                                                                     or |u|e^3/12 bilaplacian operator )
319      !!
320      !! ** action  :   ahtu, ahtv   update at each time step   
321      !!                aeiu, aeiv      -       -     -    -   (if ln_ldfeiv=T)
322      !!----------------------------------------------------------------------
323      INTEGER, INTENT(in) ::   kt   ! time step
324      !
325      INTEGER  ::   ji, jj, jk   ! dummy loop indices
326      REAL(wp) ::   zaht, zaht_min, z1_f20       ! local scalar
327      !!----------------------------------------------------------------------
328      !
329      IF( nn_aei_ijk_t == 21 ) THEN       ! eddy induced velocity coefficients
330         !                                ! =F(growth rate of baroclinic instability)
331         !                                ! max value rn_aeiv_0 ; decreased to 0 within 20N-20S
332         CALL ldf_eiv( kt, rn_aeiv_0, aeiu, aeiv )
333         IF(lwp .AND. kt<=nit000+20 )   WRITE(numout,*) ' kt , ldf_eiv appel', kt
334      ENDIF
335      !
336      SELECT CASE(  nn_aht_ijk_t  )       ! Eddy diffusivity coefficients
337      !
338      CASE(  21  )       !==  time varying 2D field  ==!   = F( growth rate of baroclinic instability )
339         !                                             !   min value rn_aht_0 / 10
340         !                                             !   max value rn_aht_0 (rn_aeiv_0 if nn_aei_ijk_t=21)
341         !                                             !   increase to rn_aht_0 within 20N-20S
342         IF( nn_aei_ijk_t /= 21 ) THEN
343            CALL ldf_eiv( kt, rn_aht_0, ahtu, ahtv )
344            IF(lwp .AND. kt<=nit000+20 )   WRITE(numout,*) ' kt , ldf_eiv appel  2', kt
345         ELSE
346            ahtu(:,:,1) = aeiu(:,:,1)
347            ahtv(:,:,1) = aeiv(:,:,1)
348            IF(lwp .AND. kt<=nit000+20 )   WRITE(numout,*) ' kt , ahtu=aeiu', kt
349         ENDIF
350         !
351         z1_f20   = 1._wp / (  2._wp * omega * SIN( rad * 20._wp )  )      ! 1 / ff(20 degrees)   
352         zaht_min = 0.2_wp * rn_aht_0                                      ! minimum value for aht
353!$OMP PARALLEL
354!$OMP DO schedule(static) private(jj,ji,zaht)
355         DO jj = 1, jpj
356            DO ji = 1, jpi
357               zaht = ( 1._wp -  MIN( 1._wp , ABS( ff(ji,jj) * z1_f20 ) ) ) * ( rn_aht_0 - zaht_min )
358               ahtu(ji,jj,1) = (  MAX( zaht_min, ahtu(ji,jj,1) ) + zaht  ) * umask(ji,jj,1)     ! min value zaht_min
359               ahtv(ji,jj,1) = (  MAX( zaht_min, ahtv(ji,jj,1) ) + zaht  ) * vmask(ji,jj,1)     ! increase within 20S-20N
360            END DO
361         END DO
362!$OMP DO schedule(static) private(jk)
363         DO jk = 2, jpkm1                             ! deeper value = surface value
364            ahtu(:,:,jk) = ahtu(:,:,1) * umask(:,:,jk)
365            ahtv(:,:,jk) = ahtv(:,:,1) * vmask(:,:,jk)
366         END DO
367!$OMP END DO NOWAIT
368!$OMP END PARALLEL
369         !
370      CASE(  31  )       !==  time varying 3D field  ==!   = F( local velocity )
371         IF( ln_traldf_lap     ) THEN          !   laplacian operator |u| e /12
372!$OMP PARALLEL DO schedule(static) private(jk)
373            DO jk = 1, jpkm1
374               ahtu(:,:,jk) = ABS( ub(:,:,jk) ) * e1u(:,:) * r1_12
375               ahtv(:,:,jk) = ABS( vb(:,:,jk) ) * e2v(:,:) * r1_12
376            END DO
377         ELSEIF( ln_traldf_blp ) THEN      ! bilaplacian operator      sqrt( |u| e^3 /12 ) = sqrt( |u| e /12 ) * e
378!$OMP PARALLEL DO schedule(static) private(jk)
379            DO jk = 1, jpkm1
380               ahtu(:,:,jk) = SQRT(  ABS( ub(:,:,jk) ) * e1u(:,:) * r1_12  ) * e1u(:,:)
381               ahtv(:,:,jk) = SQRT(  ABS( vb(:,:,jk) ) * e2v(:,:) * r1_12  ) * e2v(:,:)
382            END DO
383         ENDIF
384         !
385      END SELECT
386      !
387      IF( .NOT.lk_offline ) THEN
388         CALL iom_put( "ahtu_2d", ahtu(:,:,1) )   ! surface u-eddy diffusivity coeff.
389         CALL iom_put( "ahtv_2d", ahtv(:,:,1) )   ! surface v-eddy diffusivity coeff.
390         CALL iom_put( "ahtu_3d", ahtu(:,:,:) )   ! 3D      u-eddy diffusivity coeff.
391         CALL iom_put( "ahtv_3d", ahtv(:,:,:) )   ! 3D      v-eddy diffusivity coeff.
392         !
393!!gm  : THE IF below is to be checked (comes from Seb)
394         IF( ln_ldfeiv ) THEN
395           CALL iom_put( "aeiu_2d", aeiu(:,:,1) )   ! surface u-EIV coeff.
396           CALL iom_put( "aeiv_2d", aeiv(:,:,1) )   ! surface v-EIV coeff.
397           CALL iom_put( "aeiu_3d", aeiu(:,:,:) )   ! 3D      u-EIV coeff.
398           CALL iom_put( "aeiv_3d", aeiv(:,:,:) )   ! 3D      v-EIV coeff.
399         ENDIF     
400      ENDIF
401      !
402   END SUBROUTINE ldf_tra
403
404
405   SUBROUTINE ldf_eiv_init
406      !!----------------------------------------------------------------------
407      !!                  ***  ROUTINE ldf_eiv_init  ***
408      !!
409      !! ** Purpose :   initialization of the eiv coeff. from namelist choices.
410      !!
411      !! ** Method :
412      !!
413      !! ** Action :   aeiu , aeiv   : EIV coeff. at u- & v-points
414      !!               l_ldfeiv_time : =T if EIV coefficients vary with time
415      !!----------------------------------------------------------------------
416      INTEGER  ::   jk, jj, ji        ! dummy loop indices
417      INTEGER  ::   ierr, inum, ios   ! local integer
418      !
419      NAMELIST/namtra_ldfeiv/ ln_ldfeiv   , ln_ldfeiv_dia,   &    ! eddy induced velocity (eiv)
420         &                    nn_aei_ijk_t, rn_aeiv_0             ! eiv  coefficient
421      !!----------------------------------------------------------------------
422      !
423      REWIND( numnam_ref )              ! Namelist namtra_ldfeiv in reference namelist : eddy induced velocity param.
424      READ  ( numnam_ref, namtra_ldfeiv, IOSTAT = ios, ERR = 901)
425901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_ldfeiv in reference namelist', lwp )
426      !
427      REWIND( numnam_cfg )              ! Namelist namtra_ldfeiv in configuration namelist : eddy induced velocity param.
428      READ  ( numnam_cfg, namtra_ldfeiv, IOSTAT = ios, ERR = 902 )
429902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_ldfeiv in configuration namelist', lwp )
430      IF(lwm)  WRITE ( numond, namtra_ldfeiv )
431
432      IF(lwp) THEN                      ! control print
433         WRITE(numout,*)
434         WRITE(numout,*) 'ldf_eiv_init : eddy induced velocity parametrization'
435         WRITE(numout,*) '~~~~~~~~~~~~ '
436         WRITE(numout,*) '   Namelist namtra_ldfeiv : '
437         WRITE(numout,*) '      Eddy Induced Velocity (eiv) param.      ln_ldfeiv     = ', ln_ldfeiv
438         WRITE(numout,*) '      eiv streamfunction & velocity diag.     ln_ldfeiv_dia = ', ln_ldfeiv_dia
439         WRITE(numout,*) '      eddy induced velocity coef.             rn_aeiv_0     = ', rn_aeiv_0
440         WRITE(numout,*) '      type of time-space variation            nn_aei_ijk_t  = ', nn_aei_ijk_t
441         WRITE(numout,*)
442      ENDIF
443      !
444      IF( ln_ldfeiv .AND. ln_traldf_blp )   CALL ctl_stop( 'ldf_eiv_init: eddy induced velocity ONLY with laplacian diffusivity' )
445
446      !                                 ! Parameter control
447      l_ldfeiv_time = .FALSE.   
448      !
449      IF( ln_ldfeiv ) THEN                         ! allocate the aei arrays
450         ALLOCATE( aeiu(jpi,jpj,jpk), aeiv(jpi,jpj,jpk), STAT=ierr )
451         IF( ierr /= 0 )   CALL ctl_stop('STOP', 'ldf_eiv: failed to allocate arrays')
452         !
453         SELECT CASE( nn_aei_ijk_t )               ! Specification of space time variations of eaiu, aeiv
454         !
455         CASE(   0  )      !==  constant  ==!
456            IF(lwp) WRITE(numout,*) '          eddy induced velocity coef. = constant = ', rn_aeiv_0
457!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
458            DO jk = 1, jpk
459               DO jj = 1, jpj
460                  DO ji = 1, jpi
461                     aeiu(ji,jj,jk) = rn_aeiv_0
462                     aeiv(ji,jj,jk) = rn_aeiv_0
463                  END DO
464               END DO
465            END DO
466            !
467         CASE(  10  )      !==  fixed profile  ==!
468            IF(lwp) WRITE(numout,*) '          eddy induced velocity coef. = F( depth )'
469!$OMP PARALLEL DO schedule(static) private(jj, ji)
470            DO jj = 1, jpj
471               DO ji = 1, jpi
472                  aeiu(ji,jj,1) = rn_aeiv_0                                ! constant surface value
473                  aeiv(ji,jj,1) = rn_aeiv_0
474               END DO
475            END DO
476            CALL ldf_c1d( 'TRA', r1_4, aeiu(:,:,1), aeiv(:,:,1), aeiu, aeiv )
477            !
478         CASE ( -20 )      !== fixed horizontal shape read in file  ==!
479            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F(i,j) read in eddy_diffusivity_2D.nc file'
480            CALL iom_open ( 'eddy_induced_velocity_2D.nc', inum )
481            CALL iom_get  ( inum, jpdom_data, 'aeiu', aeiu(:,:,1) )
482            CALL iom_get  ( inum, jpdom_data, 'aeiv', aeiv(:,:,1) )
483            CALL iom_close( inum )
484!$OMP PARALLEL DO schedule(static) private(jk)
485            DO jk = 2, jpk
486               aeiu(:,:,jk) = aeiu(:,:,1)
487               aeiv(:,:,jk) = aeiv(:,:,1)
488            END DO
489            !
490         CASE(  20  )      !== fixed horizontal shape  ==!
491            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( e1, e2 ) or F( e1^3, e2^3 ) (lap or bilap case)'
492            CALL ldf_c2d( 'TRA', 'LAP', rn_aeiv_0, aeiu, aeiv )    ! surface value proportional to scale factor
493            !
494         CASE(  21  )       !==  time varying 2D field  ==!
495            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( latitude, longitude, time )'
496            IF(lwp) WRITE(numout,*) '                              = F( growth rate of baroclinic instability )'
497            !
498            l_ldfeiv_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
499            !
500         CASE( -30  )      !== fixed 3D shape read in file  ==!
501            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F(i,j,k) read in eddy_diffusivity_3D.nc file'
502            CALL iom_open ( 'eddy_induced_velocity_3D.nc', inum )
503            CALL iom_get  ( inum, jpdom_data, 'aeiu', aeiu )
504            CALL iom_get  ( inum, jpdom_data, 'aeiv', aeiv )
505            CALL iom_close( inum )
506            !
507         CASE(  30  )       !==  fixed 3D shape  ==!
508            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( latitude, longitude, depth )'
509            CALL ldf_c2d( 'TRA', 'LAP', rn_aeiv_0, aeiu, aeiv )    ! surface value proportional to scale factor
510            !                                                 ! reduction with depth
511            CALL ldf_c1d( 'TRA', r1_4, aeiu(:,:,1), aeiv(:,:,1), aeiu, aeiv )
512            !
513         CASE DEFAULT
514            CALL ctl_stop('ldf_tra_init: wrong choice for nn_aei_ijk_t, the type of space-time variation of aei')
515         END SELECT
516         !
517      ELSE
518          IF(lwp) WRITE(numout,*) '   eddy induced velocity param is NOT used neither diagnosed'
519          ln_ldfeiv_dia = .FALSE.
520      ENDIF
521      !                   
522   END SUBROUTINE ldf_eiv_init
523
524
525   SUBROUTINE ldf_eiv( kt, paei0, paeiu, paeiv )
526      !!----------------------------------------------------------------------
527      !!                  ***  ROUTINE ldf_eiv  ***
528      !!
529      !! ** Purpose :   Compute the eddy induced velocity coefficient from the
530      !!              growth rate of baroclinic instability.
531      !!
532      !! ** Method  :   coefficient function of the growth rate of baroclinic instability
533      !!
534      !! Reference : Treguier et al. JPO 1997   ; Held and Larichev JAS 1996
535      !!----------------------------------------------------------------------
536      INTEGER                         , INTENT(in   ) ::   kt             ! ocean time-step index
537      REAL(wp)                        , INTENT(inout) ::   paei0          ! max value            [m2/s]
538      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   paeiu, paeiv   ! eiv coefficient      [m2/s]
539      !
540      INTEGER  ::   ji, jj, jk    ! dummy loop indices
541      REAL(wp) ::   zfw, ze3w, zn2, z1_f20, zaht, zaht_min, zzaei   ! local scalars
542      REAL(wp), DIMENSION(:,:), POINTER ::   zn, zah, zhw, zross, zaeiw   ! 2D workspace
543      !!----------------------------------------------------------------------
544      !
545      IF( nn_timing == 1 )   CALL timing_start('ldf_eiv')
546      !
547      CALL wrk_alloc( jpi,jpj,   zn, zah, zhw, zross, zaeiw )
548      !     
549!$OMP PARALLEL DO schedule(static) private(jj,ji)
550      DO jj = 1, jpj
551         DO ji = 1, jpi
552            zn   (ji,jj) = 0._wp      ! Local initialization
553            zhw  (ji,jj) = 5._wp
554            zah  (ji,jj) = 0._wp
555            zross(ji,jj) = 0._wp
556         END DO
557      END DO
558      !                       ! Compute lateral diffusive coefficient at T-point
559      IF( ln_traldf_triad ) THEN
560         DO jk = 1, jpk
561!$OMP PARALLEL DO schedule(static) private(jj,ji,zn2,ze3w)
562            DO jj = 2, jpjm1
563               DO ji = 2, jpim1
564                  ! Take the max of N^2 and zero then take the vertical sum
565                  ! of the square root of the resulting N^2 ( required to compute
566                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
567                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
568                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * e3w_n(ji,jj,jk)
569                  ! Compute elements required for the inverse time scale of baroclinic
570                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
571                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
572                  ze3w = e3w_n(ji,jj,jk) * tmask(ji,jj,jk)
573                  zah(ji,jj) = zah(ji,jj) + zn2 * wslp2(ji,jj,jk) * ze3w
574                  zhw(ji,jj) = zhw(ji,jj) + ze3w
575               END DO
576            END DO
577         END DO
578      ELSE
579         DO jk = 1, jpk
580!$OMP PARALLEL DO schedule(static) private(jj,ji,zn2,ze3w)
581            DO jj = 2, jpjm1
582               DO ji = 2, jpim1
583                  ! Take the max of N^2 and zero then take the vertical sum
584                  ! of the square root of the resulting N^2 ( required to compute
585                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
586                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
587                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * e3w_n(ji,jj,jk)
588                  ! Compute elements required for the inverse time scale of baroclinic
589                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
590                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
591                  ze3w = e3w_n(ji,jj,jk) * tmask(ji,jj,jk)
592                  zah(ji,jj) = zah(ji,jj) + zn2 * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
593                     &                            + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) * ze3w
594                  zhw(ji,jj) = zhw(ji,jj) + ze3w
595               END DO
596            END DO
597         END DO
598      END IF
599
600!$OMP PARALLEL
601!$OMP DO schedule(static) private(jj,ji,zfw)
602      DO jj = 2, jpjm1
603         DO ji = fs_2, fs_jpim1   ! vector opt.
604            zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 )
605            ! Rossby radius at w-point taken < 40km and  > 2km
606            zross(ji,jj) = MAX( MIN( .4 * zn(ji,jj) / zfw, 40.e3 ), 2.e3 )
607            ! Compute aeiw by multiplying Ro^2 and T^-1
608            zaeiw(ji,jj) = zross(ji,jj) * zross(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1)
609         END DO
610      END DO
611
612!!gm      IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN   ! ORCA R2
613!!gm         DO jj = 2, jpjm1
614!!gm            DO ji = fs_2, fs_jpim1   ! vector opt.
615!!gm               ! Take the minimum between aeiw and 1000 m2/s over shelves (depth shallower than 650 m)
616!!gm               IF( mbkt(ji,jj) <= 20 )   zaeiw(ji,jj) = MIN( zaeiw(ji,jj), 1000. )
617!!gm            END DO
618!!gm         END DO
619!!gm      ENDIF
620
621      !                                         !==  Bound on eiv coeff.  ==!
622      z1_f20 = 1._wp / (  2._wp * omega * sin( rad * 20._wp )  )
623!$OMP DO schedule(static) private(jj,ji,zzaei)
624      DO jj = 2, jpjm1
625         DO ji = fs_2, fs_jpim1   ! vector opt.
626            zzaei = MIN( 1._wp, ABS( ff(ji,jj) * z1_f20 ) ) * zaeiw(ji,jj)       ! tropical decrease
627            zaeiw(ji,jj) = MIN( zzaei , paei0 )                                  ! Max value = paei0
628         END DO
629      END DO
630!$OMP END DO NOWAIT
631!$OMP END PARALLEL
632      CALL lbc_lnk( zaeiw(:,:), 'W', 1. )       ! lateral boundary condition
633      !               
634!$OMP PARALLEL DO schedule(static) private(jj,ji,zfw)
635      DO jj = 2, jpjm1                          !== aei at u- and v-points  ==!
636         DO ji = fs_2, fs_jpim1   ! vector opt.
637            paeiu(ji,jj,1) = 0.5_wp * ( zaeiw(ji,jj) + zaeiw(ji+1,jj  ) ) * umask(ji,jj,1)
638            paeiv(ji,jj,1) = 0.5_wp * ( zaeiw(ji,jj) + zaeiw(ji  ,jj+1) ) * vmask(ji,jj,1)
639         END DO
640      END DO
641      CALL lbc_lnk( paeiu(:,:,1), 'U', 1. )   ;   CALL lbc_lnk( paeiv(:,:,1), 'V', 1. )      ! lateral boundary condition
642
643!$OMP PARALLEL DO schedule(static) private(jk)
644      DO jk = 2, jpkm1                          !==  deeper values equal the surface one  ==!
645         paeiu(:,:,jk) = paeiu(:,:,1) * umask(:,:,jk)
646         paeiv(:,:,jk) = paeiv(:,:,1) * vmask(:,:,jk)
647      END DO
648      ! 
649      CALL wrk_dealloc( jpi,jpj,   zn, zah, zhw, zross, zaeiw )
650      !
651      IF( nn_timing == 1 )   CALL timing_stop('ldf_eiv')
652      !
653   END SUBROUTINE ldf_eiv
654
655
656   SUBROUTINE ldf_eiv_trp( kt, kit000, pun, pvn, pwn, cdtype )
657      !!----------------------------------------------------------------------
658      !!                  ***  ROUTINE ldf_eiv_trp  ***
659      !!
660      !! ** Purpose :   add to the input ocean transport the contribution of
661      !!              the eddy induced velocity parametrization.
662      !!
663      !! ** Method  :   The eddy induced transport is computed from a flux stream-
664      !!              function which depends on the slope of iso-neutral surfaces
665      !!              (see ldf_slp). For example, in the i-k plan :
666      !!                   psi_uw = mk(aeiu) e2u mi(wslpi)   [in m3/s]
667      !!                   Utr_eiv = - dk[psi_uw]
668      !!                   Vtr_eiv = + di[psi_uw]
669      !!                ln_ldfeiv_dia = T : output the associated streamfunction,
670      !!                                    velocity and heat transport (call ldf_eiv_dia)
671      !!
672      !! ** Action  : pun, pvn increased by the eiv transport
673      !!----------------------------------------------------------------------
674      INTEGER                         , INTENT(in   ) ::   kt       ! ocean time-step index
675      INTEGER                         , INTENT(in   ) ::   kit000   ! first time step index
676      CHARACTER(len=3)                , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
677      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pun      ! in : 3 ocean transport components   [m3/s]
678      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pvn      ! out: 3 ocean transport components   [m3/s]
679      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pwn      ! increased by the eiv                [m3/s]
680      !!
681      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
682      REAL(wp) ::   zuwk, zuwk1, zuwi, zuwi1   ! local scalars
683      REAL(wp) ::   zvwk, zvwk1, zvwj, zvwj1   !   -      -
684      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zpsi_uw, zpsi_vw
685      !!----------------------------------------------------------------------
686      !
687      IF( nn_timing == 1 )   CALL timing_start( 'ldf_eiv_trp')
688      !
689      CALL wrk_alloc( jpi,jpj,jpk,   zpsi_uw, zpsi_vw )
690
691      IF( kt == kit000 )  THEN
692         IF(lwp) WRITE(numout,*)
693         IF(lwp) WRITE(numout,*) 'ldf_eiv_trp : eddy induced advection on ', cdtype,' :'
694         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   add to velocity fields the eiv component'
695      ENDIF
696
697     
698!$OMP PARALLEL
699!$OMP DO schedule(static) private(jj,ji)
700      DO jj = 1, jpj
701         DO ji = 1, jpi
702            zpsi_uw(ji,jj, 1 ) = 0._wp   ;   zpsi_vw(ji,jj, 1 ) = 0._wp
703            zpsi_uw(ji,jj,jpk) = 0._wp   ;   zpsi_vw(ji,jj,jpk) = 0._wp
704         END DO
705      END DO
706!$OMP END DO NOWAIT
707      !
708!$OMP DO schedule(static) private(jk,jj,ji)
709      DO jk = 2, jpkm1
710         DO jj = 1, jpjm1
711            DO ji = 1, fs_jpim1   ! vector opt.
712               zpsi_uw(ji,jj,jk) = - 0.25_wp * e2u(ji,jj) * ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk) )   &
713                  &                                       * ( aeiu (ji,jj,jk-1) + aeiu (ji  ,jj,jk) ) * umask(ji,jj,jk)
714               zpsi_vw(ji,jj,jk) = - 0.25_wp * e1v(ji,jj) * ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk) )   &
715                  &                                       * ( aeiv (ji,jj,jk-1) + aeiv (ji,jj  ,jk) ) * vmask(ji,jj,jk)
716            END DO
717         END DO
718      END DO
719      !
720!$OMP DO schedule(static) private(jk,jj,ji)
721      DO jk = 1, jpkm1
722         DO jj = 1, jpjm1
723            DO ji = 1, fs_jpim1   ! vector opt.               
724               pun(ji,jj,jk) = pun(ji,jj,jk) - ( zpsi_uw(ji,jj,jk) - zpsi_uw(ji,jj,jk+1) )
725               pvn(ji,jj,jk) = pvn(ji,jj,jk) - ( zpsi_vw(ji,jj,jk) - zpsi_vw(ji,jj,jk+1) )
726            END DO
727         END DO
728      END DO
729!$OMP END DO NOWAIT
730!$OMP DO schedule(static) private(jk,jj,ji)
731      DO jk = 1, jpkm1
732         DO jj = 2, jpjm1
733            DO ji = fs_2, fs_jpim1   ! vector opt.
734               pwn(ji,jj,jk) = pwn(ji,jj,jk) + (  zpsi_uw(ji,jj,jk) - zpsi_uw(ji-1,jj  ,jk)   &
735                  &                             + zpsi_vw(ji,jj,jk) - zpsi_vw(ji  ,jj-1,jk) )
736            END DO
737         END DO
738      END DO
739!$OMP END DO NOWAIT
740!$OMP END PARALLEL
741      !
742      !                              ! diagnose the eddy induced velocity and associated heat transport
743      IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' )   CALL ldf_eiv_dia( zpsi_uw, zpsi_vw )
744      !
745      CALL wrk_dealloc( jpi,jpj,jpk,   zpsi_uw, zpsi_vw )
746      !
747      IF( nn_timing == 1 )   CALL timing_stop( 'ldf_eiv_trp')
748      !
749    END SUBROUTINE ldf_eiv_trp
750
751
752   SUBROUTINE ldf_eiv_dia( psi_uw, psi_vw )
753      !!----------------------------------------------------------------------
754      !!                  ***  ROUTINE ldf_eiv_dia  ***
755      !!
756      !! ** Purpose :   diagnose the eddy induced velocity and its associated
757      !!              vertically integrated heat transport.
758      !!
759      !! ** Method :
760      !!
761      !!----------------------------------------------------------------------
762      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   psi_uw, psi_vw   ! streamfunction   [m3/s]
763      !
764      INTEGER  ::   ji, jj, jk    ! dummy loop indices
765      REAL(wp) ::   zztmp   ! local scalar
766      REAL(wp), DIMENSION(:,:)  , POINTER ::   zw2d   ! 2D workspace
767      REAL(wp), DIMENSION(:,:,:), POINTER ::   zw3d   ! 3D workspace
768      !!----------------------------------------------------------------------
769      !
770      IF( nn_timing == 1 )  CALL timing_start( 'ldf_eiv_dia')
771      !
772      !                                                  !==  eiv stream function: output  ==!
773      CALL lbc_lnk( psi_uw, 'U', -1. )                         ! lateral boundary condition
774      CALL lbc_lnk( psi_vw, 'V', -1. )
775      !
776!!gm      CALL iom_put( "psi_eiv_uw", psi_uw )                 ! output
777!!gm      CALL iom_put( "psi_eiv_vw", psi_vw )
778      !
779      !                                                  !==  eiv velocities: calculate and output  ==!
780      CALL wrk_alloc( jpi,jpj,jpk,   zw3d )
781      !
782!$OMP PARALLEL
783!$OMP DO schedule(static) private(jj,ji)
784      DO jj = 1, jpj
785         DO ji = 1, jpi
786            zw3d(ji,jj,jpk) = 0._wp                                    ! bottom value always 0
787         END DO
788      END DO
789!$OMP END DO NOWAIT
790      !
791!$OMP DO schedule(static) private(jk)
792      DO jk = 1, jpkm1                                         ! e2u e3u u_eiv = -dk[psi_uw]
793         zw3d(:,:,jk) = ( psi_uw(:,:,jk+1) - psi_uw(:,:,jk) ) / ( e2u(:,:) * e3u_n(:,:,jk) )
794      END DO
795!$OMP END DO NOWAIT
796!$OMP END PARALLEL
797      CALL iom_put( "uoce_eiv", zw3d )
798      !
799!$OMP PARALLEL DO schedule(static) private(jk)
800      DO jk = 1, jpkm1                                         ! e1v e3v v_eiv = -dk[psi_vw]
801         zw3d(:,:,jk) = ( psi_vw(:,:,jk+1) - psi_vw(:,:,jk) ) / ( e1v(:,:) * e3v_n(:,:,jk) )
802      END DO
803      CALL iom_put( "voce_eiv", zw3d )
804      !
805!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
806      DO jk = 1, jpkm1                                         ! e1 e2 w_eiv = dk[psix] + dk[psix]
807         DO jj = 2, jpjm1
808            DO ji = fs_2, fs_jpim1  ! vector opt.
809               zw3d(ji,jj,jk) = (  psi_vw(ji,jj,jk) - psi_vw(ji  ,jj-1,jk)    &
810                  &              + psi_uw(ji,jj,jk) - psi_uw(ji-1,jj  ,jk)  ) / e1e2t(ji,jj)
811            END DO
812         END DO
813      END DO
814      CALL lbc_lnk( zw3d, 'T', 1. )      ! lateral boundary condition
815      CALL iom_put( "woce_eiv", zw3d )
816      !
817      CALL wrk_dealloc( jpi,jpj,jpk,   zw3d )
818      !     
819      !
820      IF( lk_diaar5 ) THEN                               !==  eiv heat transport: calculate and output  ==!
821         CALL wrk_alloc( jpi,jpj,   zw2d )
822         !
823         zztmp = 0.5_wp * rau0 * rcp 
824!$OMP PARALLEL
825!$OMP DO schedule(static) private(jj,ji)
826         DO jj = 1, jpj
827            DO ji = 1, jpi
828               zw2d(ji,jj) = 0._wp
829            END DO
830         END DO
831         DO jk = 1, jpkm1
832!$OMP DO schedule(static) private(jj,ji)
833            DO jj = 2, jpjm1
834               DO ji = fs_2, fs_jpim1   ! vector opt.
835                  zw2d(ji,jj) = zw2d(ji,jj) + zztmp * ( psi_uw(ji,jj,jk+1)      - psi_uw(ji,jj,jk)          )   &
836                     &                              * ( tsn   (ji,jj,jk,jp_tem) + tsn   (ji+1,jj,jk,jp_tem) ) 
837               END DO
838            END DO
839!$OMP END DO NOWAIT
840         END DO
841!$OMP END PARALLEL
842         CALL lbc_lnk( zw2d, 'U', -1. )
843         CALL iom_put( "ueiv_heattr", zw2d )                  ! heat transport in i-direction
844!$OMP PARALLEL
845!$OMP DO schedule(static) private(jj,ji)
846         DO jj = 1, jpj
847            DO ji = 1, jpi
848               zw2d(ji,jj) = 0._wp
849            END DO
850         END DO
851         DO jk = 1, jpkm1
852!$OMP DO schedule(static) private(jj,ji)
853            DO jj = 2, jpjm1
854               DO ji = fs_2, fs_jpim1   ! vector opt.
855                  zw2d(ji,jj) = zw2d(ji,jj) + zztmp * ( psi_vw(ji,jj,jk+1)      - psi_vw(ji,jj,jk)          )   &
856                     &                              * ( tsn   (ji,jj,jk,jp_tem) + tsn   (ji,jj+1,jk,jp_tem) ) 
857               END DO
858            END DO
859!$OMP END DO NOWAIT
860         END DO
861!$OMP END PARALLEL
862         CALL lbc_lnk( zw2d, 'V', -1. )
863         CALL iom_put( "veiv_heattr", zw2d )                  !  heat transport in i-direction
864         !
865         CALL wrk_dealloc( jpi,jpj,   zw2d )
866      ENDIF
867      !
868      IF( nn_timing == 1 )  CALL timing_stop( 'ldf_eiv_dia')     
869      !
870   END SUBROUTINE ldf_eiv_dia
871
872   !!======================================================================
873END MODULE ldftra
Note: See TracBrowser for help on using the repository browser.