New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 8373

Last change on this file since 8373 was 8373, checked in by clem, 7 years ago

remove most of wrk_alloc
  • Property svn:keywords set to Id
File size: 36.3 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! sea-ice variables
25   USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, qns_tot, qsr_tot, sprecip, ln_cpl
26   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
27      &                 fr1_i0, fr2_i0, nn_limflx
28   USE thd_ice        ! thermodynamic sea-ice variables
29   USE limthd_dif     ! vertical diffusion
30   USE limthd_dh      ! ice-snow growth and melt
31   USE limthd_da      ! lateral melting
32   USE limthd_sal     ! ice salinity
33   USE limthd_ent     ! ice enthalpy redistribution
34   USE limthd_lac     ! lateral accretion
35   USE limitd_th      ! remapping thickness distribution
36   USE limtab         ! 1D <==> 2D transformation
37   USE limvar         !
38   USE limcons        ! conservation tests
39   USE limctl         ! control print
40   !
41   USE in_out_manager ! I/O manager
42   USE lbclnk         ! lateral boundary condition - MPP links
43   USE lib_mpp        ! MPP library
44   USE wrk_nemo       ! work arrays
45   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
46   USE timing         ! Timing
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   lim_thd         ! called by limstp module
52   PUBLIC   lim_thd_init    ! called by ice_init
53
54   !! * Substitutions
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE lim_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE lim_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - Initialisation of some variables
70      !!             - Some preliminary computation (oceanic heat flux
71      !!               at the ice base, snow acc.,heat budget of the leads)
72      !!             - selection of the icy points and put them in an array
73      !!             - call lim_thd_dif  for vertical heat diffusion
74      !!             - call lim_thd_dh   for vertical ice growth and melt
75      !!             - call lim_thd_ent  for enthalpy remapping
76      !!             - call lim_thd_sal  for ice desalination
77      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
78      !!             - back to the geographic grid
79      !!     
80      !! ** References :
81      !!---------------------------------------------------------------------
82      INTEGER, INTENT(in) :: kt    ! number of iteration
83      !
84      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
85      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg
86      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
87      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
88      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
89      REAL(wp), DIMENSION(jpi,jpj) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
90      !
91      !!-------------------------------------------------------------------
92
93      IF( nn_timing == 1 )   CALL timing_start('limthd')
94
95      IF( kt == nit000 .AND. lwp ) THEN
96         WRITE(numout,*)'' 
97         WRITE(numout,*)' lim_thd '
98         WRITE(numout,*)' ~~~~~~~~'
99      ENDIF
100     
101      ! conservation test
102      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
103
104      CALL lim_var_glo2eqv
105
106      !---------------------------------------------!
107      ! computation of friction velocity at T points
108      !---------------------------------------------!
109      IF( ln_limdyn ) THEN
110         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
111         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
112         DO jj = 2, jpjm1 
113            DO ji = fs_2, fs_jpim1
114               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
115                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
116                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
117            END DO
118         END DO
119      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
120         DO jj = 2, jpjm1
121            DO ji = fs_2, fs_jpim1
122               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
123                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
124                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
125            END DO
126         END DO
127      ENDIF
128      CALL lbc_lnk( zfric, 'T',  1. )
129      !
130      ftr_ice(:,:,:) = 0._wp  ! initialization (part of solar radiation transmitted through the ice)
131
132      !--------------------------------------------------------------------!
133      ! Partial computation of forcing for the thermodynamic sea ice model
134      !--------------------------------------------------------------------!
135      DO jj = 1, jpj
136         DO ji = 1, jpi
137            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
138            !
139            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
140            !           !  practically no "direct lateral ablation"
141            !           
142            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
143            !           !  temperature and turbulent mixing (McPhee, 1992)
144            !
145            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
146            zqld =  tmask(ji,jj,1) * rdt_ice *  &
147               &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
148               &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
149
150            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
151            ! includes supercooling potential energy (>0) or "above-freezing" energy (<0)
152            zqfr = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
153
154            ! --- Above-freezing sensible heat content (J/m2 grid)
155            zqfr_neg = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * MIN( ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ), 0._wp )
156
157            ! --- Sensible ocean-to-ice heat flux (W/m2)
158            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
159            fhtur(ji,jj) = rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ! W.m-2
160
161            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
162            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
163            !                        the freezing point, so that we do not have SST < T_freeze
164            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
165
166            !-- Energy Budget of the leads (J.m-2), source of lateral accretion. Must be < 0 to form ice
167            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
168
169            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
170            IF( zqld > 0._wp ) THEN
171               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
172               qlead(ji,jj) = 0._wp
173            ELSE
174               fhld (ji,jj) = 0._wp
175            ENDIF
176            !
177            ! Net heat flux on top of the ice-ocean [W.m-2]
178            ! ---------------------------------------------
179            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
180         END DO
181      END DO
182     
183      ! In case we bypass open-water ice formation
184      IF( .NOT. ln_limdO )  qlead(:,:) = 0._wp
185      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
186      IF( .NOT. ln_limdH )  hfx_in(:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
187      IF( .NOT. ln_limdH )  fhtur (:,:) = 0._wp  ;  fhld  (:,:) = 0._wp
188
189      ! ---------------------------------------------------------------------
190      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
191      ! ---------------------------------------------------------------------
192      !     First  step here              :  non solar + precip - qlead - qturb
193      !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
194      !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
195      DO jj = 1, jpj
196         DO ji = 1, jpi
197            hfx_out(ji,jj) = ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
198               &             - qlead(ji,jj) * r1_rdtice                                    &  ! heat flux taken from the ocean where there is open water ice formation
199               &             - at_i(ji,jj) * fhtur(ji,jj)                                  &  ! heat flux taken by turbulence
200               &             - at_i(ji,jj) *  fhld(ji,jj)                                     ! heat flux taken during bottom growth/melt
201                                                                                              !    (fhld should be 0 while bott growth)
202         END DO
203      END DO
204
205      !-------------------------------------------------------------------------------------------!
206      ! Thermodynamic computation (only on grid points covered by ice) => loop over ice categories
207      !-------------------------------------------------------------------------------------------!
208      DO jl = 1, jpl
209
210         ! select ice covered grid points
211         nidx = 0 ; idxice(:) = 0
212         DO jj = 1, jpj
213            DO ji = 1, jpi
214               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
215                  nidx         = nidx  + 1
216                  idxice(nidx) = (jj - 1) * jpi + ji
217               ENDIF
218            END DO
219         END DO
220
221         ! debug point to follow
222         jiindex_1d = 0
223         IF( ln_limctl ) THEN
224            DO ji = mi0(iiceprt), mi1(iiceprt)
225               DO jj = mj0(jiceprt), mj1(jiceprt)
226                  jiindex_1d = (jj - 1) * jpi + ji
227                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
228               END DO
229            END DO
230         ENDIF
231
232         IF( lk_mpp )         CALL mpp_ini_ice( nidx , numout )
233
234         IF( nidx > 0 ) THEN  ! If there is no ice, do nothing.
235            !                                                               
236            s_i_new   (1:nidx) = 0._wp ; dh_s_tot (1:nidx) = 0._wp  ! --- some init --- !
237            dh_i_surf (1:nidx) = 0._wp ; dh_i_bott(1:nidx) = 0._wp
238            dh_snowice(1:nidx) = 0._wp ; dh_i_sub (1:nidx) = 0._wp
239
240                              CALL lim_thd_1d2d( jl, 1 )            ! --- Move to 1D arrays --- !
241            !
242            DO jk = 1, nlay_i                                       ! --- Change units from J/m2 to J/m3 --- !
243               WHERE( ht_i_1d(1:nidx)>0._wp ) e_i_1d(1:nidx,jk) = e_i_1d(1:nidx,jk) / (ht_i_1d(1:nidx) * a_i_1d(1:nidx)) * nlay_i
244            ENDDO
245            DO jk = 1, nlay_s
246               WHERE( ht_s_1d(1:nidx)>0._wp ) e_s_1d(1:nidx,jk) = e_s_1d(1:nidx,jk) / (ht_s_1d(1:nidx) * a_i_1d(1:nidx)) * nlay_s
247            ENDDO
248            !
249            IF( ln_limdH )    CALL lim_thd_dif                      ! --- Ice/Snow Temperature profile --- !
250            !
251            IF( ln_limdH )    CALL lim_thd_dh                       ! --- Ice/Snow thickness --- !   
252            !
253            IF( ln_limdH )    CALL lim_thd_ent( e_i_1d(1:nidx,:) )  ! --- Ice enthalpy remapping --- !
254            !
255                              CALL lim_thd_sal                      ! --- Ice salinity --- !   
256            !
257                              CALL lim_thd_temp                     ! --- temperature update --- !
258            !
259            IF( ln_limdH ) THEN
260               IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
261                              CALL lim_thd_lam                      ! --- extra lateral melting if monocat --- !
262               END IF
263            END IF
264            !
265            IF( ln_limdA )    CALL lim_thd_da                       ! --- lateral melting --- !
266            !
267            DO jk = 1, nlay_i                                       ! --- Change units from J/m3 to J/m2 --- !
268               e_i_1d(1:nidx,jk) = e_i_1d(1:nidx,jk) * ht_i_1d(1:nidx) * a_i_1d(1:nidx) * r1_nlay_i
269            ENDDO
270            DO jk = 1, nlay_s
271               e_s_1d(1:nidx,jk) = e_s_1d(1:nidx,jk) * ht_s_1d(1:nidx) * a_i_1d(1:nidx) * r1_nlay_s
272            ENDDO
273            !
274            ! Change thickness to volume
275            v_i_1d(1:nidx)   = ht_i_1d(1:nidx) * a_i_1d(1:nidx)
276            v_s_1d(1:nidx)   = ht_s_1d(1:nidx) * a_i_1d(1:nidx)
277            smv_i_1d(1:nidx) = sm_i_1d(1:nidx) * v_i_1d(1:nidx)
278            !
279                              CALL lim_thd_1d2d( jl, 2 )            ! --- Move to 2D arrays --- !
280            !
281            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
282         ENDIF
283         !
284      END DO
285      at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
286
287      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting)
288      DO jl  = 1, jpl
289         DO jj = 1, jpj
290            DO ji = 1, jpi
291               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
292               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
293            END DO
294         END DO
295      END DO
296
297      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
298
299      CALL lim_var_zapsmall
300
301      IF( ln_limctl )    CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
302      !
303      !------------------------------------------------!
304      !  Transport ice between thickness categories
305      !------------------------------------------------!
306      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
307
308      IF( jpl > 1 )      CALL lim_itd_th_rem( kt )
309
310      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
311
312      !------------------------------------------------!
313      !  Add frazil ice growing in leads
314      !------------------------------------------------!
315      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
316
317      IF( ln_limdO )     CALL lim_thd_lac
318     
319      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
320
321      IF( ln_ctl )       CALL lim_prt3D( 'limthd' )  ! Control print
322      !
323      IF( nn_timing == 1 )  CALL timing_stop('limthd')
324
325   END SUBROUTINE lim_thd 
326
327 
328   SUBROUTINE lim_thd_temp
329      !!-----------------------------------------------------------------------
330      !!                   ***  ROUTINE lim_thd_temp ***
331      !!                 
332      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
333      !!
334      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
335      !!-------------------------------------------------------------------
336      INTEGER  ::   ji, jk   ! dummy loop indices
337      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
338      !!-------------------------------------------------------------------
339      ! Recover ice temperature
340      DO jk = 1, nlay_i
341         DO ji = 1, nidx
342            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
343            ! Conversion q(S,T) -> T (second order equation)
344            zaaa          =  cpic
345            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + e_i_1d(ji,jk) * r1_rhoic - lfus
346            zccc          =  lfus * ( ztmelts - rt0 )
347            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
348            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
349           
350            ! mask temperature
351            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
352            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
353         END DO
354      END DO 
355      !
356   END SUBROUTINE lim_thd_temp
357
358
359   SUBROUTINE lim_thd_lam
360      !!-----------------------------------------------------------------------
361      !!                   ***  ROUTINE lim_thd_lam ***
362      !!                 
363      !! ** Purpose :   Lateral melting in case monocategory
364      !!                          ( dA = A/2h dh )
365      !!-----------------------------------------------------------------------
366      INTEGER  ::   ji                 ! dummy loop indices
367      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
368      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
369      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
370      !!-----------------------------------------------------------------------
371      !
372      DO ji = 1, nidx
373         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
374         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
375            zvi          = a_i_1d(ji) * ht_i_1d(ji)
376            zvs          = a_i_1d(ji) * ht_s_1d(ji)
377            ! lateral melting = concentration change
378            zhi_bef     = ht_i_1d(ji) - zdh_mel
379            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
380            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
381            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
382            ! adjust thickness
383            ht_i_1d(ji) = zvi / a_i_1d(ji)           
384            ht_s_1d(ji) = zvs / a_i_1d(ji)           
385            ! retrieve total concentration
386            at_i_1d(ji) = a_i_1d(ji)
387         END IF
388      END DO
389      !
390   END SUBROUTINE lim_thd_lam
391
392
393   SUBROUTINE lim_thd_1d2d( jl, kn )
394      !!-----------------------------------------------------------------------
395      !!                   ***  ROUTINE lim_thd_1d2d ***
396      !!                 
397      !! ** Purpose :   move arrays from 1d to 2d and the reverse
398      !!-----------------------------------------------------------------------
399      INTEGER, INTENT(in) ::   jl       ! ice cat
400      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D   ;   2= from 1D to 2D
401      !
402      INTEGER             ::   jk       ! dummy loop indices
403      !!-----------------------------------------------------------------------
404      !
405      SELECT CASE( kn )
406      !
407      CASE( 1 )            ! from 2D to 1D
408         !
409         CALL tab_2d_1d( nidx, idxice(1:nidx), at_i_1d(1:nidx), at_i             )
410         CALL tab_2d_1d( nidx, idxice(1:nidx), a_i_1d (1:nidx), a_i(:,:,jl)      )
411         CALL tab_2d_1d( nidx, idxice(1:nidx), ht_i_1d(1:nidx), ht_i(:,:,jl)     )
412         CALL tab_2d_1d( nidx, idxice(1:nidx), ht_s_1d(1:nidx), ht_s(:,:,jl)     )
413         CALL tab_2d_1d( nidx, idxice(1:nidx), t_su_1d(1:nidx), t_su(:,:,jl)     )
414         CALL tab_2d_1d( nidx, idxice(1:nidx), sm_i_1d(1:nidx), sm_i(:,:,jl)     )
415         DO jk = 1, nlay_s
416            CALL tab_2d_1d( nidx, idxice(1:nidx), t_s_1d(1:nidx,jk), t_s(:,:,jk,jl)   )
417            CALL tab_2d_1d( nidx, idxice(1:nidx), e_s_1d(1:nidx,jk), e_s(:,:,jk,jl)   )
418         END DO
419         DO jk = 1, nlay_i
420            CALL tab_2d_1d( nidx, idxice(1:nidx), t_i_1d(1:nidx,jk), t_i(:,:,jk,jl)   )
421            CALL tab_2d_1d( nidx, idxice(1:nidx), e_i_1d(1:nidx,jk), e_i(:,:,jk,jl)   )
422            CALL tab_2d_1d( nidx, idxice(1:nidx), s_i_1d(1:nidx,jk), s_i(:,:,jk,jl)   )
423         END DO
424         !
425         CALL tab_2d_1d( nidx, idxice(1:nidx), qprec_ice_1d(1:nidx), qprec_ice        )
426         CALL tab_2d_1d( nidx, idxice(1:nidx), qsr_ice_1d  (1:nidx), qsr_ice(:,:,jl)  )
427         CALL tab_2d_1d( nidx, idxice(1:nidx), fr1_i0_1d   (1:nidx), fr1_i0           )
428         CALL tab_2d_1d( nidx, idxice(1:nidx), fr2_i0_1d   (1:nidx), fr2_i0           )
429         CALL tab_2d_1d( nidx, idxice(1:nidx), qns_ice_1d  (1:nidx), qns_ice(:,:,jl)  )
430         CALL tab_2d_1d( nidx, idxice(1:nidx), ftr_ice_1d  (1:nidx), ftr_ice(:,:,jl)  )
431         CALL tab_2d_1d( nidx, idxice(1:nidx), evap_ice_1d (1:nidx), evap_ice(:,:,jl) )
432         CALL tab_2d_1d( nidx, idxice(1:nidx), dqns_ice_1d (1:nidx), dqns_ice(:,:,jl) )
433         CALL tab_2d_1d( nidx, idxice(1:nidx), t_bo_1d     (1:nidx), t_bo             )
434         CALL tab_2d_1d( nidx, idxice(1:nidx), sprecip_1d  (1:nidx), sprecip          ) 
435         CALL tab_2d_1d( nidx, idxice(1:nidx), fhtur_1d    (1:nidx), fhtur            )
436         CALL tab_2d_1d( nidx, idxice(1:nidx), fhld_1d     (1:nidx), fhld             )
437         !
438         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_snw_sni_1d(1:nidx), wfx_snw_sni   )
439         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_snw_sum_1d(1:nidx), wfx_snw_sum   )
440         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_sub_1d    (1:nidx), wfx_sub       )
441         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_snw_sub_1d(1:nidx), wfx_snw_sub   )
442         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_ice_sub_1d(1:nidx), wfx_ice_sub   )
443         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_err_sub_1d(1:nidx), wfx_err_sub   )
444         !
445         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_bog_1d (1:nidx), wfx_bog          )
446         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_bom_1d (1:nidx), wfx_bom          )
447         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_sum_1d (1:nidx), wfx_sum          )
448         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_sni_1d (1:nidx), wfx_sni          )
449         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_res_1d (1:nidx), wfx_res          )
450         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_spr_1d (1:nidx), wfx_spr          )
451         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_lam_1d (1:nidx), wfx_lam          )
452         !
453         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_bog_1d (1:nidx), sfx_bog          )
454         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_bom_1d (1:nidx), sfx_bom          )
455         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_sum_1d (1:nidx), sfx_sum          )
456         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_sni_1d (1:nidx), sfx_sni          )
457         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_bri_1d (1:nidx), sfx_bri          )
458         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_res_1d (1:nidx), sfx_res          )
459         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_sub_1d (1:nidx), sfx_sub          )
460         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_lam_1d (1:nidx), sfx_lam          )
461         !
462         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_thd_1d (1:nidx), hfx_thd          )
463         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_spr_1d (1:nidx), hfx_spr          )
464         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_sum_1d (1:nidx), hfx_sum          )
465         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_bom_1d (1:nidx), hfx_bom          )
466         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_bog_1d (1:nidx), hfx_bog          )
467         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_dif_1d (1:nidx), hfx_dif          )
468         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_opw_1d (1:nidx), hfx_opw          )
469         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_snw_1d (1:nidx), hfx_snw          )
470         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_sub_1d (1:nidx), hfx_sub          )
471         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_err_1d (1:nidx), hfx_err          )
472         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_res_1d (1:nidx), hfx_res          )
473         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_err_dif_1d(1:nidx), hfx_err_dif   )
474         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_err_rem_1d(1:nidx), hfx_err_rem   )
475         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_out_1d (1:nidx), hfx_out          )
476         !
477         ! SIMIP diagnostics
478         CALL tab_2d_1d( nidx, idxice(1:nidx), diag_fc_bo_1d(1:nidx), diag_fc_bo   )
479         CALL tab_2d_1d( nidx, idxice(1:nidx), diag_fc_su_1d(1:nidx), diag_fc_su   )
480         ! ocean surface fields
481         CALL tab_2d_1d( nidx, idxice(1:nidx), sst_1d(1:nidx), sst_m )
482         CALL tab_2d_1d( nidx, idxice(1:nidx), sss_1d(1:nidx), sss_m )
483         !
484      CASE( 2 )            ! from 1D to 2D
485         !
486         CALL tab_1d_2d( nidx, idxice(1:nidx), at_i_1d(1:nidx), at_i             )
487         CALL tab_1d_2d( nidx, idxice(1:nidx), a_i_1d (1:nidx), a_i(:,:,jl)      )
488         CALL tab_1d_2d( nidx, idxice(1:nidx), ht_i_1d(1:nidx), ht_i(:,:,jl)     )
489         CALL tab_1d_2d( nidx, idxice(1:nidx), ht_s_1d(1:nidx), ht_s(:,:,jl)     )
490         CALL tab_1d_2d( nidx, idxice(1:nidx), t_su_1d(1:nidx), t_su(:,:,jl)     )
491         CALL tab_1d_2d( nidx, idxice(1:nidx), sm_i_1d(1:nidx), sm_i(:,:,jl)     )
492         DO jk = 1, nlay_s
493            CALL tab_1d_2d( nidx, idxice(1:nidx), t_s_1d(1:nidx,jk), t_s(:,:,jk,jl)   )
494            CALL tab_1d_2d( nidx, idxice(1:nidx), e_s_1d(1:nidx,jk), e_s(:,:,jk,jl)   )
495         END DO
496         DO jk = 1, nlay_i
497            CALL tab_1d_2d( nidx, idxice(1:nidx), t_i_1d(1:nidx,jk), t_i(:,:,jk,jl)   )
498            CALL tab_1d_2d( nidx, idxice(1:nidx), e_i_1d(1:nidx,jk), e_i(:,:,jk,jl)   )
499            CALL tab_1d_2d( nidx, idxice(1:nidx), s_i_1d(1:nidx,jk), s_i(:,:,jk,jl)   )
500         END DO
501         !
502         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_snw_sni_1d(1:nidx), wfx_snw_sni   )
503         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_snw_sum_1d(1:nidx), wfx_snw_sum   )
504         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_sub_1d    (1:nidx), wfx_sub       )
505         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_snw_sub_1d(1:nidx), wfx_snw_sub   )
506         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_ice_sub_1d(1:nidx), wfx_ice_sub   )
507         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_err_sub_1d(1:nidx), wfx_err_sub   )
508         !
509         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_bog_1d (1:nidx), wfx_bog          )
510         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_bom_1d (1:nidx), wfx_bom          )
511         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_sum_1d (1:nidx), wfx_sum          )
512         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_sni_1d (1:nidx), wfx_sni          )
513         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_res_1d (1:nidx), wfx_res          )
514         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_spr_1d (1:nidx), wfx_spr          )
515         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_lam_1d (1:nidx), wfx_lam          )
516         !
517         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_bog_1d (1:nidx), sfx_bog          )
518         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_bom_1d (1:nidx), sfx_bom          )
519         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_sum_1d (1:nidx), sfx_sum          )
520         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_sni_1d (1:nidx), sfx_sni          )
521         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_bri_1d (1:nidx), sfx_bri          )
522         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_res_1d (1:nidx), sfx_res          )
523         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_sub_1d (1:nidx), sfx_sub          )
524         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_lam_1d (1:nidx), sfx_lam          )
525         !
526         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_thd_1d (1:nidx), hfx_thd          )
527         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_spr_1d (1:nidx), hfx_spr          )
528         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_sum_1d (1:nidx), hfx_sum          )
529         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_bom_1d (1:nidx), hfx_bom          )
530         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_bog_1d (1:nidx), hfx_bog          )
531         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_dif_1d (1:nidx), hfx_dif          )
532         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_opw_1d (1:nidx), hfx_opw          )
533         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_snw_1d (1:nidx), hfx_snw          )
534         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_sub_1d (1:nidx), hfx_sub          )
535         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_err_1d (1:nidx), hfx_err          )
536         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_res_1d (1:nidx), hfx_res          )
537         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_err_dif_1d(1:nidx), hfx_err_dif   )
538         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_err_rem_1d(1:nidx), hfx_err_rem   )
539         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_out_1d (1:nidx), hfx_out          )
540         !
541         CALL tab_1d_2d( nidx, idxice(1:nidx), qns_ice_1d  (1:nidx), qns_ice(:,:,jl)  )
542         CALL tab_1d_2d( nidx, idxice(1:nidx), ftr_ice_1d  (1:nidx), ftr_ice(:,:,jl)  )
543         !
544         ! SIMIP diagnostics         
545         CALL tab_1d_2d( nidx, idxice(1:nidx), t_si_1d      (1:nidx), t_si(:,:,jl)      )
546         CALL tab_1d_2d( nidx, idxice(1:nidx), diag_fc_bo_1d(1:nidx), diag_fc_bo        )
547         CALL tab_1d_2d( nidx, idxice(1:nidx), diag_fc_su_1d(1:nidx), diag_fc_su        )
548         ! extensive variables
549         CALL tab_1d_2d( nidx, idxice(1:nidx), v_i_1d  (1:nidx), v_i  (:,:,jl) )
550         CALL tab_1d_2d( nidx, idxice(1:nidx), v_s_1d  (1:nidx), v_s  (:,:,jl) )
551         CALL tab_1d_2d( nidx, idxice(1:nidx), smv_i_1d(1:nidx), smv_i(:,:,jl) )
552      END SELECT
553      !
554   END SUBROUTINE lim_thd_1d2d
555
556
557   SUBROUTINE lim_thd_init
558      !!-----------------------------------------------------------------------
559      !!                   ***  ROUTINE lim_thd_init ***
560      !!                 
561      !! ** Purpose :   Physical constants and parameters linked to the ice
562      !!              thermodynamics
563      !!
564      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
565      !!              parameter values called at the first timestep (nit000)
566      !!
567      !! ** input   :   Namelist namicether
568      !!-------------------------------------------------------------------
569      INTEGER  ::   ios                 ! Local integer output status for namelist read
570      NAMELIST/namicethd/ rn_kappa_i, nn_ice_thcon, ln_dqnsice, rn_cdsn,                                  &
571         &                ln_limdH, rn_betas,                                                             &
572         &                ln_limdA, rn_beta, rn_dmin,                                                     &
573         &                ln_limdO, rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb, rn_himin,   &
574         &                nn_limflx
575      !!-------------------------------------------------------------------
576      !
577      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
578      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
579901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
580
581      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
582      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
583902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
584      IF(lwm) WRITE ( numoni, namicethd )
585      !
586      !
587      IF(lwp) THEN                          ! control print
588         WRITE(numout,*) 'lim_thd_init : Ice Thermodynamics'
589         WRITE(numout,*) '~~~~~~~~~~~~~'
590         WRITE(numout,*)'   -- limthd_dif --'
591         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
592         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
593         WRITE(numout,*)'      change the surface non-solar flux with Tsu or not       ln_dqnsice   = ', ln_dqnsice
594         WRITE(numout,*)'      thermal conductivity of the snow                        rn_cdsn      = ', rn_cdsn
595         WRITE(numout,*)'   -- limthd_dh --'
596         WRITE(numout,*)'      activate ice thick change from top/bot (T) or not (F)   ln_limdH     = ', ln_limdH
597         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
598         WRITE(numout,*)'   -- limthd_da --'
599         WRITE(numout,*)'      activate lateral melting (T) or not (F)                 ln_limdA     = ', ln_limdA
600         WRITE(numout,*)'      Coef. beta for lateral melting param.                   rn_beta      = ', rn_beta
601         WRITE(numout,*)'      Minimum floe diameter for lateral melting param.        rn_dmin      = ', rn_dmin
602         WRITE(numout,*)'   -- limthd_lac --'
603         WRITE(numout,*)'      activate ice growth in open-water (T) or not (F)        ln_limdO     = ', ln_limdO
604         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
605         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
606         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
607         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
608         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
609         WRITE(numout,*)'   -- limitd_th --'
610         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
611         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
612         WRITE(numout,*)'   -- icestp --'
613         WRITE(numout,*)'      Multicategory heat flux formulation                     nn_limflx    = ', nn_limflx
614      ENDIF
615      !
616      IF ( rn_hnewice < rn_himin )   CALL ctl_stop( 'STOP', 'lim_thd_init : rn_hnewice should be >= rn_himin' )
617      !
618      IF(lwp) WRITE(numout,*)
619      SELECT CASE( nn_limflx )         ! LIM3 Multi-category heat flux formulation
620      CASE ( -1 )
621         IF(lwp) WRITE(numout,*) '   LIM3: use per-category fluxes (nn_limflx = -1) '
622         IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
623      CASE ( 0  )
624         IF(lwp) WRITE(numout,*) '   LIM3: use average per-category fluxes (nn_limflx = 0) '
625      CASE ( 1  )
626         IF(lwp) WRITE(numout,*) '   LIM3: use average then redistribute per-category fluxes (nn_limflx = 1) '
627         IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
628      CASE ( 2  )
629         IF(lwp) WRITE(numout,*) '   LIM3: Redistribute a single flux over categories (nn_limflx = 2) '
630         IF( .NOT. ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in forced mode cannot be 2' )
631      CASE DEFAULT
632         CALL ctl_stop( 'sbcmod: LIM3 option, nn_limflx, should be between -1 and 2' )
633      END SELECT
634      !
635   END SUBROUTINE lim_thd_init
636
637#else
638   !!----------------------------------------------------------------------
639   !!   Default option         Dummy module          NO  LIM3 sea-ice model
640   !!----------------------------------------------------------------------
641#endif
642
643   !!======================================================================
644END MODULE limthd
Note: See TracBrowser for help on using the repository browser.