| 1 | MODULE traqsr |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traqsr *** |
|---|
| 4 | !! Ocean physics: solar radiation penetration in the top ocean levels |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (G. Madec) |
|---|
| 8 | !! ! 1996-01 (G. Madec) s-coordinates |
|---|
| 9 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 10 | !! - ! 2005-11 (G. Madec) zco, zps, sco coordinate |
|---|
| 11 | !! 3.2 ! 2009-04 (G. Madec & NEMO team) |
|---|
| 12 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! tra_qsr : trend due to the solar radiation penetration |
|---|
| 17 | !! tra_qsr_init : solar radiation penetration initialization |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | USE oce ! ocean dynamics and active tracers |
|---|
| 20 | USE dom_oce ! ocean space and time domain |
|---|
| 21 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 22 | USE trc_oce ! share SMS/Ocean variables |
|---|
| 23 | USE trdmod_oce ! ocean variables trends |
|---|
| 24 | USE trdmod ! ocean active tracers trends |
|---|
| 25 | USE in_out_manager ! I/O manager |
|---|
| 26 | USE phycst ! physical constants |
|---|
| 27 | USE prtctl ! Print control |
|---|
| 28 | USE iom ! I/O manager |
|---|
| 29 | USE fldread ! read input fields |
|---|
| 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| 34 | PUBLIC tra_qsr ! routine called by step.F90 (ln_traqsr=T) |
|---|
| 35 | |
|---|
| 36 | ! !!* Namelist namtra_qsr: penetrative solar radiation |
|---|
| 37 | LOGICAL , PUBLIC :: ln_traqsr = .TRUE. !: light absorption (qsr) flag |
|---|
| 38 | LOGICAL , PUBLIC :: ln_qsr_rgb = .FALSE. !: Red-Green-Blue light absorption flag |
|---|
| 39 | LOGICAL , PUBLIC :: ln_qsr_2bd = .TRUE. !: 2 band light absorption flag |
|---|
| 40 | LOGICAL , PUBLIC :: ln_qsr_bio = .FALSE. !: bio-model light absorption flag |
|---|
| 41 | INTEGER , PUBLIC :: nn_chldta = 0 !: use Chlorophyll data (=1) or not (=0) |
|---|
| 42 | REAL(wp), PUBLIC :: rn_abs = 0.58_wp !: fraction absorbed in the very near surface (RGB & 2 bands) |
|---|
| 43 | REAL(wp), PUBLIC :: rn_si0 = 0.35_wp !: very near surface depth of extinction (RGB & 2 bands) |
|---|
| 44 | REAL(wp), PUBLIC :: rn_si1 = 23.0_wp !: deepest depth of extinction (water type I) (2 bands) |
|---|
| 45 | REAL(wp), PUBLIC :: rn_si2 = 61.8_wp !: deepest depth of extinction (blue & 0.01 mg.m-3) (RGB) |
|---|
| 46 | |
|---|
| 47 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_chl ! structure of input Chl (file informations, fields read) |
|---|
| 48 | |
|---|
| 49 | INTEGER , PUBLIC :: nksr ! levels below which the light cannot penetrate (depth larger than 391 m) |
|---|
| 50 | REAL(wp), DIMENSION(3,61) :: rkrgb ! tabulated attenuation coefficients for RGB absorption |
|---|
| 51 | |
|---|
| 52 | !! * Substitutions |
|---|
| 53 | # include "domzgr_substitute.h90" |
|---|
| 54 | # include "vectopt_loop_substitute.h90" |
|---|
| 55 | !!---------------------------------------------------------------------- |
|---|
| 56 | !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010) |
|---|
| 57 | !! $Id$ |
|---|
| 58 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | |
|---|
| 61 | CONTAINS |
|---|
| 62 | |
|---|
| 63 | SUBROUTINE tra_qsr( kt ) |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | !! *** ROUTINE tra_qsr *** |
|---|
| 66 | !! |
|---|
| 67 | !! ** Purpose : Compute the temperature trend due to the solar radiation |
|---|
| 68 | !! penetration and add it to the general temperature trend. |
|---|
| 69 | !! |
|---|
| 70 | !! ** Method : The profile of the solar radiation within the ocean is defined |
|---|
| 71 | !! through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs |
|---|
| 72 | !! Considering the 2 wavebands case: |
|---|
| 73 | !! I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) ) |
|---|
| 74 | !! The temperature trend associated with the solar radiation penetration |
|---|
| 75 | !! is given by : zta = 1/e3t dk[ I ] / (rau0*Cp) |
|---|
| 76 | !! At the bottom, boudary condition for the radiation is no flux : |
|---|
| 77 | !! all heat which has not been absorbed in the above levels is put |
|---|
| 78 | !! in the last ocean level. |
|---|
| 79 | !! In z-coordinate case, the computation is only done down to the |
|---|
| 80 | !! level where I(k) < 1.e-15 W/m2. In addition, the coefficients |
|---|
| 81 | !! used for the computation are calculated one for once as they |
|---|
| 82 | !! depends on k only. |
|---|
| 83 | !! |
|---|
| 84 | !! ** Action : - update ta with the penetrative solar radiation trend |
|---|
| 85 | !! - save the trend in ttrd ('key_trdtra') |
|---|
| 86 | !! |
|---|
| 87 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 88 | !! Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516. |
|---|
| 89 | !!---------------------------------------------------------------------- |
|---|
| 90 | USE oce, ONLY : ztrdt => ua ! use ua as 3D workspace |
|---|
| 91 | USE oce, ONLY : ztrds => va ! use va as 3D workspace |
|---|
| 92 | !! |
|---|
| 93 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 94 | !! |
|---|
| 95 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 96 | INTEGER :: irgb ! temporary integers |
|---|
| 97 | REAL(wp) :: zchl, zcoef, zsi0r ! temporary scalars |
|---|
| 98 | REAL(wp) :: zc0, zc1, zc2, zc3 ! - - |
|---|
| 99 | REAL(wp), DIMENSION(jpi,jpj) :: zekb, zekg, zekr ! 2D workspace |
|---|
| 100 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: ze0, ze1 , ze2, ze3, zea ! 3D workspace |
|---|
| 101 | !!---------------------------------------------------------------------- |
|---|
| 102 | |
|---|
| 103 | IF( kt == nit000 ) THEN |
|---|
| 104 | IF(lwp) WRITE(numout,*) |
|---|
| 105 | IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation' |
|---|
| 106 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 107 | CALL tra_qsr_init |
|---|
| 108 | IF( .NOT.ln_traqsr ) RETURN !!gm not authirized by Coding rules |
|---|
| 109 | ENDIF |
|---|
| 110 | |
|---|
| 111 | IF( l_trdtra ) THEN ! Save ta and sa trends |
|---|
| 112 | ztrdt(:,:,:) = ta(:,:,:) |
|---|
| 113 | ztrds(:,:,:) = 0.e0 |
|---|
| 114 | ENDIF |
|---|
| 115 | |
|---|
| 116 | ! ! ---------------------------------------- ! |
|---|
| 117 | ! ! Swap of forcing field ! |
|---|
| 118 | ! ! ---------------------------------------- ! |
|---|
| 119 | IF( kt /= nit000 ) qsr_trd_hc_b(:,:,:) = qsr_trd_hc_n(:,:,:) |
|---|
| 120 | ! ! ---------------------------------------- ! |
|---|
| 121 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 122 | ! ! ---------------------------------------- ! |
|---|
| 123 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 124 | & iom_varid( numror, 'qsr_trd_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 125 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 126 | CALL iom_get( numror, jpdom_autoglo, 'qsr_trd_hc_b', qsr_trd_hc_b ) ! before heat content trend due to Qsr flux |
|---|
| 127 | ENDIF |
|---|
| 128 | ENDIF |
|---|
| 129 | |
|---|
| 130 | |
|---|
| 131 | ! ! ============================================== ! |
|---|
| 132 | IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN ! bio-model fluxes : all vertical coordinates ! |
|---|
| 133 | ! ! ============================================== ! |
|---|
| 134 | DO jk = 1, jpkm1 |
|---|
| 135 | DO jj = 2, jpjm1 |
|---|
| 136 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 137 | !!gm how to stecify the mean of time step here : TOP versus OPA time stepping strategy not obvious |
|---|
| 138 | qsr_trd_hc_n(ji,jj,jk) = ro0cpr * ( etot3(ji,jj,jk) - etot3(ji,jj,jk+1) ) |
|---|
| 139 | END DO |
|---|
| 140 | END DO |
|---|
| 141 | END DO |
|---|
| 142 | CALL iom_put( 'qsr3d', etot3 ) ! Shortwave Radiation 3D distribution |
|---|
| 143 | ! ! ============================================== ! |
|---|
| 144 | ELSE ! Ocean alone : |
|---|
| 145 | ! ! ============================================== ! |
|---|
| 146 | ! |
|---|
| 147 | ! ! ------------------------- ! |
|---|
| 148 | IF( ln_qsr_rgb) THEN ! R-G-B light penetration ! |
|---|
| 149 | ! ! ------------------------- ! |
|---|
| 150 | ! Set chlorophyl concentration |
|---|
| 151 | IF( nn_chldta ==1 ) THEN !* Variable Chlorophyll |
|---|
| 152 | ! |
|---|
| 153 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 154 | ! |
|---|
| 155 | !CDIR COLLAPSE |
|---|
| 156 | !CDIR NOVERRCHK |
|---|
| 157 | DO jj = 1, jpj ! Separation in R-G-B depending of the surface Chl |
|---|
| 158 | !CDIR NOVERRCHK |
|---|
| 159 | DO ji = 1, jpi |
|---|
| 160 | zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj) ) ) |
|---|
| 161 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 162 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 163 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 164 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 165 | END DO |
|---|
| 166 | END DO |
|---|
| 167 | ! ! surface value |
|---|
| 168 | zsi0r = 1.e0 / rn_si0 |
|---|
| 169 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 170 | |
|---|
| 171 | ze0(:,:,1) = rn_abs * qsr(:,:) |
|---|
| 172 | ze1(:,:,1) = zcoef * qsr(:,:) |
|---|
| 173 | ze2(:,:,1) = zcoef * qsr(:,:) |
|---|
| 174 | ze3(:,:,1) = zcoef * qsr(:,:) |
|---|
| 175 | zea(:,:,1) = qsr(:,:) |
|---|
| 176 | ! |
|---|
| 177 | DO jk = 2, nksr+1 ! deeper values |
|---|
| 178 | !CDIR NOVERRCHK |
|---|
| 179 | DO jj = 1, jpj |
|---|
| 180 | !CDIR NOVERRCHK |
|---|
| 181 | DO ji = 1, jpi |
|---|
| 182 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zsi0r ) |
|---|
| 183 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 184 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 185 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 186 | ze0(ji,jj,jk) = zc0 |
|---|
| 187 | ze1(ji,jj,jk) = zc1 |
|---|
| 188 | ze2(ji,jj,jk) = zc2 |
|---|
| 189 | ze3(ji,jj,jk) = zc3 |
|---|
| 190 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 191 | END DO |
|---|
| 192 | END DO |
|---|
| 193 | END DO |
|---|
| 194 | !!gm add here etot3(:,:,jk) = ( zea(:,:,jk) - zea(:,:,jk+1) ) / fse3t(:,:,jk) |
|---|
| 195 | ! |
|---|
| 196 | DO jk = 1, nksr ! compute and add qsr trend to ta |
|---|
| 197 | qsr_trd_hc_n(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 198 | END DO |
|---|
| 199 | zea(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 200 | CALL iom_put( 'qsr3d', zea ) ! Shortwave Radiation 3D distribution |
|---|
| 201 | ! |
|---|
| 202 | ELSE !* Constant Chlorophyll |
|---|
| 203 | DO jk = 1, nksr |
|---|
| 204 | qsr_trd_hc_n(:,:,jk) = etot3(:,:,jk) * qsr(:,:) |
|---|
| 205 | END DO |
|---|
| 206 | ENDIF |
|---|
| 207 | ! |
|---|
| 208 | ENDIF |
|---|
| 209 | ! ! ------------------------- ! |
|---|
| 210 | IF( ln_qsr_2bd ) THEN ! 2 band light penetration ! |
|---|
| 211 | ! ! ------------------------- ! |
|---|
| 212 | DO jk = 1, nksr |
|---|
| 213 | DO jj = 2, jpjm1 |
|---|
| 214 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 215 | qsr_trd_hc_n(ji,jj,jk) = etot3(ji,jj,jk) * qsr(ji,jj) |
|---|
| 216 | END DO |
|---|
| 217 | END DO |
|---|
| 218 | END DO |
|---|
| 219 | ! |
|---|
| 220 | ENDIF |
|---|
| 221 | ! |
|---|
| 222 | ENDIF |
|---|
| 223 | |
|---|
| 224 | ! Add qsr trend to ta in all cases |
|---|
| 225 | IF( neuler == 0 .AND. kt == nit000 ) THEN |
|---|
| 226 | DO jk = 1, nksr |
|---|
| 227 | DO jj = 2, jpjm1 |
|---|
| 228 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 229 | ta(ji,jj,jk) = ta(ji,jj,jk) + qsr_trd_hc_n(ji,jj,jk) / fse3t(ji,jj,jk) |
|---|
| 230 | END DO |
|---|
| 231 | END DO |
|---|
| 232 | END DO |
|---|
| 233 | ELSE |
|---|
| 234 | DO jk = 1, nksr |
|---|
| 235 | DO jj = 2, jpjm1 |
|---|
| 236 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 237 | ta(ji,jj,jk) = ta(ji,jj,jk) + 0.5 * ( qsr_trd_hc_b(ji,jj,jk) + qsr_trd_hc_n(ji,jj,jk) ) / fse3t(ji,jj,jk) |
|---|
| 238 | END DO |
|---|
| 239 | END DO |
|---|
| 240 | END DO |
|---|
| 241 | ENDIF |
|---|
| 242 | |
|---|
| 243 | ! ! ---------------------------------------- ! |
|---|
| 244 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 245 | ! ! ---------------------------------------- ! |
|---|
| 246 | IF(lwp) WRITE(numout,*) |
|---|
| 247 | IF(lwp) WRITE(numout,*) 'qsr : penetrative solar radiation forcing field written in ocean restart file ', & |
|---|
| 248 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 249 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 250 | CALL iom_rstput( kt, nitrst, numrow, 'qsr_trd_hc_b', qsr_trd_hc_n ) |
|---|
| 251 | ! |
|---|
| 252 | ENDIF |
|---|
| 253 | |
|---|
| 254 | IF( l_trdtra ) THEN ! qsr tracers trends saved for diagnostics |
|---|
| 255 | ztrdt(:,:,:) = ta(:,:,:) - ztrdt(:,:,:) |
|---|
| 256 | CALL trd_mod( ztrdt, ztrds, jptra_trd_qsr, 'TRA', kt ) |
|---|
| 257 | ENDIF |
|---|
| 258 | ! ! print mean trends (used for debugging) |
|---|
| 259 | IF(ln_ctl) CALL prt_ctl( tab3d_1=ta, clinfo1=' qsr - Ta: ', mask1=tmask, clinfo3='tra-ta' ) |
|---|
| 260 | ! |
|---|
| 261 | END SUBROUTINE tra_qsr |
|---|
| 262 | |
|---|
| 263 | |
|---|
| 264 | SUBROUTINE tra_qsr_init |
|---|
| 265 | !!---------------------------------------------------------------------- |
|---|
| 266 | !! *** ROUTINE tra_qsr_init *** |
|---|
| 267 | !! |
|---|
| 268 | !! ** Purpose : Initialization for the penetrative solar radiation |
|---|
| 269 | !! |
|---|
| 270 | !! ** Method : The profile of solar radiation within the ocean is set |
|---|
| 271 | !! from two length scale of penetration (rn_si0,rn_si1) and a ratio |
|---|
| 272 | !! (rn_abs). These parameters are read in the namtra_qsr namelist. The |
|---|
| 273 | !! default values correspond to clear water (type I in Jerlov' |
|---|
| 274 | !! (1968) classification. |
|---|
| 275 | !! called by tra_qsr at the first timestep (nit000) |
|---|
| 276 | !! |
|---|
| 277 | !! ** Action : - initialize rn_si0, rn_si1 and rn_abs |
|---|
| 278 | !! |
|---|
| 279 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 280 | !!---------------------------------------------------------------------- |
|---|
| 281 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 282 | INTEGER :: irgb, ierror ! temporary integer |
|---|
| 283 | INTEGER :: ioptio, nqsr ! temporary integer |
|---|
| 284 | REAL(wp) :: zc0 , zc1 ! temporary scalars |
|---|
| 285 | REAL(wp) :: zc2 , zc3 , zchl ! - - |
|---|
| 286 | REAL(wp) :: zsi0r, zsi1r, zcoef ! - - |
|---|
| 287 | REAL(wp), DIMENSION(jpi,jpj) :: zekb, zekg, zekr ! 2D workspace |
|---|
| 288 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: ze0 , ze1 , ze2 , ze3 , zea ! 3D workspace |
|---|
| 289 | !! |
|---|
| 290 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 291 | TYPE(FLD_N) :: sn_chl ! informations about the chlorofyl field to be read |
|---|
| 292 | NAMELIST/namtra_qsr/ sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, & |
|---|
| 293 | & nn_chldta, rn_abs, rn_si0, rn_si1, rn_si2 |
|---|
| 294 | !!---------------------------------------------------------------------- |
|---|
| 295 | |
|---|
| 296 | cn_dir = './' ! directory in which the model is executed |
|---|
| 297 | ! ... default values (NB: frequency positive => hours, negative => months) |
|---|
| 298 | ! ! file ! frequency ! variable ! time interp ! clim ! 'yearly' or ! weights ! rotation ! |
|---|
| 299 | ! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs ! |
|---|
| 300 | sn_chl = FLD_N( 'chlorophyll' , -1 , 'CHLA' , .true. , .true. , 'yearly' , '' , '' ) |
|---|
| 301 | ! |
|---|
| 302 | REWIND( numnam ) ! Read Namelist namtra_qsr : ratio and length of penetration |
|---|
| 303 | READ ( numnam, namtra_qsr ) |
|---|
| 304 | ! |
|---|
| 305 | IF(lwp) THEN ! control print |
|---|
| 306 | WRITE(numout,*) |
|---|
| 307 | WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation' |
|---|
| 308 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 309 | WRITE(numout,*) ' Namelist namtra_qsr : set the parameter of penetration' |
|---|
| 310 | WRITE(numout,*) ' Light penetration (T) or not (F) ln_traqsr = ', ln_traqsr |
|---|
| 311 | WRITE(numout,*) ' RGB (Red-Green-Blue) light penetration ln_qsr_rgb = ', ln_qsr_rgb |
|---|
| 312 | WRITE(numout,*) ' 2 band light penetration ln_qsr_2bd = ', ln_qsr_2bd |
|---|
| 313 | WRITE(numout,*) ' bio-model light penetration ln_qsr_bio = ', ln_qsr_bio |
|---|
| 314 | WRITE(numout,*) ' RGB : Chl data (=1) or cst value (=0) nn_chldta = ', nn_chldta |
|---|
| 315 | WRITE(numout,*) ' RGB & 2 bands: fraction of light (rn_si1) rn_abs = ', rn_abs |
|---|
| 316 | WRITE(numout,*) ' RGB & 2 bands: shortess depth of extinction rn_si0 = ', rn_si0 |
|---|
| 317 | WRITE(numout,*) ' 2 bands: longest depth of extinction rn_si1 = ', rn_si1 |
|---|
| 318 | WRITE(numout,*) ' 3 bands: longest depth of extinction rn_si2 = ', rn_si2 |
|---|
| 319 | ENDIF |
|---|
| 320 | |
|---|
| 321 | IF( ln_traqsr ) THEN ! control consistency |
|---|
| 322 | ! |
|---|
| 323 | IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio ) THEN |
|---|
| 324 | CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' ) |
|---|
| 325 | ln_qsr_bio = .FALSE. |
|---|
| 326 | ENDIF |
|---|
| 327 | ! |
|---|
| 328 | ioptio = 0 ! Parameter control |
|---|
| 329 | IF( ln_qsr_rgb ) ioptio = ioptio + 1 |
|---|
| 330 | IF( ln_qsr_2bd ) ioptio = ioptio + 1 |
|---|
| 331 | IF( ln_qsr_bio ) ioptio = ioptio + 1 |
|---|
| 332 | ! |
|---|
| 333 | IF( ioptio /= 1 ) THEN |
|---|
| 334 | ln_qsr_rgb = .TRUE. |
|---|
| 335 | nn_chldta = 0 |
|---|
| 336 | ln_qsr_2bd = .FALSE. |
|---|
| 337 | ln_qsr_bio = .FALSE. |
|---|
| 338 | CALL ctl_warn( ' Choose ONE type of light penetration in namelist namtra_qsr', & |
|---|
| 339 | & ' otherwise, we force the model to run with RGB light penetration' ) |
|---|
| 340 | ENDIF |
|---|
| 341 | ! |
|---|
| 342 | IF( ln_qsr_rgb .AND. nn_chldta == 0 ) nqsr = 1 |
|---|
| 343 | IF( ln_qsr_rgb .AND. nn_chldta == 1 ) nqsr = 2 |
|---|
| 344 | IF( ln_qsr_2bd ) nqsr = 3 |
|---|
| 345 | IF( ln_qsr_bio ) nqsr = 4 |
|---|
| 346 | ! |
|---|
| 347 | IF(lwp) THEN ! Print the choice |
|---|
| 348 | WRITE(numout,*) |
|---|
| 349 | IF( nqsr == 1 ) WRITE(numout,*) ' R-G-B light penetration - Constant Chlorophyll' |
|---|
| 350 | IF( nqsr == 2 ) WRITE(numout,*) ' R-G-B light penetration - Chl data ' |
|---|
| 351 | IF( nqsr == 3 ) WRITE(numout,*) ' 2 band light penetration' |
|---|
| 352 | IF( nqsr == 4 ) WRITE(numout,*) ' bio-model light penetration' |
|---|
| 353 | ENDIF |
|---|
| 354 | ! |
|---|
| 355 | ENDIF |
|---|
| 356 | ! ! ===================================== ! |
|---|
| 357 | IF( ln_traqsr ) THEN ! Initialisation of Light Penetration ! |
|---|
| 358 | ! ! ===================================== ! |
|---|
| 359 | ! |
|---|
| 360 | zsi0r = 1.e0 / rn_si0 |
|---|
| 361 | zsi1r = 1.e0 / rn_si1 |
|---|
| 362 | ! ! ---------------------------------- ! |
|---|
| 363 | IF( ln_qsr_rgb ) THEN ! Red-Green-Blue light penetration ! |
|---|
| 364 | ! ! ---------------------------------- ! |
|---|
| 365 | ! |
|---|
| 366 | ! ! level of light extinction |
|---|
| 367 | nksr = trc_oce_ext_lev( rn_si2, 0.33e2 ) |
|---|
| 368 | IF(lwp) THEN |
|---|
| 369 | WRITE(numout,*) |
|---|
| 370 | WRITE(numout,*) ' level max of computation of qsr = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m' |
|---|
| 371 | ENDIF |
|---|
| 372 | ! |
|---|
| 373 | CALL trc_oce_rgb( rkrgb ) !* tabulated attenuation coef. |
|---|
| 374 | !!gm CALL trc_oce_rgb_read( rkrgb ) !* tabulated attenuation coef. |
|---|
| 375 | ! |
|---|
| 376 | IF( nn_chldta == 1 ) THEN !* Chl data : set sf_chl structure |
|---|
| 377 | IF(lwp) WRITE(numout,*) |
|---|
| 378 | IF(lwp) WRITE(numout,*) ' Chlorophyll read in a file' |
|---|
| 379 | ALLOCATE( sf_chl(1), STAT=ierror ) |
|---|
| 380 | IF( ierror > 0 ) THEN |
|---|
| 381 | CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' ) ; RETURN |
|---|
| 382 | ENDIF |
|---|
| 383 | ALLOCATE( sf_chl(1)%fnow(jpi,jpj) ) |
|---|
| 384 | ALLOCATE( sf_chl(1)%fdta(jpi,jpj,2) ) |
|---|
| 385 | ! ! fill sf_chl with sn_chl and control print |
|---|
| 386 | CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init', & |
|---|
| 387 | & 'Solar penetration function of read chlorophyll', 'namtra_qsr' ) |
|---|
| 388 | ! |
|---|
| 389 | ELSE !* constant Chl : compute once for all the distribution of light (etot3) |
|---|
| 390 | IF(lwp) WRITE(numout,*) |
|---|
| 391 | IF(lwp) WRITE(numout,*) ' Constant Chlorophyll concentration = 0.05' |
|---|
| 392 | IF(lwp) WRITE(numout,*) ' light distribution computed once for all' |
|---|
| 393 | ! |
|---|
| 394 | zchl = 0.05 ! constant chlorophyll |
|---|
| 395 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 396 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyl concentration |
|---|
| 397 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 398 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 399 | ! |
|---|
| 400 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 401 | ze0(:,:,1) = rn_abs |
|---|
| 402 | ze1(:,:,1) = zcoef |
|---|
| 403 | ze2(:,:,1) = zcoef |
|---|
| 404 | ze3(:,:,1) = zcoef |
|---|
| 405 | zea(:,:,1) = tmask(:,:,1) ! = ( ze0+ze1+z2+ze3 ) * tmask |
|---|
| 406 | |
|---|
| 407 | DO jk = 2, nksr+1 |
|---|
| 408 | !CDIR NOVERRCHK |
|---|
| 409 | DO jj = 1, jpj |
|---|
| 410 | !CDIR NOVERRCHK |
|---|
| 411 | DO ji = 1, jpi |
|---|
| 412 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zsi0r ) |
|---|
| 413 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 414 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 415 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 416 | ze0(ji,jj,jk) = zc0 |
|---|
| 417 | ze1(ji,jj,jk) = zc1 |
|---|
| 418 | ze2(ji,jj,jk) = zc2 |
|---|
| 419 | ze3(ji,jj,jk) = zc3 |
|---|
| 420 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 421 | END DO |
|---|
| 422 | END DO |
|---|
| 423 | END DO |
|---|
| 424 | ! |
|---|
| 425 | DO jk = 1, nksr |
|---|
| 426 | etot3(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 427 | END DO |
|---|
| 428 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 429 | ENDIF |
|---|
| 430 | ! |
|---|
| 431 | ENDIF |
|---|
| 432 | ! ! ---------------------------------- ! |
|---|
| 433 | IF( ln_qsr_2bd ) THEN ! 2 bands light penetration ! |
|---|
| 434 | ! ! ---------------------------------- ! |
|---|
| 435 | ! |
|---|
| 436 | ! ! level of light extinction |
|---|
| 437 | nksr = trc_oce_ext_lev( rn_si1, 1.e2 ) |
|---|
| 438 | IF(lwp) THEN |
|---|
| 439 | WRITE(numout,*) |
|---|
| 440 | WRITE(numout,*) ' level max of computation of qsr = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m' |
|---|
| 441 | ENDIF |
|---|
| 442 | ! |
|---|
| 443 | DO jk = 1, nksr !* solar heat absorbed at T-point computed once for all |
|---|
| 444 | DO jj = 1, jpj ! top 400 meters |
|---|
| 445 | DO ji = 1, jpi |
|---|
| 446 | zc0 = rn_abs * EXP( -fsdepw(ji,jj,jk )*zsi0r ) + (1.-rn_abs) * EXP( -fsdepw(ji,jj,jk )*zsi1r ) |
|---|
| 447 | zc1 = rn_abs * EXP( -fsdepw(ji,jj,jk+1)*zsi0r ) + (1.-rn_abs) * EXP( -fsdepw(ji,jj,jk+1)*zsi1r ) |
|---|
| 448 | etot3(ji,jj,jk) = ro0cpr * ( zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1) ) |
|---|
| 449 | END DO |
|---|
| 450 | END DO |
|---|
| 451 | END DO |
|---|
| 452 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 453 | ! |
|---|
| 454 | ENDIF |
|---|
| 455 | ! ! ===================================== ! |
|---|
| 456 | ELSE ! No light penetration ! |
|---|
| 457 | ! ! ===================================== ! |
|---|
| 458 | IF(lwp) THEN |
|---|
| 459 | WRITE(numout,*) |
|---|
| 460 | WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration' |
|---|
| 461 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 462 | ENDIF |
|---|
| 463 | ENDIF |
|---|
| 464 | ! |
|---|
| 465 | END SUBROUTINE tra_qsr_init |
|---|
| 466 | |
|---|
| 467 | !!====================================================================== |
|---|
| 468 | END MODULE traqsr |
|---|
