source: branches/DEV_r1837_mass_heat_salt_fluxes/NEMO/LIM_SRC_2/iceini_2.F90 @ 3147

MODULE iceini_2
   !!======================================================================
   !!                       ***  MODULE iceini   ***
   !!   Sea-ice model : LIM 2.0 Sea ice model Initialization
   !!======================================================================
   !! History :   1.0  !  02-08  (G. Madec)  F90: Free form and modules
   !!             2.0  !  03-08  (C. Ethe)  add ice_run
   !!----------------------------------------------------------------------
#if defined key_lim2
   !!----------------------------------------------------------------------
   !!   'key_lim2' :                                  LIM 2.0 sea-ice model
   !!----------------------------------------------------------------------
   !!   ice_init_2     : LIM-2 sea-ice model initialization
   !!----------------------------------------------------------------------
   USE dom_oce         ! ocean domain
   USE dom_ice_2       ! LIM-2 : ice domain
   USE sbc_oce         ! ocean surface boundary condition
   USE sbc_ice         ! ice   surface boundary condition
   USE phycst          ! physical constant
   USE ice_2           ! LIM-2 variables
   USE limmsh_2        ! LIM-2 mesh
   USE limistate_2     ! LIM-2 inital state
   USE limrst_2        ! LIM-2 restart
   USE in_out_manager  ! I/O manager
      
   IMPLICIT NONE
   PRIVATE

   PUBLIC   ice_init_2   ! called by sbcice_lim_2.F90

   !!----------------------------------------------------------------------
   !! NEMO/LIM 3.3,  UCL-LOCEAN-IPSL (2010) 
   !! $Id$ 
   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
   !!----------------------------------------------------------------------

CONTAINS

   SUBROUTINE ice_init_2
      !!----------------------------------------------------------------------
      !!                  ***  ROUTINE ice_init_2  ***
      !!
      !! ** purpose :   LIM-2 sea-ice model initialisation
      !!
      !! ** input   :   namelist_ice file
      !!                namelist namicerun (inside namelist_ice file)
      !!----------------------------------------------------------------------
      NAMELIST/namicerun/ cn_icerst_in, cn_icerst_out, ln_limdyn, ln_limdmp, acrit, hsndif, hicdif
      !!-------------------------------------------------------------------
      !
      !                                    ! Open the ice namelist file 
      CALL ctl_opn( numnam_ice, 'namelist_ice', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )   
      !
      REWIND ( numnam_ice )                ! Read Namelist namicerun 
      READ   ( numnam_ice , namicerun )
      !
      IF(lwp) THEN                         ! control print
         WRITE(numout,*)
         WRITE(numout,*) 'ice_run : ice share parameters for dynamics/advection/thermo of sea-ice'
         WRITE(numout,*) ' ~~~~~~'
         WRITE(numout,*) '   switch for ice dynamics (1) or not (0)      ln_limdyn   = ', ln_limdyn
         WRITE(numout,*) '   Ice damping                                 ln_limdmp   = ', ln_limdmp
         WRITE(numout,*) '   minimum fraction for leads in the NH (SH)  acrit(1/2)   = ', acrit(:)
         WRITE(numout,*) '   computation of temp. in snow (=0) or not (=9999) hsndif = ', hsndif
         WRITE(numout,*) '   computation of temp. in ice  (=0) or not (=9999) hicdif = ', hicdif
      ENDIF
      !         
      rdt_ice    = nn_fsbc * rdttra(1)     ! set ice time step to surface tracer time step
      r1_rdt_ice = 1.e0 / rdt_ice
      !
      CALL lim_msh_2                       ! ice mesh initialization
      !
      !                                    ! Initial sea-ice state
      IF( .NOT.ln_rstart ) THEN   ;   CALL lim_istate_2        ! start from rest: sea-ice deduced from sst
      ELSE                        ;   CALL lim_rst_read_2      ! start from a restart file
      ENDIF
      !
      tn_ice(:,:,1) = sist(:,:)            ! set initial ice temperature  
      !
      fr_i  (:,:) = 1.0 - frld(:,:)        ! set initial ice fraction    
      !
   END SUBROUTINE ice_init_2

#else
   !!----------------------------------------------------------------------
   !!   Default option :        Empty module       NO LIM 2.0 sea-ice model
   !!----------------------------------------------------------------------
CONTAINS
   SUBROUTINE ice_init_2      ! Empty routine
   END SUBROUTINE ice_init_2
#endif

   !!======================================================================
END MODULE iceini_2