New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zprod.F90 @ 6966

Last change on this file since 6966 was 6966, checked in by aumont, 8 years ago

various bug fixes and updates on carbon chemistry
File size: 29.2 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
15   !!   p4z_prod_init  :   Initialization of the parameters for growth
16   !!   p4z_prod_alloc :   Allocate variables for growth
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_prod         ! called in p4zbio.F90
30   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
31   PUBLIC   p4z_prod_alloc
32
33   !! * Shared module variables
34   LOGICAL , PUBLIC ::  ln_newprod      !:
35   REAL(wp), PUBLIC ::  pislopen         !:
36   REAL(wp), PUBLIC ::  pisloped        !:
37   REAL(wp), PUBLIC ::  xadap           !:
38   REAL(wp), PUBLIC ::  excretn          !:
39   REAL(wp), PUBLIC ::  excretd         !:
40   REAL(wp), PUBLIC ::  bresp           !:
41   REAL(wp), PUBLIC ::  chlcnm          !:
42   REAL(wp), PUBLIC ::  chlcdm          !:
43   REAL(wp), PUBLIC ::  chlcmin         !:
44   REAL(wp), PUBLIC ::  fecnm           !:
45   REAL(wp), PUBLIC ::  fecdm           !:
46   REAL(wp), PUBLIC ::  grosip          !:
47
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
51   
52   REAL(wp) :: r1_rday                !: 1 / rday
53   REAL(wp) :: texcretn               !: 1 - excretn
54   REAL(wp) :: texcretd               !: 1 - excretd       
55
56
57   !!* Substitution
58#  include "top_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
61   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   SUBROUTINE p4z_prod( kt , knt )
67      !!---------------------------------------------------------------------
68      !!                     ***  ROUTINE p4z_prod  ***
69      !!
70      !! ** Purpose :   Compute the phytoplankton production depending on
71      !!              light, temperature and nutrient availability
72      !!
73      !! ** Method  : - ???
74      !!---------------------------------------------------------------------
75      !
76      INTEGER, INTENT(in) :: kt, knt
77      !
78      INTEGER  ::   ji, jj, jk
79      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
80      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap, zlim, zsilfac2, zsiborn
81      REAL(wp) ::   zprod, zproreg, zproreg2, zprochln, zprochld
82      REAL(wp) ::   zmaxday, zdocprod, zpislopen, zpisloped
83      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup
84      REAL(wp) ::   zfact
85      CHARACTER (len=25) :: charout
86      REAL(wp), POINTER, DIMENSION(:,:  ) :: zstrn, zw2d
87      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopeadn, zpislopeadd, zprdia, zprbio, zprdch, zprnch, zysopt, zw3d   
88      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorcan, zprorcad, zprofed, zprofen, zpronewn, zpronewd
89      REAL(wp), POINTER, DIMENSION(:,:,:) :: zmxl_fac, zmxl_chl
90      !!---------------------------------------------------------------------
91      !
92      IF( nn_timing == 1 )  CALL timing_start('p4z_prod')
93      !
94      !  Allocate temporary workspace
95      CALL wrk_alloc( jpi, jpj,      zstrn )
96      CALL wrk_alloc( jpi, jpj, jpk, zpislopeadn, zpislopeadd, zprdia, zprbio, zprdch, zprnch, zysopt ) 
97      CALL wrk_alloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
98      CALL wrk_alloc( jpi, jpj, jpk, zprorcan, zprorcad, zprofed, zprofen, zpronewn, zpronewd )
99      !
100      zprorcan(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp ; zprofed (:,:,:) = 0._wp
101      zprofen (:,:,:) = 0._wp ; zysopt  (:,:,:) = 0._wp
102      zpronewn(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp ; zprdia  (:,:,:) = 0._wp
103      zprbio  (:,:,:) = 0._wp ; zprdch  (:,:,:) = 0._wp ; zprnch  (:,:,:) = 0._wp 
104
105      ! Computation of the optimal production
106      prmax(:,:,:) = 0.6_wp * r1_rday * tgfunc(:,:,:) 
107      IF( lk_degrad )  prmax(:,:,:) = prmax(:,:,:) * facvol(:,:,:) 
108
109      ! compute the day length depending on latitude and the day
110      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
111      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
112
113      ! day length in hours
114      zstrn(:,:) = 0.
115      DO jj = 1, jpj
116         DO ji = 1, jpi
117            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
118            zargu = MAX( -1., MIN(  1., zargu ) )
119            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
120         END DO
121      END DO
122
123      ! Impact of the day duration and light intermittency on phytoplankton growth
124      DO jk = 1, jpkm1
125         DO jj = 1 ,jpj
126            DO ji = 1, jpi
127               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
128                  zval = MAX( 1., zstrn(ji,jj) )
129                  zmxl_fac(ji,jj,jk) = zval
130                  zmxl_chl(ji,jj,jk) = zval / 24.
131                  IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
132                     zval = MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
133                     zmxl_fac(ji,jj,jk) = zmxl_fac(ji,jj,jk) * zval
134                     zmxl_chl(ji,jj,jk) = zmxl_chl(ji,jj,jk) * zval
135                  ENDIF
136                  zmxl_fac(ji,jj,jk) = ( 1. - exp( -0.2 * zmxl_fac(ji,jj,jk) ) )
137                  zmxl_chl(ji,jj,jk) = zmxl_chl(ji,jj,jk)
138               ENDIF
139            END DO
140         END DO
141      END DO
142
143      zprbio(:,:,:) = prmax(:,:,:) * zmxl_fac(:,:,:)
144      zprdia(:,:,:) = zprbio(:,:,:)
145
146      ! Computation of the P-I slope for nanos and diatoms
147      DO jk = 1, jpkm1
148!CDIR NOVERRCHK
149         DO jj = 1, jpj
150!CDIR NOVERRCHK
151            DO ji = 1, jpi
152               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
153                  ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
154                  zadap       = xadap * ztn / ( 2.+ ztn )
155                  zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
156                  zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
157                  !
158                  zpislopeadn(ji,jj,jk) = pislopen * ( 1.+ zadap  * EXP( -0.25 * enano(ji,jj,jk) ) )  &
159                  &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
160                  !
161                  zpislopeadd(ji,jj,jk) = (pislopen * zconctemp2 + pisloped * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn )   &
162                  &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
163               ENDIF
164            END DO
165         END DO
166      END DO
167
168      IF( ln_newprod ) THEN
169         DO jk = 1, jpkm1
170            DO jj = 1, jpj
171               DO ji = 1, jpi
172                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
173                      ! Computation of production function for Carbon
174                      !  ---------------------------------------------
175                      zpislopen = zpislopeadn(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
176                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
177                      zpisloped = zpislopeadd(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
178                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
179                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
180                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
181                      !  Computation of production function for Chlorophyll
182                      !--------------------------------------------------
183                      zpislopen = zpislopeadn(ji,jj,jk) / ( prmax(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
184                      zpisloped = zpislopeadd(ji,jj,jk) / ( prmax(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
185                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
186                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
187                  ENDIF
188               END DO
189            END DO
190         END DO
191      ELSE
192         DO jk = 1, jpkm1
193            DO jj = 1, jpj
194               DO ji = 1, jpi
195                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
196                      ! Computation of production function for Carbon
197                      !  ---------------------------------------------
198                      zpislopen = zpislopeadn(ji,jj,jk)  / ( zprbio(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
199                      zpisloped = zpislopeadd(ji,jj,jk) / ( zprdia(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
200                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
201                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
202                      !  Computation of production function for Chlorophyll
203                      !--------------------------------------------------
204                      zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
205                      zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
206                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
207                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
208                  ENDIF
209               END DO
210            END DO
211         END DO
212      ENDIF
213
214      !  Computation of a proxy of the N/C ratio
215      !  ---------------------------------------
216      DO jk = 1, jpkm1
217         DO jj = 1, jpj
218            DO ji = 1, jpi
219                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
220                &      * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
221                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
222                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
223                &      * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
224                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
225            END DO
226         END DO
227      END DO
228
229
230      DO jk = 1, jpkm1
231         DO jj = 1, jpj
232            DO ji = 1, jpi
233
234                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
235                   !    Si/C of diatoms
236                   !    ------------------------
237                   !    Si/C increases with iron stress and silicate availability
238                   !    Si/C is arbitrariliy increased for very high Si concentrations
239                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
240                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
241                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
242                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
243                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
244                  IF (gphit(ji,jj) < -30 ) THEN
245                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
246                  ELSE
247                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
248                  ENDIF
249                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
250              ENDIF
251            END DO
252         END DO
253      END DO
254
255      !  Sea-ice effect on production
256
257      DO jk = 1, jpkm1
258         zprbio(:,:,jk) = zprbio(:,:,jk) * ( 1. - fr_i(:,:) )
259         zprdia(:,:,jk) = zprdia(:,:,jk) * ( 1. - fr_i(:,:) )
260      END DO
261
262
263      ! Computation of the various production terms
264!CDIR NOVERRCHK
265      DO jk = 1, jpkm1
266!CDIR NOVERRCHK
267         DO jj = 1, jpj
268!CDIR NOVERRCHK
269            DO ji = 1, jpi
270               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
271                  !  production terms for nanophyto. (C)
272                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
273                  zpronewn(ji,jj,jk)  = zprorcan(ji,jj,jk)* xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
274                  !
275                  zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) * fecnm + rtrn )
276                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
277                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
278                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
279                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
280                  &             * zmax * trb(ji,jj,jk,jpphy) * rfact2
281                  !  production terms for diatoms (C)
282                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
283                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
284                  !
285                  zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) * fecdm + rtrn )
286                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
287                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
288                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
289                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
290                  &             * zmax * trb(ji,jj,jk,jpdia) * rfact2
291               ENDIF
292            END DO
293         END DO
294      END DO
295
296      ! Computation of the chlorophyll production terms
297      DO jk = 1, jpkm1
298         DO jj = 1, jpj
299            DO ji = 1, jpi
300               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
301                  !  production terms for nanophyto. ( chlorophyll )
302                  znanotot = enano(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
303                  zprod    = rday * zprorcan(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
304                  zprochln = chlcmin * 12. * zprorcan (ji,jj,jk)
305                  zprochln = zprochln + (chlcnm-chlcmin) * 12. * zprod / &
306                                        & (  zpislopeadn(ji,jj,jk) * znanotot +rtrn)
307                  !  production terms for diatoms ( chlorophyll )
308                  zdiattot = ediat(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
309                  zprod    = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
310                  zprochld = chlcmin * 12. * zprorcad(ji,jj,jk)
311                  zprochld = zprochld + (chlcdm-chlcmin) * 12. * zprod / &
312                                        & ( zpislopeadd(ji,jj,jk) * zdiattot +rtrn )
313                  !   Update the arrays TRA which contain the Chla sources and sinks
314                  tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln * texcretn
315                  tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld * texcretd
316               ENDIF
317            END DO
318         END DO
319      END DO
320
321      !   Update the arrays TRA which contain the biological sources and sinks
322      DO jk = 1, jpkm1
323         DO jj = 1, jpj
324           DO ji =1 ,jpi
325              IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
326                 zproreg  = zprorcan(ji,jj,jk) - zpronewn(ji,jj,jk)
327                 zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
328                 zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
329                 tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
330                 tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)
331                 tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
332                 tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcretn
333                 tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcretn
334                 tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcretd
335                 tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcretd
336                 tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
337                 tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zdocprod
338                 zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
339#if defined key_ligand
340                 tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zdocprod * ldocp  - zfeup * plig(ji,jj,jk) * lthet
341#endif
342                 tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
343                 &                   + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) )
344                 tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zfeup
345                 tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
346                 tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
347                 tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
348                 &                                         - rno3 * ( zproreg + zproreg2 )
349              ENDIF
350           END DO
351        END DO
352     END DO
353
354
355    ! Total primary production per year
356    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
357         & tpp = glob_sum( ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
358
359    IF( lk_iomput ) THEN
360       IF( knt == nrdttrc ) THEN
361          CALL wrk_alloc( jpi, jpj,      zw2d )
362          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
363          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
364          !
365          IF( iom_use( "PPPHY" ) .OR. iom_use( "PPPHY2" ) )  THEN
366              zw3d(:,:,:) = zprorcan(:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
367              CALL iom_put( "PPPHY"  , zw3d )
368              !
369              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
370              CALL iom_put( "PPPHY2"  , zw3d )
371          ENDIF
372          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
373              zw3d(:,:,:) = zpronewn(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
374              CALL iom_put( "PPNEWN"  , zw3d )
375              !
376              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
377              CALL iom_put( "PPNEWD"  , zw3d )
378          ENDIF
379          IF( iom_use( "PBSi" ) )  THEN
380              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
381              CALL iom_put( "PBSi"  , zw3d )
382          ENDIF
383          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
384              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
385              CALL iom_put( "PFeN"  , zw3d )
386              !
387              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
388              CALL iom_put( "PFeD"  , zw3d )
389          ENDIF
390          IF( iom_use( "Mumax" ) )  THEN
391              zw3d(:,:,:) = prmax(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
392              CALL iom_put( "Mumax"  , zw3d )
393          ENDIF
394          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
395              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
396              CALL iom_put( "MuN"  , zw3d )
397              !
398              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
399              CALL iom_put( "MuD"  , zw3d )
400          ENDIF
401          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
402              zw3d(:,:,:) = zprbio (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
403              CALL iom_put( "LNlight"  , zw3d )
404              !
405              zw3d(:,:,:) =  zprdia (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
406              CALL iom_put( "LDlight"  , zw3d )
407          ENDIF
408          IF( iom_use( "TPP" ) )  THEN
409              zw3d(:,:,:) = ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
410              CALL iom_put( "TPP"  , zw3d )
411          ENDIF
412          IF( iom_use( "TPNEW" ) )  THEN
413              zw3d(:,:,:) = ( zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
414              CALL iom_put( "TPNEW"  , zw3d )
415          ENDIF
416          IF( iom_use( "TPBFE" ) )  THEN
417              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
418              CALL iom_put( "TPBFE"  , zw3d )
419          ENDIF
420          IF( iom_use( "INTPPPHY" ) .OR. iom_use( "INTPPPHY2" ) ) THEN 
421             zw2d(:,:) = 0.
422             DO jk = 1, jpkm1
423               zw2d(:,:) = zw2d(:,:) + zprorcan(:,:,jk) * fse3t(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
424             ENDDO
425             CALL iom_put( "INTPPPHY" , zw2d )
426             !
427             zw2d(:,:) = 0.
428             DO jk = 1, jpkm1
429                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * fse3t(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
430             ENDDO
431             CALL iom_put( "INTPPPHY2" , zw2d )
432          ENDIF
433          IF( iom_use( "INTPP" ) ) THEN   
434             zw2d(:,:) = 0.
435             DO jk = 1, jpkm1
436                zw2d(:,:) = zw2d(:,:) + ( zprorcan(:,:,jk) + zprorcad(:,:,jk) ) * fse3t(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated pp
437             ENDDO
438             CALL iom_put( "INTPP" , zw2d )
439          ENDIF
440          IF( iom_use( "INTPNEW" ) ) THEN   
441             zw2d(:,:) = 0.
442             DO jk = 1, jpkm1
443                zw2d(:,:) = zw2d(:,:) + ( zpronewn(:,:,jk) + zpronewd(:,:,jk) ) * fse3t(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
444             ENDDO
445             CALL iom_put( "INTPNEW" , zw2d )
446          ENDIF
447          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
448             zw2d(:,:) = 0.
449             DO jk = 1, jpkm1
450                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * fse3t(:,:,jk) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
451             ENDDO
452            CALL iom_put( "INTPBFE" , zw2d )
453          ENDIF
454          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
455             zw2d(:,:) = 0.
456             DO jk = 1, jpkm1
457                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * fse3t(:,:,jk) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
458             ENDDO
459             CALL iom_put( "INTPBSI" , zw2d )
460          ENDIF
461          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
462          !
463          CALL wrk_dealloc( jpi, jpj,      zw2d )
464          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
465       ENDIF
466     ELSE
467        IF( ln_diatrc ) THEN
468           zfact = 1.e+3 * rfact2r
469           trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorcan(:,:,:) * zfact * tmask(:,:,:)
470           trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zfact * tmask(:,:,:)
471           trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronewn(:,:,:) * zfact * tmask(:,:,:)
472           trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zfact * tmask(:,:,:)
473           trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:)
474           trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zfact * tmask(:,:,:)
475#  if ! defined key_kriest
476           trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zfact * tmask(:,:,:)
477#  endif
478        ENDIF
479     ENDIF
480
481     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
482         WRITE(charout, FMT="('prod')")
483         CALL prt_ctl_trc_info(charout)
484         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
485     ENDIF
486     !
487     CALL wrk_dealloc( jpi, jpj,      zstrn )
488     CALL wrk_dealloc( jpi, jpj, jpk, zpislopeadn, zpislopeadd, zprdia, zprbio, zprdch, zprnch, zysopt ) 
489     CALL wrk_dealloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
490     CALL wrk_dealloc( jpi, jpj, jpk, zprorcan, zprorcad, zprofed, zprofen, zpronewn, zpronewd )
491     !
492     IF( nn_timing == 1 )  CALL timing_stop('p4z_prod')
493     !
494   END SUBROUTINE p4z_prod
495
496
497   SUBROUTINE p4z_prod_init
498      !!----------------------------------------------------------------------
499      !!                  ***  ROUTINE p4z_prod_init  ***
500      !!
501      !! ** Purpose :   Initialization of phytoplankton production parameters
502      !!
503      !! ** Method  :   Read the nampisprod namelist and check the parameters
504      !!      called at the first timestep (nittrc000)
505      !!
506      !! ** input   :   Namelist nampisprod
507      !!----------------------------------------------------------------------
508      !
509      NAMELIST/nampisprod/ pislopen, pisloped, xadap, ln_newprod, bresp, excretn, excretd,  &
510         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
511      INTEGER :: ios                 ! Local integer output status for namelist read
512      !!----------------------------------------------------------------------
513
514      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
515      READ  ( numnatp_ref, nampisprod, IOSTAT = ios, ERR = 901)
516901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in reference namelist', lwp )
517
518      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
519      READ  ( numnatp_cfg, nampisprod, IOSTAT = ios, ERR = 902 )
520902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in configuration namelist', lwp )
521      IF(lwm) WRITE ( numonp, nampisprod )
522
523      IF(lwp) THEN                         ! control print
524         WRITE(numout,*) ' '
525         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
526         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
527         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod    =', ln_newprod
528         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
529         WRITE(numout,*) '    P-I slope                                 pislopen     =', pislopen
530         WRITE(numout,*) '    Acclimation factor to low light           xadap        =', xadap
531         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excretn      =', excretn
532         WRITE(numout,*) '    excretion ratio of diatoms                excretd      =', excretd
533         IF( ln_newprod )  THEN
534            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
535            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
536         ENDIF
537         WRITE(numout,*) '    P-I slope  for diatoms                    pisloped     =', pisloped
538         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
539         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
540         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
541         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
542      ENDIF
543      !
544      r1_rday   = 1._wp / rday 
545      texcretn  = 1._wp - excretn
546      texcretd  = 1._wp - excretd
547      tpp       = 0._wp
548      !
549   END SUBROUTINE p4z_prod_init
550
551
552   INTEGER FUNCTION p4z_prod_alloc()
553      !!----------------------------------------------------------------------
554      !!                     ***  ROUTINE p4z_prod_alloc  ***
555      !!----------------------------------------------------------------------
556      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
557      !
558      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
559      !
560   END FUNCTION p4z_prod_alloc
561
562#else
563   !!======================================================================
564   !!  Dummy module :                                   No PISCES bio-model
565   !!======================================================================
566CONTAINS
567   SUBROUTINE p4z_prod                    ! Empty routine
568   END SUBROUTINE p4z_prod
569#endif 
570
571   !!======================================================================
572END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.