| 1 | MODULE limsbc |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code |
|---|
| 7 | !! 3.0 ! 2008-03 (C. Tallandier) surface module |
|---|
| 8 | !! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling |
|---|
| 9 | !! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 10 | !! ! + simplification of the ice-ocean stress calculation |
|---|
| 11 | !! 3.4 ! 2011-02 (G. Madec) dynamical allocation |
|---|
| 12 | !! - ! 2012 (D. Iovino) salt flux change |
|---|
| 13 | !! - ! 2012-05 (C. Rousset) add penetration solar flux |
|---|
| 14 | !! 3.5 ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | #if defined key_lim3 |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! 'key_lim3' LIM 3.0 sea-ice model |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! lim_sbc_alloc : allocate the limsbc arrays |
|---|
| 21 | !! lim_sbc_init : initialisation |
|---|
| 22 | !! lim_sbc_flx : updates mass, heat and salt fluxes at the ocean surface |
|---|
| 23 | !! lim_sbc_tau : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE par_oce ! ocean parameters |
|---|
| 26 | USE oce , ONLY : sshn, sshb |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE dom_oce ! ocean domain |
|---|
| 29 | USE ice ! LIM sea-ice variables |
|---|
| 30 | USE sbc_ice , ONLY : emp_oce, qns_oce, qsr_oce, qemp_oce, emp_ice, qsr_ice, qemp_ice, qevap_ice, alb_ice, tn_ice, cldf_ice, & |
|---|
| 31 | & snwice_mass, snwice_mass_b, snwice_fmass |
|---|
| 32 | USE sbc_oce , ONLY : nn_fsbc, ln_ice_embd, sfx, fr_i, qsr_tot, qns, qsr, fmmflx, emp, taum, utau, vtau |
|---|
| 33 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 34 | USE albedoice ! albedo parameters |
|---|
| 35 | USE traqsr ! add penetration of solar flux in the calculation of heat budget |
|---|
| 36 | USE domvvl ! Variable volume |
|---|
| 37 | USE limctl ! |
|---|
| 38 | USE limcons ! |
|---|
| 39 | USE bdy_oce , ONLY: ln_bdy |
|---|
| 40 | ! |
|---|
| 41 | USE in_out_manager ! I/O manager |
|---|
| 42 | USE iom ! xIO server |
|---|
| 43 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 44 | USE lib_mpp ! MPP library |
|---|
| 45 | USE wrk_nemo ! work arrays |
|---|
| 46 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 47 | |
|---|
| 48 | IMPLICIT NONE |
|---|
| 49 | PRIVATE |
|---|
| 50 | |
|---|
| 51 | PUBLIC lim_sbc_init ! called by ice_init |
|---|
| 52 | PUBLIC lim_sbc_flx ! called by ice_stp |
|---|
| 53 | PUBLIC lim_sbc_tau ! called by ice_stp |
|---|
| 54 | |
|---|
| 55 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean velocity [m/s] |
|---|
| 57 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0 , sice_0 ! cst SSS and ice salinity (levitating sea-ice) |
|---|
| 58 | |
|---|
| 59 | !! * Substitutions |
|---|
| 60 | # include "vectopt_loop_substitute.h90" |
|---|
| 61 | !!---------------------------------------------------------------------- |
|---|
| 62 | !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 63 | !! $Id$ |
|---|
| 64 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | CONTAINS |
|---|
| 67 | |
|---|
| 68 | INTEGER FUNCTION lim_sbc_alloc() |
|---|
| 69 | !!------------------------------------------------------------------- |
|---|
| 70 | !! *** ROUTINE lim_sbc_alloc *** |
|---|
| 71 | !!------------------------------------------------------------------- |
|---|
| 72 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 73 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc) |
|---|
| 74 | ! |
|---|
| 75 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc ) |
|---|
| 76 | IF( lim_sbc_alloc /= 0 ) CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays') |
|---|
| 77 | END FUNCTION lim_sbc_alloc |
|---|
| 78 | |
|---|
| 79 | |
|---|
| 80 | SUBROUTINE lim_sbc_flx( kt ) |
|---|
| 81 | !!------------------------------------------------------------------- |
|---|
| 82 | !! *** ROUTINE lim_sbc_flx *** |
|---|
| 83 | !! |
|---|
| 84 | !! ** Purpose : Update the surface ocean boundary condition for heat |
|---|
| 85 | !! salt and mass over areas where sea-ice is non-zero |
|---|
| 86 | !! |
|---|
| 87 | !! ** Action : - computes the heat and freshwater/salt fluxes |
|---|
| 88 | !! at the ice-ocean interface. |
|---|
| 89 | !! - Update the ocean sbc |
|---|
| 90 | !! |
|---|
| 91 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 92 | !! - qns : sea heat flux: non solar |
|---|
| 93 | !! - emp : freshwater budget: volume flux |
|---|
| 94 | !! - sfx : salt flux |
|---|
| 95 | !! - fr_i : ice fraction |
|---|
| 96 | !! - tn_ice : sea-ice surface temperature |
|---|
| 97 | !! - alb_ice : sea-ice albedo (recomputed only for coupled mode) |
|---|
| 98 | !! |
|---|
| 99 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 100 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 101 | !! These refs are now obsolete since everything has been revised |
|---|
| 102 | !! The ref should be Rousset et al., 2015 |
|---|
| 103 | !!--------------------------------------------------------------------- |
|---|
| 104 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 105 | ! |
|---|
| 106 | INTEGER :: ji, jj, jl, jk ! dummy loop indices |
|---|
| 107 | REAL(wp) :: zqmass ! Heat flux associated with mass exchange ice->ocean (W.m-2) |
|---|
| 108 | REAL(wp) :: zqsr ! New solar flux received by the ocean |
|---|
| 109 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: zalb_cs, zalb_os ! 3D workspace |
|---|
| 110 | REAL(wp), DIMENSION(jpi,jpj) :: zalb ! 2D workspace |
|---|
| 111 | !!--------------------------------------------------------------------- |
|---|
| 112 | |
|---|
| 113 | ! --- case we bypass ice thermodynamics --- ! |
|---|
| 114 | IF( .NOT. ln_limthd ) THEN ! we suppose ice is impermeable => ocean is isolated from atmosphere |
|---|
| 115 | hfx_in (:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:) |
|---|
| 116 | hfx_out (:,:) = ( 1._wp - at_i_b(:,:) ) * qns_oce(:,:) + qemp_oce(:,:) |
|---|
| 117 | ftr_ice (:,:,:) = 0._wp |
|---|
| 118 | emp_ice (:,:) = 0._wp |
|---|
| 119 | qemp_ice (:,:) = 0._wp |
|---|
| 120 | qevap_ice(:,:,:) = 0._wp |
|---|
| 121 | ENDIF |
|---|
| 122 | |
|---|
| 123 | ! albedo output |
|---|
| 124 | zalb(:,:) = 0._wp |
|---|
| 125 | WHERE ( at_i_b <= epsi06 ) ; zalb(:,:) = rn_alb_oce |
|---|
| 126 | ELSEWHERE ; zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b |
|---|
| 127 | END WHERE |
|---|
| 128 | IF( iom_use('icealb' ) ) CALL iom_put( "icealb" , zalb(:,:) ) ! ice albedo output |
|---|
| 129 | |
|---|
| 130 | zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + rn_alb_oce * ( 1._wp - at_i_b ) |
|---|
| 131 | IF( iom_use('albedo' ) ) CALL iom_put( "albedo" , zalb(:,:) ) ! surface albedo output |
|---|
| 132 | |
|---|
| 133 | |
|---|
| 134 | DO jj = 1, jpj |
|---|
| 135 | DO ji = 1, jpi |
|---|
| 136 | |
|---|
| 137 | !------------------------------------------! |
|---|
| 138 | ! heat flux at the ocean surface ! |
|---|
| 139 | !------------------------------------------! |
|---|
| 140 | ! Solar heat flux reaching the ocean = zqsr (W.m-2) |
|---|
| 141 | !--------------------------------------------------- |
|---|
| 142 | zqsr = qsr_tot(ji,jj) |
|---|
| 143 | DO jl = 1, jpl |
|---|
| 144 | zqsr = zqsr - a_i_b(ji,jj,jl) * ( qsr_ice(ji,jj,jl) - ftr_ice(ji,jj,jl) ) |
|---|
| 145 | END DO |
|---|
| 146 | |
|---|
| 147 | ! Total heat flux reaching the ocean = hfx_out (W.m-2) |
|---|
| 148 | !--------------------------------------------------- |
|---|
| 149 | zqmass = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC) |
|---|
| 150 | hfx_out(ji,jj) = hfx_out(ji,jj) + zqmass + zqsr |
|---|
| 151 | |
|---|
| 152 | ! Add the residual from heat diffusion equation and sublimation (W.m-2) |
|---|
| 153 | !---------------------------------------------------------------------- |
|---|
| 154 | hfx_out(ji,jj) = hfx_out(ji,jj) + hfx_err_dif(ji,jj) + & |
|---|
| 155 | & ( hfx_sub(ji,jj) - SUM( qevap_ice(ji,jj,:) * a_i_b(ji,jj,:) ) ) |
|---|
| 156 | |
|---|
| 157 | ! New qsr and qns used to compute the oceanic heat flux at the next time step |
|---|
| 158 | !---------------------------------------------------------------------------- |
|---|
| 159 | qsr(ji,jj) = zqsr |
|---|
| 160 | qns(ji,jj) = hfx_out(ji,jj) - zqsr |
|---|
| 161 | |
|---|
| 162 | ! Mass flux at the atm. surface |
|---|
| 163 | !----------------------------------- |
|---|
| 164 | wfx_sub(ji,jj) = wfx_snw_sub(ji,jj) + wfx_ice_sub(ji,jj) |
|---|
| 165 | |
|---|
| 166 | ! Mass flux at the ocean surface |
|---|
| 167 | !------------------------------------ |
|---|
| 168 | ! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED) |
|---|
| 169 | ! ------------------------------------------------------------------------------------- |
|---|
| 170 | ! The idea of this approach is that the system that we consider is the ICE-OCEAN system |
|---|
| 171 | ! Thus FW flux = External ( E-P+snow melt) |
|---|
| 172 | ! Salt flux = Exchanges in the ice-ocean system then converted into FW |
|---|
| 173 | ! Associated to Ice formation AND Ice melting |
|---|
| 174 | ! Even if i see Ice melting as a FW and SALT flux |
|---|
| 175 | ! |
|---|
| 176 | ! mass flux from ice/ocean |
|---|
| 177 | wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj) & |
|---|
| 178 | + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) + wfx_lam(ji,jj) |
|---|
| 179 | |
|---|
| 180 | IF ( ln_pnd_fw ) wfx_ice(ji,jj) = wfx_ice(ji,jj) + wfx_pnd(ji,jj) |
|---|
| 181 | |
|---|
| 182 | ! add the snow melt water to snow mass flux to the ocean |
|---|
| 183 | wfx_snw(ji,jj) = wfx_snw_sni(ji,jj) + wfx_snw_dyn(ji,jj) + wfx_snw_sum(ji,jj) |
|---|
| 184 | |
|---|
| 185 | ! mass flux at the ocean/ice interface |
|---|
| 186 | fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) + wfx_err_sub(ji,jj) ) ! F/M mass flux save at least for biogeochemical model |
|---|
| 187 | emp(ji,jj) = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj) ! mass flux + F/M mass flux (always ice/ocean mass exchange) |
|---|
| 188 | |
|---|
| 189 | |
|---|
| 190 | ! Salt flux at the ocean surface |
|---|
| 191 | !------------------------------------------ |
|---|
| 192 | sfx(ji,jj) = sfx_bog(ji,jj) + sfx_bom(ji,jj) + sfx_sum(ji,jj) + sfx_sni(ji,jj) + sfx_opw(ji,jj) & |
|---|
| 193 | & + sfx_res(ji,jj) + sfx_dyn(ji,jj) + sfx_bri(ji,jj) + sfx_sub(ji,jj) + sfx_lam(ji,jj) |
|---|
| 194 | |
|---|
| 195 | ! Mass of snow and ice per unit area |
|---|
| 196 | !---------------------------------------- |
|---|
| 197 | ! save mass from the previous ice time step |
|---|
| 198 | snwice_mass_b(ji,jj) = snwice_mass(ji,jj) |
|---|
| 199 | ! new mass per unit area |
|---|
| 200 | snwice_mass (ji,jj) = tmask(ji,jj,1) * ( rhosn * vt_s(ji,jj) + rhoic * vt_i(ji,jj) ) |
|---|
| 201 | ! time evolution of snow+ice mass |
|---|
| 202 | snwice_fmass (ji,jj) = ( snwice_mass(ji,jj) - snwice_mass_b(ji,jj) ) * r1_rdtice |
|---|
| 203 | |
|---|
| 204 | END DO |
|---|
| 205 | END DO |
|---|
| 206 | |
|---|
| 207 | !-----------------------------------------------! |
|---|
| 208 | ! Storing the transmitted variables ! |
|---|
| 209 | !-----------------------------------------------! |
|---|
| 210 | fr_i (:,:) = at_i(:,:) ! Sea-ice fraction |
|---|
| 211 | tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature |
|---|
| 212 | |
|---|
| 213 | !------------------------------------------------------------------------! |
|---|
| 214 | ! Snow/ice albedo (only if sent to coupler, useless in forced mode) ! |
|---|
| 215 | !------------------------------------------------------------------------! |
|---|
| 216 | CALL albedo_ice( t_su, ht_i, ht_s, a_ip_frac, h_ip, ln_pnd_rad, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos |
|---|
| 217 | |
|---|
| 218 | alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:) |
|---|
| 219 | |
|---|
| 220 | ! conservation test |
|---|
| 221 | IF( ln_limdiachk .AND. .NOT. ln_bdy) CALL lim_cons_final( 'limsbc' ) |
|---|
| 222 | |
|---|
| 223 | ! control prints |
|---|
| 224 | IF( ln_limctl ) CALL lim_prt( kt, iiceprt, jiceprt, 3, ' - Final state lim_sbc - ' ) |
|---|
| 225 | IF( ln_ctl ) CALL lim_prt3D( 'limsbc' ) |
|---|
| 226 | |
|---|
| 227 | END SUBROUTINE lim_sbc_flx |
|---|
| 228 | |
|---|
| 229 | |
|---|
| 230 | SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce ) |
|---|
| 231 | !!------------------------------------------------------------------- |
|---|
| 232 | !! *** ROUTINE lim_sbc_tau *** |
|---|
| 233 | !! |
|---|
| 234 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 235 | !! |
|---|
| 236 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 237 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 238 | !! (*rho*Cd) at T-point (C-grid) or I-point (B-grid) |
|---|
| 239 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 240 | !! - update the modulus of stress at ocean surface |
|---|
| 241 | !! taum = (1-a) * taum + a * tmod_io * | U_ice-U_oce | |
|---|
| 242 | !! * at each ocean time step (every kt): |
|---|
| 243 | !! compute linearized ice-ocean stresses as |
|---|
| 244 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 245 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 246 | !! |
|---|
| 247 | !! NB: - ice-ocean rotation angle no more allowed |
|---|
| 248 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 249 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 250 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton... |
|---|
| 251 | !! |
|---|
| 252 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 253 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 254 | !!--------------------------------------------------------------------- |
|---|
| 255 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 256 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 257 | ! |
|---|
| 258 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 259 | REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 260 | REAL(wp) :: zat_v, zvtau_ice, zv_t, zrhoco ! - - |
|---|
| 261 | !!--------------------------------------------------------------------- |
|---|
| 262 | zrhoco = rau0 * rn_cio |
|---|
| 263 | ! |
|---|
| 264 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 265 | DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 266 | DO ji = fs_2, fs_jpim1 |
|---|
| 267 | ! ! 2*(U_ice-U_oce) at T-point |
|---|
| 268 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) |
|---|
| 269 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 270 | ! ! |U_ice-U_oce|^2 |
|---|
| 271 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) |
|---|
| 272 | ! ! update the ocean stress modulus |
|---|
| 273 | taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * zrhoco * zmodt |
|---|
| 274 | tmod_io(ji,jj) = zrhoco * SQRT( zmodt ) ! rhoco * |U_ice-U_oce| at T-point |
|---|
| 275 | END DO |
|---|
| 276 | END DO |
|---|
| 277 | CALL lbc_lnk_multi( taum, 'T', 1., tmod_io, 'T', 1. ) |
|---|
| 278 | ! |
|---|
| 279 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 280 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 281 | ! |
|---|
| 282 | ENDIF |
|---|
| 283 | ! |
|---|
| 284 | ! !== every ocean time-step ==! |
|---|
| 285 | ! |
|---|
| 286 | DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle |
|---|
| 287 | DO ji = fs_2, fs_jpim1 ! Vect. Opt. |
|---|
| 288 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points |
|---|
| 289 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp |
|---|
| 290 | ! ! linearized quadratic drag formulation |
|---|
| 291 | zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 292 | zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 293 | ! ! stresses at the ocean surface |
|---|
| 294 | utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice |
|---|
| 295 | vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice |
|---|
| 296 | END DO |
|---|
| 297 | END DO |
|---|
| 298 | CALL lbc_lnk_multi( utau, 'U', -1., vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 299 | ! |
|---|
| 300 | ! |
|---|
| 301 | END SUBROUTINE lim_sbc_tau |
|---|
| 302 | |
|---|
| 303 | |
|---|
| 304 | SUBROUTINE lim_sbc_init |
|---|
| 305 | !!------------------------------------------------------------------- |
|---|
| 306 | !! *** ROUTINE lim_sbc_init *** |
|---|
| 307 | !! |
|---|
| 308 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 309 | !! the temporal evolution of key variables |
|---|
| 310 | !! |
|---|
| 311 | !! ** input : Namelist namicedia |
|---|
| 312 | !!------------------------------------------------------------------- |
|---|
| 313 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 314 | REAL(wp) :: zcoefu, zcoefv, zcoeff ! local scalar |
|---|
| 315 | !!------------------------------------------------------------------- |
|---|
| 316 | ! |
|---|
| 317 | IF(lwp) WRITE(numout,*) |
|---|
| 318 | IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition' |
|---|
| 319 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ ' |
|---|
| 320 | |
|---|
| 321 | ! ! allocate lim_sbc array |
|---|
| 322 | IF( lim_sbc_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' ) |
|---|
| 323 | ! |
|---|
| 324 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 325 | sice_0(:,:) = sice |
|---|
| 326 | ! ! decrease ocean & ice reference salinities in the Baltic Sea area |
|---|
| 327 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 328 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 329 | soce_0(:,:) = 4._wp |
|---|
| 330 | sice_0(:,:) = 2._wp |
|---|
| 331 | END WHERE |
|---|
| 332 | ! |
|---|
| 333 | IF( .NOT. ln_rstart ) THEN |
|---|
| 334 | ! |
|---|
| 335 | snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) ! snow+ice mass |
|---|
| 336 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 337 | ! |
|---|
| 338 | IF( ln_ice_embd ) THEN ! embedded sea-ice: deplete the initial ssh below sea-ice area |
|---|
| 339 | sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 340 | sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 341 | |
|---|
| 342 | !!gm I really don't like this stuff here... Find a way to put that elsewhere or differently |
|---|
| 343 | !!gm |
|---|
| 344 | IF( .NOT.ln_linssh ) THEN |
|---|
| 345 | DO jk = 1,jpkm1 ! adjust initial vertical scale factors |
|---|
| 346 | e3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 347 | e3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 348 | END DO |
|---|
| 349 | e3t_a(:,:,:) = e3t_b(:,:,:) |
|---|
| 350 | ! Reconstruction of all vertical scale factors at now and before time-steps |
|---|
| 351 | ! ========================================================================= |
|---|
| 352 | ! Horizontal scale factor interpolations |
|---|
| 353 | ! -------------------------------------- |
|---|
| 354 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3u_b(:,:,:), 'U' ) |
|---|
| 355 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3v_b(:,:,:), 'V' ) |
|---|
| 356 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3u_n(:,:,:), 'U' ) |
|---|
| 357 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3v_n(:,:,:), 'V' ) |
|---|
| 358 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3f_n(:,:,:), 'F' ) |
|---|
| 359 | ! Vertical scale factor interpolations |
|---|
| 360 | ! ------------------------------------ |
|---|
| 361 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3w_n (:,:,:), 'W' ) |
|---|
| 362 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3uw_n(:,:,:), 'UW' ) |
|---|
| 363 | CALL dom_vvl_interpol( e3v_n(:,:,:), e3vw_n(:,:,:), 'VW' ) |
|---|
| 364 | CALL dom_vvl_interpol( e3u_b(:,:,:), e3uw_b(:,:,:), 'UW' ) |
|---|
| 365 | CALL dom_vvl_interpol( e3v_b(:,:,:), e3vw_b(:,:,:), 'VW' ) |
|---|
| 366 | ! t- and w- points depth |
|---|
| 367 | ! ---------------------- |
|---|
| 368 | !!gm not sure of that.... |
|---|
| 369 | gdept_n(:,:,1) = 0.5_wp * e3w_n(:,:,1) |
|---|
| 370 | gdepw_n(:,:,1) = 0.0_wp |
|---|
| 371 | gde3w_n(:,:,1) = gdept_n(:,:,1) - sshn(:,:) |
|---|
| 372 | DO jk = 2, jpk |
|---|
| 373 | gdept_n(:,:,jk) = gdept_n(:,:,jk-1) + e3w_n(:,:,jk) |
|---|
| 374 | gdepw_n(:,:,jk) = gdepw_n(:,:,jk-1) + e3t_n(:,:,jk-1) |
|---|
| 375 | gde3w_n(:,:,jk) = gdept_n(:,:,jk ) - sshn (:,:) |
|---|
| 376 | END DO |
|---|
| 377 | ENDIF |
|---|
| 378 | ENDIF |
|---|
| 379 | ENDIF ! .NOT. ln_rstart |
|---|
| 380 | ! |
|---|
| 381 | END SUBROUTINE lim_sbc_init |
|---|
| 382 | |
|---|
| 383 | #else |
|---|
| 384 | !!---------------------------------------------------------------------- |
|---|
| 385 | !! Default option : Dummy module NO LIM 3.0 sea-ice model |
|---|
| 386 | !!---------------------------------------------------------------------- |
|---|
| 387 | CONTAINS |
|---|
| 388 | SUBROUTINE lim_sbc ! Dummy routine |
|---|
| 389 | END SUBROUTINE lim_sbc |
|---|
| 390 | #endif |
|---|
| 391 | |
|---|
| 392 | !!====================================================================== |
|---|
| 393 | END MODULE limsbc |
|---|
