New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 2034

Last change on this file since 2034 was 2034, checked in by cetlod, 14 years ago

cosmetic changes
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 7.8 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  87-06  (P. Andrich, D. L Hostis)  Original code
7   !!                 !  91-11  (G. Madec)
8   !!                 !  95-11  (G. Madec)  suppress volumetric scale factors
9   !!                 !  96-01  (G. Madec)  statement function for e3
10   !!            NEMO !  02-06  (G. Madec)  F90: Free form and module
11   !!            1.0  !  04-08  (C. Talandier) New trends organization
12   !!                 !  05-11  (G. Madec)  add zps case
13   !!            3.0  !  10-06  (C. Ethe, G. Madec) Merge TRA-TRC
14   !!----------------------------------------------------------------------
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_lap  : update the tracer trend with the horizontal diffusion
17   !!                 using a iso-level harmonic (laplacien) operator.
18   !!----------------------------------------------------------------------
19   !! * Modules used
20   USE oce             ! ocean dynamics and active tracers
21   USE dom_oce         ! ocean space and time domain
22   USE ldftra_oce      ! ocean active tracers: lateral physics
23   USE in_out_manager  ! I/O manager
24   USE diaptr          ! poleward transport diagnostics
25
26
27   IMPLICIT NONE
28   PRIVATE
29
30   !! * Routine accessibility
31   PUBLIC tra_ldf_lap  ! routine called by step.F90
32
33   REAL(wp), DIMENSION(jpi,jpj) ::   e1ur, e2vr   ! scale factor coefficients
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "ldftra_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010)
41   !! $Id$
42   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
43   !!----------------------------------------------------------------------
44   
45CONTAINS
46
47   SUBROUTINE tra_ldf_lap( kt, cdtype, pgu, pgv,  &
48      &                                ptb, pta, kjpt ) 
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE tra_ldf_lap  ***
51      !!                   
52      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
53      !!      trend and add it to the general trend of tracer equation.
54      !!
55      !! ** Method  :   Second order diffusive operator evaluated using before
56      !!      fields (forward time scheme). The horizontal diffusive trends of
57      !!      the tracer is given by:
58      !!          difft = 1/(e1t*e2t*e3t) {  di-1[ aht e2u*e3u/e1u di(tb) ]
59      !!                                   + dj-1[ aht e1v*e3v/e2v dj(tb) ] }
60      !!     Note: key_zco defined, the e3t=e3u=e3v, the trend becomes: 
61      !!          difft = 1/(e1t*e2t) {  di-1[ aht e2u/e1u di(tb) ]
62      !!                               + dj-1[ aht e1v/e2v dj(tb) ] }
63      !!      Add this trend to the general tracer trend pta :
64      !!          pta = pta + difft
65      !!
66      !! ** Action  : - Update pta arrays with the before iso-level
67      !!                harmonic mixing trend.
68      !!----------------------------------------------------------------------
69      !!
70      USE oce         , ztu => ua   ! use ua as workspace
71      USE oce         , ztv => va   ! use va as workspace
72      !!
73      INTEGER         , INTENT(in   )                                ::   kt             ! ocean time-step index
74      CHARACTER(len=3), INTENT(in   )                                ::   cdtype         ! =TRA or TRC (tracer indicator)
75      INTEGER         , INTENT(in   )                                ::   kjpt            ! number of tracers
76      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,kjpt  )     ::   pgu, pgv     ! tracer gradient at pstep levels
77      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk,kjpt)   ::   ptb          ! before and now tracer fields
78      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)   ::   pta          ! tracer trend
79      !!
80      INTEGER ::   ji, jj, jk, jn          ! dummy loop indices
81      INTEGER ::   iku, ikv                ! temporary integers
82      REAL(wp) ::   &
83         zabe1, zabe2, ztra, zbtr           ! temporary scalars
84      !!----------------------------------------------------------------------
85     
86      IF( kt == nit000 ) THEN
87         IF(lwp) WRITE(numout,*)
88         IF(lwp) WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion'
89         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
90         e1ur(:,:) = e2u(:,:) / e1u(:,:)
91         e2vr(:,:) = e1v(:,:) / e2v(:,:)
92      ENDIF
93
94      !
95      DO jn = 1, kjpt                                            ! tracer loop
96         !                                                       ! ===========     
97         !                                                 
98         DO jk = 1, jpkm1                               
99            !                                           
100            ! 1. First derivative (gradient)
101            ! -------------------
102            DO jj = 1, jpjm1
103               DO ji = 1, fs_jpim1   ! vector opt.
104                  zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * e1ur(ji,jj) * fse3u(ji,jj,jk)
105                  zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * e2vr(ji,jj) * fse3v(ji,jj,jk)
106                  ztu(ji,jj,jk) = zabe1 * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
107                  ztv(ji,jj,jk) = zabe2 * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
108               END DO
109            END DO
110            IF( ln_zps ) THEN      ! set gradient at partial step level
111               DO jj = 1, jpjm1
112                  DO ji = 1, fs_jpim1   ! vector opt.
113                     ! last level
114                     iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
115                     ikv = MIN ( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
116                     IF( iku == jk ) THEN
117                        zabe1 = fsahtu(ji,jj,iku) * umask(ji,jj,iku) * e1ur(ji,jj) * fse3u(ji,jj,iku)
118                        ztu(ji,jj,jk) = zabe1 * pgu(ji,jj,jn)
119                     ENDIF
120                     IF( ikv == jk ) THEN
121                        zabe2 = fsahtv(ji,jj,ikv) * vmask(ji,jj,ikv) * e2vr(ji,jj) * fse3v(ji,jj,ikv)
122                        ztv(ji,jj,jk) = zabe2 * pgv(ji,jj,jn)
123                     ENDIF
124                  END DO
125               END DO
126            ENDIF
127         
128         
129            ! 2. Second derivative (divergence) added to the general tracer trends
130            ! ---------------------------------------------------------------------
131            DO jj = 2, jpjm1
132               DO ji = fs_2, fs_jpim1   ! vector opt.
133                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
134                  ! horizontal diffusive trends
135                  ztra = zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
136                     &           + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
137                  ! add it to the general tracer trends
138                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
139               END DO
140            END DO
141            !                                               ! =============
142         END DO                                             !  End of slab 
143         !                                                  ! =============
144         ! "Poleward" diffusive heat or salt transports
145         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
146            IF( jn  == jp_tem)   pht_ldf(:) = ptr_vj( ztv(:,:,:) )
147            IF( jn  == jp_sal)   pst_ldf(:) = ptr_vj( ztv(:,:,:) )
148         ENDIF
149         !
150      END DO
151      !
152   END SUBROUTINE tra_ldf_lap
153
154   !!==============================================================================
155END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.