New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zrem.F90 in branches/CNRS/dev_r4826_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r4826_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p5zrem.F90 @ 5288

Last change on this file since 5288 was 5288, checked in by aumont, 9 years ago

various bug fixes and updates of PISCES quota
  • Property svn:executable set to *
File size: 20.9 KB
Line 
1MODULE p5zrem
2   !!======================================================================
3   !!                         ***  MODULE p5zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11#if defined key_pisces_quota
12   !!----------------------------------------------------------------------
13   !!   'key_top'       and                                      TOP models
14   !!   'key_pisces_quota'     PISCES bio-model with variable stoichiometry
15   !!----------------------------------------------------------------------
16   !!   p5z_rem       :  Compute remineralization/dissolution of organic compounds
17   !!   p5z_rem_init  :  Initialisation of parameters for remineralisation
18   !!   p5z_rem_alloc :  Allocate remineralisation variables
19   !!----------------------------------------------------------------------
20   USE oce_trc         !  shared variables between ocean and passive tracers
21   USE trc             !  passive tracers common variables
22   USE sms_pisces      !  PISCES Source Minus Sink variables
23   USE p4zopt          !  optical model
24   USE p4zche          !  chemical model
25   USE p5zprod         !  Growth rate of the 2 phyto groups
26   USE p5zmeso         !  Sources and sinks of mesozooplankton
27   USE p4zint          !  interpolation and computation of various fields
28   USE p5zlim
29   USE prtctl_trc      !  print control for debugging
30   USE iom             !  I/O manager
31
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   p5z_rem         ! called in p4zbio.F90
37   PUBLIC   p5z_rem_init    ! called in trcsms_pisces.F90
38   PUBLIC   p5z_rem_alloc
39
40   !! * Shared module variables
41   REAL(wp), PUBLIC ::  xremikc    !: remineralisation rate of POC
42   REAL(wp), PUBLIC ::  xremikn    !: remineralisation rate of POC
43   REAL(wp), PUBLIC ::  xremikp    !: remineralisation rate of POC
44   REAL(wp), PUBLIC ::  xremipc    !: remineralisation rate of DOC
45   REAL(wp), PUBLIC ::  xremipn    !: remineralisation rate of DOC
46   REAL(wp), PUBLIC ::  xremipp    !: remineralisation rate of DOC
47   REAL(wp), PUBLIC ::  nitrif     !: NH4 nitrification rate
48   REAL(wp), PUBLIC ::  xsirem     !: remineralisation rate of POC
49   REAL(wp), PUBLIC ::  xsiremlab  !: fast remineralisation rate of POC
50   REAL(wp), PUBLIC ::  xsilab     !: fraction of labile biogenic silica
51   REAL(wp), PUBLIC ::  oxymin     !: half saturation constant for anoxia
52   REAL(wp), PUBLIC ::  oxymin2    !: Minimum O2 concentration for oxic remin.
53
54
55   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitrc     !: denitrification array
56
57   !!* Substitution
58#  include "top_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
61   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   SUBROUTINE p5z_rem( kt, jnt )
67      !!---------------------------------------------------------------------
68      !!                     ***  ROUTINE p5z_rem  ***
69      !!
70      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
71      !!
72      !! ** Method  : - ???
73      !!---------------------------------------------------------------------
74      !
75      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
76      !
77      INTEGER  ::   ji, jj, jk
78      REAL(wp) ::   zremip, zremik, zremikc, zremikn, zremikp, zsiremin 
79      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
80      REAL(wp) ::   zbactfer, zopoc, zopon, zopop, zopoc2, zopon2, zopop2, zofer, zolimit
81      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
82#if ! defined key_kriest
83      REAL(wp) ::   zofer2
84#endif
85      REAL(wp) ::   zonitr, zstep, zrfact2
86      CHARACTER (len=25) :: charout
87      REAL(wp), POINTER, DIMENSION(:,:  ) :: ztempbac 
88      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdepbac, zwork1, zdepprod
89      !!---------------------------------------------------------------------
90      !
91      IF( nn_timing == 1 )  CALL timing_start('p5z_rem')
92      !
93      ! Allocate temporary workspace
94      CALL wrk_alloc( jpi, jpj,      ztempbac                  )
95      CALL wrk_alloc( jpi, jpj, jpk, zdepbac, zdepprod, zwork1 )
96
97      ! Initialisation of temprary arrys
98      zdepprod(:,:,:) = 1._wp
99      ztempbac(:,:)   = 0._wp
100
101      ! Computation of the mean phytoplankton concentration as
102      ! a crude estimate of the bacterial biomass
103      ! this parameterization has been deduced from a model version
104      ! that was modeling explicitely bacteria
105      ! -------------------------------------------------------
106      DO jk = 1, jpkm1
107         DO jj = 1, jpj
108            DO ji = 1, jpi
109               zdep = MAX( hmld(ji,jj), heup_01(ji,jj) )
110               IF( fsdept(ji,jj,jk) < zdep ) THEN
111                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trn(ji,jj,jk,jpzoo) + 2.* trn(ji,jj,jk,jpmes) ), 4.e-6 )
112                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
113               ELSE
114                  zdepmin = MIN( 1., zdep / fsdept(ji,jj,jk) )
115                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
116                  zdepprod(ji,jj,jk) = zdepmin**0.273
117               ENDIF
118            END DO
119         END DO
120      END DO
121
122      DO jk = 1, jpkm1
123         DO jj = 1, jpj
124            DO ji = 1, jpi
125               ! denitrification factor computed from O2 levels
126               ! ----------------------------------------------
127               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( oxymin2 - trn(ji,jj,jk,jpoxy) )    &
128                  &                                / ( oxymin + trn(ji,jj,jk,jpoxy) )  )
129               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
130            END DO
131         END DO
132      END DO
133
134      DO jk = 1, jpkm1
135         DO jj = 1, jpj
136            DO ji = 1, jpi
137               zstep   = xstep
138# if defined key_degrad
139               zstep = zstep * facvol(ji,jj,jk)
140# endif
141               ! DOC ammonification. Depends on depth, phytoplankton biomass
142               ! and a limitation term which is supposed to be a parameterization
143               ! of the bacterial activity.
144               ! -----------------------------------------------------------------
145               zremik = zstep / 1.e-6 * MAX(0.02, xlimbac(ji,jj,jk) ) * zdepbac(ji,jj,jk) 
146               zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
147
148               zremikc = xremikc * zremik
149               zremikn = xremikn * zremik * 1.0 / (5.6*rno3)
150               zremikp = xremikp * zremik * 1.0 / (75.0*po4r)
151
152               ! Ammonification in oxic waters with oxygen consumption
153               ! -----------------------------------------------------
154               zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trn(ji,jj,jk,jpdoc) 
155               zolimic = MAX( 0.e0, MIN( ( trn(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) ) 
156               zwork1(ji,jj,jk) = zolimic
157               zolimin = zolimic * trn(ji,jj,jk,jpdon) / ( trn(ji,jj,jk,jpdoc) + rtrn )
158               zolimip = zolimic * trn(ji,jj,jk,jpdop) / ( trn(ji,jj,jk,jpdoc) + rtrn ) 
159
160               ! Ammonification in suboxic waters with denitrification
161               ! -------------------------------------------------------
162               zolimit = zremikc * nitrfac(ji,jj,jk) * trn(ji,jj,jk,jpdoc)
163               denitrc(ji,jj,jk)  = MIN(  ( trn(ji,jj,jk,jpno3) - rtrn ) / rdenit, zolimit )
164               denitrc (ji,jj,jk) = MAX( 0.e0, denitrc (ji,jj,jk) )
165               zdenitrn  = denitrc(ji,jj,jk) * trn(ji,jj,jk,jpdon) / ( trn(ji,jj,jk,jpdoc) + rtrn )
166               zdenitrp  = denitrc(ji,jj,jk) * trn(ji,jj,jk,jpdop) / ( trn(ji,jj,jk,jpdoc) + rtrn )
167
168               ! Update of trends TRA
169               ! --------------------
170               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimip + zdenitrp
171               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimin + zdenitrn
172               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitrc(ji,jj,jk) * rdenit
173               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimic - denitrc(ji,jj,jk)
174               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zolimin - zdenitrn
175               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zolimip - zdenitrp
176               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
177               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitrc(ji,jj,jk)
178               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimin + ( rdenit + 1.) * zdenitrn )
179
180            END DO
181         END DO
182      END DO
183
184
185      DO jk = 1, jpkm1
186         DO jj = 1, jpj
187            DO ji = 1, jpi
188               zstep   = xstep
189# if defined key_degrad
190               zstep = zstep * facvol(ji,jj,jk)
191# endif
192               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
193               ! below 2 umol/L. Inhibited at strong light
194               ! ----------------------------------------------------------
195               zonitr   = nitrif * zstep * trn(ji,jj,jk,jpnh4) * (0.2 + 0.8 / ( 1.+ emoy(ji,jj,jk) ) ) &
196               &          * ( 1.- nitrfac(ji,jj,jk) ) 
197               zdenitnh4 = nitrif * zstep * trn(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk) 
198
199               ! Update of the tracers trends
200               ! ----------------------------
201               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
202               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
203               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
204               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
205            END DO
206         END DO
207      END DO
208
209      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
210        WRITE(charout, FMT="('rem1')")
211        CALL prt_ctl_trc_info(charout)
212        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
213      ENDIF
214
215      DO jk = 1, jpkm1
216         DO jj = 1, jpj
217            DO ji = 1, jpi
218
219               ! Bacterial uptake of iron. No iron is available in DOC. So
220               ! Bacteries are obliged to take up iron from the water. Some
221               ! studies (especially at Papa) have shown this uptake to be significant
222               ! ----------------------------------------------------------
223               zbactfer = ferat3 *  rfact2 * prmaxp(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
224                  &              * biron(ji,jj,jk) / ( 2E-10 + biron(ji,jj,jk) )    &
225                  &              * zdepprod(ji,jj,jk) * zdepbac(ji,jj,jk)
226#if defined key_kriest
227               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.05
228               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.05
229#else
230               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.16
231               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.12
232               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.04
233#endif
234            END DO
235         END DO
236      END DO
237
238      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
239        WRITE(charout, FMT="('rem2')")
240        CALL prt_ctl_trc_info(charout)
241        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
242      ENDIF
243
244      DO jk = 1, jpkm1
245         DO jj = 1, jpj
246            DO ji = 1, jpi
247               zstep   = xstep
248# if defined key_degrad
249               zstep = zstep * facvol(ji,jj,jk)
250# endif
251               ! POC disaggregation by turbulence and bacterial activity.
252               ! --------------------------------------------------------
253               zremip = zstep * tgfunc(ji,jj,jk) * ( 1.- 0.55 * nitrfac(ji,jj,jk) ) 
254
255               ! POC disaggregation rate is reduced in anoxic zone as shown by
256               ! sediment traps data. In oxic area, the exponent of the martin s
257               ! law is around -0.87. In anoxic zone, it is around -0.35. This
258               ! means a disaggregation constant about 0.5 the value in oxic zones
259               ! -----------------------------------------------------------------
260               zopoc  = xremipc * zremip * trn(ji,jj,jk,jppoc)
261               zopon  = xremipn * zremip * trn(ji,jj,jk,jppon)
262               zopop  = xremipp * zremip * trn(ji,jj,jk,jppop)
263               zofer  = xremipn * zremip * trn(ji,jj,jk,jpsfe)
264#if ! defined key_kriest
265               zopoc2 = xremipc * zremip * trn(ji,jj,jk,jpgoc)
266               zopon2 = xremipn * zremip * trn(ji,jj,jk,jpgon)
267               zopop2 = xremipp * zremip * trn(ji,jj,jk,jpgop)
268               zofer2 = xremipn * zremip * trn(ji,jj,jk,jpbfe)
269#else
270               zopoc2 = xremipc * zremip * trn(ji,jj,jk,jpnum)
271#endif
272
273               ! Update the appropriate tracers trends
274               ! -------------------------------------
275#if defined key_kriest
276               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zopoc
277               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) - zopon
278               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) - zopop
279               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zofer
280               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zopoc
281               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zopon
282               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + zopop
283               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zofer
284               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) - zopoc2
285#else
286               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zopoc + zopoc2
287               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) - zopon + zopon2
288               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) - zopop + zopop2
289               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zofer + zofer2
290               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zopoc 
291               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zopon 
292               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + zopop 
293               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zofer 
294               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) - zopoc2
295               tra(ji,jj,jk,jpgon) = tra(ji,jj,jk,jpgon) - zopon2
296               tra(ji,jj,jk,jpgop) = tra(ji,jj,jk,jpgop) - zopop2
297               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) - zofer2
298#endif
299            END DO
300         END DO
301      END DO
302
303      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
304        WRITE(charout, FMT="('rem3')")
305        CALL prt_ctl_trc_info(charout)
306        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
307      ENDIF
308
309      DO jk = 1, jpkm1
310         DO jj = 1, jpj
311            DO ji = 1, jpi
312               zstep   = xstep
313# if defined key_degrad
314               zstep = zstep * facvol(ji,jj,jk)
315# endif
316               ! Remineralization rate of BSi depedant on T and saturation
317               ! ---------------------------------------------------------
318               zsatur   = ( sio3eq(ji,jj,jk) - trn(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn )
319               zsatur   = MAX( rtrn, zsatur )
320               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
321               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
322               znusil2  = 0.225  * ( 1. + tsn(ji,jj,1,jp_tem) / 15.) + 0.775 * zsatur2
323
324               ! Two classes of BSi are considered : a labile fraction and
325               ! a more refractory one. The ratio between both fractions is
326               ! constant and specified in the namelist.
327               ! ----------------------------------------------------------
328               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) ) 
329               zdep     = MAX( 0., fsdept(ji,jj,jk) - zdep )
330               ztem     = MAX( tsn(ji,jj,1,jp_tem), 0. )
331               zfactdep = xsilab * EXP(-( xsiremlab - xsirem ) * znusil2 * zdep / wsbio2 ) * ztem / ( ztem + 10. )
332               zsiremin = ( xsiremlab * zfactdep + xsirem * ( 1. - zfactdep ) ) * zstep * znusil
333               zosil    = zsiremin * trn(ji,jj,jk,jpgsi)
334               !
335               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
336               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
337               !
338            END DO
339         END DO
340      END DO
341
342      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
343         WRITE(charout, FMT="('rem4')")
344         CALL prt_ctl_trc_info(charout)
345         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
346       ENDIF
347
348      IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc ) THEN
349          zrfact2 = 1.e3 * rfact2r
350          CALL iom_put( "REMIN" , zwork1(:,:,:) * tmask(:,:,:) * zrfact2 )  ! Remineralisation rate
351          CALL iom_put( "DENIT" , denitrc(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zrfact2  )  ! Denitrification
352      ENDIF
353
354      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
355         WRITE(charout, FMT="('rem6')")
356         CALL prt_ctl_trc_info(charout)
357         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
358      ENDIF
359      !
360      CALL wrk_dealloc( jpi, jpj,      ztempbac                  )
361      CALL wrk_dealloc( jpi, jpj, jpk, zdepbac, zdepprod, zwork1 )
362      !
363      IF( nn_timing == 1 )  CALL timing_stop('p5z_rem')
364      !
365   END SUBROUTINE p5z_rem
366
367
368   SUBROUTINE p5z_rem_init
369      !!----------------------------------------------------------------------
370      !!                  ***  ROUTINE p5z_rem_init  ***
371      !!
372      !! ** Purpose :   Initialization of remineralization parameters
373      !!
374      !! ** Method  :   Read the nampisrem namelist and check the parameters
375      !!      called at the first timestep
376      !!
377      !! ** input   :   Namelist nampisrem
378      !!
379      !!----------------------------------------------------------------------
380      NAMELIST/nampisrem/ xremikc, xremikn, xremikp, xremipc, xremipn, xremipp,   &
381      &                   nitrif, xsirem, xsiremlab, xsilab, oxymin, oxymin2
382      INTEGER :: ios                 ! Local integer output status for namelist read
383
384      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
385      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
386901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
387
388      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
389      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
390902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
391      IF(lwm) WRITE ( numonp, nampisrem )
392
393      IF(lwp) THEN                         ! control print
394         WRITE(numout,*) ' '
395         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
396         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
397         WRITE(numout,*) '    remineralisation rate of POC              xremipc   =', xremipc
398         WRITE(numout,*) '    remineralisation rate of PON              xremipn   =', xremipn
399         WRITE(numout,*) '    remineralisation rate of POP              xremipp   =', xremipp
400         WRITE(numout,*) '    remineralization rate of DOC              xremikc   =', xremikc
401         WRITE(numout,*) '    remineralization rate of DON              xremikn   =', xremikn
402         WRITE(numout,*) '    remineralization rate of DOP              xremikp   =', xremikp
403         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
404         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
405         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
406         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
407         WRITE(numout,*) '    half saturation constant for anoxia       oxymin    =', oxymin
408         WRITE(numout,*) '    Minimum O2 concentration for oxic remin.  oxymin2   =', oxymin2
409      ENDIF
410      !
411      nitrfac (:,:,:) = 0._wp
412      denitrc (:,:,:) = 0._wp
413      !
414   END SUBROUTINE p5z_rem_init
415
416
417   INTEGER FUNCTION p5z_rem_alloc()
418      !!----------------------------------------------------------------------
419      !!                     ***  ROUTINE p5z_rem_alloc  ***
420      !!----------------------------------------------------------------------
421      ALLOCATE( denitrc(jpi,jpj,jpk), STAT=p5z_rem_alloc )
422      !
423      IF( p5z_rem_alloc /= 0 )   CALL ctl_warn('p5z_rem_alloc: failed to allocate arrays')
424      !
425   END FUNCTION p5z_rem_alloc
426
427#else
428   !!======================================================================
429   !!  Dummy module :                                   No PISCES bio-model
430   !!======================================================================
431CONTAINS
432   SUBROUTINE p5z_rem                    ! Empty routine
433   END SUBROUTINE p5z_rem
434#endif 
435
436   !!======================================================================
437END MODULE p5zrem
Note: See TracBrowser for help on using the repository browser.