New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 8371

Last change on this file since 8371 was 8371, checked in by clem, 7 years ago

minor updates
  • Property svn:keywords set to Id
File size: 36.4 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! sea-ice variables
25   USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, qns_tot, qsr_tot, sprecip, ln_cpl
26   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
27      &                 fr1_i0, fr2_i0, nn_limflx
28   USE thd_ice        ! thermodynamic sea-ice variables
29   USE limthd_dif     ! vertical diffusion
30   USE limthd_dh      ! ice-snow growth and melt
31   USE limthd_da      ! lateral melting
32   USE limthd_sal     ! ice salinity
33   USE limthd_ent     ! ice enthalpy redistribution
34   USE limthd_lac     ! lateral accretion
35   USE limitd_th      ! remapping thickness distribution
36   USE limtab         ! 1D <==> 2D transformation
37   USE limvar         !
38   USE limcons        ! conservation tests
39   USE limctl         ! control print
40   !
41   USE in_out_manager ! I/O manager
42   USE lbclnk         ! lateral boundary condition - MPP links
43   USE lib_mpp        ! MPP library
44   USE wrk_nemo       ! work arrays
45   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
46   USE timing         ! Timing
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   lim_thd         ! called by limstp module
52   PUBLIC   lim_thd_init    ! called by ice_init
53
54   !! * Substitutions
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE lim_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE lim_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - Initialisation of some variables
70      !!             - Some preliminary computation (oceanic heat flux
71      !!               at the ice base, snow acc.,heat budget of the leads)
72      !!             - selection of the icy points and put them in an array
73      !!             - call lim_thd_dif  for vertical heat diffusion
74      !!             - call lim_thd_dh   for vertical ice growth and melt
75      !!             - call lim_thd_ent  for enthalpy remapping
76      !!             - call lim_thd_sal  for ice desalination
77      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
78      !!             - back to the geographic grid
79      !!     
80      !! ** References :
81      !!---------------------------------------------------------------------
82      INTEGER, INTENT(in) :: kt    ! number of iteration
83      !
84      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
85      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg
86      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
87      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
88      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
89      REAL(wp), POINTER, DIMENSION(:,:) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
90      !
91      !!-------------------------------------------------------------------
92
93      IF( nn_timing == 1 )   CALL timing_start('limthd')
94
95      CALL wrk_alloc( jpi,jpj, zu_io, zv_io, zfric )
96
97      IF( kt == nit000 .AND. lwp ) THEN
98         WRITE(numout,*)'' 
99         WRITE(numout,*)' lim_thd '
100         WRITE(numout,*)' ~~~~~~~~'
101      ENDIF
102     
103      ! conservation test
104      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
105
106      CALL lim_var_glo2eqv
107
108      !---------------------------------------------!
109      ! computation of friction velocity at T points
110      !---------------------------------------------!
111      IF( ln_limdyn ) THEN
112         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
113         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
114         DO jj = 2, jpjm1 
115            DO ji = fs_2, fs_jpim1
116               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
117                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
118                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
119            END DO
120         END DO
121      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
122         DO jj = 2, jpjm1
123            DO ji = fs_2, fs_jpim1
124               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
125                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
126                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
127            END DO
128         END DO
129      ENDIF
130      CALL lbc_lnk( zfric, 'T',  1. )
131      !
132      ftr_ice(:,:,:) = 0._wp  ! initialization (part of solar radiation transmitted through the ice)
133
134      !--------------------------------------------------------------------!
135      ! Partial computation of forcing for the thermodynamic sea ice model
136      !--------------------------------------------------------------------!
137      DO jj = 1, jpj
138         DO ji = 1, jpi
139            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
140            !
141            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
142            !           !  practically no "direct lateral ablation"
143            !           
144            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
145            !           !  temperature and turbulent mixing (McPhee, 1992)
146            !
147            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
148            zqld =  tmask(ji,jj,1) * rdt_ice *  &
149               &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
150               &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
151
152            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
153            ! includes supercooling potential energy (>0) or "above-freezing" energy (<0)
154            zqfr = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
155
156            ! --- Above-freezing sensible heat content (J/m2 grid)
157            zqfr_neg = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * MIN( ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ), 0._wp )
158
159            ! --- Sensible ocean-to-ice heat flux (W/m2)
160            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
161            fhtur(ji,jj) = rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ! W.m-2
162
163            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
164            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
165            !                        the freezing point, so that we do not have SST < T_freeze
166            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
167
168            !-- Energy Budget of the leads (J.m-2), source of lateral accretion. Must be < 0 to form ice
169            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
170
171            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
172            IF( zqld > 0._wp ) THEN
173               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
174               qlead(ji,jj) = 0._wp
175            ELSE
176               fhld (ji,jj) = 0._wp
177            ENDIF
178            !
179            ! Net heat flux on top of the ice-ocean [W.m-2]
180            ! ---------------------------------------------
181            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
182         END DO
183      END DO
184     
185      ! In case we bypass open-water ice formation
186      IF( .NOT. ln_limdO )  qlead(:,:) = 0._wp
187      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
188      IF( .NOT. ln_limdH )  hfx_in(:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
189      IF( .NOT. ln_limdH )  fhtur (:,:) = 0._wp  ;  fhld  (:,:) = 0._wp
190
191      ! ---------------------------------------------------------------------
192      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
193      ! ---------------------------------------------------------------------
194      !     First  step here              :  non solar + precip - qlead - qturb
195      !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
196      !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
197      DO jj = 1, jpj
198         DO ji = 1, jpi
199            hfx_out(ji,jj) = ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
200               &             - qlead(ji,jj) * r1_rdtice                                    &  ! heat flux taken from the ocean where there is open water ice formation
201               &             - at_i(ji,jj) * fhtur(ji,jj)                                  &  ! heat flux taken by turbulence
202               &             - at_i(ji,jj) *  fhld(ji,jj)                                     ! heat flux taken during bottom growth/melt
203                                                                                              !    (fhld should be 0 while bott growth)
204         END DO
205      END DO
206
207      !-------------------------------------------------------------------------------------------!
208      ! Thermodynamic computation (only on grid points covered by ice) => loop over ice categories
209      !-------------------------------------------------------------------------------------------!
210      DO jl = 1, jpl
211
212         ! select ice covered grid points
213         nidx = 0 ; idxice(:) = 0
214         DO jj = 1, jpj
215            DO ji = 1, jpi
216               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
217                  nidx         = nidx  + 1
218                  idxice(nidx) = (jj - 1) * jpi + ji
219               ENDIF
220            END DO
221         END DO
222
223         ! debug point to follow
224         jiindex_1d = 0
225         IF( ln_limctl ) THEN
226            DO ji = mi0(iiceprt), mi1(iiceprt)
227               DO jj = mj0(jiceprt), mj1(jiceprt)
228                  jiindex_1d = (jj - 1) * jpi + ji
229                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
230               END DO
231            END DO
232         ENDIF
233
234         IF( lk_mpp )         CALL mpp_ini_ice( nidx , numout )
235
236         IF( nidx > 0 ) THEN  ! If there is no ice, do nothing.
237            !                                                               
238            s_i_new   (1:nidx) = 0._wp ; dh_s_tot (1:nidx) = 0._wp  ! --- some init --- !
239            dh_i_surf (1:nidx) = 0._wp ; dh_i_bott(1:nidx) = 0._wp
240            dh_snowice(1:nidx) = 0._wp ; dh_i_sub (1:nidx) = 0._wp
241
242                              CALL lim_thd_1d2d( jl, 1 )            ! --- Move to 1D arrays --- !
243            !
244            DO jk = 1, nlay_i                                       ! --- Change units from J/m2 to J/m3 --- !
245               WHERE( ht_i_1d(1:nidx)>0._wp ) e_i_1d(1:nidx,jk) = e_i_1d(1:nidx,jk) / (ht_i_1d(1:nidx) * a_i_1d(1:nidx)) * nlay_i
246            ENDDO
247            DO jk = 1, nlay_s
248               WHERE( ht_s_1d(1:nidx)>0._wp ) e_s_1d(1:nidx,jk) = e_s_1d(1:nidx,jk) / (ht_s_1d(1:nidx) * a_i_1d(1:nidx)) * nlay_s
249            ENDDO
250            !
251            IF( ln_limdH )    CALL lim_thd_dif                      ! --- Ice/Snow Temperature profile --- !
252            !
253            IF( ln_limdH )    CALL lim_thd_dh                       ! --- Ice/Snow thickness --- !   
254            !
255            IF( ln_limdH )    CALL lim_thd_ent( e_i_1d(1:nidx,:) )  ! --- Ice enthalpy remapping --- !
256            !
257                              CALL lim_thd_sal                      ! --- Ice salinity --- !   
258            !
259                              CALL lim_thd_temp                     ! --- temperature update --- !
260            !
261            IF( ln_limdH ) THEN
262               IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
263                              CALL lim_thd_lam                      ! --- extra lateral melting if monocat --- !
264               END IF
265            END IF
266            !
267            IF( ln_limdA )    CALL lim_thd_da                       ! --- lateral melting --- !
268            !
269            DO jk = 1, nlay_i                                       ! --- Change units from J/m3 to J/m2 --- !
270               e_i_1d(1:nidx,jk) = e_i_1d(1:nidx,jk) * ht_i_1d(1:nidx) * a_i_1d(1:nidx) * r1_nlay_i
271            ENDDO
272            DO jk = 1, nlay_s
273               e_s_1d(1:nidx,jk) = e_s_1d(1:nidx,jk) * ht_s_1d(1:nidx) * a_i_1d(1:nidx) * r1_nlay_s
274            ENDDO
275            !
276            ! Change thickness to volume
277            v_i_1d(1:nidx)   = ht_i_1d(1:nidx) * a_i_1d(1:nidx)
278            v_s_1d(1:nidx)   = ht_s_1d(1:nidx) * a_i_1d(1:nidx)
279            smv_i_1d(1:nidx) = sm_i_1d(1:nidx) * v_i_1d(1:nidx)
280            !
281                              CALL lim_thd_1d2d( jl, 2 )            ! --- Move to 2D arrays --- !
282            !
283            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
284         ENDIF
285         !
286      END DO
287      at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
288
289      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting)
290      DO jl  = 1, jpl
291         DO jj = 1, jpj
292            DO ji = 1, jpi
293               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
294               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
295            END DO
296         END DO
297      END DO
298
299      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
300
301      CALL lim_var_zapsmall
302
303      IF( ln_limctl )    CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
304      !
305      !------------------------------------------------!
306      !  Transport ice between thickness categories
307      !------------------------------------------------!
308      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
309
310      IF( jpl > 1 )      CALL lim_itd_th_rem( kt )
311
312      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
313
314      !------------------------------------------------!
315      !  Add frazil ice growing in leads
316      !------------------------------------------------!
317      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
318
319      IF( ln_limdO )     CALL lim_thd_lac
320     
321      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
322
323      IF( ln_ctl )       CALL lim_prt3D( 'limthd' )  ! Control print
324      !
325      CALL wrk_dealloc( jpi,jpj, zu_io, zv_io, zfric )
326      !
327      IF( nn_timing == 1 )  CALL timing_stop('limthd')
328
329   END SUBROUTINE lim_thd 
330
331 
332   SUBROUTINE lim_thd_temp
333      !!-----------------------------------------------------------------------
334      !!                   ***  ROUTINE lim_thd_temp ***
335      !!                 
336      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
337      !!
338      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
339      !!-------------------------------------------------------------------
340      INTEGER  ::   ji, jk   ! dummy loop indices
341      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
342      !!-------------------------------------------------------------------
343      ! Recover ice temperature
344      DO jk = 1, nlay_i
345         DO ji = 1, nidx
346            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
347            ! Conversion q(S,T) -> T (second order equation)
348            zaaa          =  cpic
349            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + e_i_1d(ji,jk) * r1_rhoic - lfus
350            zccc          =  lfus * ( ztmelts - rt0 )
351            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
352            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
353           
354            ! mask temperature
355            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
356            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
357         END DO
358      END DO 
359      !
360   END SUBROUTINE lim_thd_temp
361
362
363   SUBROUTINE lim_thd_lam
364      !!-----------------------------------------------------------------------
365      !!                   ***  ROUTINE lim_thd_lam ***
366      !!                 
367      !! ** Purpose :   Lateral melting in case monocategory
368      !!                          ( dA = A/2h dh )
369      !!-----------------------------------------------------------------------
370      INTEGER  ::   ji                 ! dummy loop indices
371      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
372      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
373      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
374      !!-----------------------------------------------------------------------
375      !
376      DO ji = 1, nidx
377         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
378         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
379            zvi          = a_i_1d(ji) * ht_i_1d(ji)
380            zvs          = a_i_1d(ji) * ht_s_1d(ji)
381            ! lateral melting = concentration change
382            zhi_bef     = ht_i_1d(ji) - zdh_mel
383            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
384            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
385            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
386            ! adjust thickness
387            ht_i_1d(ji) = zvi / a_i_1d(ji)           
388            ht_s_1d(ji) = zvs / a_i_1d(ji)           
389            ! retrieve total concentration
390            at_i_1d(ji) = a_i_1d(ji)
391         END IF
392      END DO
393      !
394   END SUBROUTINE lim_thd_lam
395
396
397   SUBROUTINE lim_thd_1d2d( jl, kn )
398      !!-----------------------------------------------------------------------
399      !!                   ***  ROUTINE lim_thd_1d2d ***
400      !!                 
401      !! ** Purpose :   move arrays from 1d to 2d and the reverse
402      !!-----------------------------------------------------------------------
403      INTEGER, INTENT(in) ::   jl       ! ice cat
404      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D   ;   2= from 1D to 2D
405      !
406      INTEGER             ::   jk       ! dummy loop indices
407      !!-----------------------------------------------------------------------
408      !
409      SELECT CASE( kn )
410      !
411      CASE( 1 )            ! from 2D to 1D
412         !
413         CALL tab_2d_1d( nidx, idxice(1:nidx), at_i_1d(1:nidx), at_i             )
414         CALL tab_2d_1d( nidx, idxice(1:nidx), a_i_1d (1:nidx), a_i(:,:,jl)      )
415         CALL tab_2d_1d( nidx, idxice(1:nidx), ht_i_1d(1:nidx), ht_i(:,:,jl)     )
416         CALL tab_2d_1d( nidx, idxice(1:nidx), ht_s_1d(1:nidx), ht_s(:,:,jl)     )
417         CALL tab_2d_1d( nidx, idxice(1:nidx), t_su_1d(1:nidx), t_su(:,:,jl)     )
418         CALL tab_2d_1d( nidx, idxice(1:nidx), sm_i_1d(1:nidx), sm_i(:,:,jl)     )
419         DO jk = 1, nlay_s
420            CALL tab_2d_1d( nidx, idxice(1:nidx), t_s_1d(1:nidx,jk), t_s(:,:,jk,jl)   )
421            CALL tab_2d_1d( nidx, idxice(1:nidx), e_s_1d(1:nidx,jk), e_s(:,:,jk,jl)   )
422         END DO
423         DO jk = 1, nlay_i
424            CALL tab_2d_1d( nidx, idxice(1:nidx), t_i_1d(1:nidx,jk), t_i(:,:,jk,jl)   )
425            CALL tab_2d_1d( nidx, idxice(1:nidx), e_i_1d(1:nidx,jk), e_i(:,:,jk,jl)   )
426            CALL tab_2d_1d( nidx, idxice(1:nidx), s_i_1d(1:nidx,jk), s_i(:,:,jk,jl)   )
427         END DO
428         !
429         CALL tab_2d_1d( nidx, idxice(1:nidx), qprec_ice_1d(1:nidx), qprec_ice        )
430         CALL tab_2d_1d( nidx, idxice(1:nidx), qsr_ice_1d  (1:nidx), qsr_ice(:,:,jl)  )
431         CALL tab_2d_1d( nidx, idxice(1:nidx), fr1_i0_1d   (1:nidx), fr1_i0           )
432         CALL tab_2d_1d( nidx, idxice(1:nidx), fr2_i0_1d   (1:nidx), fr2_i0           )
433         CALL tab_2d_1d( nidx, idxice(1:nidx), qns_ice_1d  (1:nidx), qns_ice(:,:,jl)  )
434         CALL tab_2d_1d( nidx, idxice(1:nidx), ftr_ice_1d  (1:nidx), ftr_ice(:,:,jl)  )
435         CALL tab_2d_1d( nidx, idxice(1:nidx), evap_ice_1d (1:nidx), evap_ice(:,:,jl) )
436         CALL tab_2d_1d( nidx, idxice(1:nidx), dqns_ice_1d (1:nidx), dqns_ice(:,:,jl) )
437         CALL tab_2d_1d( nidx, idxice(1:nidx), t_bo_1d     (1:nidx), t_bo             )
438         CALL tab_2d_1d( nidx, idxice(1:nidx), sprecip_1d  (1:nidx), sprecip          ) 
439         CALL tab_2d_1d( nidx, idxice(1:nidx), fhtur_1d    (1:nidx), fhtur            )
440         CALL tab_2d_1d( nidx, idxice(1:nidx), fhld_1d     (1:nidx), fhld             )
441         !
442         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_snw_sni_1d(1:nidx), wfx_snw_sni   )
443         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_snw_sum_1d(1:nidx), wfx_snw_sum   )
444         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_sub_1d    (1:nidx), wfx_sub       )
445         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_snw_sub_1d(1:nidx), wfx_snw_sub   )
446         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_ice_sub_1d(1:nidx), wfx_ice_sub   )
447         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_err_sub_1d(1:nidx), wfx_err_sub   )
448         !
449         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_bog_1d (1:nidx), wfx_bog          )
450         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_bom_1d (1:nidx), wfx_bom          )
451         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_sum_1d (1:nidx), wfx_sum          )
452         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_sni_1d (1:nidx), wfx_sni          )
453         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_res_1d (1:nidx), wfx_res          )
454         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_spr_1d (1:nidx), wfx_spr          )
455         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_lam_1d (1:nidx), wfx_lam          )
456         !
457         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_bog_1d (1:nidx), sfx_bog          )
458         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_bom_1d (1:nidx), sfx_bom          )
459         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_sum_1d (1:nidx), sfx_sum          )
460         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_sni_1d (1:nidx), sfx_sni          )
461         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_bri_1d (1:nidx), sfx_bri          )
462         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_res_1d (1:nidx), sfx_res          )
463         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_sub_1d (1:nidx), sfx_sub          )
464         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_lam_1d (1:nidx), sfx_lam          )
465         !
466         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_thd_1d (1:nidx), hfx_thd          )
467         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_spr_1d (1:nidx), hfx_spr          )
468         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_sum_1d (1:nidx), hfx_sum          )
469         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_bom_1d (1:nidx), hfx_bom          )
470         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_bog_1d (1:nidx), hfx_bog          )
471         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_dif_1d (1:nidx), hfx_dif          )
472         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_opw_1d (1:nidx), hfx_opw          )
473         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_snw_1d (1:nidx), hfx_snw          )
474         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_sub_1d (1:nidx), hfx_sub          )
475         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_err_1d (1:nidx), hfx_err          )
476         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_res_1d (1:nidx), hfx_res          )
477         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_err_dif_1d(1:nidx), hfx_err_dif   )
478         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_err_rem_1d(1:nidx), hfx_err_rem   )
479         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_out_1d (1:nidx), hfx_out          )
480         !
481         ! SIMIP diagnostics
482         CALL tab_2d_1d( nidx, idxice(1:nidx), diag_fc_bo_1d(1:nidx), diag_fc_bo   )
483         CALL tab_2d_1d( nidx, idxice(1:nidx), diag_fc_su_1d(1:nidx), diag_fc_su   )
484         ! ocean surface fields
485         CALL tab_2d_1d( nidx, idxice(1:nidx), sst_1d(1:nidx), sst_m )
486         CALL tab_2d_1d( nidx, idxice(1:nidx), sss_1d(1:nidx), sss_m )
487         !
488      CASE( 2 )            ! from 1D to 2D
489         !
490         CALL tab_1d_2d( nidx, idxice(1:nidx), at_i_1d(1:nidx), at_i             )
491         CALL tab_1d_2d( nidx, idxice(1:nidx), a_i_1d (1:nidx), a_i(:,:,jl)      )
492         CALL tab_1d_2d( nidx, idxice(1:nidx), ht_i_1d(1:nidx), ht_i(:,:,jl)     )
493         CALL tab_1d_2d( nidx, idxice(1:nidx), ht_s_1d(1:nidx), ht_s(:,:,jl)     )
494         CALL tab_1d_2d( nidx, idxice(1:nidx), t_su_1d(1:nidx), t_su(:,:,jl)     )
495         CALL tab_1d_2d( nidx, idxice(1:nidx), sm_i_1d(1:nidx), sm_i(:,:,jl)     )
496         DO jk = 1, nlay_s
497            CALL tab_1d_2d( nidx, idxice(1:nidx), t_s_1d(1:nidx,jk), t_s(:,:,jk,jl)   )
498            CALL tab_1d_2d( nidx, idxice(1:nidx), e_s_1d(1:nidx,jk), e_s(:,:,jk,jl)   )
499         END DO
500         DO jk = 1, nlay_i
501            CALL tab_1d_2d( nidx, idxice(1:nidx), t_i_1d(1:nidx,jk), t_i(:,:,jk,jl)   )
502            CALL tab_1d_2d( nidx, idxice(1:nidx), e_i_1d(1:nidx,jk), e_i(:,:,jk,jl)   )
503            CALL tab_1d_2d( nidx, idxice(1:nidx), s_i_1d(1:nidx,jk), s_i(:,:,jk,jl)   )
504         END DO
505         !
506         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_snw_sni_1d(1:nidx), wfx_snw_sni   )
507         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_snw_sum_1d(1:nidx), wfx_snw_sum   )
508         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_sub_1d    (1:nidx), wfx_sub       )
509         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_snw_sub_1d(1:nidx), wfx_snw_sub   )
510         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_ice_sub_1d(1:nidx), wfx_ice_sub   )
511         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_err_sub_1d(1:nidx), wfx_err_sub   )
512         !
513         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_bog_1d (1:nidx), wfx_bog          )
514         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_bom_1d (1:nidx), wfx_bom          )
515         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_sum_1d (1:nidx), wfx_sum          )
516         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_sni_1d (1:nidx), wfx_sni          )
517         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_res_1d (1:nidx), wfx_res          )
518         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_spr_1d (1:nidx), wfx_spr          )
519         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_lam_1d (1:nidx), wfx_lam          )
520         !
521         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_bog_1d (1:nidx), sfx_bog          )
522         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_bom_1d (1:nidx), sfx_bom          )
523         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_sum_1d (1:nidx), sfx_sum          )
524         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_sni_1d (1:nidx), sfx_sni          )
525         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_bri_1d (1:nidx), sfx_bri          )
526         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_res_1d (1:nidx), sfx_res          )
527         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_sub_1d (1:nidx), sfx_sub          )
528         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_lam_1d (1:nidx), sfx_lam          )
529         !
530         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_thd_1d (1:nidx), hfx_thd          )
531         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_spr_1d (1:nidx), hfx_spr          )
532         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_sum_1d (1:nidx), hfx_sum          )
533         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_bom_1d (1:nidx), hfx_bom          )
534         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_bog_1d (1:nidx), hfx_bog          )
535         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_dif_1d (1:nidx), hfx_dif          )
536         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_opw_1d (1:nidx), hfx_opw          )
537         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_snw_1d (1:nidx), hfx_snw          )
538         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_sub_1d (1:nidx), hfx_sub          )
539         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_err_1d (1:nidx), hfx_err          )
540         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_res_1d (1:nidx), hfx_res          )
541         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_err_dif_1d(1:nidx), hfx_err_dif   )
542         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_err_rem_1d(1:nidx), hfx_err_rem   )
543         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_out_1d (1:nidx), hfx_out          )
544         !
545         CALL tab_1d_2d( nidx, idxice(1:nidx), qns_ice_1d  (1:nidx), qns_ice(:,:,jl)  )
546         CALL tab_1d_2d( nidx, idxice(1:nidx), ftr_ice_1d  (1:nidx), ftr_ice(:,:,jl)  )
547         !
548         ! SIMIP diagnostics         
549         CALL tab_1d_2d( nidx, idxice(1:nidx), t_si_1d      (1:nidx), t_si(:,:,jl)      )
550         CALL tab_1d_2d( nidx, idxice(1:nidx), diag_fc_bo_1d(1:nidx), diag_fc_bo        )
551         CALL tab_1d_2d( nidx, idxice(1:nidx), diag_fc_su_1d(1:nidx), diag_fc_su        )
552         ! extensive variables
553         CALL tab_1d_2d( nidx, idxice(1:nidx), v_i_1d  (1:nidx), v_i  (:,:,jl) )
554         CALL tab_1d_2d( nidx, idxice(1:nidx), v_s_1d  (1:nidx), v_s  (:,:,jl) )
555         CALL tab_1d_2d( nidx, idxice(1:nidx), smv_i_1d(1:nidx), smv_i(:,:,jl) )
556      END SELECT
557      !
558   END SUBROUTINE lim_thd_1d2d
559
560
561   SUBROUTINE lim_thd_init
562      !!-----------------------------------------------------------------------
563      !!                   ***  ROUTINE lim_thd_init ***
564      !!                 
565      !! ** Purpose :   Physical constants and parameters linked to the ice
566      !!              thermodynamics
567      !!
568      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
569      !!              parameter values called at the first timestep (nit000)
570      !!
571      !! ** input   :   Namelist namicether
572      !!-------------------------------------------------------------------
573      INTEGER  ::   ios                 ! Local integer output status for namelist read
574      NAMELIST/namicethd/ rn_kappa_i, nn_ice_thcon, ln_dqnsice, rn_cdsn,                                  &
575         &                ln_limdH, rn_betas,                                                             &
576         &                ln_limdA, rn_beta, rn_dmin,                                                     &
577         &                ln_limdO, rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb, rn_himin,   &
578         &                nn_limflx
579      !!-------------------------------------------------------------------
580      !
581      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
582      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
583901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
584
585      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
586      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
587902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
588      IF(lwm) WRITE ( numoni, namicethd )
589      !
590      !
591      IF(lwp) THEN                          ! control print
592         WRITE(numout,*) 'lim_thd_init : Ice Thermodynamics'
593         WRITE(numout,*) '~~~~~~~~~~~~~'
594         WRITE(numout,*)'   -- limthd_dif --'
595         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
596         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
597         WRITE(numout,*)'      change the surface non-solar flux with Tsu or not       ln_dqnsice   = ', ln_dqnsice
598         WRITE(numout,*)'      thermal conductivity of the snow                        rn_cdsn      = ', rn_cdsn
599         WRITE(numout,*)'   -- limthd_dh --'
600         WRITE(numout,*)'      activate ice thick change from top/bot (T) or not (F)   ln_limdH     = ', ln_limdH
601         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
602         WRITE(numout,*)'   -- limthd_da --'
603         WRITE(numout,*)'      activate lateral melting (T) or not (F)                 ln_limdA     = ', ln_limdA
604         WRITE(numout,*)'      Coef. beta for lateral melting param.                   rn_beta      = ', rn_beta
605         WRITE(numout,*)'      Minimum floe diameter for lateral melting param.        rn_dmin      = ', rn_dmin
606         WRITE(numout,*)'   -- limthd_lac --'
607         WRITE(numout,*)'      activate ice growth in open-water (T) or not (F)        ln_limdO     = ', ln_limdO
608         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
609         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
610         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
611         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
612         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
613         WRITE(numout,*)'   -- limitd_th --'
614         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
615         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
616         WRITE(numout,*)'   -- icestp --'
617         WRITE(numout,*)'      Multicategory heat flux formulation                     nn_limflx    = ', nn_limflx
618      ENDIF
619      !
620      IF ( rn_hnewice < rn_himin )   CALL ctl_stop( 'STOP', 'lim_thd_init : rn_hnewice should be >= rn_himin' )
621      !
622      IF(lwp) WRITE(numout,*)
623      SELECT CASE( nn_limflx )         ! LIM3 Multi-category heat flux formulation
624      CASE ( -1 )
625         IF(lwp) WRITE(numout,*) '   LIM3: use per-category fluxes (nn_limflx = -1) '
626         IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
627      CASE ( 0  )
628         IF(lwp) WRITE(numout,*) '   LIM3: use average per-category fluxes (nn_limflx = 0) '
629      CASE ( 1  )
630         IF(lwp) WRITE(numout,*) '   LIM3: use average then redistribute per-category fluxes (nn_limflx = 1) '
631         IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
632      CASE ( 2  )
633         IF(lwp) WRITE(numout,*) '   LIM3: Redistribute a single flux over categories (nn_limflx = 2) '
634         IF( .NOT. ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in forced mode cannot be 2' )
635      CASE DEFAULT
636         CALL ctl_stop( 'sbcmod: LIM3 option, nn_limflx, should be between -1 and 2' )
637      END SELECT
638      !
639   END SUBROUTINE lim_thd_init
640
641#else
642   !!----------------------------------------------------------------------
643   !!   Default option         Dummy module          NO  LIM3 sea-ice model
644   !!----------------------------------------------------------------------
645#endif
646
647   !!======================================================================
648END MODULE limthd
Note: See TracBrowser for help on using the repository browser.