New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zprod.F90 @ 9125

Last change on this file since 9125 was 9125, checked in by timgraham, 6 years ago

Removed wrk_arrays from whole code. No change in SETTE results from this.
File size: 28.0 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
11   !!   p4z_prod_init  :   Initialization of the parameters for growth
12   !!   p4z_prod_alloc :   Allocate variables for growth
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zlim          !  Co-limitations of differents nutrients
18   USE prtctl_trc      !  print control for debugging
19   USE iom             !  I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_prod         ! called in p4zbio.F90
25   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
26   PUBLIC   p4z_prod_alloc
27
28   !! * Shared module variables
29   LOGICAL , PUBLIC ::  ln_newprod      !:
30   REAL(wp), PUBLIC ::  pislopen         !:
31   REAL(wp), PUBLIC ::  pisloped        !:
32   REAL(wp), PUBLIC ::  xadap           !:
33   REAL(wp), PUBLIC ::  excretn          !:
34   REAL(wp), PUBLIC ::  excretd         !:
35   REAL(wp), PUBLIC ::  bresp           !:
36   REAL(wp), PUBLIC ::  chlcnm          !:
37   REAL(wp), PUBLIC ::  chlcdm          !:
38   REAL(wp), PUBLIC ::  chlcmin         !:
39   REAL(wp), PUBLIC ::  fecnm           !:
40   REAL(wp), PUBLIC ::  fecdm           !:
41   REAL(wp), PUBLIC ::  grosip          !:
42
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
46   
47   REAL(wp) :: r1_rday                !: 1 / rday
48   REAL(wp) :: texcretn               !: 1 - excretn
49   REAL(wp) :: texcretd               !: 1 - excretd       
50
51   !!----------------------------------------------------------------------
52   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
53   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE p4z_prod( kt , knt )
59      !!---------------------------------------------------------------------
60      !!                     ***  ROUTINE p4z_prod  ***
61      !!
62      !! ** Purpose :   Compute the phytoplankton production depending on
63      !!              light, temperature and nutrient availability
64      !!
65      !! ** Method  : - ???
66      !!---------------------------------------------------------------------
67      INTEGER, INTENT(in) :: kt, knt
68      !
69      INTEGER  ::   ji, jj, jk
70      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
71      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap, zlim, zsilfac2, zsiborn
72      REAL(wp) ::   zprod, zproreg, zproreg2, zprochln, zprochld
73      REAL(wp) ::   zmaxday, zdocprod, zpislopen, zpisloped
74      REAL(wp) ::   zmxltst, zmxlday
75      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup, chlcnm_n, chlcdm_n
76      REAL(wp) ::   zfact
77      CHARACTER (len=25) :: charout
78      REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zw2d
79      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
80      REAL(wp), DIMENSION(jpi,jpj    ) :: zstrn, zmixnano, zmixdiat
81      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpislopeadn, zpislopeadd, zysopt 
82      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprdia, zprbio, zprdch, zprnch   
83      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprorcan, zprorcad, zprofed, zprofen
84      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpronewn, zpronewd
85      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zmxl_fac, zmxl_chl
86      !!---------------------------------------------------------------------
87      !
88      IF( ln_timing )   CALL timing_start('p4z_prod')
89      !
90      !  Allocate temporary workspace
91      !
92      zprorcan(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp ; zprofed (:,:,:) = 0._wp
93      zprofen (:,:,:) = 0._wp ; zysopt  (:,:,:) = 0._wp
94      zpronewn(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp ; zprdia  (:,:,:) = 0._wp
95      zprbio  (:,:,:) = 0._wp ; zprdch  (:,:,:) = 0._wp ; zprnch  (:,:,:) = 0._wp 
96      zmxl_fac(:,:,:) = 0._wp ; zmxl_chl(:,:,:) = 0._wp 
97
98      ! Computation of the optimal production
99      prmax(:,:,:) = 0.8_wp * r1_rday * tgfunc(:,:,:) 
100
101      ! compute the day length depending on latitude and the day
102      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
103      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
104
105      ! day length in hours
106      zstrn(:,:) = 0.
107      DO jj = 1, jpj
108         DO ji = 1, jpi
109            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
110            zargu = MAX( -1., MIN(  1., zargu ) )
111            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
112         END DO
113      END DO
114
115      ! Impact of the day duration and light intermittency on phytoplankton growth
116      DO jk = 1, jpkm1
117         DO jj = 1 ,jpj
118            DO ji = 1, jpi
119               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
120                  zval = MAX( 1., zstrn(ji,jj) )
121                  IF( gdept_n(ji,jj,jk) <= hmld(ji,jj) ) THEN
122                     zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
123                  ENDIF
124                  zmxl_chl(ji,jj,jk) = zval / 24.
125                  zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval )
126               ENDIF
127            END DO
128         END DO
129      END DO
130
131      zprbio(:,:,:) = prmax(:,:,:) * zmxl_fac(:,:,:)
132      zprdia(:,:,:) = zprbio(:,:,:)
133
134      ! Maximum light intensity
135      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
136
137      ! Computation of the P-I slope for nanos and diatoms
138      DO jk = 1, jpkm1
139         DO jj = 1, jpj
140            DO ji = 1, jpi
141               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
142                  ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
143                  zadap       = xadap * ztn / ( 2.+ ztn )
144                  zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
145                  zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
146                  !
147                  zpislopeadn(ji,jj,jk) = pislopen * ( 1.+ zadap  * EXP( -0.25 * enano(ji,jj,jk) ) )  &
148                  &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
149                  !
150                  zpislopeadd(ji,jj,jk) = (pislopen * zconctemp2 + pisloped * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn )   &
151                  &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
152               ENDIF
153            END DO
154         END DO
155      END DO
156
157      IF( ln_newprod ) THEN
158         DO jk = 1, jpkm1
159            DO jj = 1, jpj
160               DO ji = 1, jpi
161                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
162                      ! Computation of production function for Carbon
163                      !  ---------------------------------------------
164                      zpislopen = zpislopeadn(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
165                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
166                      zpisloped = zpislopeadd(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
167                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
168                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
169                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
170                      !  Computation of production function for Chlorophyll
171                      !--------------------------------------------------
172                      zpislopen = zpislopeadn(ji,jj,jk) / ( prmax(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
173                      zpisloped = zpislopeadd(ji,jj,jk) / ( prmax(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
174                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
175                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
176                  ENDIF
177               END DO
178            END DO
179         END DO
180      ELSE
181         DO jk = 1, jpkm1
182            DO jj = 1, jpj
183               DO ji = 1, jpi
184                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
185                      ! Computation of production function for Carbon
186                      !  ---------------------------------------------
187                      zpislopen = zpislopeadn(ji,jj,jk)  / ( zprbio(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
188                      zpisloped = zpislopeadd(ji,jj,jk) / ( zprdia(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
189                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
190                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
191                      !  Computation of production function for Chlorophyll
192                      !--------------------------------------------------
193                      zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
194                      zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
195                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
196                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
197                  ENDIF
198               END DO
199            END DO
200         END DO
201      ENDIF
202
203      !  Computation of a proxy of the N/C ratio
204      !  ---------------------------------------
205      DO jk = 1, jpkm1
206         DO jj = 1, jpj
207            DO ji = 1, jpi
208                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
209                &      * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
210                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
211                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
212                &      * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
213                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
214            END DO
215         END DO
216      END DO
217
218
219      DO jk = 1, jpkm1
220         DO jj = 1, jpj
221            DO ji = 1, jpi
222
223                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
224                   !    Si/C of diatoms
225                   !    ------------------------
226                   !    Si/C increases with iron stress and silicate availability
227                   !    Si/C is arbitrariliy increased for very high Si concentrations
228                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
229                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
230                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
231                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
232                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
233                  IF (gphit(ji,jj) < -30 ) THEN
234                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
235                  ELSE
236                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
237                  ENDIF
238                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
239              ENDIF
240            END DO
241         END DO
242      END DO
243
244      !  Mixed-layer effect on production
245      !  Sea-ice effect on production
246
247      DO jk = 1, jpkm1
248         DO jj = 1, jpj
249            DO ji = 1, jpi
250               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
251               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
252               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
253               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
254            END DO
255         END DO
256      END DO
257
258      ! Computation of the various production terms
259      DO jk = 1, jpkm1
260         DO jj = 1, jpj
261            DO ji = 1, jpi
262               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
263                  !  production terms for nanophyto. (C)
264                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
265                  zpronewn(ji,jj,jk)  = zprorcan(ji,jj,jk)* xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
266                  !
267                  zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) * fecnm + rtrn )
268                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
269                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
270                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
271                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
272                  &             * zmax * trb(ji,jj,jk,jpphy) * rfact2
273                  !  production terms for diatoms (C)
274                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
275                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
276                  !
277                  zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) * fecdm + rtrn )
278                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
279                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
280                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
281                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
282                  &             * zmax * trb(ji,jj,jk,jpdia) * rfact2
283               ENDIF
284            END DO
285         END DO
286      END DO
287
288      ! Computation of the chlorophyll production terms
289      DO jk = 1, jpkm1
290         DO jj = 1, jpj
291            DO ji = 1, jpi
292               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
293                  !  production terms for nanophyto. ( chlorophyll )
294                  znanotot = enano(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
295                  zprod    = rday * zprorcan(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
296                  zprochln = chlcmin * 12. * zprorcan (ji,jj,jk)
297                  chlcnm_n   = MIN ( chlcnm, ( chlcnm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.))
298                  zprochln = zprochln + (chlcnm_n-chlcmin) * 12. * zprod / &
299                                        & (  zpislopeadn(ji,jj,jk) * znanotot +rtrn)
300                  !  production terms for diatoms ( chlorophyll )
301                  zdiattot = ediat(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
302                  zprod    = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
303                  zprochld = chlcmin * 12. * zprorcad(ji,jj,jk)
304                  chlcdm_n   = MIN ( chlcdm, ( chlcdm / (1. - 1.14 / 43.4 * tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.))
305                  zprochld = zprochld + (chlcdm_n-chlcmin) * 12. * zprod / &
306                                        & ( zpislopeadd(ji,jj,jk) * zdiattot +rtrn )
307                  !   Update the arrays TRA which contain the Chla sources and sinks
308                  tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln * texcretn
309                  tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld * texcretd
310               ENDIF
311            END DO
312         END DO
313      END DO
314
315      !   Update the arrays TRA which contain the biological sources and sinks
316      DO jk = 1, jpkm1
317         DO jj = 1, jpj
318           DO ji =1 ,jpi
319              IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
320                 zproreg  = zprorcan(ji,jj,jk) - zpronewn(ji,jj,jk)
321                 zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
322                 zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
323                 tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
324                 tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)
325                 tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
326                 tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcretn
327                 tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcretn
328                 tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcretd
329                 tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcretd
330                 tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
331                 tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zdocprod
332                 tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
333                 &                   + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) )
334                 !
335                 zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
336                 tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zfeup
337                 tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
338                 tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
339                 tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
340                 &                                         - rno3 * ( zproreg + zproreg2 )
341              ENDIF
342           END DO
343        END DO
344     END DO
345     !
346     IF( ln_ligand ) THEN
347         DO jk = 1, jpkm1
348            DO jj = 1, jpj
349              DO ji =1 ,jpi
350                 IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
351                    zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
352                    zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
353                    tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
354                 ENDIF
355              END DO
356           END DO
357        END DO
358     ENDIF
359
360
361    ! Total primary production per year
362    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
363         & tpp = glob_sum( ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
364
365    IF( lk_iomput ) THEN
366       IF( knt == nrdttrc ) THEN
367          ALLOCATE( zw2d(jpi,jpj), zw3d(jpi,jpj,jpk) )
368          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
369          !
370          IF( iom_use( "PPPHYN" ) .OR. iom_use( "PPPHYD" ) )  THEN
371              zw3d(:,:,:) = zprorcan(:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
372              CALL iom_put( "PPPHYN"  , zw3d )
373              !
374              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
375              CALL iom_put( "PPPHYD"  , zw3d )
376          ENDIF
377          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
378              zw3d(:,:,:) = zpronewn(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
379              CALL iom_put( "PPNEWN"  , zw3d )
380              !
381              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
382              CALL iom_put( "PPNEWD"  , zw3d )
383          ENDIF
384          IF( iom_use( "PBSi" ) )  THEN
385              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
386              CALL iom_put( "PBSi"  , zw3d )
387          ENDIF
388          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
389              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
390              CALL iom_put( "PFeN"  , zw3d )
391              !
392              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
393              CALL iom_put( "PFeD"  , zw3d )
394          ENDIF
395          IF( iom_use( "Mumax" ) )  THEN
396              zw3d(:,:,:) = prmax(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
397              CALL iom_put( "Mumax"  , zw3d )
398          ENDIF
399          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
400              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
401              CALL iom_put( "MuN"  , zw3d )
402              !
403              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
404              CALL iom_put( "MuD"  , zw3d )
405          ENDIF
406          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
407              zw3d(:,:,:) = zprbio (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
408              CALL iom_put( "LNlight"  , zw3d )
409              !
410              zw3d(:,:,:) =  zprdia (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
411              CALL iom_put( "LDlight"  , zw3d )
412          ENDIF
413          IF( iom_use( "TPP" ) )  THEN
414              zw3d(:,:,:) = ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
415              CALL iom_put( "TPP"  , zw3d )
416          ENDIF
417          IF( iom_use( "TPNEW" ) )  THEN
418              zw3d(:,:,:) = ( zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
419              CALL iom_put( "TPNEW"  , zw3d )
420          ENDIF
421          IF( iom_use( "TPBFE" ) )  THEN
422              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
423              CALL iom_put( "TPBFE"  , zw3d )
424          ENDIF
425          IF( iom_use( "INTPPPHYN" ) .OR. iom_use( "INTPPPHYD" ) ) THEN 
426             zw2d(:,:) = 0.
427             DO jk = 1, jpkm1
428               zw2d(:,:) = zw2d(:,:) + zprorcan(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
429             ENDDO
430             CALL iom_put( "INTPPPHYN" , zw2d )
431             !
432             zw2d(:,:) = 0.
433             DO jk = 1, jpkm1
434                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
435             ENDDO
436             CALL iom_put( "INTPPPHYD" , zw2d )
437          ENDIF
438          IF( iom_use( "INTPP" ) ) THEN   
439             zw2d(:,:) = 0.
440             DO jk = 1, jpkm1
441                zw2d(:,:) = zw2d(:,:) + ( zprorcan(:,:,jk) + zprorcad(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated pp
442             ENDDO
443             CALL iom_put( "INTPP" , zw2d )
444          ENDIF
445          IF( iom_use( "INTPNEW" ) ) THEN   
446             zw2d(:,:) = 0.
447             DO jk = 1, jpkm1
448                zw2d(:,:) = zw2d(:,:) + ( zpronewn(:,:,jk) + zpronewd(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
449             ENDDO
450             CALL iom_put( "INTPNEW" , zw2d )
451          ENDIF
452          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
453             zw2d(:,:) = 0.
454             DO jk = 1, jpkm1
455                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
456             ENDDO
457            CALL iom_put( "INTPBFE" , zw2d )
458          ENDIF
459          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
460             zw2d(:,:) = 0.
461             DO jk = 1, jpkm1
462                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
463             ENDDO
464             CALL iom_put( "INTPBSI" , zw2d )
465          ENDIF
466          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
467          !
468          DEALLOCATE( zw2d, zw3d )
469       ENDIF
470     ENDIF
471
472     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
473         WRITE(charout, FMT="('prod')")
474         CALL prt_ctl_trc_info(charout)
475         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
476     ENDIF
477     !
478     IF( ln_timing )  CALL timing_stop('p4z_prod')
479     !
480   END SUBROUTINE p4z_prod
481
482
483   SUBROUTINE p4z_prod_init
484      !!----------------------------------------------------------------------
485      !!                  ***  ROUTINE p4z_prod_init  ***
486      !!
487      !! ** Purpose :   Initialization of phytoplankton production parameters
488      !!
489      !! ** Method  :   Read the nampisprod namelist and check the parameters
490      !!      called at the first timestep (nittrc000)
491      !!
492      !! ** input   :   Namelist nampisprod
493      !!----------------------------------------------------------------------
494      INTEGER :: ios                 ! Local integer output status for namelist read
495      !
496      NAMELIST/namp4zprod/ pislopen, pisloped, xadap, ln_newprod, bresp, excretn, excretd,  &
497         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
498      !!----------------------------------------------------------------------
499
500      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
501      READ  ( numnatp_ref, namp4zprod, IOSTAT = ios, ERR = 901)
502901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zprod in reference namelist', lwp )
503
504      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
505      READ  ( numnatp_cfg, namp4zprod, IOSTAT = ios, ERR = 902 )
506902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp4zprod in configuration namelist', lwp )
507      IF(lwm) WRITE ( numonp, namp4zprod )
508
509      IF(lwp) THEN                         ! control print
510         WRITE(numout,*) ' '
511         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, namp4zprod'
512         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
513         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod    =', ln_newprod
514         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
515         WRITE(numout,*) '    P-I slope                                 pislopen     =', pislopen
516         WRITE(numout,*) '    Acclimation factor to low light           xadap        =', xadap
517         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excretn      =', excretn
518         WRITE(numout,*) '    excretion ratio of diatoms                excretd      =', excretd
519         IF( ln_newprod )  THEN
520            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
521            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
522         ENDIF
523         WRITE(numout,*) '    P-I slope  for diatoms                    pisloped     =', pisloped
524         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
525         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
526         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
527         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
528      ENDIF
529      !
530      r1_rday   = 1._wp / rday 
531      texcretn  = 1._wp - excretn
532      texcretd  = 1._wp - excretd
533      tpp       = 0._wp
534      !
535   END SUBROUTINE p4z_prod_init
536
537
538   INTEGER FUNCTION p4z_prod_alloc()
539      !!----------------------------------------------------------------------
540      !!                     ***  ROUTINE p4z_prod_alloc  ***
541      !!----------------------------------------------------------------------
542      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
543      !
544      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
545      !
546   END FUNCTION p4z_prod_alloc
547
548   !!======================================================================
549END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.