| 1 | MODULE traqsr |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traqsr *** |
|---|
| 4 | !! Ocean physics: solar radiation penetration in the top ocean levels |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (G. Madec) |
|---|
| 8 | !! ! 1996-01 (G. Madec) s-coordinates |
|---|
| 9 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 10 | !! - ! 2005-11 (G. Madec) zco, zps, sco coordinate |
|---|
| 11 | !! 3.2 ! 2009-04 (G. Madec & NEMO team) |
|---|
| 12 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! tra_qsr : trend due to the solar radiation penetration |
|---|
| 17 | !! tra_qsr_init : solar radiation penetration initialization |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | USE oce ! ocean dynamics and active tracers |
|---|
| 20 | USE dom_oce ! ocean space and time domain |
|---|
| 21 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 22 | USE trc_oce ! share SMS/Ocean variables |
|---|
| 23 | USE trdmod_oce ! ocean variables trends |
|---|
| 24 | USE trdmod ! ocean active tracers trends |
|---|
| 25 | USE in_out_manager ! I/O manager |
|---|
| 26 | USE phycst ! physical constants |
|---|
| 27 | USE prtctl ! Print control |
|---|
| 28 | USE iom ! I/O manager |
|---|
| 29 | USE fldread ! read input fields |
|---|
| 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| 34 | PUBLIC tra_qsr ! routine called by step.F90 (ln_traqsr=T) |
|---|
| 35 | |
|---|
| 36 | ! !!* Namelist namtra_qsr: penetrative solar radiation |
|---|
| 37 | LOGICAL , PUBLIC :: ln_traqsr = .TRUE. !: light absorption (qsr) flag |
|---|
| 38 | LOGICAL , PUBLIC :: ln_qsr_rgb = .FALSE. !: Red-Green-Blue light absorption flag |
|---|
| 39 | LOGICAL , PUBLIC :: ln_qsr_2bd = .TRUE. !: 2 band light absorption flag |
|---|
| 40 | LOGICAL , PUBLIC :: ln_qsr_bio = .FALSE. !: bio-model light absorption flag |
|---|
| 41 | INTEGER , PUBLIC :: nn_chldta = 0 !: use Chlorophyll data (=1) or not (=0) |
|---|
| 42 | REAL(wp), PUBLIC :: rn_abs = 0.58_wp !: fraction absorbed in the very near surface (RGB & 2 bands) |
|---|
| 43 | REAL(wp), PUBLIC :: rn_si0 = 0.35_wp !: very near surface depth of extinction (RGB & 2 bands) |
|---|
| 44 | REAL(wp), PUBLIC :: rn_si1 = 23.0_wp !: deepest depth of extinction (water type I) (2 bands) |
|---|
| 45 | REAL(wp), PUBLIC :: rn_si2 = 61.8_wp !: deepest depth of extinction (blue & 0.01 mg.m-3) (RGB) |
|---|
| 46 | |
|---|
| 47 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_chl ! structure of input Chl (file informations, fields read) |
|---|
| 48 | |
|---|
| 49 | INTEGER , PUBLIC :: nksr ! levels below which the light cannot penetrate (depth larger than 391 m) |
|---|
| 50 | REAL(wp), DIMENSION(3,61) :: rkrgb ! tabulated attenuation coefficients for RGB absorption |
|---|
| 51 | |
|---|
| 52 | !! * Substitutions |
|---|
| 53 | # include "domzgr_substitute.h90" |
|---|
| 54 | # include "vectopt_loop_substitute.h90" |
|---|
| 55 | !!---------------------------------------------------------------------- |
|---|
| 56 | !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010) |
|---|
| 57 | !! $Id$ |
|---|
| 58 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | |
|---|
| 61 | CONTAINS |
|---|
| 62 | |
|---|
| 63 | SUBROUTINE tra_qsr( kt ) |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | !! *** ROUTINE tra_qsr *** |
|---|
| 66 | !! |
|---|
| 67 | !! ** Purpose : Compute the temperature trend due to the solar radiation |
|---|
| 68 | !! penetration and add it to the general temperature trend. |
|---|
| 69 | !! |
|---|
| 70 | !! ** Method : The profile of the solar radiation within the ocean is defined |
|---|
| 71 | !! through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs |
|---|
| 72 | !! Considering the 2 wavebands case: |
|---|
| 73 | !! I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) ) |
|---|
| 74 | !! The temperature trend associated with the solar radiation penetration |
|---|
| 75 | !! is given by : zta = 1/e3t dk[ I ] / (rau0*Cp) |
|---|
| 76 | !! At the bottom, boudary condition for the radiation is no flux : |
|---|
| 77 | !! all heat which has not been absorbed in the above levels is put |
|---|
| 78 | !! in the last ocean level. |
|---|
| 79 | !! In z-coordinate case, the computation is only done down to the |
|---|
| 80 | !! level where I(k) < 1.e-15 W/m2. In addition, the coefficients |
|---|
| 81 | !! used for the computation are calculated one for once as they |
|---|
| 82 | !! depends on k only. |
|---|
| 83 | !! |
|---|
| 84 | !! ** Action : - update ta with the penetrative solar radiation trend |
|---|
| 85 | !! - save the trend in ttrd ('key_trdtra') |
|---|
| 86 | !! |
|---|
| 87 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 88 | !! Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516. |
|---|
| 89 | !!---------------------------------------------------------------------- |
|---|
| 90 | USE oce, ONLY : ztrdt => ua ! use ua as 3D workspace |
|---|
| 91 | USE oce, ONLY : ztrds => va ! use va as 3D workspace |
|---|
| 92 | !! |
|---|
| 93 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 94 | !! |
|---|
| 95 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 96 | INTEGER :: irgb ! temporary integers |
|---|
| 97 | REAL(wp) :: zchl, zcoef, zsi0r ! temporary scalars |
|---|
| 98 | REAL(wp) :: zc0, zc1, zc2, zc3 ! - - |
|---|
| 99 | REAL(wp), DIMENSION(jpi,jpj) :: zekb, zekg, zekr ! 2D workspace |
|---|
| 100 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: ze0, ze1 , ze2, ze3, zea ! 3D workspace |
|---|
| 101 | !!---------------------------------------------------------------------- |
|---|
| 102 | |
|---|
| 103 | IF( kt == nit000 ) THEN |
|---|
| 104 | IF(lwp) WRITE(numout,*) |
|---|
| 105 | IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation' |
|---|
| 106 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 107 | CALL tra_qsr_init |
|---|
| 108 | IF( .NOT.ln_traqsr ) RETURN !!gm not authirized by Coding rules |
|---|
| 109 | ENDIF |
|---|
| 110 | |
|---|
| 111 | IF( l_trdtra ) THEN ! Save ta and sa trends |
|---|
| 112 | ztrdt(:,:,:) = ta(:,:,:) |
|---|
| 113 | ztrds(:,:,:) = 0.e0 |
|---|
| 114 | ENDIF |
|---|
| 115 | |
|---|
| 116 | |
|---|
| 117 | ! ! ============================================== ! |
|---|
| 118 | IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN ! bio-model fluxes : all vertical coordinates ! |
|---|
| 119 | ! ! ============================================== ! |
|---|
| 120 | DO jk = 1, jpkm1 |
|---|
| 121 | DO jj = 2, jpjm1 |
|---|
| 122 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 123 | !!gm how to stecify the mean of time step here : TOP versus OPA time stepping strategy not obvious |
|---|
| 124 | qsr_trd_hc_n(ji,jj,jk) = ro0cpr * ( etot3(ji,jj,jk) - etot3(ji,jj,jk+1) ) |
|---|
| 125 | END DO |
|---|
| 126 | END DO |
|---|
| 127 | END DO |
|---|
| 128 | CALL iom_put( 'qsr3d', etot3 ) ! Shortwave Radiation 3D distribution |
|---|
| 129 | ! ! ============================================== ! |
|---|
| 130 | ELSE ! Ocean alone : |
|---|
| 131 | ! ! ============================================== ! |
|---|
| 132 | ! |
|---|
| 133 | ! ! ------------------------- ! |
|---|
| 134 | IF( ln_qsr_rgb) THEN ! R-G-B light penetration ! |
|---|
| 135 | ! ! ------------------------- ! |
|---|
| 136 | ! Set chlorophyl concentration |
|---|
| 137 | IF( nn_chldta ==1 ) THEN !* Variable Chlorophyll |
|---|
| 138 | ! |
|---|
| 139 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 140 | ! |
|---|
| 141 | !CDIR COLLAPSE |
|---|
| 142 | !CDIR NOVERRCHK |
|---|
| 143 | DO jj = 1, jpj ! Separation in R-G-B depending of the surface Chl |
|---|
| 144 | !CDIR NOVERRCHK |
|---|
| 145 | DO ji = 1, jpi |
|---|
| 146 | zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj) ) ) |
|---|
| 147 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 148 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 149 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 150 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 151 | END DO |
|---|
| 152 | END DO |
|---|
| 153 | ! ! surface value |
|---|
| 154 | zsi0r = 1.e0 / rn_si0 |
|---|
| 155 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 156 | |
|---|
| 157 | ze0(:,:,1) = rn_abs * qsr(:,:) |
|---|
| 158 | ze1(:,:,1) = zcoef * qsr(:,:) |
|---|
| 159 | ze2(:,:,1) = zcoef * qsr(:,:) |
|---|
| 160 | ze3(:,:,1) = zcoef * qsr(:,:) |
|---|
| 161 | zea(:,:,1) = qsr(:,:) |
|---|
| 162 | ! |
|---|
| 163 | DO jk = 2, nksr+1 ! deeper values |
|---|
| 164 | !CDIR NOVERRCHK |
|---|
| 165 | DO jj = 1, jpj |
|---|
| 166 | !CDIR NOVERRCHK |
|---|
| 167 | DO ji = 1, jpi |
|---|
| 168 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zsi0r ) |
|---|
| 169 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 170 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 171 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 172 | ze0(ji,jj,jk) = zc0 |
|---|
| 173 | ze1(ji,jj,jk) = zc1 |
|---|
| 174 | ze2(ji,jj,jk) = zc2 |
|---|
| 175 | ze3(ji,jj,jk) = zc3 |
|---|
| 176 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 177 | END DO |
|---|
| 178 | END DO |
|---|
| 179 | END DO |
|---|
| 180 | !!gm add here etot3(:,:,jk) = ( zea(:,:,jk) - zea(:,:,jk+1) ) / fse3t(:,:,jk) |
|---|
| 181 | ! |
|---|
| 182 | DO jk = 1, nksr ! compute and add qsr trend to ta |
|---|
| 183 | qsr_trd_hc_n(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 184 | END DO |
|---|
| 185 | zea(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 186 | CALL iom_put( 'qsr3d', zea ) ! Shortwave Radiation 3D distribution |
|---|
| 187 | ! |
|---|
| 188 | ELSE !* Constant Chlorophyll |
|---|
| 189 | DO jk = 1, nksr |
|---|
| 190 | qsr_trd_hc_n(:,:,jk) = etot3(:,:,jk) * qsr(:,:) |
|---|
| 191 | END DO |
|---|
| 192 | ENDIF |
|---|
| 193 | ! |
|---|
| 194 | ENDIF |
|---|
| 195 | ! ! ------------------------- ! |
|---|
| 196 | IF( ln_qsr_2bd ) THEN ! 2 band light penetration ! |
|---|
| 197 | ! ! ------------------------- ! |
|---|
| 198 | DO jk = 1, nksr |
|---|
| 199 | DO jj = 2, jpjm1 |
|---|
| 200 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 201 | qsr_trd_hc_n(ji,jj,jk) = etot3(ji,jj,jk) * qsr(ji,jj) |
|---|
| 202 | END DO |
|---|
| 203 | END DO |
|---|
| 204 | END DO |
|---|
| 205 | ! |
|---|
| 206 | ENDIF |
|---|
| 207 | ! |
|---|
| 208 | ENDIF |
|---|
| 209 | |
|---|
| 210 | ! Add qsr trend to ta in all cases |
|---|
| 211 | IF( neuler == 0 .AND. kt == nit000 ) THEN |
|---|
| 212 | DO jk = 1, nksr |
|---|
| 213 | DO jj = 2, jpjm1 |
|---|
| 214 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 215 | ta(ji,jj,jk) = ta(ji,jj,jk) + qsr_trd_hc_n(ji,jj,jk) / fse3t(ji,jj,jk) |
|---|
| 216 | END DO |
|---|
| 217 | END DO |
|---|
| 218 | END DO |
|---|
| 219 | ELSE |
|---|
| 220 | DO jk = 1, nksr |
|---|
| 221 | DO jj = 2, jpjm1 |
|---|
| 222 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 223 | ta(ji,jj,jk) = ta(ji,jj,jk) + 0.5 * ( qsr_trd_hc_b(ji,jj,jk) + qsr_trd_hc_n(ji,jj,jk) ) / fse3t(ji,jj,jk) |
|---|
| 224 | END DO |
|---|
| 225 | END DO |
|---|
| 226 | END DO |
|---|
| 227 | ENDIF |
|---|
| 228 | |
|---|
| 229 | IF( l_trdtra ) THEN ! qsr tracers trends saved for diagnostics |
|---|
| 230 | ztrdt(:,:,:) = ta(:,:,:) - ztrdt(:,:,:) |
|---|
| 231 | CALL trd_mod( ztrdt, ztrds, jptra_trd_qsr, 'TRA', kt ) |
|---|
| 232 | ENDIF |
|---|
| 233 | ! ! print mean trends (used for debugging) |
|---|
| 234 | IF(ln_ctl) CALL prt_ctl( tab3d_1=ta, clinfo1=' qsr - Ta: ', mask1=tmask, clinfo3='tra-ta' ) |
|---|
| 235 | ! |
|---|
| 236 | END SUBROUTINE tra_qsr |
|---|
| 237 | |
|---|
| 238 | |
|---|
| 239 | SUBROUTINE tra_qsr_init |
|---|
| 240 | !!---------------------------------------------------------------------- |
|---|
| 241 | !! *** ROUTINE tra_qsr_init *** |
|---|
| 242 | !! |
|---|
| 243 | !! ** Purpose : Initialization for the penetrative solar radiation |
|---|
| 244 | !! |
|---|
| 245 | !! ** Method : The profile of solar radiation within the ocean is set |
|---|
| 246 | !! from two length scale of penetration (rn_si0,rn_si1) and a ratio |
|---|
| 247 | !! (rn_abs). These parameters are read in the namtra_qsr namelist. The |
|---|
| 248 | !! default values correspond to clear water (type I in Jerlov' |
|---|
| 249 | !! (1968) classification. |
|---|
| 250 | !! called by tra_qsr at the first timestep (nit000) |
|---|
| 251 | !! |
|---|
| 252 | !! ** Action : - initialize rn_si0, rn_si1 and rn_abs |
|---|
| 253 | !! |
|---|
| 254 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 255 | !!---------------------------------------------------------------------- |
|---|
| 256 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 257 | INTEGER :: irgb, ierror ! temporary integer |
|---|
| 258 | INTEGER :: ioptio, nqsr ! temporary integer |
|---|
| 259 | REAL(wp) :: zc0 , zc1 ! temporary scalars |
|---|
| 260 | REAL(wp) :: zc2 , zc3 , zchl ! - - |
|---|
| 261 | REAL(wp) :: zsi0r, zsi1r, zcoef ! - - |
|---|
| 262 | REAL(wp), DIMENSION(jpi,jpj) :: zekb, zekg, zekr ! 2D workspace |
|---|
| 263 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: ze0 , ze1 , ze2 , ze3 , zea ! 3D workspace |
|---|
| 264 | !! |
|---|
| 265 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 266 | TYPE(FLD_N) :: sn_chl ! informations about the chlorofyl field to be read |
|---|
| 267 | NAMELIST/namtra_qsr/ sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, & |
|---|
| 268 | & nn_chldta, rn_abs, rn_si0, rn_si1, rn_si2 |
|---|
| 269 | !!---------------------------------------------------------------------- |
|---|
| 270 | |
|---|
| 271 | cn_dir = './' ! directory in which the model is executed |
|---|
| 272 | ! ... default values (NB: frequency positive => hours, negative => months) |
|---|
| 273 | ! ! file ! frequency ! variable ! time interp ! clim ! 'yearly' or ! weights ! rotation ! |
|---|
| 274 | ! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs ! |
|---|
| 275 | sn_chl = FLD_N( 'chlorophyll' , -1 , 'CHLA' , .true. , .true. , 'yearly' , '' , '' ) |
|---|
| 276 | ! |
|---|
| 277 | REWIND( numnam ) ! Read Namelist namtra_qsr : ratio and length of penetration |
|---|
| 278 | READ ( numnam, namtra_qsr ) |
|---|
| 279 | ! |
|---|
| 280 | IF(lwp) THEN ! control print |
|---|
| 281 | WRITE(numout,*) |
|---|
| 282 | WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation' |
|---|
| 283 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 284 | WRITE(numout,*) ' Namelist namtra_qsr : set the parameter of penetration' |
|---|
| 285 | WRITE(numout,*) ' Light penetration (T) or not (F) ln_traqsr = ', ln_traqsr |
|---|
| 286 | WRITE(numout,*) ' RGB (Red-Green-Blue) light penetration ln_qsr_rgb = ', ln_qsr_rgb |
|---|
| 287 | WRITE(numout,*) ' 2 band light penetration ln_qsr_2bd = ', ln_qsr_2bd |
|---|
| 288 | WRITE(numout,*) ' bio-model light penetration ln_qsr_bio = ', ln_qsr_bio |
|---|
| 289 | WRITE(numout,*) ' RGB : Chl data (=1) or cst value (=0) nn_chldta = ', nn_chldta |
|---|
| 290 | WRITE(numout,*) ' RGB & 2 bands: fraction of light (rn_si1) rn_abs = ', rn_abs |
|---|
| 291 | WRITE(numout,*) ' RGB & 2 bands: shortess depth of extinction rn_si0 = ', rn_si0 |
|---|
| 292 | WRITE(numout,*) ' 2 bands: longest depth of extinction rn_si1 = ', rn_si1 |
|---|
| 293 | WRITE(numout,*) ' 3 bands: longest depth of extinction rn_si2 = ', rn_si2 |
|---|
| 294 | ENDIF |
|---|
| 295 | |
|---|
| 296 | IF( ln_traqsr ) THEN ! control consistency |
|---|
| 297 | ! |
|---|
| 298 | IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio ) THEN |
|---|
| 299 | CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' ) |
|---|
| 300 | ln_qsr_bio = .FALSE. |
|---|
| 301 | ENDIF |
|---|
| 302 | ! |
|---|
| 303 | ioptio = 0 ! Parameter control |
|---|
| 304 | IF( ln_qsr_rgb ) ioptio = ioptio + 1 |
|---|
| 305 | IF( ln_qsr_2bd ) ioptio = ioptio + 1 |
|---|
| 306 | IF( ln_qsr_bio ) ioptio = ioptio + 1 |
|---|
| 307 | ! |
|---|
| 308 | IF( ioptio /= 1 ) THEN |
|---|
| 309 | ln_qsr_rgb = .TRUE. |
|---|
| 310 | nn_chldta = 0 |
|---|
| 311 | ln_qsr_2bd = .FALSE. |
|---|
| 312 | ln_qsr_bio = .FALSE. |
|---|
| 313 | CALL ctl_warn( ' Choose ONE type of light penetration in namelist namtra_qsr', & |
|---|
| 314 | & ' otherwise, we force the model to run with RGB light penetration' ) |
|---|
| 315 | ENDIF |
|---|
| 316 | ! |
|---|
| 317 | IF( ln_qsr_rgb .AND. nn_chldta == 0 ) nqsr = 1 |
|---|
| 318 | IF( ln_qsr_rgb .AND. nn_chldta == 1 ) nqsr = 2 |
|---|
| 319 | IF( ln_qsr_2bd ) nqsr = 3 |
|---|
| 320 | IF( ln_qsr_bio ) nqsr = 4 |
|---|
| 321 | ! |
|---|
| 322 | IF(lwp) THEN ! Print the choice |
|---|
| 323 | WRITE(numout,*) |
|---|
| 324 | IF( nqsr == 1 ) WRITE(numout,*) ' R-G-B light penetration - Constant Chlorophyll' |
|---|
| 325 | IF( nqsr == 2 ) WRITE(numout,*) ' R-G-B light penetration - Chl data ' |
|---|
| 326 | IF( nqsr == 3 ) WRITE(numout,*) ' 2 band light penetration' |
|---|
| 327 | IF( nqsr == 4 ) WRITE(numout,*) ' bio-model light penetration' |
|---|
| 328 | ENDIF |
|---|
| 329 | ! |
|---|
| 330 | ENDIF |
|---|
| 331 | ! ! ===================================== ! |
|---|
| 332 | IF( ln_traqsr ) THEN ! Initialisation of Light Penetration ! |
|---|
| 333 | ! ! ===================================== ! |
|---|
| 334 | ! |
|---|
| 335 | zsi0r = 1.e0 / rn_si0 |
|---|
| 336 | zsi1r = 1.e0 / rn_si1 |
|---|
| 337 | ! ! ---------------------------------- ! |
|---|
| 338 | IF( ln_qsr_rgb ) THEN ! Red-Green-Blue light penetration ! |
|---|
| 339 | ! ! ---------------------------------- ! |
|---|
| 340 | ! |
|---|
| 341 | ! ! level of light extinction |
|---|
| 342 | nksr = trc_oce_ext_lev( rn_si2, 0.33e2 ) |
|---|
| 343 | IF(lwp) THEN |
|---|
| 344 | WRITE(numout,*) |
|---|
| 345 | WRITE(numout,*) ' level max of computation of qsr = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m' |
|---|
| 346 | ENDIF |
|---|
| 347 | ! |
|---|
| 348 | CALL trc_oce_rgb( rkrgb ) !* tabulated attenuation coef. |
|---|
| 349 | !!gm CALL trc_oce_rgb_read( rkrgb ) !* tabulated attenuation coef. |
|---|
| 350 | ! |
|---|
| 351 | IF( nn_chldta == 1 ) THEN !* Chl data : set sf_chl structure |
|---|
| 352 | IF(lwp) WRITE(numout,*) |
|---|
| 353 | IF(lwp) WRITE(numout,*) ' Chlorophyll read in a file' |
|---|
| 354 | ALLOCATE( sf_chl(1), STAT=ierror ) |
|---|
| 355 | IF( ierror > 0 ) THEN |
|---|
| 356 | CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' ) ; RETURN |
|---|
| 357 | ENDIF |
|---|
| 358 | ALLOCATE( sf_chl(1)%fnow(jpi,jpj) ) |
|---|
| 359 | ALLOCATE( sf_chl(1)%fdta(jpi,jpj,2) ) |
|---|
| 360 | ! ! fill sf_chl with sn_chl and control print |
|---|
| 361 | CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init', & |
|---|
| 362 | & 'Solar penetration function of read chlorophyll', 'namtra_qsr' ) |
|---|
| 363 | ! |
|---|
| 364 | ELSE !* constant Chl : compute once for all the distribution of light (etot3) |
|---|
| 365 | IF(lwp) WRITE(numout,*) |
|---|
| 366 | IF(lwp) WRITE(numout,*) ' Constant Chlorophyll concentration = 0.05' |
|---|
| 367 | IF(lwp) WRITE(numout,*) ' light distribution computed once for all' |
|---|
| 368 | ! |
|---|
| 369 | zchl = 0.05 ! constant chlorophyll |
|---|
| 370 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 371 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyl concentration |
|---|
| 372 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 373 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 374 | ! |
|---|
| 375 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 376 | ze0(:,:,1) = rn_abs |
|---|
| 377 | ze1(:,:,1) = zcoef |
|---|
| 378 | ze2(:,:,1) = zcoef |
|---|
| 379 | ze3(:,:,1) = zcoef |
|---|
| 380 | zea(:,:,1) = tmask(:,:,1) ! = ( ze0+ze1+z2+ze3 ) * tmask |
|---|
| 381 | |
|---|
| 382 | DO jk = 2, nksr+1 |
|---|
| 383 | !CDIR NOVERRCHK |
|---|
| 384 | DO jj = 1, jpj |
|---|
| 385 | !CDIR NOVERRCHK |
|---|
| 386 | DO ji = 1, jpi |
|---|
| 387 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zsi0r ) |
|---|
| 388 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 389 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 390 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 391 | ze0(ji,jj,jk) = zc0 |
|---|
| 392 | ze1(ji,jj,jk) = zc1 |
|---|
| 393 | ze2(ji,jj,jk) = zc2 |
|---|
| 394 | ze3(ji,jj,jk) = zc3 |
|---|
| 395 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 396 | END DO |
|---|
| 397 | END DO |
|---|
| 398 | END DO |
|---|
| 399 | ! |
|---|
| 400 | DO jk = 1, nksr |
|---|
| 401 | etot3(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 402 | END DO |
|---|
| 403 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 404 | ENDIF |
|---|
| 405 | ! |
|---|
| 406 | ENDIF |
|---|
| 407 | ! ! ---------------------------------- ! |
|---|
| 408 | IF( ln_qsr_2bd ) THEN ! 2 bands light penetration ! |
|---|
| 409 | ! ! ---------------------------------- ! |
|---|
| 410 | ! |
|---|
| 411 | ! ! level of light extinction |
|---|
| 412 | nksr = trc_oce_ext_lev( rn_si1, 1.e2 ) |
|---|
| 413 | IF(lwp) THEN |
|---|
| 414 | WRITE(numout,*) |
|---|
| 415 | WRITE(numout,*) ' level max of computation of qsr = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m' |
|---|
| 416 | ENDIF |
|---|
| 417 | ! |
|---|
| 418 | DO jk = 1, nksr !* solar heat absorbed at T-point computed once for all |
|---|
| 419 | DO jj = 1, jpj ! top 400 meters |
|---|
| 420 | DO ji = 1, jpi |
|---|
| 421 | zc0 = rn_abs * EXP( -fsdepw(ji,jj,jk )*zsi0r ) + (1.-rn_abs) * EXP( -fsdepw(ji,jj,jk )*zsi1r ) |
|---|
| 422 | zc1 = rn_abs * EXP( -fsdepw(ji,jj,jk+1)*zsi0r ) + (1.-rn_abs) * EXP( -fsdepw(ji,jj,jk+1)*zsi1r ) |
|---|
| 423 | etot3(ji,jj,jk) = ro0cpr * ( zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1) ) |
|---|
| 424 | END DO |
|---|
| 425 | END DO |
|---|
| 426 | END DO |
|---|
| 427 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 428 | ! |
|---|
| 429 | ENDIF |
|---|
| 430 | ! ! ===================================== ! |
|---|
| 431 | ELSE ! No light penetration ! |
|---|
| 432 | ! ! ===================================== ! |
|---|
| 433 | IF(lwp) THEN |
|---|
| 434 | WRITE(numout,*) |
|---|
| 435 | WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration' |
|---|
| 436 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 437 | ENDIF |
|---|
| 438 | ENDIF |
|---|
| 439 | ! |
|---|
| 440 | END SUBROUTINE tra_qsr_init |
|---|
| 441 | |
|---|
| 442 | !!====================================================================== |
|---|
| 443 | END MODULE traqsr |
|---|
