| [3] | 1 | MODULE stpctl |
|---|
| [1489] | 2 | !!====================================================================== |
|---|
| [3] | 3 | !! *** MODULE stpctl *** |
|---|
| 4 | !! Ocean run control : gross check of the ocean time stepping |
|---|
| [1489] | 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1991-03 (G. Madec) Original code |
|---|
| 7 | !! 6.0 ! 1992-06 (M. Imbard) |
|---|
| 8 | !! 8.0 ! 1997-06 (A.M. Treguier) |
|---|
| 9 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 10 | !! 2.0 ! 2009-07 (G. Madec) Add statistic for time-spliting |
|---|
| [9019] | 11 | !! 3.7 ! 2016-09 (G. Madec) Remove solver |
|---|
| 12 | !! 4.0 ! 2017-04 (G. Madec) regroup global communications |
|---|
| [1489] | 13 | !!---------------------------------------------------------------------- |
|---|
| [3] | 14 | |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! stp_ctl : Control the run |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE oce ! ocean dynamics and tracers variables |
|---|
| 19 | USE dom_oce ! ocean space and time domain variables |
|---|
| [6140] | 20 | USE c1d ! 1D vertical configuration |
|---|
| 21 | ! |
|---|
| [3] | 22 | USE in_out_manager ! I/O manager |
|---|
| 23 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 24 | USE lib_mpp ! distributed memory computing |
|---|
| [9023] | 25 | USE wet_dry, ONLY: ll_wd, ssh_ref ! reference depth for negative bathy |
|---|
| [3] | 26 | |
|---|
| 27 | IMPLICIT NONE |
|---|
| 28 | PRIVATE |
|---|
| 29 | |
|---|
| 30 | PUBLIC stp_ctl ! routine called by step.F90 |
|---|
| 31 | !!---------------------------------------------------------------------- |
|---|
| [9019] | 32 | !! NEMO/OPA 4.0 , NEMO Consortium (2017) |
|---|
| [1489] | 33 | !! $Id$ |
|---|
| [2528] | 34 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| [1489] | 35 | !!---------------------------------------------------------------------- |
|---|
| [3] | 36 | CONTAINS |
|---|
| 37 | |
|---|
| 38 | SUBROUTINE stp_ctl( kt, kindic ) |
|---|
| 39 | !!---------------------------------------------------------------------- |
|---|
| 40 | !! *** ROUTINE stp_ctl *** |
|---|
| 41 | !! |
|---|
| 42 | !! ** Purpose : Control the run |
|---|
| 43 | !! |
|---|
| 44 | !! ** Method : - Save the time step in numstp |
|---|
| 45 | !! - Print it each 50 time steps |
|---|
| [9019] | 46 | !! - Stop the run IF problem encountered by setting indic=-3 |
|---|
| 47 | !! Problems checked: |ssh| maximum larger than 10 m |
|---|
| 48 | !! |U| maximum larger than 10 m/s |
|---|
| 49 | !! negative sea surface salinity |
|---|
| [3] | 50 | !! |
|---|
| [9019] | 51 | !! ** Actions : "time.step" file = last ocean time-step |
|---|
| 52 | !! "run.stat" file = run statistics |
|---|
| [3] | 53 | !!---------------------------------------------------------------------- |
|---|
| [6140] | 54 | INTEGER, INTENT(in ) :: kt ! ocean time-step index |
|---|
| 55 | INTEGER, INTENT(inout) :: kindic ! error indicator |
|---|
| [1489] | 56 | !! |
|---|
| [6140] | 57 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| [9019] | 58 | INTEGER :: iih, ijh ! local integers |
|---|
| 59 | INTEGER :: iiu, iju, iku ! - - |
|---|
| 60 | INTEGER :: iis, ijs, iks ! - - |
|---|
| 61 | REAL(wp) :: zzz ! local real |
|---|
| 62 | INTEGER , DIMENSION(3) :: ilocu, ilocs |
|---|
| 63 | INTEGER , DIMENSION(2) :: iloch |
|---|
| 64 | REAL(wp), DIMENSION(3) :: zmax |
|---|
| [3] | 65 | !!---------------------------------------------------------------------- |
|---|
| [6140] | 66 | ! |
|---|
| [3] | 67 | IF( kt == nit000 .AND. lwp ) THEN |
|---|
| 68 | WRITE(numout,*) |
|---|
| 69 | WRITE(numout,*) 'stp_ctl : time-stepping control' |
|---|
| [79] | 70 | WRITE(numout,*) '~~~~~~~' |
|---|
| [9019] | 71 | ! ! open time.step file |
|---|
| [1581] | 72 | CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea ) |
|---|
| [9019] | 73 | ! ! open run.stat file |
|---|
| 74 | CALL ctl_opn( numrun, 'run.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea ) |
|---|
| [3] | 75 | ENDIF |
|---|
| [6140] | 76 | ! |
|---|
| [9019] | 77 | IF(lwp) THEN !== current time step ==! ("time.step" file) |
|---|
| 78 | WRITE ( numstp, '(1x, i8)' ) kt |
|---|
| 79 | REWIND( numstp ) |
|---|
| [3] | 80 | ENDIF |
|---|
| [6140] | 81 | ! |
|---|
| [9019] | 82 | ! !== test of extrema ==! |
|---|
| [9023] | 83 | IF( ll_wd ) THEN |
|---|
| 84 | zmax(1) = MAXVAL( ABS( sshn(:,:) + ssh_ref*tmask(:,:,1) ) ) ! ssh max |
|---|
| 85 | ELSE |
|---|
| 86 | zmax(1) = MAXVAL( ABS( sshn(:,:) ) ) ! ssh max |
|---|
| 87 | ENDIF |
|---|
| [9019] | 88 | zmax(2) = MAXVAL( ABS( un(:,:,:) ) ) ! velocity max (zonal only) |
|---|
| 89 | zmax(3) = MAXVAL( -tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp ) ! minus salinity max |
|---|
| [1489] | 90 | ! |
|---|
| [9019] | 91 | IF( lk_mpp ) CALL mpp_max_multiple( zmax(:), 3 ) ! max over the global domain |
|---|
| [1489] | 92 | ! |
|---|
| [9019] | 93 | IF( MOD( kt, nwrite ) == 1 .AND. lwp ) THEN |
|---|
| 94 | WRITE(numout,*) ' ==>> time-step= ', kt, ' |ssh| max: ', zmax(1), ' |U| max: ', zmax(2), & |
|---|
| 95 | & ' S min: ' , - zmax(3) |
|---|
| [3] | 96 | ENDIF |
|---|
| [6140] | 97 | ! |
|---|
| [9023] | 98 | IF ( zmax(1) > 15._wp .OR. & ! too large sea surface height ( > 10 m) |
|---|
| [9019] | 99 | & zmax(2) > 10._wp .OR. & ! too large velocity ( > 10 m/s) |
|---|
| 100 | & zmax(3) >= 0._wp .OR. & ! negative or zero sea surface salinity |
|---|
| 101 | & ISNAN( zmax(1) + zmax(2) + zmax(3) ) ) THEN ! NaN encounter in the tests |
|---|
| 102 | IF( lk_mpp ) THEN |
|---|
| 103 | CALL mpp_maxloc( ABS(sshn) , ssmask(:,:) , zzz, iih, ijh ) |
|---|
| 104 | CALL mpp_maxloc( ABS(un) , umask (:,:,:), zzz, iiu, iju, iku ) |
|---|
| 105 | CALL mpp_minloc( tsn(:,:,:,jp_sal), tmask (:,:,:), zzz, iis, ijs, iks ) |
|---|
| [7852] | 106 | ELSE |
|---|
| [9019] | 107 | iloch = MINLOC( ABS( sshn(:,:) ) ) |
|---|
| 108 | ilocu = MAXLOC( ABS( un (:,:,:) ) ) |
|---|
| 109 | ilocs = MINLOC( tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp ) |
|---|
| 110 | iih = iloch(1) + nimpp - 1 ; ijh = iloch(2) + njmpp - 1 |
|---|
| 111 | iiu = ilocu(1) + nimpp - 1 ; iju = ilocu(2) + njmpp - 1 ; iku = ilocu(3) |
|---|
| 112 | iis = ilocs(1) + nimpp - 1 ; ijs = ilocs(2) + njmpp - 1 ; iks = ilocu(3) |
|---|
| [7852] | 113 | ENDIF |
|---|
| 114 | IF(lwp) THEN |
|---|
| 115 | WRITE(numout,cform_err) |
|---|
| [9019] | 116 | WRITE(numout,*) ' stpctl: |ssh| > 10 m or |U| > 10 m/s or S < 0 or NaN encounter in the tests' |
|---|
| 117 | WRITE(numout,*) ' ====== ' |
|---|
| 118 | WRITE(numout,9100) kt, zmax(1), iih, ijh |
|---|
| 119 | WRITE(numout,9200) kt, zmax(2), iiu, iju, iku |
|---|
| 120 | WRITE(numout,9300) kt, - zmax(3), iis, ijs, iks |
|---|
| [7852] | 121 | WRITE(numout,*) |
|---|
| [9019] | 122 | WRITE(numout,*) ' output of last computed fields in output.abort.nc file' |
|---|
| [7852] | 123 | ENDIF |
|---|
| 124 | kindic = -3 |
|---|
| 125 | ENDIF |
|---|
| [9019] | 126 | 9100 FORMAT (' kt=',i8,' |ssh| max: ',1pg11.4,', at i j : ',2i5) |
|---|
| 127 | 9200 FORMAT (' kt=',i8,' |U| max: ',1pg11.4,', at i j k: ',3i5) |
|---|
| 128 | 9300 FORMAT (' kt=',i8,' S min: ',1pg11.4,', at i j : ',2i5) |
|---|
| [1489] | 129 | ! |
|---|
| [9019] | 130 | ! !== run statistics ==! ("run.stat" file) |
|---|
| 131 | IF(lwp) WRITE(numrun,9400) kt, zmax(1), zmax(2), - zmax(3) |
|---|
| [7852] | 132 | ! |
|---|
| [9019] | 133 | 9400 FORMAT(' it :', i8, ' |ssh|_max: ', e16.10, ' |U|_max: ',e16.10,' S_min: ',e16.10) |
|---|
| [7852] | 134 | ! |
|---|
| [3] | 135 | END SUBROUTINE stp_ctl |
|---|
| 136 | |
|---|
| 137 | !!====================================================================== |
|---|
| 138 | END MODULE stpctl |
|---|
