New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iceadv_umx.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/iceadv_umx.F90 @ 8517

Last change on this file since 8517 was 8512, checked in by clem, 7 years ago

changes in style - part5 - reaching the end
File size: 33.8 KB
Line 
1MODULE iceadv_umx
2   !!==============================================================================
3   !!                       ***  MODULE  iceadv_umx  ***
4   !! LIM sea-ice model : sea-ice advection using the ULTIMATE-MACHO scheme
5   !!==============================================================================
6   !! History :  3.6  !  2014-11  (C. Rousset, G. Madec)  Original code
7   !!----------------------------------------------------------------------
8#if defined key_lim3
9   !!----------------------------------------------------------------------
10   !!   'key_lim3'                                    LIM 3.0 sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_adv_umx   : update the tracer trend with the 3D advection trends using a TVD scheme
13   !!   ultimate_x(_y): compute a tracer value at velocity points using ULTIMATE scheme at various orders
14   !!   macho         : ???
15   !!   nonosc_2d     : compute monotonic tracer fluxes by a non-oscillatory algorithm
16   !!----------------------------------------------------------------------
17   USE phycst         ! physical constant
18   USE dom_oce        ! ocean domain
19   USE sbc_oce , ONLY : nn_fsbc   ! update frequency of surface boundary condition
20   USE ice            ! sea-ice variables
21   !
22   USE in_out_manager ! I/O manager
23   USE lbclnk         ! lateral boundary conditions -- MPP exchanges
24   USE lib_mpp        ! MPP library
25   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
26   USE timing         ! Timing
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   ice_adv_umx    ! routine called by iceadv.F90
32     
33   REAL(wp) ::   z1_6   = 1._wp /   6._wp   ! =1/6
34   REAL(wp) ::   z1_120 = 1._wp / 120._wp   ! =1/120
35
36   !! * Substitutions
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/ICE 4.0 , NEMO Consortium (2017)
40   !! $Id: iceadv_umx.F90 4499 2014-02-18 15:14:31Z timgraham $
41   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE ice_adv_umx( kt, pu_ice, pv_ice,  &
46      &                    pato_i, pv_i, pv_s, psmv_i, poa_i, pa_i, pa_ip, pv_ip, pe_s, pe_i )
47      !!----------------------------------------------------------------------
48      !!                  ***  ROUTINE ice_adv_umx  ***
49      !!
50      !! **  Purpose :   Compute the now trend due to total advection of
51      !!                 tracers and add it to the general trend of tracer equations
52      !!                 using an "Ultimate-Macho" scheme
53      !!
54      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
55      !!----------------------------------------------------------------------
56      INTEGER                     , INTENT(in   ) ::   kt         ! time step
57      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pu_ice     ! ice i-velocity
58      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pv_ice     ! ice j-velocity
59      REAL(wp), DIMENSION(:,:)    , INTENT(inout) ::   pato_i     ! open water area
60      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_i       ! ice volume
61      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_s       ! snw volume
62      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   psmv_i     ! salt content
63      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   poa_i      ! age content
64      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_i       ! ice concentration
65      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_ip      ! melt pond fraction
66      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_ip      ! melt pond volume
67      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_s       ! snw heat content
68      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_i       ! ice heat content
69      !
70      INTEGER  ::   ji, jj, jk, jl, jt      ! dummy loop indices
71      INTEGER  ::   initad                  ! number of sub-timestep for the advection
72      REAL(wp) ::   zcfl , zusnit, zdt      !   -      -
73      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zudy, zvdx, zcu_box, zcv_box
74      !!----------------------------------------------------------------------
75      !
76      IF( kt == nit000 .AND. lwp )   WRITE(numout,*) '-- ice_adv_umx: Ultimate-Macho advection scheme'
77      !
78      ALLOCATE( zudy(jpi,jpj) , zvdx(jpi,jpj) , zcu_box(jpi,jpj) , zcv_box(jpi,jpj) )
79      !
80      ! --- If ice drift field is too fast, use an appropriate time step for advection (CFL test for stability) --- !       
81      zcfl  =            MAXVAL( ABS( pu_ice(:,:) ) * rdt_ice * r1_e1u(:,:) )
82      zcfl  = MAX( zcfl, MAXVAL( ABS( pv_ice(:,:) ) * rdt_ice * r1_e2v(:,:) ) )
83      IF( lk_mpp )   CALL mpp_max( zcfl )
84
85      IF( zcfl > 0.5 ) THEN   ;   initad = 2   ;   zusnit = 0.5_wp
86      ELSE                    ;   initad = 1   ;   zusnit = 1.0_wp
87      ENDIF
88
89      zdt = rdt_ice / REAL(initad)
90
91      ! --- transport --- !
92      zudy(:,:) = pu_ice(:,:) * e2u(:,:)
93      zvdx(:,:) = pv_ice(:,:) * e1v(:,:)
94
95      ! --- define velocity for advection: u*grad(H) --- !
96      DO jj = 2, jpjm1
97         DO ji = fs_2, fs_jpim1
98            IF    ( pu_ice(ji,jj) * pu_ice(ji-1,jj) <= 0._wp ) THEN   ;   zcu_box(ji,jj) = 0._wp
99            ELSEIF( pu_ice(ji,jj)                   >  0._wp ) THEN   ;   zcu_box(ji,jj) = pu_ice(ji-1,jj)
100            ELSE                                                      ;   zcu_box(ji,jj) = pu_ice(ji  ,jj)
101            ENDIF
102
103            IF    ( pv_ice(ji,jj) * pv_ice(ji,jj-1) <= 0._wp ) THEN   ;   zcv_box(ji,jj) = 0._wp
104            ELSEIF( pv_ice(ji,jj)                   >  0._wp ) THEN   ;   zcv_box(ji,jj) = pv_ice(ji,jj-1)
105            ELSE                                                      ;   zcv_box(ji,jj) = pv_ice(ji,jj  )
106            ENDIF
107         END DO
108      END DO
109
110      !---------------!
111      !== advection ==!
112      !---------------!
113      DO jt = 1, initad
114         CALL adv_umx( kt, zdt, zudy, zvdx, zcu_box, zcv_box, pato_i(:,:) )             ! Open water area
115         DO jl = 1, jpl
116            CALL adv_umx( kt, zdt, zudy, zvdx, zcu_box, zcv_box, pa_i(:,:,jl) )         ! Ice area
117            CALL adv_umx( kt, zdt, zudy, zvdx, zcu_box, zcv_box, pv_i(:,:,jl) )         ! Ice  volume
118            CALL adv_umx( kt, zdt, zudy, zvdx, zcu_box, zcv_box, psmv_i(:,:,jl) )       ! Salt content
119            CALL adv_umx( kt, zdt, zudy, zvdx, zcu_box, zcv_box, poa_i (:,:,jl) )       ! Age content
120            DO jk = 1, nlay_i
121               CALL adv_umx( kt, zdt, zudy, zvdx, zcu_box, zcv_box, pe_i(:,:,jk,jl) )   ! Ice  heat content
122            END DO
123            CALL adv_umx( kt, zdt, zudy, zvdx, zcu_box, zcv_box, pv_s(:,:,jl) )         ! Snow volume
124            CALL adv_umx( kt, zdt, zudy, zvdx, zcu_box, zcv_box, pe_s(:,:,1,jl) )       ! Snow heat content
125            IF ( nn_pnd_scheme > 0 ) THEN
126               CALL adv_umx( kt, zdt, zudy, zvdx, zcu_box, zcv_box, pa_ip(:,:,jl) )     ! Melt pond fraction
127               CALL adv_umx( kt, zdt, zudy, zvdx, zcu_box, zcv_box, pv_ip(:,:,jl) )     ! Melt pond volume
128            ENDIF
129         END DO
130      END DO
131      !
132      DEALLOCATE( zudy, zvdx, zcu_box, zcv_box )
133      !
134   END SUBROUTINE ice_adv_umx
135   
136   SUBROUTINE adv_umx( kt, pdt, puc, pvc, pubox, pvbox, ptc )
137      !!----------------------------------------------------------------------
138      !!                  ***  ROUTINE adv_umx  ***
139      !!
140      !! **  Purpose :   Compute the now trend due to total advection of
141      !!       tracers and add it to the general trend of tracer equations
142      !!
143      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
144      !!       corrected flux (monotonic correction)
145      !!       note: - this advection scheme needs a leap-frog time scheme
146      !!
147      !! ** Action : - pt  the after advective tracer
148      !!----------------------------------------------------------------------
149      INTEGER                     , INTENT(in   ) ::   kt             ! number of iteration
150      REAL(wp)                    , INTENT(in   ) ::   pdt            ! tracer time-step
151      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   puc  , pvc     ! 2 ice velocity components => u*e2
152      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
153      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   ptc            ! tracer content field
154      !
155      INTEGER  ::   ji, jj           ! dummy loop indices 
156      REAL(wp) ::   ztra             ! local scalar
157      REAL(wp) ::   zfp_ui, zfp_vj   !   -      -
158      REAL(wp) ::   zfm_ui, zfm_vj   !   -      -
159      REAL(wp), DIMENSION(jpi,jpj) ::   zfu_ups, zfu_ho, zt_u, zt_ups
160      REAL(wp), DIMENSION(jpi,jpj) ::   zfv_ups, zfv_ho, zt_v, ztrd
161      !!----------------------------------------------------------------------
162      !
163      IF( nn_timing == 1 )  CALL timing_start('ice_adv_umx')
164      !
165      !  upstream advection with initial mass fluxes & intermediate update
166      ! --------------------------------------------------------------------
167      DO jj = 1, jpjm1         ! upstream tracer flux in the i and j direction
168         DO ji = 1, fs_jpim1   ! vector opt.
169            zfp_ui = puc(ji,jj) + ABS( puc(ji,jj) )
170            zfm_ui = puc(ji,jj) - ABS( puc(ji,jj) )
171            zfp_vj = pvc(ji,jj) + ABS( pvc(ji,jj) )
172            zfm_vj = pvc(ji,jj) - ABS( pvc(ji,jj) )
173            zfu_ups(ji,jj) = 0.5_wp * ( zfp_ui * ptc(ji,jj) + zfm_ui * ptc(ji+1,jj  ) )
174            zfv_ups(ji,jj) = 0.5_wp * ( zfp_vj * ptc(ji,jj) + zfm_vj * ptc(ji  ,jj+1) )
175         END DO
176      END DO
177     
178      DO jj = 2, jpjm1            ! total intermediate advective trends
179         DO ji = fs_2, fs_jpim1   ! vector opt.
180            ztra = - (   zfu_ups(ji,jj) - zfu_ups(ji-1,jj  )   &
181               &       + zfv_ups(ji,jj) - zfv_ups(ji  ,jj-1)   ) * r1_e1e2t(ji,jj)
182            !
183            ztrd(ji,jj) =                         ztra                         ! upstream trend [ -div(uh) or -div(uhT) ] 
184            zt_ups (ji,jj) = ( ptc(ji,jj) + pdt * ztra ) * tmask(ji,jj,1)      ! guess after content field with monotonic scheme
185         END DO
186      END DO
187      CALL lbc_lnk( zt_ups, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
188     
189      ! High order (_ho) fluxes
190      ! -----------------------
191      SELECT CASE( nn_UMx )
192      CASE ( 20 )                          ! centered second order
193         DO jj = 2, jpjm1
194            DO ji = fs_2, fs_jpim1   ! vector opt.
195               zfu_ho(ji,jj) = 0.5 * puc(ji,jj) * ( ptc(ji,jj) + ptc(ji+1,jj) )
196               zfv_ho(ji,jj) = 0.5 * pvc(ji,jj) * ( ptc(ji,jj) + ptc(ji,jj+1) )
197            END DO
198         END DO
199         !
200      CASE ( 1:5 )                      ! 1st to 5th order ULTIMATE-MACHO scheme
201         CALL macho( kt, nn_UMx, pdt, ptc, puc, pvc, pubox, pvbox, zt_u, zt_v )
202         !
203         DO jj = 2, jpjm1
204            DO ji = fs_2, fs_jpim1   ! vector opt.
205               zfu_ho(ji,jj) = puc(ji,jj) * zt_u(ji,jj)
206               zfv_ho(ji,jj) = pvc(ji,jj) * zt_v(ji,jj)
207            END DO
208         END DO
209         !
210      END SELECT
211         
212      ! antidiffusive flux : high order minus low order
213      ! --------------------------------------------------
214      DO jj = 2, jpjm1
215         DO ji = fs_2, fs_jpim1   ! vector opt.
216            zfu_ho(ji,jj) = zfu_ho(ji,jj) - zfu_ups(ji,jj)
217            zfv_ho(ji,jj) = zfv_ho(ji,jj) - zfv_ups(ji,jj)
218         END DO
219      END DO
220      CALL lbc_lnk_multi( zfu_ho, 'U', -1., zfv_ho, 'V', -1. )         ! Lateral bondary conditions
221     
222      ! monotonicity algorithm
223      ! -------------------------
224      CALL nonosc_2d( ptc, zfu_ho, zfv_ho, zt_ups, pdt )
225     
226      ! final trend with corrected fluxes
227      ! ------------------------------------
228      DO jj = 2, jpjm1
229         DO ji = fs_2, fs_jpim1   ! vector opt. 
230            ztra       = ztrd(ji,jj)  - (  zfu_ho(ji,jj) - zfu_ho(ji-1,jj  )   &
231               &                         + zfv_ho(ji,jj) - zfv_ho(ji  ,jj-1) ) * r1_e1e2t(ji,jj) 
232            ptc(ji,jj) = ptc(ji,jj) + pdt * ztra
233         END DO
234      END DO
235      CALL lbc_lnk( ptc(:,:) , 'T',  1. )
236      !
237      IF( nn_timing == 1 )  CALL timing_stop('ice_adv_umx')
238      !
239   END SUBROUTINE adv_umx
240
241
242   SUBROUTINE macho( kt, k_order, pdt, ptc, puc, pvc, pubox, pvbox, pt_u, pt_v )
243      !!---------------------------------------------------------------------
244      !!                    ***  ROUTINE ultimate_x  ***
245      !!     
246      !! **  Purpose :   compute 
247      !!
248      !! **  Method  :   ... ???
249      !!                 TIM = transient interpolation Modeling
250      !!
251      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
252      !!----------------------------------------------------------------------
253      INTEGER                     , INTENT(in   ) ::   kt         ! number of iteration
254      INTEGER                     , INTENT(in   ) ::   k_order    ! order of the ULTIMATE scheme
255      REAL(wp)                    , INTENT(in   ) ::   pdt        ! tracer time-step
256      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   ptc        ! tracer fields
257      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   puc, pvc   ! 2 ice velocity components
258      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
259      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   pt_u, pt_v ! tracer at u- and v-points
260      !
261      INTEGER  ::   ji, jj    ! dummy loop indices
262      REAL(wp) ::   zc_box    !   -      -
263      REAL(wp), DIMENSION(jpi,jpj) :: zzt
264      !!----------------------------------------------------------------------
265      !
266      IF( nn_timing == 1 )  CALL timing_start('macho')
267      !
268      IF( MOD( (kt - 1) / nn_fsbc , 2 ) == 0 ) THEN         !==  odd ice time step:  adv_x then adv_y  ==!
269         !
270         !                                                           !--  ultimate interpolation of pt at u-point  --!
271         CALL ultimate_x( k_order, pdt, ptc, puc, pt_u )
272         !
273         !                                                           !--  advective form update in zzt  --!
274         DO jj = 2, jpjm1
275            DO ji = fs_2, fs_jpim1   ! vector opt.
276               zzt(ji,jj) = ptc(ji,jj) - pubox(ji,jj) * pdt * ( pt_u(ji,jj) - pt_u(ji-1,jj) ) * r1_e1t(ji,jj)  &
277                  &                    - ptc  (ji,jj) * pdt * ( puc (ji,jj) - puc (ji-1,jj) ) * r1_e1e2t(ji,jj)
278               zzt(ji,jj) = zzt(ji,jj) * tmask(ji,jj,1)
279            END DO
280         END DO
281         CALL lbc_lnk( zzt, 'T', 1. )
282         !
283         !                                                           !--  ultimate interpolation of pt at v-point  --!
284         CALL ultimate_y( k_order, pdt, zzt, pvc, pt_v )
285         !
286      ELSE                                                  !==  even ice time step:  adv_y then adv_x  ==!
287         !
288         !                                                           !--  ultimate interpolation of pt at v-point  --!
289         CALL ultimate_y( k_order, pdt, ptc, pvc, pt_v )
290         !
291         !                                                           !--  advective form update in zzt  --!
292         DO jj = 2, jpjm1
293            DO ji = fs_2, fs_jpim1
294               zzt(ji,jj) = ptc(ji,jj) - pvbox(ji,jj) * pdt * ( pt_v(ji,jj) - pt_v(ji,jj-1) ) * r1_e2t(ji,jj)  &
295                  &                    - ptc  (ji,jj) * pdt * ( pvc (ji,jj) - pvc (ji,jj-1) ) * r1_e1e2t(ji,jj)
296               zzt(ji,jj) = zzt(ji,jj) * tmask(ji,jj,1)
297            END DO
298         END DO
299         CALL lbc_lnk( zzt, 'T', 1. )
300         !
301         !                                                           !--  ultimate interpolation of pt at u-point  --!
302         CALL ultimate_x( k_order, pdt, zzt, puc, pt_u )
303         !     
304      ENDIF     
305      !
306      IF( nn_timing == 1 )  CALL timing_stop('macho')
307      !
308   END SUBROUTINE macho
309
310
311   SUBROUTINE ultimate_x( k_order, pdt, pt, puc, pt_u )
312      !!---------------------------------------------------------------------
313      !!                    ***  ROUTINE ultimate_x  ***
314      !!     
315      !! **  Purpose :   compute 
316      !!
317      !! **  Method  :   ... ???
318      !!                 TIM = transient interpolation Modeling
319      !!
320      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
321      !!----------------------------------------------------------------------
322      INTEGER                     , INTENT(in   ) ::   k_order   ! ocean time-step index
323      REAL(wp)                    , INTENT(in   ) ::   pdt       ! tracer time-step
324      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   puc       ! ice i-velocity component
325      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pt        ! tracer fields
326      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   pt_u      ! tracer at u-point
327      !
328      INTEGER  ::   ji, jj       ! dummy loop indices
329      REAL(wp) ::   zcu, zdx2, zdx4    !   -      -
330      REAL(wp), DIMENSION(jpi,jpj) :: ztu1, ztu2, ztu3, ztu4
331      !!----------------------------------------------------------------------
332      !
333      IF( nn_timing == 1 )  CALL timing_start('ultimate_x')
334      !
335      !                                                     !--  Laplacian in i-direction  --!
336      DO jj = 2, jpjm1         ! First derivative (gradient)
337         DO ji = 1, fs_jpim1
338            ztu1(ji,jj) = ( pt(ji+1,jj) - pt(ji,jj) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
339         END DO
340         !                     ! Second derivative (Laplacian)
341         DO ji = fs_2, fs_jpim1
342            ztu2(ji,jj) = ( ztu1(ji,jj) - ztu1(ji-1,jj) ) * r1_e1t(ji,jj)
343         END DO
344      END DO
345      CALL lbc_lnk( ztu2, 'T', 1. )
346      !
347      !                                                     !--  BiLaplacian in i-direction  --!
348      DO jj = 2, jpjm1         ! Third derivative
349         DO ji = 1, fs_jpim1
350            ztu3(ji,jj) = ( ztu2(ji+1,jj) - ztu2(ji,jj) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
351         END DO
352         !                     ! Fourth derivative
353         DO ji = fs_2, fs_jpim1
354            ztu4(ji,jj) = ( ztu3(ji,jj) - ztu3(ji-1,jj) ) * r1_e1t(ji,jj)
355         END DO
356      END DO
357      CALL lbc_lnk( ztu4, 'T', 1. )
358      !
359      !
360      SELECT CASE (k_order )
361      !
362      CASE( 1 )                                                   !==  1st order central TIM  ==! (Eq. 21)
363         !       
364         DO jj = 1, jpj
365            DO ji = 1, fs_jpim1   ! vector opt.
366               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (                               pt(ji+1,jj) + pt(ji,jj)   &
367                  &                                    - SIGN( 1._wp, puc(ji,jj) ) * ( pt(ji+1,jj) - pt(ji,jj) ) )
368            END DO
369         END DO
370         !
371      CASE( 2 )                                                   !==  2nd order central TIM  ==! (Eq. 23)
372         !
373         DO jj = 1, jpj
374            DO ji = 1, fs_jpim1   ! vector opt.
375               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
376               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (                                   pt(ji+1,jj) + pt(ji,jj)   &
377                  &                                               -              zcu   * ( pt(ji+1,jj) - pt(ji,jj) ) ) 
378            END DO
379         END DO
380         CALL lbc_lnk( pt_u(:,:) , 'U',  1. )
381         ! 
382      CASE( 3 )                                                   !==  3rd order central TIM  ==! (Eq. 24)
383         !
384         DO jj = 1, jpj
385            DO ji = 1, fs_jpim1   ! vector opt.
386               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
387               zdx2 = e1u(ji,jj) * e1u(ji,jj)
388!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
389               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (         (                         pt  (ji+1,jj) + pt  (ji,jj)        &
390                  &                                               -              zcu   * ( pt  (ji+1,jj) - pt  (ji,jj) )  )   &
391                  &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                         ztu2(ji+1,jj) + ztu2(ji,jj)        &
392                  &                                               - SIGN( 1._wp, zcu ) * ( ztu2(ji+1,jj) - ztu2(ji,jj) )  )   )
393            END DO
394         END DO
395         !
396      CASE( 4 )                                                   !==  4th order central TIM  ==! (Eq. 27)
397         !
398         DO jj = 1, jpj
399            DO ji = 1, fs_jpim1   ! vector opt.
400               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
401               zdx2 = e1u(ji,jj) * e1u(ji,jj)
402!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
403               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (         (                   pt  (ji+1,jj) + pt  (ji,jj)        &
404                  &                                               -          zcu * ( pt  (ji+1,jj) - pt  (ji,jj) )  )   &
405                  &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                   ztu2(ji+1,jj) + ztu2(ji,jj)        &
406                  &                                               - 0.5_wp * zcu * ( ztu2(ji+1,jj) - ztu2(ji,jj) )  )   )
407            END DO
408         END DO
409         !
410      CASE( 5 )                                                   !==  5th order central TIM  ==! (Eq. 29)
411         !
412         DO jj = 1, jpj
413            DO ji = 1, fs_jpim1   ! vector opt.
414               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
415               zdx2 = e1u(ji,jj) * e1u(ji,jj)
416!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
417               zdx4 = zdx2 * zdx2
418               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (               (                   pt  (ji+1,jj) + pt  (ji,jj)       &
419                  &                                                     -          zcu * ( pt  (ji+1,jj) - pt  (ji,jj) ) )   &
420                  &        + z1_6   * zdx2 * ( zcu*zcu - 1._wp ) *     (                   ztu2(ji+1,jj) + ztu2(ji,jj)       &
421                  &                                                     - 0.5_wp * zcu * ( ztu2(ji+1,jj) - ztu2(ji,jj) ) )   &
422                  &        + z1_120 * zdx4 * ( zcu*zcu - 1._wp ) * ( zcu*zcu - 4._wp ) * ( ztu4(ji+1,jj) + ztu4(ji,jj)       &
423                  &                                               - SIGN( 1._wp, zcu ) * ( ztu4(ji+1,jj) - ztu4(ji,jj) ) ) )
424            END DO
425         END DO
426         !
427      END SELECT
428      !
429      IF( nn_timing == 1 )  CALL timing_stop('ultimate_x')
430      !
431   END SUBROUTINE ultimate_x
432   
433 
434   SUBROUTINE ultimate_y( k_order, pdt, pt, pvc, pt_v )
435      !!---------------------------------------------------------------------
436      !!                    ***  ROUTINE ultimate_y  ***
437      !!     
438      !! **  Purpose :   compute 
439      !!
440      !! **  Method  :   ... ???
441      !!                 TIM = transient interpolation Modeling
442      !!
443      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
444      !!----------------------------------------------------------------------
445      INTEGER                     , INTENT(in   ) ::   k_order   ! ocean time-step index
446      REAL(wp)                    , INTENT(in   ) ::   pdt       ! tracer time-step
447      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pvc       ! ice j-velocity component
448      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pt        ! tracer fields
449      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   pt_v      ! tracer at v-point
450      !
451      INTEGER  ::   ji, jj       ! dummy loop indices
452      REAL(wp) ::   zcv, zdy2, zdy4    !   -      -
453      REAL(wp), DIMENSION(jpi,jpj) :: ztv1, ztv2, ztv3, ztv4
454      !!----------------------------------------------------------------------
455      !
456      IF( nn_timing == 1 )  CALL timing_start('ultimate_y')
457      !
458      !                                                     !--  Laplacian in j-direction  --!
459      DO jj = 1, jpjm1         ! First derivative (gradient)
460         DO ji = fs_2, fs_jpim1
461            ztv1(ji,jj) = ( pt(ji,jj+1) - pt(ji,jj) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
462         END DO
463      END DO
464      DO jj = 2, jpjm1         ! Second derivative (Laplacian)
465         DO ji = fs_2, fs_jpim1
466            ztv2(ji,jj) = ( ztv1(ji,jj) - ztv1(ji,jj-1) ) * r1_e2t(ji,jj)
467         END DO
468      END DO
469      CALL lbc_lnk( ztv2, 'T', 1. )
470      !
471      !                                                     !--  BiLaplacian in j-direction  --!
472      DO jj = 1, jpjm1         ! First derivative
473         DO ji = fs_2, fs_jpim1
474            ztv3(ji,jj) = ( ztv2(ji,jj+1) - ztv2(ji,jj) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
475         END DO
476      END DO
477      DO jj = 2, jpjm1         ! Second derivative
478         DO ji = fs_2, fs_jpim1
479            ztv4(ji,jj) = ( ztv3(ji,jj) - ztv3(ji,jj-1) ) * r1_e2t(ji,jj)
480         END DO
481      END DO
482      CALL lbc_lnk( ztv4, 'T', 1. )
483      !
484      !
485      SELECT CASE (k_order )
486      !
487      CASE( 1 )                                                !==  1st order central TIM  ==! (Eq. 21)
488         DO jj = 1, jpjm1
489            DO ji = 1, jpi
490               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                              ( pt(ji,jj+1) + pt(ji,jj) )  &
491                  &                                     - SIGN( 1._wp, pvc(ji,jj) ) * ( pt(ji,jj+1) - pt(ji,jj) ) )
492            END DO
493         END DO
494         !
495      CASE( 2 )                                                !==  2nd order central TIM  ==! (Eq. 23)
496         DO jj = 1, jpjm1
497            DO ji = 1, jpi
498               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
499               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (        ( pt(ji,jj+1) + pt(ji,jj) )  &
500                  &                                     - zcv * ( pt(ji,jj+1) - pt(ji,jj) ) )
501            END DO
502         END DO
503         CALL lbc_lnk( pt_v(:,:) , 'V',  1. )
504         !
505      CASE( 3 )                                                !==  3rd order central TIM  ==! (Eq. 24)
506         DO jj = 1, jpjm1
507            DO ji = 1, jpi
508               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
509               zdy2 = e2v(ji,jj) * e2v(ji,jj)
510!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
511               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                                 ( pt  (ji,jj+1) + pt  (ji,jj)       &
512                  &                                     -                        zcv   * ( pt  (ji,jj+1) - pt  (ji,jj) ) )   &
513                  &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                         ztv2(ji,jj+1) + ztv2(ji,jj)       &
514                  &                                               - SIGN( 1._wp, zcv ) * ( ztv2(ji,jj+1) - ztv2(ji,jj) ) ) )
515            END DO
516         END DO
517         !
518      CASE( 4 )                                                !==  4th order central TIM  ==! (Eq. 27)
519         DO jj = 1, jpjm1
520            DO ji = 1, jpi
521               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
522               zdy2 = e2v(ji,jj) * e2v(ji,jj)
523!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
524               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                           ( pt  (ji,jj+1) + pt  (ji,jj)       &
525                  &                                               -          zcv * ( pt  (ji,jj+1) - pt  (ji,jj) ) )   &
526                  &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                   ztv2(ji,jj+1) + ztv2(ji,jj)       &
527                  &                                               - 0.5_wp * zcv * ( ztv2(ji,jj+1) - ztv2(ji,jj) ) ) )
528            END DO
529         END DO
530         !
531      CASE( 5 )                                                !==  5th order central TIM  ==! (Eq. 29)
532         DO jj = 1, jpjm1
533            DO ji = 1, jpi
534               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
535               zdy2 = e2v(ji,jj) * e2v(ji,jj)
536!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
537               zdy4 = zdy2 * zdy2
538               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                                 ( pt  (ji,jj+1) + pt  (ji,jj)      &
539                  &                                                     -          zcv * ( pt  (ji,jj+1) - pt  (ji,jj) ) )  &
540                  &        + z1_6   * zdy2 * ( zcv*zcv - 1._wp ) *     (                   ztv2(ji,jj+1) + ztv2(ji,jj)      &
541                  &                                                     - 0.5_wp * zcv * ( ztv2(ji,jj+1) - ztv2(ji,jj) ) )  &
542                  &        + z1_120 * zdy4 * ( zcv*zcv - 1._wp ) * ( zcv*zcv - 4._wp ) * ( ztv4(ji,jj+1) + ztv4(ji,jj)      &
543                  &                                               - SIGN( 1._wp, zcv ) * ( ztv4(ji,jj+1) - ztv4(ji,jj) ) ) )
544            END DO
545         END DO
546         !
547      END SELECT
548      !
549      IF( nn_timing == 1 )  CALL timing_stop('ultimate_y')
550      !
551   END SUBROUTINE ultimate_y
552   
553 
554   SUBROUTINE nonosc_2d( pbef, paa, pbb, paft, pdt )
555      !!---------------------------------------------------------------------
556      !!                    ***  ROUTINE nonosc  ***
557      !!     
558      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
559      !!       scheme and the before field by a nonoscillatory algorithm
560      !!
561      !! **  Method  :   ... ???
562      !!       warning : pbef and paft must be masked, but the boundaries
563      !!       conditions on the fluxes are not necessary zalezak (1979)
564      !!       drange (1995) multi-dimensional forward-in-time and upstream-
565      !!       in-space based differencing for fluid
566      !!----------------------------------------------------------------------
567      REAL(wp)                     , INTENT(in   ) ::   pdt          ! tracer time-step
568      REAL(wp), DIMENSION (jpi,jpj), INTENT(in   ) ::   pbef, paft   ! before & after field
569      REAL(wp), DIMENSION (jpi,jpj), INTENT(inout) ::   paa, pbb     ! monotonic fluxes in the 2 directions
570      !
571      INTEGER  ::   ji, jj    ! dummy loop indices
572      INTEGER  ::   ikm1      ! local integer
573      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zsml, z1_dt   ! local scalars
574      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
575      REAL(wp), DIMENSION(jpi,jpj) :: zbetup, zbetdo, zbup, zbdo, zmsk, zdiv
576      !!----------------------------------------------------------------------
577      !
578      IF( nn_timing == 1 )  CALL timing_start('nonosc_2d')
579      !
580      zbig = 1.e+40_wp
581      zsml = 1.e-15_wp
582
583      ! clem test
584      DO jj = 2, jpjm1
585         DO ji = fs_2, fs_jpim1   ! vector opt. 
586            zdiv(ji,jj) =  - (  paa(ji,jj) - paa(ji-1,jj  )   &
587               &              + pbb(ji,jj) - pbb(ji  ,jj-1) ) 
588         END DO
589      END DO
590      CALL lbc_lnk( zdiv, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
591
592      ! Determine ice masks for before and after tracers
593      WHERE( pbef(:,:) == 0._wp .AND. paft(:,:) == 0._wp .AND. zdiv(:,:) == 0._wp )   ;   zmsk(:,:) = 0._wp
594      ELSEWHERE                                                                       ;   zmsk(:,:) = 1._wp * tmask(:,:,1)
595      END WHERE
596
597      ! Search local extrema
598      ! --------------------
599      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
600!      zbup(:,:) = MAX( pbef(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) ),   &
601!         &             paft(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) )  )
602!      zbdo(:,:) = MIN( pbef(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) ),   &
603!         &             paft(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) )  )
604      zbup(:,:) = MAX( pbef(:,:) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) ),   &
605         &             paft(:,:) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) )  )
606      zbdo(:,:) = MIN( pbef(:,:) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) ),   &
607         &             paft(:,:) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) )  )
608
609      z1_dt = 1._wp / pdt
610      DO jj = 2, jpjm1
611         DO ji = fs_2, fs_jpim1   ! vector opt.
612            !
613            zup  = MAX(   zbup(ji,jj), zbup(ji-1,jj  ), zbup(ji+1,jj  ),   &        ! search max/min in neighbourhood
614               &                       zbup(ji  ,jj-1), zbup(ji  ,jj+1)    )
615            zdo  = MIN(   zbdo(ji,jj), zbdo(ji-1,jj  ), zbdo(ji+1,jj  ),   &
616               &                       zbdo(ji  ,jj-1), zbdo(ji  ,jj+1)    )
617               !
618            zpos = MAX( 0., paa(ji-1,jj  ) ) - MIN( 0., paa(ji  ,jj  ) )   &        ! positive/negative  part of the flux
619               & + MAX( 0., pbb(ji  ,jj-1) ) - MIN( 0., pbb(ji  ,jj  ) )
620            zneg = MAX( 0., paa(ji  ,jj  ) ) - MIN( 0., paa(ji-1,jj  ) )   &
621               & + MAX( 0., pbb(ji  ,jj  ) ) - MIN( 0., pbb(ji  ,jj-1) )
622               !
623            zbt = e1e2t(ji,jj) * z1_dt                                   ! up & down beta terms
624            zbetup(ji,jj) = ( zup         - paft(ji,jj) ) / ( zpos + zsml ) * zbt
625            zbetdo(ji,jj) = ( paft(ji,jj) - zdo         ) / ( zneg + zsml ) * zbt
626         END DO
627      END DO
628      CALL lbc_lnk_multi( zbetup, 'T', 1., zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
629
630      ! monotonic flux in the i & j direction (paa & pbb)
631      ! -------------------------------------
632      DO jj = 2, jpjm1
633         DO ji = fs_2, fs_jpim1   ! vector opt.
634            zau = MIN( 1._wp , zbetdo(ji,jj) , zbetup(ji+1,jj) )
635            zbu = MIN( 1._wp , zbetup(ji,jj) , zbetdo(ji+1,jj) )
636            zcu = 0.5  + SIGN( 0.5 , paa(ji,jj) )
637            !
638            zav = MIN( 1._wp , zbetdo(ji,jj) , zbetup(ji,jj+1) )
639            zbv = MIN( 1._wp , zbetup(ji,jj) , zbetdo(ji,jj+1) )
640            zcv = 0.5  + SIGN( 0.5 , pbb(ji,jj) )
641            !
642            paa(ji,jj) = paa(ji,jj) * ( zcu * zau + ( 1._wp - zcu) * zbu )
643            pbb(ji,jj) = pbb(ji,jj) * ( zcv * zav + ( 1._wp - zcv) * zbv )
644            !
645         END DO
646      END DO
647      CALL lbc_lnk_multi( paa, 'U', -1., pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
648      !
649      IF( nn_timing == 1 )  CALL timing_stop('nonosc_2d')
650      !
651   END SUBROUTINE nonosc_2d
652
653#else
654   !!----------------------------------------------------------------------
655   !!   Default option           Dummy module      NO LIM 3.0 sea-ice model
656   !!----------------------------------------------------------------------
657#endif
658
659   !!======================================================================
660END MODULE iceadv_umx
Note: See TracBrowser for help on using the repository browser.