| 1 | MODULE limsbc |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code |
|---|
| 7 | !! 3.0 ! 2008-03 (C. Tallandier) surface module |
|---|
| 8 | !! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling |
|---|
| 9 | !! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 10 | !! ! + simplification of the ice-ocean stress calculation |
|---|
| 11 | !! 3.4 ! 2011-02 (G. Madec) dynamical allocation |
|---|
| 12 | !! - ! 2012 (D. Iovino) salt flux change |
|---|
| 13 | !! - ! 2012-05 (C. Rousset) add penetration solar flux |
|---|
| 14 | !! 3.5 ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | #if defined key_lim3 |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! 'key_lim3' LIM 3.0 sea-ice model |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! lim_sbc_alloc : allocate the limsbc arrays |
|---|
| 21 | !! lim_sbc_init : initialisation |
|---|
| 22 | !! lim_sbc_flx : updates mass, heat and salt fluxes at the ocean surface |
|---|
| 23 | !! lim_sbc_tau : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE par_oce ! ocean parameters |
|---|
| 26 | USE oce , ONLY : sshn, sshb |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE dom_oce ! ocean domain |
|---|
| 29 | USE ice ! LIM sea-ice variables |
|---|
| 30 | USE sbc_ice , ONLY : emp_oce, qns_oce, qsr_oce, qemp_oce, emp_ice, qsr_ice, qemp_ice, qevap_ice, alb_ice, tn_ice, cldf_ice, & |
|---|
| 31 | & snwice_mass, snwice_mass_b, snwice_fmass |
|---|
| 32 | USE sbc_oce , ONLY : nn_fsbc, ln_ice_embd, sfx, fr_i, qsr_tot, qns, qsr, fmmflx, emp, taum, utau, vtau |
|---|
| 33 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 34 | USE albedoice ! albedo parameters |
|---|
| 35 | USE traqsr ! add penetration of solar flux in the calculation of heat budget |
|---|
| 36 | USE domvvl ! Variable volume |
|---|
| 37 | USE limctl ! |
|---|
| 38 | USE limcons ! |
|---|
| 39 | USE bdy_oce , ONLY: ln_bdy |
|---|
| 40 | ! |
|---|
| 41 | USE in_out_manager ! I/O manager |
|---|
| 42 | USE iom ! xIO server |
|---|
| 43 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 44 | USE lib_mpp ! MPP library |
|---|
| 45 | USE wrk_nemo ! work arrays |
|---|
| 46 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 47 | |
|---|
| 48 | IMPLICIT NONE |
|---|
| 49 | PRIVATE |
|---|
| 50 | |
|---|
| 51 | PUBLIC lim_sbc_init ! called by ice_init |
|---|
| 52 | PUBLIC lim_sbc_flx ! called by ice_stp |
|---|
| 53 | PUBLIC lim_sbc_tau ! called by ice_stp |
|---|
| 54 | |
|---|
| 55 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean velocity [m/s] |
|---|
| 57 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0 , sice_0 ! cst SSS and ice salinity (levitating sea-ice) |
|---|
| 58 | |
|---|
| 59 | !! * Substitutions |
|---|
| 60 | # include "vectopt_loop_substitute.h90" |
|---|
| 61 | !!---------------------------------------------------------------------- |
|---|
| 62 | !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 63 | !! $Id$ |
|---|
| 64 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | CONTAINS |
|---|
| 67 | |
|---|
| 68 | INTEGER FUNCTION lim_sbc_alloc() |
|---|
| 69 | !!------------------------------------------------------------------- |
|---|
| 70 | !! *** ROUTINE lim_sbc_alloc *** |
|---|
| 71 | !!------------------------------------------------------------------- |
|---|
| 72 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 73 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc) |
|---|
| 74 | ! |
|---|
| 75 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc ) |
|---|
| 76 | IF( lim_sbc_alloc /= 0 ) CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays') |
|---|
| 77 | END FUNCTION lim_sbc_alloc |
|---|
| 78 | |
|---|
| 79 | |
|---|
| 80 | SUBROUTINE lim_sbc_flx( kt ) |
|---|
| 81 | !!------------------------------------------------------------------- |
|---|
| 82 | !! *** ROUTINE lim_sbc_flx *** |
|---|
| 83 | !! |
|---|
| 84 | !! ** Purpose : Update the surface ocean boundary condition for heat |
|---|
| 85 | !! salt and mass over areas where sea-ice is non-zero |
|---|
| 86 | !! |
|---|
| 87 | !! ** Action : - computes the heat and freshwater/salt fluxes |
|---|
| 88 | !! at the ice-ocean interface. |
|---|
| 89 | !! - Update the ocean sbc |
|---|
| 90 | !! |
|---|
| 91 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 92 | !! - qns : sea heat flux: non solar |
|---|
| 93 | !! - emp : freshwater budget: volume flux |
|---|
| 94 | !! - sfx : salt flux |
|---|
| 95 | !! - fr_i : ice fraction |
|---|
| 96 | !! - tn_ice : sea-ice surface temperature |
|---|
| 97 | !! - alb_ice : sea-ice albedo (recomputed only for coupled mode) |
|---|
| 98 | !! |
|---|
| 99 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 100 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 101 | !! These refs are now obsolete since everything has been revised |
|---|
| 102 | !! The ref should be Rousset et al., 2015 |
|---|
| 103 | !!--------------------------------------------------------------------- |
|---|
| 104 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 105 | ! |
|---|
| 106 | INTEGER :: ji, jj, jl, jk ! dummy loop indices |
|---|
| 107 | REAL(wp) :: zqmass ! Heat flux associated with mass exchange ice->ocean (W.m-2) |
|---|
| 108 | REAL(wp) :: zqsr ! New solar flux received by the ocean |
|---|
| 109 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_cs, zalb_os ! 3D workspace |
|---|
| 110 | REAL(wp), POINTER, DIMENSION(:,:) :: zalb ! 2D workspace |
|---|
| 111 | !!--------------------------------------------------------------------- |
|---|
| 112 | |
|---|
| 113 | ! --- case we bypass ice thermodynamics --- ! |
|---|
| 114 | IF( .NOT. ln_limthd ) THEN ! we suppose ice is impermeable => ocean is isolated from atmosphere |
|---|
| 115 | hfx_in (:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:) |
|---|
| 116 | hfx_out (:,:) = ( 1._wp - at_i_b(:,:) ) * qns_oce(:,:) + qemp_oce(:,:) |
|---|
| 117 | ftr_ice (:,:,:) = 0._wp |
|---|
| 118 | emp_ice (:,:) = 0._wp |
|---|
| 119 | qemp_ice (:,:) = 0._wp |
|---|
| 120 | qevap_ice(:,:,:) = 0._wp |
|---|
| 121 | ENDIF |
|---|
| 122 | |
|---|
| 123 | ! albedo output |
|---|
| 124 | CALL wrk_alloc( jpi,jpj, zalb ) |
|---|
| 125 | |
|---|
| 126 | zalb(:,:) = 0._wp |
|---|
| 127 | WHERE ( at_i_b <= epsi06 ) ; zalb(:,:) = rn_alb_oce |
|---|
| 128 | ELSEWHERE ; zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b |
|---|
| 129 | END WHERE |
|---|
| 130 | IF( iom_use('icealb' ) ) CALL iom_put( "icealb" , zalb(:,:) ) ! ice albedo output |
|---|
| 131 | |
|---|
| 132 | zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + rn_alb_oce * ( 1._wp - at_i_b ) |
|---|
| 133 | IF( iom_use('albedo' ) ) CALL iom_put( "albedo" , zalb(:,:) ) ! surface albedo output |
|---|
| 134 | |
|---|
| 135 | CALL wrk_dealloc( jpi,jpj, zalb ) |
|---|
| 136 | |
|---|
| 137 | DO jj = 1, jpj |
|---|
| 138 | DO ji = 1, jpi |
|---|
| 139 | |
|---|
| 140 | !------------------------------------------! |
|---|
| 141 | ! heat flux at the ocean surface ! |
|---|
| 142 | !------------------------------------------! |
|---|
| 143 | ! Solar heat flux reaching the ocean = zqsr (W.m-2) |
|---|
| 144 | !--------------------------------------------------- |
|---|
| 145 | zqsr = qsr_tot(ji,jj) |
|---|
| 146 | DO jl = 1, jpl |
|---|
| 147 | zqsr = zqsr - a_i_b(ji,jj,jl) * ( qsr_ice(ji,jj,jl) - ftr_ice(ji,jj,jl) ) |
|---|
| 148 | END DO |
|---|
| 149 | |
|---|
| 150 | ! Total heat flux reaching the ocean = hfx_out (W.m-2) |
|---|
| 151 | !--------------------------------------------------- |
|---|
| 152 | zqmass = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC) |
|---|
| 153 | hfx_out(ji,jj) = hfx_out(ji,jj) + zqmass + zqsr |
|---|
| 154 | |
|---|
| 155 | ! Add the residual from heat diffusion equation and sublimation (W.m-2) |
|---|
| 156 | !---------------------------------------------------------------------- |
|---|
| 157 | hfx_out(ji,jj) = hfx_out(ji,jj) + hfx_err_dif(ji,jj) + & |
|---|
| 158 | & ( hfx_sub(ji,jj) - SUM( qevap_ice(ji,jj,:) * a_i_b(ji,jj,:) ) ) |
|---|
| 159 | |
|---|
| 160 | ! New qsr and qns used to compute the oceanic heat flux at the next time step |
|---|
| 161 | !---------------------------------------------------------------------------- |
|---|
| 162 | qsr(ji,jj) = zqsr |
|---|
| 163 | qns(ji,jj) = hfx_out(ji,jj) - zqsr |
|---|
| 164 | |
|---|
| 165 | ! Mass flux at the atm. surface |
|---|
| 166 | !----------------------------------- |
|---|
| 167 | wfx_sub(ji,jj) = wfx_snw_sub(ji,jj) + wfx_ice_sub(ji,jj) |
|---|
| 168 | |
|---|
| 169 | ! Mass flux at the ocean surface |
|---|
| 170 | !------------------------------------ |
|---|
| 171 | ! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED) |
|---|
| 172 | ! ------------------------------------------------------------------------------------- |
|---|
| 173 | ! The idea of this approach is that the system that we consider is the ICE-OCEAN system |
|---|
| 174 | ! Thus FW flux = External ( E-P+snow melt) |
|---|
| 175 | ! Salt flux = Exchanges in the ice-ocean system then converted into FW |
|---|
| 176 | ! Associated to Ice formation AND Ice melting |
|---|
| 177 | ! Even if i see Ice melting as a FW and SALT flux |
|---|
| 178 | ! |
|---|
| 179 | ! mass flux from ice/ocean |
|---|
| 180 | wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj) & |
|---|
| 181 | + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) + wfx_lam(ji,jj) |
|---|
| 182 | |
|---|
| 183 | IF ( ln_pnd_fw ) wfx_ice(ji,jj) = wfx_ice(ji,jj) + wfx_pnd(ji,jj) |
|---|
| 184 | |
|---|
| 185 | ! add the snow melt water to snow mass flux to the ocean |
|---|
| 186 | wfx_snw(ji,jj) = wfx_snw_sni(ji,jj) + wfx_snw_dyn(ji,jj) + wfx_snw_sum(ji,jj) |
|---|
| 187 | |
|---|
| 188 | ! mass flux at the ocean/ice interface |
|---|
| 189 | fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) + wfx_err_sub(ji,jj) ) ! F/M mass flux save at least for biogeochemical model |
|---|
| 190 | emp(ji,jj) = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj) ! mass flux + F/M mass flux (always ice/ocean mass exchange) |
|---|
| 191 | |
|---|
| 192 | |
|---|
| 193 | ! Salt flux at the ocean surface |
|---|
| 194 | !------------------------------------------ |
|---|
| 195 | sfx(ji,jj) = sfx_bog(ji,jj) + sfx_bom(ji,jj) + sfx_sum(ji,jj) + sfx_sni(ji,jj) + sfx_opw(ji,jj) & |
|---|
| 196 | & + sfx_res(ji,jj) + sfx_dyn(ji,jj) + sfx_bri(ji,jj) + sfx_sub(ji,jj) + sfx_lam(ji,jj) |
|---|
| 197 | |
|---|
| 198 | ! Mass of snow and ice per unit area |
|---|
| 199 | !---------------------------------------- |
|---|
| 200 | ! save mass from the previous ice time step |
|---|
| 201 | snwice_mass_b(ji,jj) = snwice_mass(ji,jj) |
|---|
| 202 | ! new mass per unit area |
|---|
| 203 | snwice_mass (ji,jj) = tmask(ji,jj,1) * ( rhosn * vt_s(ji,jj) + rhoic * vt_i(ji,jj) ) |
|---|
| 204 | ! time evolution of snow+ice mass |
|---|
| 205 | snwice_fmass (ji,jj) = ( snwice_mass(ji,jj) - snwice_mass_b(ji,jj) ) * r1_rdtice |
|---|
| 206 | |
|---|
| 207 | END DO |
|---|
| 208 | END DO |
|---|
| 209 | |
|---|
| 210 | !-----------------------------------------------! |
|---|
| 211 | ! Storing the transmitted variables ! |
|---|
| 212 | !-----------------------------------------------! |
|---|
| 213 | fr_i (:,:) = at_i(:,:) ! Sea-ice fraction |
|---|
| 214 | tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature |
|---|
| 215 | |
|---|
| 216 | !------------------------------------------------------------------------! |
|---|
| 217 | ! Snow/ice albedo (only if sent to coupler, useless in forced mode) ! |
|---|
| 218 | !------------------------------------------------------------------------! |
|---|
| 219 | CALL wrk_alloc( jpi,jpj,jpl, zalb_cs, zalb_os ) |
|---|
| 220 | CALL albedo_ice( t_su, ht_i, ht_s, a_ip_frac, h_ip, ln_pnd_rad, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos |
|---|
| 221 | |
|---|
| 222 | alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:) |
|---|
| 223 | CALL wrk_dealloc( jpi,jpj,jpl, zalb_cs, zalb_os ) |
|---|
| 224 | |
|---|
| 225 | ! conservation test |
|---|
| 226 | IF( ln_limdiachk .AND. .NOT. ln_bdy) CALL lim_cons_final( 'limsbc' ) |
|---|
| 227 | |
|---|
| 228 | ! control prints |
|---|
| 229 | IF( ln_limctl ) CALL lim_prt( kt, iiceprt, jiceprt, 3, ' - Final state lim_sbc - ' ) |
|---|
| 230 | IF( ln_ctl ) CALL lim_prt3D( 'limsbc' ) |
|---|
| 231 | |
|---|
| 232 | END SUBROUTINE lim_sbc_flx |
|---|
| 233 | |
|---|
| 234 | |
|---|
| 235 | SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce ) |
|---|
| 236 | !!------------------------------------------------------------------- |
|---|
| 237 | !! *** ROUTINE lim_sbc_tau *** |
|---|
| 238 | !! |
|---|
| 239 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 240 | !! |
|---|
| 241 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 242 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 243 | !! (*rho*Cd) at T-point (C-grid) or I-point (B-grid) |
|---|
| 244 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 245 | !! - update the modulus of stress at ocean surface |
|---|
| 246 | !! taum = (1-a) * taum + a * tmod_io * | U_ice-U_oce | |
|---|
| 247 | !! * at each ocean time step (every kt): |
|---|
| 248 | !! compute linearized ice-ocean stresses as |
|---|
| 249 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 250 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 251 | !! |
|---|
| 252 | !! NB: - ice-ocean rotation angle no more allowed |
|---|
| 253 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 254 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 255 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton... |
|---|
| 256 | !! |
|---|
| 257 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 258 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 259 | !!--------------------------------------------------------------------- |
|---|
| 260 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 261 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 262 | ! |
|---|
| 263 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 264 | REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 265 | REAL(wp) :: zat_v, zvtau_ice, zv_t, zrhoco ! - - |
|---|
| 266 | !!--------------------------------------------------------------------- |
|---|
| 267 | zrhoco = rau0 * rn_cio |
|---|
| 268 | ! |
|---|
| 269 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 270 | DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 271 | DO ji = fs_2, fs_jpim1 |
|---|
| 272 | ! ! 2*(U_ice-U_oce) at T-point |
|---|
| 273 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) |
|---|
| 274 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 275 | ! ! |U_ice-U_oce|^2 |
|---|
| 276 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) |
|---|
| 277 | ! ! update the ocean stress modulus |
|---|
| 278 | taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * zrhoco * zmodt |
|---|
| 279 | tmod_io(ji,jj) = zrhoco * SQRT( zmodt ) ! rhoco * |U_ice-U_oce| at T-point |
|---|
| 280 | END DO |
|---|
| 281 | END DO |
|---|
| 282 | CALL lbc_lnk_multi( taum, 'T', 1., tmod_io, 'T', 1. ) |
|---|
| 283 | ! |
|---|
| 284 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 285 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 286 | ! |
|---|
| 287 | ENDIF |
|---|
| 288 | ! |
|---|
| 289 | ! !== every ocean time-step ==! |
|---|
| 290 | ! |
|---|
| 291 | DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle |
|---|
| 292 | DO ji = fs_2, fs_jpim1 ! Vect. Opt. |
|---|
| 293 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points |
|---|
| 294 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp |
|---|
| 295 | ! ! linearized quadratic drag formulation |
|---|
| 296 | zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 297 | zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 298 | ! ! stresses at the ocean surface |
|---|
| 299 | utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice |
|---|
| 300 | vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice |
|---|
| 301 | END DO |
|---|
| 302 | END DO |
|---|
| 303 | CALL lbc_lnk_multi( utau, 'U', -1., vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 304 | ! |
|---|
| 305 | ! |
|---|
| 306 | END SUBROUTINE lim_sbc_tau |
|---|
| 307 | |
|---|
| 308 | |
|---|
| 309 | SUBROUTINE lim_sbc_init |
|---|
| 310 | !!------------------------------------------------------------------- |
|---|
| 311 | !! *** ROUTINE lim_sbc_init *** |
|---|
| 312 | !! |
|---|
| 313 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 314 | !! the temporal evolution of key variables |
|---|
| 315 | !! |
|---|
| 316 | !! ** input : Namelist namicedia |
|---|
| 317 | !!------------------------------------------------------------------- |
|---|
| 318 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 319 | REAL(wp) :: zcoefu, zcoefv, zcoeff ! local scalar |
|---|
| 320 | !!------------------------------------------------------------------- |
|---|
| 321 | ! |
|---|
| 322 | IF(lwp) WRITE(numout,*) |
|---|
| 323 | IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition' |
|---|
| 324 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ ' |
|---|
| 325 | |
|---|
| 326 | ! ! allocate lim_sbc array |
|---|
| 327 | IF( lim_sbc_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' ) |
|---|
| 328 | ! |
|---|
| 329 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 330 | sice_0(:,:) = sice |
|---|
| 331 | ! ! decrease ocean & ice reference salinities in the Baltic Sea area |
|---|
| 332 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 333 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 334 | soce_0(:,:) = 4._wp |
|---|
| 335 | sice_0(:,:) = 2._wp |
|---|
| 336 | END WHERE |
|---|
| 337 | ! |
|---|
| 338 | IF( .NOT. ln_rstart ) THEN |
|---|
| 339 | ! |
|---|
| 340 | snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) ! snow+ice mass |
|---|
| 341 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 342 | ! |
|---|
| 343 | IF( ln_ice_embd ) THEN ! embedded sea-ice: deplete the initial ssh below sea-ice area |
|---|
| 344 | sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 345 | sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 346 | |
|---|
| 347 | !!gm I really don't like this stuff here... Find a way to put that elsewhere or differently |
|---|
| 348 | !!gm |
|---|
| 349 | IF( .NOT.ln_linssh ) THEN |
|---|
| 350 | DO jk = 1,jpkm1 ! adjust initial vertical scale factors |
|---|
| 351 | e3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 352 | e3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 353 | END DO |
|---|
| 354 | e3t_a(:,:,:) = e3t_b(:,:,:) |
|---|
| 355 | ! Reconstruction of all vertical scale factors at now and before time-steps |
|---|
| 356 | ! ========================================================================= |
|---|
| 357 | ! Horizontal scale factor interpolations |
|---|
| 358 | ! -------------------------------------- |
|---|
| 359 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3u_b(:,:,:), 'U' ) |
|---|
| 360 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3v_b(:,:,:), 'V' ) |
|---|
| 361 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3u_n(:,:,:), 'U' ) |
|---|
| 362 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3v_n(:,:,:), 'V' ) |
|---|
| 363 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3f_n(:,:,:), 'F' ) |
|---|
| 364 | ! Vertical scale factor interpolations |
|---|
| 365 | ! ------------------------------------ |
|---|
| 366 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3w_n (:,:,:), 'W' ) |
|---|
| 367 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3uw_n(:,:,:), 'UW' ) |
|---|
| 368 | CALL dom_vvl_interpol( e3v_n(:,:,:), e3vw_n(:,:,:), 'VW' ) |
|---|
| 369 | CALL dom_vvl_interpol( e3u_b(:,:,:), e3uw_b(:,:,:), 'UW' ) |
|---|
| 370 | CALL dom_vvl_interpol( e3v_b(:,:,:), e3vw_b(:,:,:), 'VW' ) |
|---|
| 371 | ! t- and w- points depth |
|---|
| 372 | ! ---------------------- |
|---|
| 373 | !!gm not sure of that.... |
|---|
| 374 | gdept_n(:,:,1) = 0.5_wp * e3w_n(:,:,1) |
|---|
| 375 | gdepw_n(:,:,1) = 0.0_wp |
|---|
| 376 | gde3w_n(:,:,1) = gdept_n(:,:,1) - sshn(:,:) |
|---|
| 377 | DO jk = 2, jpk |
|---|
| 378 | gdept_n(:,:,jk) = gdept_n(:,:,jk-1) + e3w_n(:,:,jk) |
|---|
| 379 | gdepw_n(:,:,jk) = gdepw_n(:,:,jk-1) + e3t_n(:,:,jk-1) |
|---|
| 380 | gde3w_n(:,:,jk) = gdept_n(:,:,jk ) - sshn (:,:) |
|---|
| 381 | END DO |
|---|
| 382 | ENDIF |
|---|
| 383 | ENDIF |
|---|
| 384 | ENDIF ! .NOT. ln_rstart |
|---|
| 385 | ! |
|---|
| 386 | END SUBROUTINE lim_sbc_init |
|---|
| 387 | |
|---|
| 388 | #else |
|---|
| 389 | !!---------------------------------------------------------------------- |
|---|
| 390 | !! Default option : Dummy module NO LIM 3.0 sea-ice model |
|---|
| 391 | !!---------------------------------------------------------------------- |
|---|
| 392 | CONTAINS |
|---|
| 393 | SUBROUTINE lim_sbc ! Dummy routine |
|---|
| 394 | END SUBROUTINE lim_sbc |
|---|
| 395 | #endif |
|---|
| 396 | |
|---|
| 397 | !!====================================================================== |
|---|
| 398 | END MODULE limsbc |
|---|
