New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zprod.F90 @ 9124

Last change on this file since 9124 was 9124, checked in by gm, 6 years ago

dev_merge_2017: ln_timing instead of nn_timing + restricted timing to nemo_init and routine called by step in OPA_SRC

File size: 28.7 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
11   !!   p4z_prod_init  :   Initialization of the parameters for growth
12   !!   p4z_prod_alloc :   Allocate variables for growth
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zlim          !  Co-limitations of differents nutrients
18   USE prtctl_trc      !  print control for debugging
19   USE iom             !  I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_prod         ! called in p4zbio.F90
25   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
26   PUBLIC   p4z_prod_alloc
27
28   !! * Shared module variables
29   LOGICAL , PUBLIC ::  ln_newprod      !:
30   REAL(wp), PUBLIC ::  pislopen         !:
31   REAL(wp), PUBLIC ::  pisloped        !:
32   REAL(wp), PUBLIC ::  xadap           !:
33   REAL(wp), PUBLIC ::  excretn          !:
34   REAL(wp), PUBLIC ::  excretd         !:
35   REAL(wp), PUBLIC ::  bresp           !:
36   REAL(wp), PUBLIC ::  chlcnm          !:
37   REAL(wp), PUBLIC ::  chlcdm          !:
38   REAL(wp), PUBLIC ::  chlcmin         !:
39   REAL(wp), PUBLIC ::  fecnm           !:
40   REAL(wp), PUBLIC ::  fecdm           !:
41   REAL(wp), PUBLIC ::  grosip          !:
42
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
46   
47   REAL(wp) :: r1_rday                !: 1 / rday
48   REAL(wp) :: texcretn               !: 1 - excretn
49   REAL(wp) :: texcretd               !: 1 - excretd       
50
51   !!----------------------------------------------------------------------
52   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
53   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE p4z_prod( kt , knt )
59      !!---------------------------------------------------------------------
60      !!                     ***  ROUTINE p4z_prod  ***
61      !!
62      !! ** Purpose :   Compute the phytoplankton production depending on
63      !!              light, temperature and nutrient availability
64      !!
65      !! ** Method  : - ???
66      !!---------------------------------------------------------------------
67      INTEGER, INTENT(in) :: kt, knt
68      !
69      INTEGER  ::   ji, jj, jk
70      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
71      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap, zlim, zsilfac2, zsiborn
72      REAL(wp) ::   zprod, zproreg, zproreg2, zprochln, zprochld
73      REAL(wp) ::   zmaxday, zdocprod, zpislopen, zpisloped
74      REAL(wp) ::   zmxltst, zmxlday
75      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup, chlcnm_n, chlcdm_n
76      REAL(wp) ::   zfact
77      CHARACTER (len=25) :: charout
78      REAL(wp), POINTER, DIMENSION(:,:  ) :: zstrn, zw2d, zmixnano, zmixdiat
79      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopeadn, zpislopeadd, zysopt, zw3d   
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprdia, zprbio, zprdch, zprnch   
81      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorcan, zprorcad, zprofed, zprofen
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpronewn, zpronewd
83      REAL(wp), POINTER, DIMENSION(:,:,:) :: zmxl_fac, zmxl_chl
84      !!---------------------------------------------------------------------
85      !
86      IF( ln_timing )   CALL timing_start('p4z_prod')
87      !
88      !  Allocate temporary workspace
89      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixdiat, zstrn )
90      CALL wrk_alloc( jpi, jpj, jpk, zpislopeadn, zpislopeadd, zprdia, zprbio, zprdch, zprnch, zysopt ) 
91      CALL wrk_alloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
92      CALL wrk_alloc( jpi, jpj, jpk, zprorcan, zprorcad, zprofed, zprofen, zpronewn, zpronewd )
93      !
94      zprorcan(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp ; zprofed (:,:,:) = 0._wp
95      zprofen (:,:,:) = 0._wp ; zysopt  (:,:,:) = 0._wp
96      zpronewn(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp ; zprdia  (:,:,:) = 0._wp
97      zprbio  (:,:,:) = 0._wp ; zprdch  (:,:,:) = 0._wp ; zprnch  (:,:,:) = 0._wp 
98      zmxl_fac(:,:,:) = 0._wp ; zmxl_chl(:,:,:) = 0._wp 
99
100      ! Computation of the optimal production
101      prmax(:,:,:) = 0.8_wp * r1_rday * tgfunc(:,:,:) 
102
103      ! compute the day length depending on latitude and the day
104      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
105      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
106
107      ! day length in hours
108      zstrn(:,:) = 0.
109      DO jj = 1, jpj
110         DO ji = 1, jpi
111            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
112            zargu = MAX( -1., MIN(  1., zargu ) )
113            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
114         END DO
115      END DO
116
117      ! Impact of the day duration and light intermittency on phytoplankton growth
118      DO jk = 1, jpkm1
119         DO jj = 1 ,jpj
120            DO ji = 1, jpi
121               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
122                  zval = MAX( 1., zstrn(ji,jj) )
123                  IF( gdept_n(ji,jj,jk) <= hmld(ji,jj) ) THEN
124                     zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
125                  ENDIF
126                  zmxl_chl(ji,jj,jk) = zval / 24.
127                  zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval )
128               ENDIF
129            END DO
130         END DO
131      END DO
132
133      zprbio(:,:,:) = prmax(:,:,:) * zmxl_fac(:,:,:)
134      zprdia(:,:,:) = zprbio(:,:,:)
135
136      ! Maximum light intensity
137      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
138
139      ! Computation of the P-I slope for nanos and diatoms
140      DO jk = 1, jpkm1
141         DO jj = 1, jpj
142            DO ji = 1, jpi
143               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
144                  ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
145                  zadap       = xadap * ztn / ( 2.+ ztn )
146                  zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
147                  zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
148                  !
149                  zpislopeadn(ji,jj,jk) = pislopen * ( 1.+ zadap  * EXP( -0.25 * enano(ji,jj,jk) ) )  &
150                  &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
151                  !
152                  zpislopeadd(ji,jj,jk) = (pislopen * zconctemp2 + pisloped * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn )   &
153                  &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
154               ENDIF
155            END DO
156         END DO
157      END DO
158
159      IF( ln_newprod ) THEN
160         DO jk = 1, jpkm1
161            DO jj = 1, jpj
162               DO ji = 1, jpi
163                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
164                      ! Computation of production function for Carbon
165                      !  ---------------------------------------------
166                      zpislopen = zpislopeadn(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
167                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
168                      zpisloped = zpislopeadd(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
169                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
170                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
171                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
172                      !  Computation of production function for Chlorophyll
173                      !--------------------------------------------------
174                      zpislopen = zpislopeadn(ji,jj,jk) / ( prmax(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
175                      zpisloped = zpislopeadd(ji,jj,jk) / ( prmax(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
176                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
177                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
178                  ENDIF
179               END DO
180            END DO
181         END DO
182      ELSE
183         DO jk = 1, jpkm1
184            DO jj = 1, jpj
185               DO ji = 1, jpi
186                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
187                      ! Computation of production function for Carbon
188                      !  ---------------------------------------------
189                      zpislopen = zpislopeadn(ji,jj,jk)  / ( zprbio(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
190                      zpisloped = zpislopeadd(ji,jj,jk) / ( zprdia(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
191                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
192                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
193                      !  Computation of production function for Chlorophyll
194                      !--------------------------------------------------
195                      zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
196                      zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
197                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
198                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
199                  ENDIF
200               END DO
201            END DO
202         END DO
203      ENDIF
204
205      !  Computation of a proxy of the N/C ratio
206      !  ---------------------------------------
207      DO jk = 1, jpkm1
208         DO jj = 1, jpj
209            DO ji = 1, jpi
210                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
211                &      * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
212                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
213                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
214                &      * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
215                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
216            END DO
217         END DO
218      END DO
219
220
221      DO jk = 1, jpkm1
222         DO jj = 1, jpj
223            DO ji = 1, jpi
224
225                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
226                   !    Si/C of diatoms
227                   !    ------------------------
228                   !    Si/C increases with iron stress and silicate availability
229                   !    Si/C is arbitrariliy increased for very high Si concentrations
230                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
231                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
232                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
233                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
234                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
235                  IF (gphit(ji,jj) < -30 ) THEN
236                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
237                  ELSE
238                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
239                  ENDIF
240                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
241              ENDIF
242            END DO
243         END DO
244      END DO
245
246      !  Mixed-layer effect on production
247      !  Sea-ice effect on production
248
249      DO jk = 1, jpkm1
250         DO jj = 1, jpj
251            DO ji = 1, jpi
252               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
253               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
254               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
255               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
256            END DO
257         END DO
258      END DO
259
260      ! Computation of the various production terms
261      DO jk = 1, jpkm1
262         DO jj = 1, jpj
263            DO ji = 1, jpi
264               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
265                  !  production terms for nanophyto. (C)
266                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
267                  zpronewn(ji,jj,jk)  = zprorcan(ji,jj,jk)* xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
268                  !
269                  zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) * fecnm + rtrn )
270                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
271                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
272                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
273                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
274                  &             * zmax * trb(ji,jj,jk,jpphy) * rfact2
275                  !  production terms for diatoms (C)
276                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
277                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
278                  !
279                  zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) * fecdm + rtrn )
280                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
281                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
282                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
283                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
284                  &             * zmax * trb(ji,jj,jk,jpdia) * rfact2
285               ENDIF
286            END DO
287         END DO
288      END DO
289
290      ! Computation of the chlorophyll production terms
291      DO jk = 1, jpkm1
292         DO jj = 1, jpj
293            DO ji = 1, jpi
294               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
295                  !  production terms for nanophyto. ( chlorophyll )
296                  znanotot = enano(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
297                  zprod    = rday * zprorcan(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
298                  zprochln = chlcmin * 12. * zprorcan (ji,jj,jk)
299                  chlcnm_n   = MIN ( chlcnm, ( chlcnm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.))
300                  zprochln = zprochln + (chlcnm_n-chlcmin) * 12. * zprod / &
301                                        & (  zpislopeadn(ji,jj,jk) * znanotot +rtrn)
302                  !  production terms for diatoms ( chlorophyll )
303                  zdiattot = ediat(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
304                  zprod    = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
305                  zprochld = chlcmin * 12. * zprorcad(ji,jj,jk)
306                  chlcdm_n   = MIN ( chlcdm, ( chlcdm / (1. - 1.14 / 43.4 * tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.))
307                  zprochld = zprochld + (chlcdm_n-chlcmin) * 12. * zprod / &
308                                        & ( zpislopeadd(ji,jj,jk) * zdiattot +rtrn )
309                  !   Update the arrays TRA which contain the Chla sources and sinks
310                  tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln * texcretn
311                  tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld * texcretd
312               ENDIF
313            END DO
314         END DO
315      END DO
316
317      !   Update the arrays TRA which contain the biological sources and sinks
318      DO jk = 1, jpkm1
319         DO jj = 1, jpj
320           DO ji =1 ,jpi
321              IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
322                 zproreg  = zprorcan(ji,jj,jk) - zpronewn(ji,jj,jk)
323                 zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
324                 zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
325                 tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
326                 tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)
327                 tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
328                 tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcretn
329                 tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcretn
330                 tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcretd
331                 tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcretd
332                 tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
333                 tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zdocprod
334                 tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
335                 &                   + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) )
336                 !
337                 zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
338                 tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zfeup
339                 tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
340                 tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
341                 tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
342                 &                                         - rno3 * ( zproreg + zproreg2 )
343              ENDIF
344           END DO
345        END DO
346     END DO
347     !
348     IF( ln_ligand ) THEN
349         DO jk = 1, jpkm1
350            DO jj = 1, jpj
351              DO ji =1 ,jpi
352                 IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
353                    zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
354                    zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
355                    tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
356                 ENDIF
357              END DO
358           END DO
359        END DO
360     ENDIF
361
362
363    ! Total primary production per year
364    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
365         & tpp = glob_sum( ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
366
367    IF( lk_iomput ) THEN
368       IF( knt == nrdttrc ) THEN
369          CALL wrk_alloc( jpi, jpj,      zw2d )
370          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
371          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
372          !
373          IF( iom_use( "PPPHYN" ) .OR. iom_use( "PPPHYD" ) )  THEN
374              zw3d(:,:,:) = zprorcan(:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
375              CALL iom_put( "PPPHYN"  , zw3d )
376              !
377              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
378              CALL iom_put( "PPPHYD"  , zw3d )
379          ENDIF
380          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
381              zw3d(:,:,:) = zpronewn(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
382              CALL iom_put( "PPNEWN"  , zw3d )
383              !
384              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
385              CALL iom_put( "PPNEWD"  , zw3d )
386          ENDIF
387          IF( iom_use( "PBSi" ) )  THEN
388              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
389              CALL iom_put( "PBSi"  , zw3d )
390          ENDIF
391          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
392              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
393              CALL iom_put( "PFeN"  , zw3d )
394              !
395              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
396              CALL iom_put( "PFeD"  , zw3d )
397          ENDIF
398          IF( iom_use( "Mumax" ) )  THEN
399              zw3d(:,:,:) = prmax(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
400              CALL iom_put( "Mumax"  , zw3d )
401          ENDIF
402          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
403              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
404              CALL iom_put( "MuN"  , zw3d )
405              !
406              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
407              CALL iom_put( "MuD"  , zw3d )
408          ENDIF
409          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
410              zw3d(:,:,:) = zprbio (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
411              CALL iom_put( "LNlight"  , zw3d )
412              !
413              zw3d(:,:,:) =  zprdia (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
414              CALL iom_put( "LDlight"  , zw3d )
415          ENDIF
416          IF( iom_use( "TPP" ) )  THEN
417              zw3d(:,:,:) = ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
418              CALL iom_put( "TPP"  , zw3d )
419          ENDIF
420          IF( iom_use( "TPNEW" ) )  THEN
421              zw3d(:,:,:) = ( zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
422              CALL iom_put( "TPNEW"  , zw3d )
423          ENDIF
424          IF( iom_use( "TPBFE" ) )  THEN
425              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
426              CALL iom_put( "TPBFE"  , zw3d )
427          ENDIF
428          IF( iom_use( "INTPPPHYN" ) .OR. iom_use( "INTPPPHYD" ) ) THEN 
429             zw2d(:,:) = 0.
430             DO jk = 1, jpkm1
431               zw2d(:,:) = zw2d(:,:) + zprorcan(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
432             ENDDO
433             CALL iom_put( "INTPPPHYN" , zw2d )
434             !
435             zw2d(:,:) = 0.
436             DO jk = 1, jpkm1
437                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
438             ENDDO
439             CALL iom_put( "INTPPPHYD" , zw2d )
440          ENDIF
441          IF( iom_use( "INTPP" ) ) THEN   
442             zw2d(:,:) = 0.
443             DO jk = 1, jpkm1
444                zw2d(:,:) = zw2d(:,:) + ( zprorcan(:,:,jk) + zprorcad(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated pp
445             ENDDO
446             CALL iom_put( "INTPP" , zw2d )
447          ENDIF
448          IF( iom_use( "INTPNEW" ) ) THEN   
449             zw2d(:,:) = 0.
450             DO jk = 1, jpkm1
451                zw2d(:,:) = zw2d(:,:) + ( zpronewn(:,:,jk) + zpronewd(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
452             ENDDO
453             CALL iom_put( "INTPNEW" , zw2d )
454          ENDIF
455          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
456             zw2d(:,:) = 0.
457             DO jk = 1, jpkm1
458                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
459             ENDDO
460            CALL iom_put( "INTPBFE" , zw2d )
461          ENDIF
462          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
463             zw2d(:,:) = 0.
464             DO jk = 1, jpkm1
465                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
466             ENDDO
467             CALL iom_put( "INTPBSI" , zw2d )
468          ENDIF
469          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
470          !
471          CALL wrk_dealloc( jpi, jpj,      zw2d )
472          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
473       ENDIF
474     ENDIF
475
476     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
477         WRITE(charout, FMT="('prod')")
478         CALL prt_ctl_trc_info(charout)
479         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
480     ENDIF
481     !
482     CALL wrk_dealloc( jpi, jpj,  zmixnano, zmixdiat,    zstrn )
483     CALL wrk_dealloc( jpi, jpj, jpk, zpislopeadn, zpislopeadd, zprdia, zprbio, zprdch, zprnch, zysopt ) 
484     CALL wrk_dealloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
485     CALL wrk_dealloc( jpi, jpj, jpk, zprorcan, zprorcad, zprofed, zprofen, zpronewn, zpronewd )
486     !
487     IF( ln_timing )  CALL timing_stop('p4z_prod')
488     !
489   END SUBROUTINE p4z_prod
490
491
492   SUBROUTINE p4z_prod_init
493      !!----------------------------------------------------------------------
494      !!                  ***  ROUTINE p4z_prod_init  ***
495      !!
496      !! ** Purpose :   Initialization of phytoplankton production parameters
497      !!
498      !! ** Method  :   Read the nampisprod namelist and check the parameters
499      !!      called at the first timestep (nittrc000)
500      !!
501      !! ** input   :   Namelist nampisprod
502      !!----------------------------------------------------------------------
503      INTEGER :: ios                 ! Local integer output status for namelist read
504      !
505      NAMELIST/namp4zprod/ pislopen, pisloped, xadap, ln_newprod, bresp, excretn, excretd,  &
506         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
507      !!----------------------------------------------------------------------
508
509      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
510      READ  ( numnatp_ref, namp4zprod, IOSTAT = ios, ERR = 901)
511901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zprod in reference namelist', lwp )
512
513      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
514      READ  ( numnatp_cfg, namp4zprod, IOSTAT = ios, ERR = 902 )
515902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp4zprod in configuration namelist', lwp )
516      IF(lwm) WRITE ( numonp, namp4zprod )
517
518      IF(lwp) THEN                         ! control print
519         WRITE(numout,*) ' '
520         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, namp4zprod'
521         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
522         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod    =', ln_newprod
523         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
524         WRITE(numout,*) '    P-I slope                                 pislopen     =', pislopen
525         WRITE(numout,*) '    Acclimation factor to low light           xadap        =', xadap
526         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excretn      =', excretn
527         WRITE(numout,*) '    excretion ratio of diatoms                excretd      =', excretd
528         IF( ln_newprod )  THEN
529            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
530            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
531         ENDIF
532         WRITE(numout,*) '    P-I slope  for diatoms                    pisloped     =', pisloped
533         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
534         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
535         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
536         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
537      ENDIF
538      !
539      r1_rday   = 1._wp / rday 
540      texcretn  = 1._wp - excretn
541      texcretd  = 1._wp - excretd
542      tpp       = 0._wp
543      !
544   END SUBROUTINE p4z_prod_init
545
546
547   INTEGER FUNCTION p4z_prod_alloc()
548      !!----------------------------------------------------------------------
549      !!                     ***  ROUTINE p4z_prod_alloc  ***
550      !!----------------------------------------------------------------------
551      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
552      !
553      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
554      !
555   END FUNCTION p4z_prod_alloc
556
557   !!======================================================================
558END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.