New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_mus.F90 @ 7508

Last change on this file since 7508 was 7508, checked in by mocavero, 7 years ago

changes on code duplication and workshare construct
  • Property svn:keywords set to Id
File size: 16.8 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   !
26   USE wrk_nemo       ! Memory Allocation
27   USE timing         ! Timing
28   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
37   
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
39   !                                                           !  and in closed seas (orca 2 and 4 configurations)
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
41   
42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pun, pvn, pwn,             &
52      &                                              ptb, pta, kjpt, ld_msc_ups )
53      !!----------------------------------------------------------------------
54      !!                    ***  ROUTINE tra_adv_mus  ***
55      !!
56      !! ** Purpose :   Compute the now trend due to total advection of tracers
57      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
58      !!              Conservation Laws) and add it to the general tracer trend.
59      !!
60      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
61      !!              ld_msc_ups=T :
62      !!
63      !! ** Action : - update pta  with the now advective tracer trends
64      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
65      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
66      !!
67      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
68      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
69      !!----------------------------------------------------------------------
70      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
71      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
72      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
73      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
74      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
75      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
76      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
79      !
80      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
81      INTEGER  ::   ierr                 ! local integer
82      REAL(wp) ::   zu, z0u, zzwx, zw    ! local scalars
83      REAL(wp) ::   zv, z0v, zzwy, z0w   !   -      -
84      REAL(wp) ::   zalpha               !   -      -
85      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zslpx, zslpy   ! 3D workspace
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwx  , zwy     ! -      -
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('tra_adv_mus')
90      !
91      CALL wrk_alloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
92      !
93      IF( kt == kit000 )  THEN
94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
96         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
97         IF(lwp) WRITE(numout,*) '~~~~~~~'
98         IF(lwp) WRITE(numout,*)
99         !
100         ! Upstream / MUSCL scheme indicator
101         !
102         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
103!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
104         DO jk = 1, jpk
105            DO jj = 1, jpj
106               DO ji = 1, jpi
107                  xind(ji,jj,jk) = 1._wp              ! set equal to 1 where up-stream is not needed
108               END DO
109            END DO
110         END DO
111         !
112         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
113            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
114!$OMP PARALLEL
115!$OMP DO schedule(static) private(jj, ji)
116         DO jj = 1, jpj
117            DO ji = 1, jpi
118               upsmsk(ji,jj) = 0._wp                             ! not upstream by default
119            END DO
120         END DO
121            !
122!$OMP DO schedule(static) private(jk)
123            DO jk = 1, jpkm1
124               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
125                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
126                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
127            END DO
128!$OMP END DO NOWAIT
129!$OMP END PARALLEL
130         ENDIF 
131         !
132      ENDIF 
133      !     
134      DO jn = 1, kjpt            !==  loop over the tracers  ==!
135         !
136         !                          !* Horizontal advective fluxes
137         !
138         !                                !-- first guess of the slopes
139!$OMP PARALLEL
140!$OMP DO schedule(static) private(jj, ji)
141         DO jj = 1, jpj
142            DO ji = 1, jpi
143               zwx(ji,jj,jpk) = 0._wp                   ! bottom values
144               zwy(ji,jj,jpk) = 0._wp
145            END DO
146         END DO
147!$OMP DO schedule(static) private(jk, jj, ji)
148         DO jk = 1, jpkm1                       ! interior values
149            DO jj = 1, jpjm1     
150               DO ji = 1, fs_jpim1   ! vector opt.
151                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
152                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
153               END DO
154           END DO
155         END DO
156!$OMP END DO NOWAIT
157!$OMP END PARALLEL
158         CALL lbc_lnk( zwx, 'U', -1. )          ! lateral boundary conditions   (changed sign)
159         CALL lbc_lnk( zwy, 'V', -1. )
160         !                                !-- Slopes of tracer
161!$OMP PARALLEL
162!$OMP DO schedule(static) private(jj, ji)
163         DO jj = 1, jpj
164            DO ji = 1, jpi
165               zslpx(ji,jj,jpk) = 0._wp                 ! bottom values
166               zslpy(ji,jj,jpk) = 0._wp
167            END DO
168         END DO
169!$OMP DO schedule(static) private(jk, jj, ji)
170         DO jk = 1, jpkm1                       ! interior values
171            DO jj = 2, jpj
172               DO ji = fs_2, jpi   ! vector opt.
173                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
174                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
175                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
176                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
177               END DO
178            END DO
179         END DO
180         !
181!$OMP DO schedule(static) private(jk, jj, ji)
182         DO jk = 1, jpkm1                 !-- Slopes limitation
183            DO jj = 2, jpj
184               DO ji = fs_2, jpi   ! vector opt.
185                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
186                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
187                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
188                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
189                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
190                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
191               END DO
192           END DO
193         END DO
194         !
195!$OMP DO schedule(static) private(jk, jj, ji, z0u, zalpha, zu, zv, zzwx, zzwy, z0v)
196         DO jk = 1, jpkm1                 !-- MUSCL horizontal advective fluxes
197            DO jj = 2, jpjm1
198               DO ji = fs_2, fs_jpim1   ! vector opt.
199                  ! MUSCL fluxes
200                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
201                  zalpha = 0.5 - z0u
202                  zu  = z0u - 0.5 * pun(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
203                  zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
204                  zzwy = ptb(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
205                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
206                  !
207                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
208                  zalpha = 0.5 - z0v
209                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
210                  zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
211                  zzwy = ptb(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
212                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
213               END DO
214            END DO
215         END DO
216!$OMP END DO NOWAIT
217!$OMP END PARALLEL
218         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
219         !
220!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
221         DO jk = 1, jpkm1                 !-- Tracer advective trend
222            DO jj = 2, jpjm1     
223               DO ji = fs_2, fs_jpim1   ! vector opt.
224                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
225                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
226                  &                                   * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
227               END DO
228           END DO
229         END DO       
230         !                                ! trend diagnostics
231         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.   &
232            &( cdtype == 'TRC' .AND. l_trdtrc )      )  THEN
233            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
234            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
235         END IF
236         !                                ! "Poleward" heat and salt transports
237         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
238            IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
239            IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
240         ENDIF
241         !
242         !                          !* Vertical advective fluxes
243         !
244         !                                !-- first guess of the slopes
245!$OMP PARALLEL
246!$OMP DO schedule(static) private(jj, ji)
247         DO jj = 1, jpj
248            DO ji = 1, jpi
249               zwx(ji,jj, 1 ) = 0._wp                   ! surface & bottom boundary conditions
250               zwx(ji,jj,jpk) = 0._wp
251           END DO
252         END DO
253!$OMP DO schedule(static) private(jk)
254         DO jk = 2, jpkm1                       ! interior values
255            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
256         END DO
257         !                                !-- Slopes of tracer
258!$OMP END DO NOWAIT
259!$OMP DO schedule(static) private(jj, ji)
260         DO jj = 1, jpj
261            DO ji = 1, jpi
262               zslpx(ji,jj,1) = 0._wp                   ! surface values
263           END DO
264         END DO
265!$OMP DO schedule(static) private(jk, jj, ji)
266         DO jk = 2, jpkm1                       ! interior value
267            DO jj = 1, jpj
268               DO ji = 1, jpi
269                  zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
270                     &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
271               END DO
272            END DO
273         END DO
274!$OMP DO schedule(static) private(jk, jj, ji)
275         DO jk = 2, jpkm1                 !-- Slopes limitation
276            DO jj = 1, jpj                      ! interior values
277               DO ji = 1, jpi
278                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
279                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
280                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
281               END DO
282            END DO
283         END DO
284!$OMP DO schedule(static) private(jk, jj, ji, z0w, zalpha, zw, zzwx, zzwy)
285         DO jk = 1, jpk-2                 !-- vertical advective flux
286            DO jj = 2, jpjm1     
287               DO ji = fs_2, fs_jpim1   ! vector opt.
288                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
289                  zalpha = 0.5 + z0w
290                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w_n(ji,jj,jk+1)
291                  zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
292                  zzwy = ptb(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
293                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
294               END DO
295            END DO
296         END DO
297!$OMP END DO NOWAIT
298!$OMP END PARALLEL
299         IF( ln_linssh ) THEN                   ! top values, linear free surface only
300            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
301!$OMP PARALLEL DO schedule(static) private(jj, ji)
302               DO jj = 1, jpj
303                  DO ji = 1, jpi
304                     zwx(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)
305                  END DO
306               END DO   
307            ELSE                                      ! no cavities: only at the ocean surface
308!$OMP PARALLEL DO schedule(static) private(jj, ji)
309               DO jj = 1, jpj
310                  DO ji = 1, jpi
311                     zwx(ji,jj,1) = pwn(ji,jj,1) * ptb(ji,jj,1,jn)
312                  END DO
313               END DO
314            ENDIF
315         ENDIF
316         !
317!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
318         DO jk = 1, jpkm1                 !-- vertical advective trend
319            DO jj = 2, jpjm1     
320               DO ji = fs_2, fs_jpim1   ! vector opt.
321                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
322               END DO
323            END DO
324         END DO
325         !                                ! send trends for diagnostic
326         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.     &
327            &( cdtype == 'TRC' .AND. l_trdtrc )      )   &
328            CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
329         !
330      END DO                     ! end of tracer loop
331      !
332      CALL wrk_dealloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
333      !
334      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_mus')
335      !
336   END SUBROUTINE tra_adv_mus
337
338   !!======================================================================
339END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.