New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_fct.F90 @ 7508

Last change on this file since 7508 was 7508, checked in by mocavero, 7 years ago

changes on code duplication and workshare construct
  • Property svn:keywords set to Id
File size: 43.2 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!  tra_adv_fct_zts: update the tracer trend with a 3D advective trends using a 2nd order FCT scheme
12   !!                   with sub-time-stepping in the vertical direction
13   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
14   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE trc_oce        ! share passive tracers/Ocean variables
19   USE trd_oce        ! trends: ocean variables
20   USE trdtra         ! tracers trends
21   USE diaptr         ! poleward transport diagnostics
22   !
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
26   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
27   USE wrk_nemo       ! Memory Allocation
28   USE timing         ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_adv_fct        ! routine called by traadv.F90
34   PUBLIC   tra_adv_fct_zts    ! routine called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! routine called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
39
40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pun, pvn, pwn,       &
50      &                                              ptb, ptn, pta, kjpt, kn_fct_h, kn_fct_v )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_adv_fct  ***
53      !!
54      !! **  Purpose :   Compute the now trend due to total advection of tracers
55      !!               and add it to the general trend of tracer equations
56      !!
57      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
58      !!               (choice through the value of kn_fct)
59      !!               - on the vertical the 4th order is a compact scheme
60      !!               - corrected flux (monotonic correction)
61      !!
62      !! ** Action : - update pta  with the now advective tracer trends
63      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
64      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
65      !!----------------------------------------------------------------------
66      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
67      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
68      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
69      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
70      INTEGER                              , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
71      INTEGER                              , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
72      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
73      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
74      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
75      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
76      !
77      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
78      REAL(wp) ::   ztra                                     ! local scalar
79      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
80      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
81      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
82      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrdx, ztrdy, ztrdz
83      !!----------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct')
86      !
87      CALL wrk_alloc( jpi,jpj,jpk,   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
88      !
89      IF( kt == kit000 )  THEN
90         IF(lwp) WRITE(numout,*)
91         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
92         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
93      ENDIF
94      !
95      l_trd = .FALSE.
96      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
97      !
98      !                          ! surface & bottom value : flux set to zero one for all
99!$OMP PARALLEL
100!$OMP DO schedule(static) private(jj, ji)
101      DO jj = 1, jpj
102         DO ji = 1, jpi
103            zwz(ji,jj, 1 ) = 0._wp           
104            zwx(ji,jj,jpk) = 0._wp
105            zwy(ji,jj,jpk) = 0._wp   
106            zwz(ji,jj,jpk) = 0._wp
107         END DO       
108      END DO       
109!$OMP DO schedule(static) private(jk, jj, ji)
110      DO jk = 1, jpk
111         DO jj = 1, jpj
112            DO ji = 1, jpi
113               zwi(ji,jj,jk) = 0._wp
114            END DO       
115         END DO       
116      END DO       
117!$OMP END PARALLEL
118      !
119      DO jn = 1, kjpt            !==  loop over the tracers  ==!
120         !
121         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
122         !                    !* upstream tracer flux in the i and j direction
123!$OMP PARALLEL
124!$OMP DO schedule(static) private(jk, jj, ji, zfp_vj, zfm_vj, zfp_ui,zfm_ui)
125         DO jk = 1, jpkm1
126            DO jj = 1, jpjm1
127               DO ji = 1, fs_jpim1   ! vector opt.
128                  ! upstream scheme
129                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
130                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
131                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
132                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
133                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
134                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
135               END DO
136            END DO
137         END DO
138!$OMP END DO NOWAIT
139         !                    !* upstream tracer flux in the k direction *!
140!$OMP DO schedule(static) private(jk, jj, ji, zfp_wk, zfm_wk)
141         DO jk = 2, jpkm1        ! Interior value ( multiplied by wmask)
142            DO jj = 1, jpj
143               DO ji = 1, jpi
144                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
145                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
146                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
147               END DO
148            END DO
149         END DO
150!$OMP END DO NOWAIT
151!$OMP END PARALLEL
152         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
153            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
154!$OMP PARALLEL DO schedule(static) private(jj, ji)
155               DO jj = 1, jpj
156                  DO ji = 1, jpi
157                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
158                  END DO
159               END DO   
160            ELSE                             ! no cavities: only at the ocean surface
161!$OMP PARALLEL DO schedule(static) private(jj, ji)
162               DO jj = 1, jpj
163                  DO ji = 1, jpi
164                     zwz(ji,jj,1) = pwn(ji,jj,1) * ptb(ji,jj,1,jn)
165                  END DO
166               END DO   
167            ENDIF
168         ENDIF
169         !               
170!$OMP PARALLEL DO schedule(static) private(jk, jj, ji, ztra)
171         DO jk = 1, jpkm1     !* trend and after field with monotonic scheme
172            DO jj = 2, jpjm1
173               DO ji = fs_2, fs_jpim1   ! vector opt.
174                  ! total intermediate advective trends
175                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
176                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
177                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
178                  ! update and guess with monotonic sheme
179!!gm why tmask added in the two following lines ???    the mask is done in tranxt !
180                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra   * tmask(ji,jj,jk)
181                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + p2dt * ztra ) * tmask(ji,jj,jk)
182               END DO
183            END DO
184         END DO
185         CALL lbc_lnk( zwi, 'T', 1. )  ! Lateral boundary conditions on zwi  (unchanged sign)
186         !               
187         IF( l_trd )  THEN             ! trend diagnostics (contribution of upstream fluxes)
188         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
189!$OMP PARALLEL
190!$OMP DO schedule(static) private(jk, jj, ji)
191            DO jk = 1, jpk
192               DO jj = 1, jpj
193                  DO ji = 1, jpi
194                     ztrdx(ji,jj,jk) = 0._wp
195                     ztrdy(ji,jj,jk) = 0._wp
196                     ztrdz(ji,jj,jk) = 0._wp
197                  END DO
198               END DO
199            END DO
200!$OMP DO schedule(static) private(jk, jj, ji)
201            DO jk = 1, jpk
202               DO jj = 1, jpj
203                  DO ji = 1, jpi
204                     ztrdx(ji,jj,jk) = zwx(ji,jj,jk)   
205                     ztrdy(ji,jj,jk) = zwy(ji,jj,jk)
206                     ztrdz(ji,jj,jk) = zwz(ji,jj,jk)
207                  END DO
208               END DO
209            END DO
210!$OMP END PARALLEL
211         END IF
212         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
213         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
214           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
215           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
216         ENDIF
217         !
218         !        !==  anti-diffusive flux : high order minus low order  ==!
219         !
220         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
221         !
222         CASE(  2  )                   !- 2nd order centered
223!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
224            DO jk = 1, jpkm1
225               DO jj = 1, jpjm1
226                  DO ji = 1, fs_jpim1   ! vector opt.
227                     zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
228                     zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
229                  END DO
230               END DO
231            END DO
232            !
233         CASE(  4  )                   !- 4th order centered
234!$OMP PARALLEL
235!$OMP DO schedule(static) private(jj, ji)
236               DO jj = 1, jpj
237                  DO ji = 1, jpi
238                     zltu(ji,jj,jpk) = 0._wp            ! Bottom value : flux set to zero
239                     zltv(ji,jj,jpk) = 0._wp
240                  END DO
241               END DO
242!$OMP DO schedule(static) private(jk, jj, ji)
243            DO jk = 1, jpkm1                 ! Laplacian
244               DO jj = 1, jpjm1                    ! 1st derivative (gradient)
245                  DO ji = 1, fs_jpim1   ! vector opt.
246                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
247                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
248                  END DO
249               END DO
250               DO jj = 2, jpjm1                    ! 2nd derivative * 1/ 6
251                  DO ji = fs_2, fs_jpim1   ! vector opt.
252                     zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
253                     zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
254                  END DO
255               END DO
256            END DO
257!$OMP END DO NOWAIT
258!$OMP END PARALLEL
259            CALL lbc_lnk( zltu, 'T', 1. )   ;    CALL lbc_lnk( zltv, 'T', 1. )   ! Lateral boundary cond. (unchanged sgn)
260            !
261!$OMP PARALLEL DO schedule(static) private(jk, jj, ji, zC2t_u, zC2t_v)
262            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
263               DO jj = 1, jpjm1
264                  DO ji = 1, fs_jpim1   ! vector opt.
265                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points
266                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
267                     !                                                  ! C4 minus upstream advective fluxes
268                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
269                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
270                  END DO
271               END DO
272            END DO         
273            !
274         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
275!$OMP PARALLEL
276!$OMP DO schedule(static) private(jj, ji)
277            DO jj = 1, jpj
278               DO ji = 1, jpi
279                  ztu(ji,jj,jpk) = 0._wp             ! Bottom value : flux set to zero
280                  ztv(ji,jj,jpk) = 0._wp
281               END DO
282            END DO
283!$OMP DO schedule(static) private(jk, jj, ji)
284            DO jk = 1, jpkm1                 ! 1st derivative (gradient)
285               DO jj = 1, jpjm1
286                  DO ji = 1, fs_jpim1   ! vector opt.
287                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
288                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
289                  END DO
290               END DO
291            END DO
292!$OMP END DO NOWAIT
293!$OMP END PARALLEL
294            CALL lbc_lnk( ztu, 'U', -1. )   ;    CALL lbc_lnk( ztv, 'V', -1. )   ! Lateral boundary cond. (unchanged sgn)
295            !
296!$OMP PARALLEL DO schedule(static) private(jk, jj, ji, zC2t_u, zC2t_v, zC4t_u, zC4t_v)
297            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
298               DO jj = 2, jpjm1
299                  DO ji = 2, fs_jpim1   ! vector opt.
300                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points (x2)
301                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
302                     !                                                  ! C4 interpolation of T at u- & v-points (x2)
303                     zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
304                     zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
305                     !                                                  ! C4 minus upstream advective fluxes
306                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
307                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
308                  END DO
309               END DO
310            END DO
311            !
312         END SELECT
313         !                     
314         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
315         !
316         CASE(  2  )                   !- 2nd order centered
317!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
318            DO jk = 2, jpkm1   
319               DO jj = 2, jpjm1
320                  DO ji = fs_2, fs_jpim1
321                     zwz(ji,jj,jk) =  (  pwn(ji,jj,jk) * 0.5_wp * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) )   &
322                        &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
323                  END DO
324               END DO
325            END DO
326            !
327         CASE(  4  )                   !- 4th order COMPACT
328            CALL interp_4th_cpt( ptn(:,:,:,jn) , ztw )   ! zwt = COMPACT interpolation of T at w-point
329!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
330            DO jk = 2, jpkm1
331               DO jj = 2, jpjm1
332                  DO ji = fs_2, fs_jpim1
333                     zwz(ji,jj,jk) = ( pwn(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
334                  END DO
335               END DO
336            END DO
337            !
338         END SELECT
339         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
340!$OMP PARALLEL DO schedule(static) private(jj, ji)
341               DO jj = 1, jpj
342                  DO ji = 1, jpi
343                     zwz(ji,jj,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
344                  END DO
345               END DO
346         ENDIF
347         !
348         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
349         CALL lbc_lnk( zwz, 'W',  1. )
350         !
351         !        !==  monotonicity algorithm  ==!
352         !
353         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
354         !
355         !        !==  final trend with corrected fluxes  ==!
356         !
357!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
358         DO jk = 1, jpkm1
359            DO jj = 2, jpjm1
360               DO ji = fs_2, fs_jpim1   ! vector opt. 
361                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
362                     &                                   + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
363                     &                                   + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) &
364                     &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
365               END DO
366            END DO
367         END DO
368         !
369         IF( l_trd ) THEN     ! trend diagnostics (contribution of upstream fluxes)
370!$OMP DO schedule(static) private(jk, jj, ji)
371            DO jk = 1, jpk
372               DO jj = 1, jpj
373                  DO ji = 1, jpi
374                     ztrdx(ji,jj,jk) = ztrdx(ji,jj,jk) + zwx(ji,jj,jk)  ! <<< Add to previously computed
375                     ztrdy(ji,jj,jk) = ztrdy(ji,jj,jk) + zwy(ji,jj,jk)  ! <<< Add to previously computed
376                     ztrdz(ji,jj,jk) = ztrdz(ji,jj,jk) + zwz(ji,jj,jk)  ! <<< Add to previously computed
377               END DO
378            END DO
379         END DO
380            !
381            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
382            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
383            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
384            !
385            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
386         END IF
387         !                    ! "Poleward" heat and salt transports (contribution of upstream fluxes)
388         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
389           IF( jn == jp_tem )   htr_adv(:) = htr_adv(:) + ptr_sj( zwy(:,:,:) )
390           IF( jn == jp_sal )   str_adv(:) = str_adv(:) + ptr_sj( zwy(:,:,:) )
391         ENDIF
392         !
393      END DO                     ! end of tracer loop
394      !
395      CALL wrk_dealloc( jpi,jpj,jpk,    zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
396      !
397      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct')
398      !
399   END SUBROUTINE tra_adv_fct
400
401
402   SUBROUTINE tra_adv_fct_zts( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
403      &                                                  ptb, ptn, pta, kjpt, kn_fct_zts )
404      !!----------------------------------------------------------------------
405      !!                  ***  ROUTINE tra_adv_fct_zts  ***
406      !!
407      !! **  Purpose :   Compute the now trend due to total advection of
408      !!       tracers and add it to the general trend of tracer equations
409      !!
410      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
411      !!       corrected flux (monotonic correction). This version use sub-
412      !!       timestepping for the vertical advection which increases stability
413      !!       when vertical metrics are small.
414      !!       note: - this advection scheme needs a leap-frog time scheme
415      !!
416      !! ** Action : - update (pta) with the now advective tracer trends
417      !!             - save the trends
418      !!----------------------------------------------------------------------
419      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
420      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
421      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
422      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
423      INTEGER                              , INTENT(in   ) ::   kn_fct_zts      ! number of number of vertical sub-timesteps
424      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
425      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
426      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
427      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
428      !
429      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
430      REAL(wp)                                             ::   zr_p2dt         ! reciprocal of tracer timestep
431      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
432      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
433      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
434      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
435      REAL(wp) ::   ztra            ! local scalar
436      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
437      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
438      REAL(wp), POINTER, DIMENSION(:,:  )   ::   zwx_sav , zwy_sav
439      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zwi, zwx, zwy, zwz, zhdiv, zwzts, zwz_sav
440      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   ztrdx, ztrdy, ztrdz
441      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   ztrs
442      !!----------------------------------------------------------------------
443      !
444      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct_zts')
445      !
446      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
447      CALL wrk_alloc( jpi,jpj, jpk,        zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
448      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
449      !
450      IF( kt == kit000 )  THEN
451         IF(lwp) WRITE(numout,*)
452         IF(lwp) WRITE(numout,*) 'tra_adv_fct_zts : 2nd order FCT scheme with ', kn_fct_zts, ' vertical sub-timestep on ', cdtype
453         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
454      ENDIF
455      !
456      l_trd = .FALSE.
457      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
458      !
459      IF( l_trd )  THEN
460         CALL wrk_alloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
461         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
462      ENDIF
463      !
464      zwi(:,:,:) = 0._wp
465      z_rzts = 1._wp / REAL( kn_fct_zts, wp )
466      zr_p2dt = 1._wp / p2dt
467      !
468      ! surface & Bottom value : flux set to zero for all tracers
469      zwz(:,:, 1 ) = 0._wp
470      zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
471      zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
472      !
473      !                                                          ! ===========
474      DO jn = 1, kjpt                                            ! tracer loop
475         !                                                       ! ===========
476         !
477         ! Upstream advection with initial mass fluxes & intermediate update
478         DO jk = 1, jpkm1        ! upstream tracer flux in the i and j direction
479            DO jj = 1, jpjm1
480               DO ji = 1, fs_jpim1   ! vector opt.
481                  ! upstream scheme
482                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
483                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
484                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
485                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
486                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
487                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
488               END DO
489            END DO
490         END DO
491         !                       ! upstream tracer flux in the k direction
492         DO jk = 2, jpkm1              ! Interior value
493            DO jj = 1, jpj
494               DO ji = 1, jpi
495                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
496                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
497                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
498               END DO
499            END DO
500         END DO
501         IF( ln_linssh ) THEN          ! top value : linear free surface case only (as zwz is multiplied by wmask)
502            IF( ln_isfcav ) THEN             ! ice-shelf cavities: top value
503               DO jj = 1, jpj
504                  DO ji = 1, jpi
505                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn) 
506                  END DO
507               END DO   
508            ELSE                             ! no cavities, surface value
509               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
510            ENDIF
511         ENDIF
512         !
513         DO jk = 1, jpkm1         ! total advective trend
514            DO jj = 2, jpjm1
515               DO ji = fs_2, fs_jpim1   ! vector opt.
516                  !                             ! total intermediate advective trends
517                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
518                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
519                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
520                  !                             ! update and guess with monotonic sheme
521                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
522                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + p2dt * ztra ) * tmask(ji,jj,jk)
523               END DO
524            END DO
525         END DO
526         !                           
527         CALL lbc_lnk( zwi, 'T', 1. )     ! Lateral boundary conditions on zwi  (unchanged sign)
528         !               
529         IF( l_trd )  THEN                ! trend diagnostics (contribution of upstream fluxes)
530            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
531         END IF
532         !                                ! "Poleward" heat and salt transports (contribution of upstream fluxes)
533         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
534           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
535           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
536         ENDIF
537
538         ! 3. anti-diffusive flux : high order minus low order
539         ! ---------------------------------------------------
540
541         DO jk = 1, jpkm1                    !* horizontal anti-diffusive fluxes
542            !
543            DO jj = 1, jpjm1
544               DO ji = 1, fs_jpim1   ! vector opt.
545                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
546                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
547                  !
548                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
549                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
550               END DO
551            END DO
552            !
553            DO jj = 2, jpjm1                    ! partial horizontal divergence
554               DO ji = fs_2, fs_jpim1
555                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
556                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
557               END DO
558            END DO
559            !
560            DO jj = 1, jpjm1
561               DO ji = 1, fs_jpim1   ! vector opt.
562                  zwx(ji,jj,jk) = zwx(ji,jj,jk) - zwx_sav(ji,jj)
563                  zwy(ji,jj,jk) = zwy(ji,jj,jk) - zwy_sav(ji,jj)
564               END DO
565            END DO
566         END DO
567         !
568         !                                !* vertical anti-diffusive flux
569         zwz_sav(:,:,:)   = zwz(:,:,:)
570         ztrs   (:,:,:,1) = ptb(:,:,:,jn)
571         zwzts  (:,:,:)   = 0._wp
572         !
573         DO jl = 1, kn_fct_zts                  ! Start of sub timestepping loop
574            !
575            IF( jl == 1 ) THEN                        ! Euler forward to kick things off
576               jtb = 1   ;   jtn = 1   ;   jta = 2
577               zts(:) = p2dt * z_rzts
578               jtaken = MOD( kn_fct_zts + 1 , 2)            ! Toggle to collect every second flux
579               !                                            ! starting at jl =1 if kn_fct_zts is odd;
580               !                                            ! starting at jl =2 otherwise
581            ELSEIF( jl == 2 ) THEN                    ! First leapfrog step
582               jtb = 1   ;   jtn = 2   ;   jta = 3
583               zts(:) = 2._wp * p2dt * z_rzts
584            ELSE                                      ! Shuffle pointers for subsequent leapfrog steps
585               jtb = MOD(jtb,3) + 1
586               jtn = MOD(jtn,3) + 1
587               jta = MOD(jta,3) + 1
588            ENDIF
589            DO jk = 2, jpkm1                          ! interior value
590               DO jj = 2, jpjm1
591                  DO ji = fs_2, fs_jpim1
592                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) ) * wmask(ji,jj,jk)
593                     IF( jtaken == 0 )   zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk) * zts(jk)    ! Accumulate time-weighted vertcal flux
594                  END DO
595               END DO
596            END DO
597            IF( ln_linssh ) THEN                    ! top value (only in linear free surface case)
598               IF( ln_isfcav ) THEN                      ! ice-shelf cavities
599                  DO jj = 1, jpj
600                     DO ji = 1, jpi
601                        zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
602                     END DO
603                  END DO   
604               ELSE                                      ! no ocean cavities
605                  zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
606               ENDIF
607            ENDIF
608            !
609            jtaken = MOD( jtaken + 1 , 2 )
610            !
611            DO jk = 2, jpkm1                             ! total advective trends
612               DO jj = 2, jpjm1
613                  DO ji = fs_2, fs_jpim1
614                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb)                                                 &
615                        &               - zts(jk) * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji,jj,jk+1) )   &
616                        &                         * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
617                  END DO
618               END DO
619            END DO
620            !
621         END DO
622
623         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
624            DO jj = 2, jpjm1
625               DO ji = fs_2, fs_jpim1
626                  zwz(ji,jj,jk) = ( zwzts(ji,jj,jk) * zr_p2dt - zwz_sav(ji,jj,jk) ) * wmask(ji,jj,jk)
627               END DO
628            END DO
629         END DO
630         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
631         CALL lbc_lnk( zwz, 'W',  1. )
632
633         ! 4. monotonicity algorithm
634         ! -------------------------
635         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
636
637
638         ! 5. final trend with corrected fluxes
639         ! ------------------------------------
640         DO jk = 1, jpkm1
641            DO jj = 2, jpjm1
642               DO ji = fs_2, fs_jpim1   ! vector opt. 
643                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (   zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )       &
644                     &                                    + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   )   &
645                     &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
646               END DO
647            END DO
648         END DO
649
650         !                                 ! trend diagnostics (contribution of upstream fluxes)
651         IF( l_trd )  THEN
652            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
653            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
654            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
655            !
656            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
657            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
658            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
659            !
660            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
661         END IF
662         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
663         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
664           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
665           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
666         ENDIF
667         !
668      END DO
669      !
670      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
671      CALL wrk_alloc( jpi,jpj, jpk,        zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
672      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
673      !
674      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct_zts')
675      !
676   END SUBROUTINE tra_adv_fct_zts
677
678
679   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
680      !!---------------------------------------------------------------------
681      !!                    ***  ROUTINE nonosc  ***
682      !!     
683      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
684      !!       scheme and the before field by a nonoscillatory algorithm
685      !!
686      !! **  Method  :   ... ???
687      !!       warning : pbef and paft must be masked, but the boundaries
688      !!       conditions on the fluxes are not necessary zalezak (1979)
689      !!       drange (1995) multi-dimensional forward-in-time and upstream-
690      !!       in-space based differencing for fluid
691      !!----------------------------------------------------------------------
692      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
693      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
694      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
695      !
696      INTEGER  ::   ji, jj, jk   ! dummy loop indices
697      INTEGER  ::   ikm1         ! local integer
698      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
699      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
700      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
701      !!----------------------------------------------------------------------
702      !
703      IF( nn_timing == 1 )  CALL timing_start('nonosc')
704      !
705      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
706      !
707      zbig  = 1.e+40_wp
708      zrtrn = 1.e-15_wp
709
710      ! Search local extrema
711      ! --------------------
712      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
713      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
714         &        paft * tmask - zbig * ( 1._wp - tmask )  )
715      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
716         &        paft * tmask + zbig * ( 1._wp - tmask )  )
717
718!$OMP PARALLEL
719!$OMP DO schedule(static) private(jk, jj, ji)
720      DO jk = 1, jpk
721         DO jj = 1, jpj
722            DO ji = 1, jpi
723               zbetup(ji,jj,jk) = 0._wp   
724               zbetdo(ji,jj,jk) = 0._wp
725            END DO
726         END DO
727      END DO
728!$OMP DO schedule(static) private(jk, jj, ji, ikm1, zup, zdo, zpos, zneg, zbt)
729      DO jk = 1, jpkm1
730         ikm1 = MAX(jk-1,1)
731         DO jj = 2, jpjm1
732            DO ji = fs_2, fs_jpim1   ! vector opt.
733
734               ! search maximum in neighbourhood
735               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
736                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
737                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
738                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
739
740               ! search minimum in neighbourhood
741               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
742                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
743                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
744                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
745
746               ! positive part of the flux
747               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
748                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
749                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
750
751               ! negative part of the flux
752               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
753                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
754                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
755
756               ! up & down beta terms
757               zbt = e1e2t(ji,jj) * e3t_n(ji,jj,jk) / p2dt
758               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
759               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
760            END DO
761         END DO
762      END DO
763!$OMP END PARALLEL
764      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
765
766      ! 3. monotonic flux in the i & j direction (paa & pbb)
767      ! ----------------------------------------
768!$OMP PARALLEL DO schedule(static) private(jk, jj, ji, za, zb, zc, zav, zbv, zcv, zau, zbu, zcu)
769      DO jk = 1, jpkm1
770         DO jj = 2, jpjm1
771            DO ji = fs_2, fs_jpim1   ! vector opt.
772               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
773               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
774               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
775               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
776
777               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
778               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
779               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
780               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
781
782      ! monotonic flux in the k direction, i.e. pcc
783      ! -------------------------------------------
784               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
785               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
786               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
787               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
788            END DO
789         END DO
790      END DO
791      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
792      !
793      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
794      !
795      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
796      !
797   END SUBROUTINE nonosc
798
799
800   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
801      !!----------------------------------------------------------------------
802      !!                  ***  ROUTINE interp_4th_cpt  ***
803      !!
804      !! **  Purpose :   Compute the interpolation of tracer at w-point
805      !!
806      !! **  Method  :   4th order compact interpolation
807      !!----------------------------------------------------------------------
808      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
809      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
810      !
811      INTEGER :: ji, jj, jk   ! dummy loop integers
812      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
813      !!----------------------------------------------------------------------
814     
815      DO jk = 3, jpkm1        !==  build the three diagonal matrix  ==!
816         DO jj = 1, jpj
817            DO ji = 1, jpi
818               zwd (ji,jj,jk) = 4._wp
819               zwi (ji,jj,jk) = 1._wp
820               zws (ji,jj,jk) = 1._wp
821               zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
822               !
823               IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
824                  zwd (ji,jj,jk) = 1._wp
825                  zwi (ji,jj,jk) = 0._wp
826                  zws (ji,jj,jk) = 0._wp
827                  zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
828               ENDIF
829            END DO
830         END DO
831      END DO
832      !
833      jk=2                                            ! Switch to second order centered at top
834      DO jj=1,jpj
835         DO ji=1,jpi
836            zwd (ji,jj,jk) = 1._wp
837            zwi (ji,jj,jk) = 0._wp
838            zws (ji,jj,jk) = 0._wp
839            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
840         END DO
841      END DO   
842      !
843      !                       !==  tridiagonal solve  ==!
844      DO jj = 1, jpj                ! first recurrence
845         DO ji = 1, jpi
846            zwt(ji,jj,2) = zwd(ji,jj,2)
847         END DO
848      END DO
849      DO jk = 3, jpkm1
850         DO jj = 1, jpj
851            DO ji = 1, jpi
852               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
853            END DO
854         END DO
855      END DO
856      !
857      DO jj = 1, jpj                ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
858         DO ji = 1, jpi
859            pt_out(ji,jj,2) = zwrm(ji,jj,2)
860         END DO
861      END DO
862      DO jk = 3, jpkm1
863         DO jj = 1, jpj
864            DO ji = 1, jpi
865               pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
866            END DO
867         END DO
868      END DO
869
870      DO jj = 1, jpj                ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
871         DO ji = 1, jpi
872            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
873         END DO
874      END DO
875      DO jk = jpk-2, 2, -1
876         DO jj = 1, jpj
877            DO ji = 1, jpi
878               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
879            END DO
880         END DO
881      END DO
882      !   
883   END SUBROUTINE interp_4th_cpt
884   
885   !!======================================================================
886END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.