New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsed.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsed.F90 @ 7525

Last change on this file since 7525 was 7508, checked in by mocavero, 7 years ago

changes on code duplication and workshare construct
  • Property svn:keywords set to Id
File size: 23.5 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11#if defined key_pisces
12   !!----------------------------------------------------------------------
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_sed        :  Compute loss of organic matter in the sediments
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE p4zsbc          !  External source of nutrients
24   USE p4zint          !  interpolation and computation of various fields
25   USE iom             !  I/O manager
26   USE prtctl_trc      !  print control for debugging
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   p4z_sed 
32   PUBLIC   p4z_sed_alloc
33 
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: nitrpot    !: Nitrogen fixation
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:  ) :: sdenit     !: Nitrate reduction in the sediments
36   REAL(wp) :: r1_rday                  !: inverse of rday
37
38   !!----------------------------------------------------------------------
39   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
40   !! $Id$
41   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE p4z_sed( kt, knt )
46      !!---------------------------------------------------------------------
47      !!                     ***  ROUTINE p4z_sed  ***
48      !!
49      !! ** Purpose :   Compute loss of organic matter in the sediments. This
50      !!              is by no way a sediment model. The loss is simply
51      !!              computed to balance the inout from rivers and dust
52      !!
53      !! ** Method  : - ???
54      !!---------------------------------------------------------------------
55      !
56      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
57      INTEGER  ::   ji, jj, jk, ikt
58#if ! defined key_sed
59      REAL(wp) ::   zsumsedsi, zsumsedpo4, zsumsedcal
60      REAL(wp) ::   zrivalk, zrivsil, zrivno3
61#endif
62      REAL(wp) ::  zwflux, zfminus, zfplus
63      REAL(wp) ::  zlim, zfact, zfactcal
64      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zdenitt, zolimit
65      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep, zwstpoc
66      REAL(wp) ::  ztrfer, ztrpo4, zwdust, zlight
67      !
68      CHARACTER (len=25) :: charout
69      REAL(wp), POINTER, DIMENSION(:,:  ) :: zpdep, zsidep, zwork1, zwork2, zwork3
70      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdenit2d, zironice, zbureff
71      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsbio3, zwsbio4, zwscal
72      REAL(wp), POINTER, DIMENSION(:,:,:) :: zirondep, zsoufer
73      !!---------------------------------------------------------------------
74      !
75      IF( nn_timing == 1 )  CALL timing_start('p4z_sed')
76      !
77      IF( kt == nittrc000 .AND. knt == 1 )   r1_rday  = 1. / rday
78      !
79      ! Allocate temporary workspace
80      CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zbureff )
81      CALL wrk_alloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
82      CALL wrk_alloc( jpi, jpj, jpk, zsoufer )
83
84!$OMP PARALLEL DO schedule(static) private(jj,ji)
85      DO jj = 1, jpj
86         DO ji = 1, jpi
87            zdenit2d(ji,jj) = 0.e0
88            zbureff (ji,jj) = 0.e0
89            zwork1  (ji,jj) = 0.e0
90            zwork2  (ji,jj) = 0.e0
91            zwork3  (ji,jj) = 0.e0
92         END DO
93      END DO
94
95      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
96      ! ----------------------------------------------------
97      IF( ln_ironice ) THEN 
98         !                                             
99         CALL wrk_alloc( jpi, jpj, zironice )
100!$OMP PARALLEL
101!$OMP DO schedule(static) private(jj,ji,zdep,zwflux,zfminus,zfplus)
102         DO jj = 1, jpj
103            DO ji = 1, jpi
104               zdep    = rfact2 / e3t_n(ji,jj,1)
105               zwflux  = fmmflx(ji,jj) / 1000._wp
106               zfminus = MIN( 0._wp, -zwflux ) * trb(ji,jj,1,jpfer) * zdep
107               zfplus  = MAX( 0._wp, -zwflux ) * icefeinput * zdep
108               zironice(ji,jj) =  zfplus + zfminus
109            END DO
110         END DO
111         !
112!$OMP DO schedule(static) private(jj,ji)
113      DO jj = 1, jpj
114         DO ji = 1, jpi
115            tra(ji,jj,1,jpfer) = tra(ji,jj,1,jpfer) + zironice(ji,jj) 
116         END DO
117      END DO
118!$OMP END PARALLEL
119         !
120         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironice" ) )   &
121            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
122         !
123         CALL wrk_dealloc( jpi, jpj, zironice )
124         !                                             
125      ENDIF
126
127      ! Add the external input of nutrients from dust deposition
128      ! ----------------------------------------------------------
129      IF( ln_dust ) THEN
130         !                                             
131         CALL wrk_alloc( jpi, jpj,      zpdep, zsidep )
132         CALL wrk_alloc( jpi, jpj, jpk, zirondep      )
133         !                                              ! Iron and Si deposition at the surface
134         IF( ln_solub ) THEN
135!$OMP PARALLEL DO schedule(static) private(jj,ji)
136           DO jj = 1, jpj
137              DO ji = 1, jpi
138                 zirondep(ji,jj,1) = solub(ji,jj) * dust(ji,jj) * mfrac * rfact2 / e3t_n(ji,jj,1) / 55.85 + 3.e-10 * r1_ryyss
139              END DO
140           END DO
141         ELSE
142!$OMP PARALLEL DO schedule(static) private(jj,ji)
143           DO jj = 1, jpj
144              DO ji = 1, jpi
145                 zirondep(ji,jj,1) = dustsolub  * dust(ji,jj) * mfrac * rfact2 / e3t_n(ji,jj,1) / 55.85 + 3.e-10 * r1_ryyss
146              END DO
147           END DO
148         ENDIF
149!$OMP PARALLEL DO schedule(static) private(jj,ji)
150         DO jj = 1, jpj
151            DO ji = 1, jpi
152               zsidep(ji,jj) = 8.8 * 0.075 * dust(ji,jj) * mfrac * rfact2 / e3t_n(ji,jj,1) / 28.1
153               zpdep (ji,jj) = 0.1 * 0.021 * dust(ji,jj) * mfrac * rfact2 / e3t_n(ji,jj,1) / 31. / po4r
154            END DO
155         END DO
156         !                                              ! Iron solubilization of particles in the water column
157         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
158         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
159!$OMP PARALLEL
160!$OMP DO schedule(static) private(jk)
161         DO jk = 2, jpkm1
162            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -gdept_n(:,:,jk) / 540. )
163         END DO
164         !                                              ! Iron solubilization of particles in the water column
165!$OMP DO schedule(static) private(jj,ji)
166         DO jj = 1, jpj
167            DO ji = 1, jpi
168               tra(ji,jj,1,jppo4) = tra(ji,jj,1,jppo4) + zpdep   (ji,jj)
169               tra(ji,jj,1,jpsil) = tra(ji,jj,1,jpsil) + zsidep  (ji,jj)
170            END DO
171         END DO
172!$OMP DO schedule(static) private(jk,jj,ji)
173         DO jk = 1, jpk
174            DO jj = 1, jpj
175               DO ji = 1, jpi
176                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zirondep(ji,jj,jk) 
177               END DO
178            END DO
179         END DO
180!$OMP END PARALLEL
181         !
182         IF( lk_iomput ) THEN
183            IF( knt == nrdttrc ) THEN
184                IF( iom_use( "Irondep" ) )   &
185                &  CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
186                IF( iom_use( "pdust" ) )   &
187                &  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
188            ENDIF
189         ELSE                                   
190            IF( ln_diatrc )  THEN
191!$OMP PARALLEL DO schedule(static) private(jj,ji)
192               DO jj = 1, jpj
193                  DO ji = 1, jpi
194                     trc2d(ji,jj,jp_pcs0_2d + 11) = zirondep(ji,jj,1) * 1.e+3 * rfact2r * e3t_n(ji,jj,1) * tmask(ji,jj,1)
195                  END DO
196               END DO
197            ENDIF
198         ENDIF
199         CALL wrk_dealloc( jpi, jpj,      zpdep, zsidep )
200         CALL wrk_dealloc( jpi, jpj, jpk, zirondep      )
201         !                                             
202      ENDIF
203     
204      ! Add the external input of nutrients from river
205      ! ----------------------------------------------------------
206      IF( ln_river ) THEN
207!$OMP DO schedule(static) private(jj,ji,jk)
208         DO jj = 1, jpj
209            DO ji = 1, jpi
210               DO jk = 1, nk_rnf(ji,jj)
211                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) +  rivdip(ji,jj) * rfact2
212                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) +  rivdin(ji,jj) * rfact2
213                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) +  rivdic(ji,jj) * 5.e-5 * rfact2
214                  tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) +  rivdsi(ji,jj) * rfact2
215                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +  rivdic(ji,jj) * rfact2
216                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) +  ( rivalk(ji,jj) - rno3 * rivdin(ji,jj) ) * rfact2
217               END DO
218            END DO
219         END DO
220      ENDIF
221     
222      ! Add the external input of nutrients from nitrogen deposition
223      ! ----------------------------------------------------------
224      IF( ln_ndepo ) THEN
225!$OMP PARALLEL DO schedule(static) private(jj,ji)
226         DO jj = 1, jpj
227            DO ji = 1, jpi
228               tra(ji,jj,1,jpno3) = tra(ji,jj,1,jpno3) + nitdep(ji,jj) * rfact2
229               tra(ji,jj,1,jptal) = tra(ji,jj,1,jptal) - rno3 * nitdep(ji,jj) * rfact2
230            ENDDO
231         ENDDO
232      ENDIF
233
234      ! Add the external input of iron from sediment mobilization
235      ! ------------------------------------------------------
236      IF( ln_ironsed ) THEN
237!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
238         DO jk = 1, jpk
239            DO jj = 1, jpj
240               DO ji = 1, jpi
241                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + ironsed(ji,jj,jk) * rfact2
242               END DO
243            END DO
244         END DO
245         !
246         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironsed" ) )   &
247            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
248      ENDIF
249
250      ! Add the external input of iron from hydrothermal vents
251      ! ------------------------------------------------------
252      IF( ln_hydrofe ) THEN
253!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
254         DO jk = 1, jpk
255            DO jj = 1, jpj
256               DO ji = 1, jpi
257                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + hydrofe(ji,jj,jk) * rfact2
258               END DO
259            END DO
260         END DO
261         !
262         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "HYDR" ) )   &
263            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
264      ENDIF
265
266      ! OA: Warning, the following part is necessary, especially with Kriest
267      ! to avoid CFL problems above the sediments
268      ! --------------------------------------------------------------------
269!$OMP PARALLEL
270!$OMP DO schedule(static) private(jj,ji,ikt,zdep)
271      DO jj = 1, jpj
272         DO ji = 1, jpi
273            ikt  = mbkt(ji,jj)
274            zdep = e3t_n(ji,jj,ikt) / xstep
275            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
276            zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) )
277            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
278         END DO
279      END DO
280
281#if ! defined key_sed
282      ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
283      ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
284      ! -------------------------------------------------------
285!$OMP DO schedule(static) private(jj,ji,ikt,zflx,zo2,zno3,zdep)
286      DO jj = 1, jpj
287         DO ji = 1, jpi
288           IF( tmask(ji,jj,1) == 1 ) THEN
289              ikt = mbkt(ji,jj)
290# if defined key_kriest
291              zflx =    trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)    * 1E3 * 1E6 / 1E4
292# else
293              zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
294                &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
295#endif
296              zflx  = LOG10( MAX( 1E-3, zflx ) )
297              zo2   = LOG10( MAX( 10. , trb(ji,jj,ikt,jpoxy) * 1E6 ) )
298              zno3  = LOG10( MAX( 1.  , trb(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
299              zdep  = LOG10( gdepw_n(ji,jj,ikt+1) )
300              zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
301              &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
302              zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
303              !
304              zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
305                &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6
306              zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
307           ENDIF
308         END DO
309      END DO 
310
311      ! Loss of biogenic silicon, Caco3 organic carbon in the sediments.
312      ! First, the total loss is computed.
313      ! The factor for calcite comes from the alkalinity effect
314      ! -------------------------------------------------------------
315!$OMP DO schedule(static) private(jj,ji,ikt,zfactcal)
316      DO jj = 1, jpj
317         DO ji = 1, jpi
318            IF( tmask(ji,jj,1) == 1 ) THEN
319               ikt = mbkt(ji,jj) 
320# if defined key_kriest
321               zwork1(ji,jj) = trb(ji,jj,ikt,jpgsi) * zwscal (ji,jj)
322               zwork2(ji,jj) = trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)
323# else
324               zwork1(ji,jj) = trb(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj)
325               zwork2(ji,jj) = trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) 
326# endif
327               ! For calcite, burial efficiency is made a function of saturation
328               zfactcal      = MIN( excess(ji,jj,ikt), 0.2 )
329               zfactcal      = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
330               zwork3(ji,jj) = trb(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal
331            ENDIF
332         END DO
333      END DO
334!$OMP END PARALLEL
335
336      zsumsedsi  = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday
337      zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday
338      zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday
339#endif
340
341      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
342      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
343      ! ------------------------------------------------------
344#if ! defined key_sed
345      zrivsil =  1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / ( zsumsedsi + rtrn )
346#endif
347!$OMP PARALLEL
348
349!$OMP DO schedule(static) private(jj,ji,ikt,zdep,zws4,zwsc,zsiloss,zcaloss,zfactcal,zrivalk)
350      DO jj = 1, jpj
351         DO ji = 1, jpi
352            ikt  = mbkt(ji,jj)
353            zdep = xstep / e3t_n(ji,jj,ikt) 
354            zws4 = zwsbio4(ji,jj) * zdep
355            zwsc = zwscal (ji,jj) * zdep
356# if defined key_kriest
357            zsiloss = trb(ji,jj,ikt,jpgsi) * zws4
358# else
359            zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc
360# endif
361            zcaloss = trb(ji,jj,ikt,jpcal) * zwsc
362            !
363            tra(ji,jj,ikt,jpgsi) = tra(ji,jj,ikt,jpgsi) - zsiloss
364            tra(ji,jj,ikt,jpcal) = tra(ji,jj,ikt,jpcal) - zcaloss
365#if ! defined key_sed
366            tra(ji,jj,ikt,jpsil) = tra(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
367            zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
368            zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
369            zrivalk  =  1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / ( zsumsedcal + rtrn )
370            tra(ji,jj,ikt,jptal) =  tra(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
371            tra(ji,jj,ikt,jpdic) =  tra(ji,jj,ikt,jpdic) + zcaloss * zrivalk
372#endif
373         END DO
374      END DO
375
376!$OMP DO schedule(static) private(jj,ji,ikt,zdep,zws3,zws4,zrivno3,zwstpoc,zpdenit,z1pdenit,zolimit,zdenitt)
377      DO jj = 1, jpj
378         DO ji = 1, jpi
379            ikt  = mbkt(ji,jj)
380            zdep = xstep / e3t_n(ji,jj,ikt) 
381            zws4 = zwsbio4(ji,jj) * zdep
382            zws3 = zwsbio3(ji,jj) * zdep
383            zrivno3 = 1. - zbureff(ji,jj)
384# if ! defined key_kriest
385            tra(ji,jj,ikt,jpgoc) = tra(ji,jj,ikt,jpgoc) - trb(ji,jj,ikt,jpgoc) * zws4 
386            tra(ji,jj,ikt,jppoc) = tra(ji,jj,ikt,jppoc) - trb(ji,jj,ikt,jppoc) * zws3
387            tra(ji,jj,ikt,jpbfe) = tra(ji,jj,ikt,jpbfe) - trb(ji,jj,ikt,jpbfe) * zws4
388            tra(ji,jj,ikt,jpsfe) = tra(ji,jj,ikt,jpsfe) - trb(ji,jj,ikt,jpsfe) * zws3
389            zwstpoc              = trb(ji,jj,ikt,jpgoc) * zws4 + trb(ji,jj,ikt,jppoc) * zws3
390# else
391            tra(ji,jj,ikt,jpnum) = tra(ji,jj,ikt,jpnum) - trb(ji,jj,ikt,jpnum) * zws4 
392            tra(ji,jj,ikt,jppoc) = tra(ji,jj,ikt,jppoc) - trb(ji,jj,ikt,jppoc) * zws3
393            tra(ji,jj,ikt,jpsfe) = tra(ji,jj,ikt,jpsfe) - trb(ji,jj,ikt,jpsfe) * zws3
394            zwstpoc = trb(ji,jj,ikt,jppoc) * zws3 
395# endif
396
397#if ! defined key_sed
398            ! The 0.5 factor in zpdenit and zdenitt is to avoid negative NO3 concentration after both denitrification
399            ! in the sediments and just above the sediments. Not very clever, but simpliest option.
400            zpdenit  = MIN( 0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
401            z1pdenit = zwstpoc * zrivno3 - zpdenit
402            zolimit = MIN( ( trb(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
403            zdenitt = MIN(  0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, z1pdenit * nitrfac(ji,jj,ikt) )
404            tra(ji,jj,ikt,jpdoc) = tra(ji,jj,ikt,jpdoc) + z1pdenit - zolimit - zdenitt
405            tra(ji,jj,ikt,jppo4) = tra(ji,jj,ikt,jppo4) + zpdenit + zolimit + zdenitt
406            tra(ji,jj,ikt,jpnh4) = tra(ji,jj,ikt,jpnh4) + zpdenit + zolimit + zdenitt
407            tra(ji,jj,ikt,jpno3) = tra(ji,jj,ikt,jpno3) - rdenit * (zpdenit + zdenitt)
408            tra(ji,jj,ikt,jpoxy) = tra(ji,jj,ikt,jpoxy) - zolimit * o2ut
409            tra(ji,jj,ikt,jptal) = tra(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * (zpdenit + zdenitt) )
410            tra(ji,jj,ikt,jpdic) = tra(ji,jj,ikt,jpdic) + zpdenit + zolimit + zdenitt
411            sdenit(ji,jj) = rdenit * zpdenit * e3t_n(ji,jj,ikt)
412#endif
413         END DO
414      END DO
415!$OMP END DO NOWAIT
416      ! Nitrogen fixation process
417      ! Small source iron from particulate inorganic iron
418      !-----------------------------------
419!$OMP DO schedule(static) private(jk,jj,ji,zlim,zfact,ztrfer,ztrpo4,zlight)
420      DO jk = 1, jpkm1
421         DO jj = 1, jpj
422            DO ji = 1, jpi
423               !                      ! Potential nitrogen fixation dependant on temperature and iron
424               zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) )
425               IF( zlim <= 0.2 )   zlim = 0.01
426#if defined key_degrad
427               zfact = zlim * rfact2 * facvol(ji,jj,jk)
428#else
429               zfact = zlim * rfact2
430#endif
431               ztrfer = biron(ji,jj,jk)       / ( concfediaz + biron(ji,jj,jk)       )
432               ztrpo4 = trb  (ji,jj,jk,jppo4) / ( concnnh4   + trb  (ji,jj,jk,jppo4) ) 
433               zlight =  ( 1.- EXP( -etot_ndcy(ji,jj,jk) / diazolight ) ) 
434               nitrpot(ji,jj,jk) =  MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday )   &
435                 &         *  zfact * MIN( ztrfer, ztrpo4 ) * zlight
436               zsoufer(ji,jj,jk) = zlight * 2E-11 / (2E-11 + biron(ji,jj,jk))
437            END DO
438         END DO
439      END DO
440
441      ! Nitrogen change due to nitrogen fixation
442      ! ----------------------------------------
443!$OMP DO schedule(static) private(jk,jj,ji,zfact)
444      DO jk = 1, jpkm1
445         DO jj = 1, jpj
446            DO ji = 1, jpi
447               zfact = nitrpot(ji,jj,jk) * nitrfix
448               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) +             zfact
449               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3      * zfact
450               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2nit     * zfact 
451               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + concdnh4 / ( concdnh4 + trb(ji,jj,jk,jppo4) ) &
452               &                     * 0.002 * trb(ji,jj,jk,jpdoc) * xstep
453               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * xstep
454           END DO
455         END DO
456      END DO
457!$OMP END DO NOWAIT
458!$OMP END PARALLEL
459
460      IF( lk_iomput ) THEN
461         IF( knt == nrdttrc ) THEN
462            zfact = 1.e+3 * rfact2r * rno3  !  conversion from molC/l/kt  to molN/m3/s
463            IF( iom_use("Nfix"   ) ) CALL iom_put( "Nfix", nitrpot(:,:,:) * nitrfix * zfact * tmask(:,:,:) )  ! nitrogen fixation
464            IF( iom_use("INTNFIX") ) THEN   ! nitrogen fixation rate in ocean ( vertically integrated )
465               zwork1(:,:) = 0.
466               DO jk = 1, jpkm1
467!$OMP PARALLEL DO schedule(static) private(jj,ji)
468                  DO jj = 1, jpj
469                     DO ji = 1, jpi
470                        zwork1(ji,jj) = zwork1(ji,jj) + nitrpot(ji,jj,jk) * nitrfix * zfact * e3t_n(ji,jj,jk) * tmask(ji,jj,jk)
471                     END DO
472                  END DO
473               ENDDO
474               CALL iom_put( "INTNFIX" , zwork1 ) 
475            ENDIF
476         ENDIF
477      ELSE
478         IF( ln_diatrc )  &
479            &  trc2d(:,:,jp_pcs0_2d + 12) = nitrpot(:,:,1) * nitrfix * rno3 * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1)
480      ENDIF
481      !
482      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
483         WRITE(charout, fmt="('sed ')")
484         CALL prt_ctl_trc_info(charout)
485         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
486      ENDIF
487      !
488      CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zbureff )
489      CALL wrk_dealloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
490      CALL wrk_dealloc( jpi, jpj, jpk, zsoufer )
491      !
492      IF( nn_timing == 1 )  CALL timing_stop('p4z_sed')
493      !
494 9100  FORMAT(i8,3f10.5)
495      !
496   END SUBROUTINE p4z_sed
497
498
499   INTEGER FUNCTION p4z_sed_alloc()
500      !!----------------------------------------------------------------------
501      !!                     ***  ROUTINE p4z_sed_alloc  ***
502      !!----------------------------------------------------------------------
503      ALLOCATE( nitrpot(jpi,jpj,jpk), sdenit(jpi,jpj), STAT=p4z_sed_alloc )
504      !
505      IF( p4z_sed_alloc /= 0 )   CALL ctl_warn('p4z_sed_alloc: failed to allocate arrays')
506      !
507   END FUNCTION p4z_sed_alloc
508
509
510#else
511   !!======================================================================
512   !!  Dummy module :                                   No PISCES bio-model
513   !!======================================================================
514CONTAINS
515   SUBROUTINE p4z_sed                         ! Empty routine
516   END SUBROUTINE p4z_sed
517#endif 
518
519   !!======================================================================
520END MODULE p4zsed
Note: See TracBrowser for help on using the repository browser.