New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_mus.F90 @ 7525

Last change on this file since 7525 was 7525, checked in by mocavero, 7 years ago

changes after review
  • Property svn:keywords set to Id
File size: 16.9 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   !
26   USE wrk_nemo       ! Memory Allocation
27   USE timing         ! Timing
28   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
37   
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
39   !                                                           !  and in closed seas (orca 2 and 4 configurations)
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
41   
42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pun, pvn, pwn,             &
52      &                                              ptb, pta, kjpt, ld_msc_ups )
53      !!----------------------------------------------------------------------
54      !!                    ***  ROUTINE tra_adv_mus  ***
55      !!
56      !! ** Purpose :   Compute the now trend due to total advection of tracers
57      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
58      !!              Conservation Laws) and add it to the general tracer trend.
59      !!
60      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
61      !!              ld_msc_ups=T :
62      !!
63      !! ** Action : - update pta  with the now advective tracer trends
64      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
65      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
66      !!
67      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
68      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
69      !!----------------------------------------------------------------------
70      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
71      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
72      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
73      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
74      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
75      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
76      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
79      !
80      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
81      INTEGER  ::   ierr                 ! local integer
82      REAL(wp) ::   zu, z0u, zzwx, zw    ! local scalars
83      REAL(wp) ::   zv, z0v, zzwy, z0w   !   -      -
84      REAL(wp) ::   zalpha               !   -      -
85      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zslpx, zslpy   ! 3D workspace
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwx  , zwy     ! -      -
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('tra_adv_mus')
90      !
91      CALL wrk_alloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
92      !
93      IF( kt == kit000 )  THEN
94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
96         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
97         IF(lwp) WRITE(numout,*) '~~~~~~~'
98         IF(lwp) WRITE(numout,*)
99         !
100         ! Upstream / MUSCL scheme indicator
101         !
102         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
103!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
104         DO jk = 1, jpk
105            DO jj = 1, jpj
106               DO ji = 1, jpi
107                  xind(ji,jj,jk) = 1._wp              ! set equal to 1 where up-stream is not needed
108               END DO
109            END DO
110         END DO
111         !
112         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
113            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
114!$OMP PARALLEL
115!$OMP DO schedule(static) private(jj, ji)
116            DO jj = 1, jpj
117               DO ji = 1, jpi
118                  upsmsk(ji,jj) = 0._wp                             ! not upstream by default
119               END DO
120            END DO
121            !
122!$OMP DO schedule(static) private(jk,jj,ji)
123            DO jk = 1, jpkm1
124               DO jj = 1, jpj
125                  DO ji = 1, jpi
126                     xind(ji,jj,jk) = 1._wp                              &                   ! =>1 where up-stream is not needed
127                        &         - MAX ( rnfmsk(ji,jj) * rnfmsk_z(jk),  &                   ! =>0 near runoff mouths (& closed sea outflows)
128                        &                 upsmsk(ji,jj)                ) * tmask(ji,jj,jk)   ! =>0 in some user defined area
129                  END DO
130               END DO
131            END DO
132!$OMP END DO NOWAIT
133!$OMP END PARALLEL
134         ENDIF 
135         !
136      ENDIF 
137      !     
138      DO jn = 1, kjpt            !==  loop over the tracers  ==!
139         !
140         !                          !* Horizontal advective fluxes
141         !
142         !                                !-- first guess of the slopes
143!$OMP PARALLEL
144!$OMP DO schedule(static) private(jj, ji)
145         DO jj = 1, jpj
146            DO ji = 1, jpi
147               zwx(ji,jj,jpk) = 0._wp                   ! bottom values
148               zwy(ji,jj,jpk) = 0._wp
149            END DO
150         END DO
151!$OMP DO schedule(static) private(jk, jj, ji)
152         DO jk = 1, jpkm1                       ! interior values
153            DO jj = 1, jpjm1     
154               DO ji = 1, fs_jpim1   ! vector opt.
155                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
156                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
157               END DO
158           END DO
159         END DO
160!$OMP END DO NOWAIT
161!$OMP END PARALLEL
162         CALL lbc_lnk( zwx, 'U', -1. )          ! lateral boundary conditions   (changed sign)
163         CALL lbc_lnk( zwy, 'V', -1. )
164         !                                !-- Slopes of tracer
165!$OMP PARALLEL
166!$OMP DO schedule(static) private(jj, ji)
167         DO jj = 1, jpj
168            DO ji = 1, jpi
169               zslpx(ji,jj,jpk) = 0._wp                 ! bottom values
170               zslpy(ji,jj,jpk) = 0._wp
171            END DO
172         END DO
173!$OMP DO schedule(static) private(jk, jj, ji)
174         DO jk = 1, jpkm1                       ! interior values
175            DO jj = 2, jpj
176               DO ji = fs_2, jpi   ! vector opt.
177                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
178                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
179                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
180                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
181               END DO
182            END DO
183         END DO
184         !
185!$OMP DO schedule(static) private(jk, jj, ji)
186         DO jk = 1, jpkm1                 !-- Slopes limitation
187            DO jj = 2, jpj
188               DO ji = fs_2, jpi   ! vector opt.
189                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
190                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
191                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
192                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
193                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
194                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
195               END DO
196           END DO
197         END DO
198         !
199!$OMP DO schedule(static) private(jk, jj, ji, z0u, zalpha, zu, zv, zzwx, zzwy, z0v)
200         DO jk = 1, jpkm1                 !-- MUSCL horizontal advective fluxes
201            DO jj = 2, jpjm1
202               DO ji = fs_2, fs_jpim1   ! vector opt.
203                  ! MUSCL fluxes
204                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
205                  zalpha = 0.5 - z0u
206                  zu  = z0u - 0.5 * pun(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
207                  zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
208                  zzwy = ptb(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
209                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
210                  !
211                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
212                  zalpha = 0.5 - z0v
213                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
214                  zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
215                  zzwy = ptb(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
216                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
217               END DO
218            END DO
219         END DO
220!$OMP END DO NOWAIT
221!$OMP END PARALLEL
222         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
223         !
224!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
225         DO jk = 1, jpkm1                 !-- Tracer advective trend
226            DO jj = 2, jpjm1     
227               DO ji = fs_2, fs_jpim1   ! vector opt.
228                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
229                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
230                  &                                   * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
231               END DO
232           END DO
233         END DO       
234         !                                ! trend diagnostics
235         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.   &
236            &( cdtype == 'TRC' .AND. l_trdtrc )      )  THEN
237            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
238            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
239         END IF
240         !                                ! "Poleward" heat and salt transports
241         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
242            IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
243            IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
244         ENDIF
245         !
246         !                          !* Vertical advective fluxes
247         !
248         !                                !-- first guess of the slopes
249!$OMP PARALLEL
250!$OMP DO schedule(static) private(jj, ji)
251         DO jj = 1, jpj
252            DO ji = 1, jpi
253               zwx(ji,jj, 1 ) = 0._wp                   ! surface & bottom boundary conditions
254               zwx(ji,jj,jpk) = 0._wp
255           END DO
256         END DO
257!$OMP DO schedule(static) private(jk)
258         DO jk = 2, jpkm1                       ! interior values
259            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
260         END DO
261         !                                !-- Slopes of tracer
262!$OMP END DO NOWAIT
263!$OMP DO schedule(static) private(jj, ji)
264         DO jj = 1, jpj
265            DO ji = 1, jpi
266               zslpx(ji,jj,1) = 0._wp                   ! surface values
267           END DO
268         END DO
269!$OMP DO schedule(static) private(jk, jj, ji)
270         DO jk = 2, jpkm1                       ! interior value
271            DO jj = 1, jpj
272               DO ji = 1, jpi
273                  zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
274                     &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
275               END DO
276            END DO
277         END DO
278!$OMP DO schedule(static) private(jk, jj, ji)
279         DO jk = 2, jpkm1                 !-- Slopes limitation
280            DO jj = 1, jpj                      ! interior values
281               DO ji = 1, jpi
282                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
283                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
284                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
285               END DO
286            END DO
287         END DO
288!$OMP DO schedule(static) private(jk, jj, ji, z0w, zalpha, zw, zzwx, zzwy)
289         DO jk = 1, jpk-2                 !-- vertical advective flux
290            DO jj = 2, jpjm1     
291               DO ji = fs_2, fs_jpim1   ! vector opt.
292                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
293                  zalpha = 0.5 + z0w
294                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w_n(ji,jj,jk+1)
295                  zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
296                  zzwy = ptb(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
297                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
298               END DO
299            END DO
300         END DO
301!$OMP END DO NOWAIT
302!$OMP END PARALLEL
303         IF( ln_linssh ) THEN                   ! top values, linear free surface only
304            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
305!$OMP PARALLEL DO schedule(static) private(jj, ji)
306               DO jj = 1, jpj
307                  DO ji = 1, jpi
308                     zwx(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)
309                  END DO
310               END DO   
311            ELSE                                      ! no cavities: only at the ocean surface
312!$OMP PARALLEL DO schedule(static) private(jj, ji)
313               DO jj = 1, jpj
314                  DO ji = 1, jpi
315                     zwx(ji,jj,1) = pwn(ji,jj,1) * ptb(ji,jj,1,jn)
316                  END DO
317               END DO
318            ENDIF
319         ENDIF
320         !
321!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
322         DO jk = 1, jpkm1                 !-- vertical advective trend
323            DO jj = 2, jpjm1     
324               DO ji = fs_2, fs_jpim1   ! vector opt.
325                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
326               END DO
327            END DO
328         END DO
329         !                                ! send trends for diagnostic
330         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.     &
331            &( cdtype == 'TRC' .AND. l_trdtrc )      )   &
332            CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
333         !
334      END DO                     ! end of tracer loop
335      !
336      CALL wrk_dealloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
337      !
338      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_mus')
339      !
340   END SUBROUTINE tra_adv_mus
341
342   !!======================================================================
343END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.