source: branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 7905

Last change on this file since 7905 was 7905, checked in by jcastill, 3 years ago

Series of small bug fixes and stetic changes:

-Fix possible bug in the calculation of Stokes-Coriolis
-Move all the wave control variables to namelist namsbc_wave
-Use one namelist variable instead of two to set Stokes drift velocity coupling
-Cap the values of the Craig and Banner constant as calculated from wave input fields to take into account small values of the friction velocity
-Add new Phillips parametrization for Stokes drift vertical velocity, using the inverse depth scale as in Breivik 2015, instead of the peak wave number as calculated from wave input fields
-Better control of the wave fields that are read from file depending on the wave parameters

File size: 31.6 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting                   
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   sbc_init       : read namsbc namelist
20   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
21   !!----------------------------------------------------------------------
22   USE oce              ! ocean dynamics and tracers
23   USE dom_oce          ! ocean space and time domain
24   USE phycst           ! physical constants
25   USE sbc_oce          ! Surface boundary condition: ocean fields
26   USE trc_oce          ! shared ocean-passive tracers variables
27   USE sbc_ice          ! Surface boundary condition: ice fields
28   USE sbcdcy           ! surface boundary condition: diurnal cycle
29   USE sbcssm           ! surface boundary condition: sea-surface mean variables
30   USE sbcapr           ! surface boundary condition: atmospheric pressure
31   USE sbcana           ! surface boundary condition: analytical formulation
32   USE sbcflx           ! surface boundary condition: flux formulation
33   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
34   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
35   USE sbcblk_mfs       ! surface boundary condition: bulk formulation : MFS
36   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
37   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
38   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
39   USE sbcice_cice      ! surface boundary condition: CICE    sea-ice model
40   USE sbccpl           ! surface boundary condition: coupled florulation
41   USE cpl_oasis3       ! OASIS routines for coupling
42   USE sbcssr           ! surface boundary condition: sea surface restoring
43   USE sbcrnf           ! surface boundary condition: runoffs
44   USE sbcisf           ! surface boundary condition: ice shelf
45   USE sbcfwb           ! surface boundary condition: freshwater budget
46   USE closea           ! closed sea
47   USE icbstp           ! Icebergs!
48
49   USE prtctl           ! Print control                    (prt_ctl routine)
50   USE iom              ! IOM library
51   USE in_out_manager   ! I/O manager
52   USE lib_mpp          ! MPP library
53   USE timing           ! Timing
54   USE sbcwave          ! Wave module
55   USE bdy_par          ! Require lk_bdy
56
57   IMPLICIT NONE
58   PRIVATE
59
60   PUBLIC   sbc        ! routine called by step.F90
61   PUBLIC   sbc_init   ! routine called by opa.F90
62   
63   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
64     
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67   !!----------------------------------------------------------------------
68   !! NEMO/OPA 4.0 , NEMO-consortium (2011)
69   !! $Id$
70   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
71   !!----------------------------------------------------------------------
72CONTAINS
73
74   SUBROUTINE sbc_init
75      !!---------------------------------------------------------------------
76      !!                    ***  ROUTINE sbc_init ***
77      !!
78      !! ** Purpose :   Initialisation of the ocean surface boundary computation
79      !!
80      !! ** Method  :   Read the namsbc namelist and set derived parameters
81      !!                Call init routines for all other SBC modules that have one
82      !!
83      !! ** Action  : - read namsbc parameters
84      !!              - nsbc: type of sbc
85      !!----------------------------------------------------------------------
86      INTEGER ::   icpt   ! local integer
87      !!
88      NAMELIST/namsbc/ nn_fsbc   , ln_ana    , ln_flx, ln_blk_clio, ln_blk_core, ln_mixcpl,   &
89         &             ln_blk_mfs, ln_apr_dyn, nn_ice, nn_ice_embd, ln_dm2dc   , ln_rnf   ,   &
90         &             ln_ssr    , nn_isf    , nn_fwb, ln_wave    , nn_lsm     , nn_limflx,   &
91                       nn_components, ln_cpl , ln_wavcpl
92      INTEGER  ::   ios
93      INTEGER  ::   ierr, ierr0, ierr1, ierr2, ierr3, jpm
94      !!----------------------------------------------------------------------
95
96      IF(lwp) THEN
97         WRITE(numout,*)
98         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
99         WRITE(numout,*) '~~~~~~~~ '
100      ENDIF
101
102      REWIND( numnam_ref )              ! Namelist namsbc in reference namelist : Surface boundary
103      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
104901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
105
106      REWIND( numnam_cfg )              ! Namelist namsbc in configuration namelist : Parameters of the run
107      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
108902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
109      IF(lwm) WRITE ( numond, namsbc )
110
111      !                          ! overwrite namelist parameter using CPP key information
112      IF( Agrif_Root() ) THEN                ! AGRIF zoom
113        IF( lk_lim2 )   nn_ice      = 2
114        IF( lk_lim3 )   nn_ice      = 3
115        IF( lk_cice )   nn_ice      = 4
116      ENDIF
117      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
118          ln_ana      = .TRUE.   
119          nn_ice      =   0
120      ENDIF
121
122      IF(lwp) THEN               ! Control print
123         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
124         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
125         WRITE(numout,*) '           Type of sbc : '
126         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
127         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
128         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
129         WRITE(numout,*) '              CORE bulk  formulation                     ln_blk_core = ', ln_blk_core
130         WRITE(numout,*) '              MFS  bulk  formulation                     ln_blk_mfs  = ', ln_blk_mfs
131         WRITE(numout,*) '              ocean-atmosphere coupled formulation       ln_cpl      = ', ln_cpl
132         WRITE(numout,*) '              forced-coupled atm mixed formulation       ln_mixcpl   = ', ln_mixcpl
133         WRITE(numout,*) '              forced-coupled wav mixed formulation       ln_wavcpl   = ', ln_wavcpl
134         WRITE(numout,*) '              wave physics                               ln_wave     = ', ln_wave 
135         WRITE(numout,*) '              OASIS coupling (with atm or sas)           lk_oasis    = ', lk_oasis
136         WRITE(numout,*) '              components of your executable              nn_components = ', nn_components
137         WRITE(numout,*) '              Multicategory heat flux formulation (LIM3) nn_limflx   = ', nn_limflx
138         WRITE(numout,*) '           Misc. options of sbc : '
139         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn  = ', ln_apr_dyn
140         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
141         WRITE(numout,*) '              ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd = ', nn_ice_embd
142         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
143         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
144         WRITE(numout,*) '              iceshelf formulation                       nn_isf      = ', nn_isf
145         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
146         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
147         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
148         WRITE(numout,*) '              n. of iterations if land-sea-mask applied  nn_lsm      = ', nn_lsm
149      ENDIF
150
151      ! LIM3 Multi-category heat flux formulation
152      SELECT CASE ( nn_limflx)
153      CASE ( -1 )
154         IF(lwp) WRITE(numout,*) '              Use of per-category fluxes (nn_limflx = -1) '
155      CASE ( 0  )
156         IF(lwp) WRITE(numout,*) '              Average per-category fluxes (nn_limflx = 0) ' 
157      CASE ( 1  )
158         IF(lwp) WRITE(numout,*) '              Average then redistribute per-category fluxes (nn_limflx = 1) '
159      CASE ( 2  )
160         IF(lwp) WRITE(numout,*) '              Redistribute a single flux over categories (nn_limflx = 2) '
161      END SELECT
162      !
163      IF ( nn_components /= jp_iam_nemo .AND. .NOT. lk_oasis )   &
164         &      CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
165      IF ( nn_components == jp_iam_opa .AND. ln_cpl )   &
166         &      CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA' )
167      IF ( nn_components == jp_iam_opa .AND. ( ln_mixcpl .OR. ln_wavcpl) )   &
168         &      CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl or ln_wavcpl = T in OPA' )
169      IF ( ln_cpl .AND. .NOT. lk_oasis )    &
170         &      CALL ctl_stop( 'STOP', 'sbc_init : OASIS-coupled atmosphere model, but key_oasis3 disabled' )
171      IF( ( ln_mixcpl .OR. ln_wavcpl ) .AND. .NOT. lk_oasis )    &
172         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl or ln_wavcpl) requires the cpp key key_oasis3' )
173      IF( ( ln_mixcpl .OR. ln_wavcpl ) .AND. .NOT. ln_cpl )    &
174         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl or ln_wavcpl) requires ln_cpl = T' )
175      IF( ( ln_mixcpl .OR. ln_wavcpl ) .AND. nn_components /= jp_iam_nemo )    &
176         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl or ln_wavcpl) is not yet working with sas-opa coupling via oasis' )
177
178      !                              ! allocate sbc arrays
179      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
180
181      !                          ! Checks:
182      IF( nn_isf .EQ. 0 ) THEN                      ! variable initialisation if no ice shelf
183         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
184         fwfisf  (:,:)   = 0.0_wp ; fwfisf_b  (:,:)   = 0.0_wp
185         risf_tsc(:,:,:) = 0.0_wp ; risf_tsc_b(:,:,:) = 0.0_wp
186         rdivisf       = 0.0_wp
187      END IF
188      IF( nn_ice == 0 .AND. nn_components /= jp_iam_opa )   fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero
189
190      sfx(:,:) = 0.0_wp                            ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero)
191                                                   ! only if sea-ice is present
192 
193      fmmflx(:,:) = 0.0_wp                        ! freezing-melting array initialisation
194     
195      taum(:,:) = 0.0_wp                           ! Initialise taum for use in gls in case of reduced restart
196
197      !                                            ! restartability   
198      IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. ln_cpl ) )   &
199         &   CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
200      IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. ln_cpl ) )   &
201         &   CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or ln_cpl' )
202      IF( nn_ice == 4 .AND. lk_agrif )   &
203         &   CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' )
204      IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 )   &
205         &   CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' )
206      IF( ( nn_ice /= 3 ) .AND. ( nn_limflx >= 0 ) )   &
207         &   WRITE(numout,*) 'The nn_limflx>=0 option has no effect if sea ice model is not LIM3'
208      IF( ( nn_ice == 3 ) .AND. ( ln_cpl ) .AND. ( ( nn_limflx == -1 ) .OR. ( nn_limflx == 1 ) ) )   &
209         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
210      IF( ( nn_ice == 3 ) .AND. ( .NOT. ln_cpl ) .AND. ( nn_limflx == 2 ) )   &
211         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in forced mode cannot be 2' )
212
213      IF( ln_dm2dc )   nday_qsr = -1   ! initialisation flag
214
215      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) .AND. nn_components /= jp_iam_opa )   &
216         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' )
217      !                          ! Choice of the Surface Boudary Condition (set nsbc)
218      ll_purecpl = ln_cpl .AND. .NOT. ln_mixcpl .AND. .NOT. ln_wavcpl
219      !
220      icpt = 0
221      IF( ln_ana          ) THEN   ;   nsbc = jp_ana     ; icpt = icpt + 1   ;   ENDIF       ! analytical           formulation
222      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
223      IF( ln_blk_clio     ) THEN   ;   nsbc = jp_clio    ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk            formulation
224      IF( ln_blk_core     ) THEN   ;   nsbc = jp_core    ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk            formulation
225      IF( ln_blk_mfs      ) THEN   ;   nsbc = jp_mfs     ; icpt = icpt + 1   ;   ENDIF       ! MFS  bulk            formulation
226      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
227      IF( cp_cfg == 'gyre') THEN   ;   nsbc = jp_gyre                        ;   ENDIF       ! GYRE analytical      formulation
228      IF( nn_components == jp_iam_opa )   &
229         &                  THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
230      IF( lk_esopa        )            nsbc = jp_esopa                                       ! esopa test, ALL formulations
231      !
232      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
233         WRITE(numout,*)
234         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
235         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
236         WRITE(numout,*) '                     We stop'
237         nstop = nstop + 1
238      ENDIF
239      IF(lwp) THEN
240         WRITE(numout,*)
241         IF( nsbc == jp_esopa   )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
242         IF( nsbc == jp_gyre    )   WRITE(numout,*) '              GYRE analytical formulation'
243         IF( nsbc == jp_ana     )   WRITE(numout,*) '              analytical formulation'
244         IF( nsbc == jp_flx     )   WRITE(numout,*) '              flux formulation'
245         IF( nsbc == jp_clio    )   WRITE(numout,*) '              CLIO bulk formulation'
246         IF( nsbc == jp_core    )   WRITE(numout,*) '              CORE bulk formulation'
247         IF( nsbc == jp_purecpl )   WRITE(numout,*) '              pure coupled formulation'
248         IF( nsbc == jp_mfs     )   WRITE(numout,*) '              MFS Bulk formulation'
249         IF( nsbc == jp_none    )   WRITE(numout,*) '              OPA coupled to SAS via oasis'
250         IF( ln_mixcpl          )   WRITE(numout,*) '              + forced-coupled mixed atm formulation'
251         IF( ln_wavcpl          )   WRITE(numout,*) '              + forced-coupled mixed wav formulation'
252         IF( nn_components/= jp_iam_nemo )  &
253            &                       WRITE(numout,*) '              + OASIS coupled SAS'
254      ENDIF
255      !
256      IF( lk_oasis )   CALL sbc_cpl_init (nn_ice)   ! OASIS initialisation. must be done before: (1) first time step
257      !                                                     !                                            (2) the use of nn_fsbc
258
259!     nn_fsbc initialization if OPA-SAS coupling via OASIS
260!     sas model time step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
261      IF ( nn_components /= jp_iam_nemo ) THEN
262
263         IF ( nn_components == jp_iam_opa ) nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
264         IF ( nn_components == jp_iam_sas ) nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
265         !
266         IF(lwp)THEN
267            WRITE(numout,*)
268            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
269            WRITE(numout,*)
270         ENDIF
271      ENDIF
272
273      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
274          MOD( nstock             , nn_fsbc) /= 0 ) THEN
275         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
276            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
277         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
278      ENDIF
279      !
280      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
281         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
282      !
283      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
284         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
285
286                               CALL sbc_ssm_init               ! Sea-surface mean fields initialisation
287      !
288      IF( ln_ssr           )   CALL sbc_ssr_init               ! Sea-Surface Restoring initialisation
289      !
290                               CALL sbc_rnf_init               ! Runof initialisation
291      !
292      IF( nn_ice == 3      )   CALL sbc_lim_init               ! LIM3 initialisation
293
294      IF( nn_ice == 4      )   CALL cice_sbc_init( nsbc )      ! CICE initialisation
295      !
296      IF( ln_wave          )   CALL sbc_wave_init              ! surface wave initialisation
297      !
298     
299   END SUBROUTINE sbc_init
300
301
302   SUBROUTINE sbc( kt )
303      !!---------------------------------------------------------------------
304      !!                    ***  ROUTINE sbc  ***
305      !!             
306      !! ** Purpose :   provide at each time-step the ocean surface boundary
307      !!                condition (momentum, heat and freshwater fluxes)
308      !!
309      !! ** Method  :   blah blah  to be written ?????????
310      !!                CAUTION : never mask the surface stress field (tke sbc)
311      !!
312      !! ** Action  : - set the ocean surface boundary condition at before and now
313      !!                time step, i.e. 
314      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
315      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
316      !!              - updte the ice fraction : fr_i
317      !!----------------------------------------------------------------------
318      INTEGER, INTENT(in) ::   kt       ! ocean time step
319      !!---------------------------------------------------------------------
320      !
321      IF( nn_timing == 1 )  CALL timing_start('sbc')
322      !
323      !                                            ! ---------------------------------------- !
324      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
325         !                                         ! ---------------------------------------- !
326         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
327         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
328         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
329         ! The 3D heat content due to qsr forcing is treated in traqsr
330         ! qsr_b (:,:) = qsr (:,:)
331         emp_b(:,:) = emp(:,:)
332         sfx_b(:,:) = sfx(:,:)
333      ENDIF
334      !                                            ! ---------------------------------------- !
335      !                                            !        forcing field computation         !
336      !                                            ! ---------------------------------------- !
337      !
338      IF ( .NOT. lk_bdy ) then
339         IF( ln_apr_dyn ) CALL sbc_apr( kt )                ! atmospheric pressure provided at kt+0.5*nn_fsbc
340      ENDIF
341                                                         ! (caution called before sbc_ssm)
342      !
343      IF( nn_components /= jp_iam_sas )   CALL sbc_ssm( kt )   ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
344      !                                                        ! averaged over nf_sbc time-step
345
346      IF (ln_wave) CALL sbc_wave( kt )
347                                                   !==  sbc formulation  ==!
348                                                           
349      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
350      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
351      CASE( jp_gyre  )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
352      CASE( jp_ana   )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
353      CASE( jp_flx   )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
354      CASE( jp_clio  )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
355      CASE( jp_core  )   
356         IF( nn_components == jp_iam_sas ) &
357            &                CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
358                             CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
359                                                                        ! from oce: sea surface variables (sst_m, sss_m,  ssu_m,  ssv_m)
360      CASE( jp_purecpl )  ;  CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
361                                                                        !
362      CASE( jp_mfs   )   ;   CALL sbc_blk_mfs ( kt )                    ! bulk formulation : MFS for the ocean
363      CASE( jp_none  ) 
364         IF( nn_components == jp_iam_opa ) &
365                             CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
366      CASE( jp_esopa )                               
367                             CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
368                             CALL sbc_gyre    ( kt )                    !
369                             CALL sbc_flx     ( kt )                    !
370                             CALL sbc_blk_clio( kt )                    !
371                             CALL sbc_blk_core( kt )                    !
372                             CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
373      END SELECT
374
375      IF( ln_mixcpl .OR. ln_wavcpl )  CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
376
377      IF ( ln_wave .AND. ln_tauoc) THEN                 ! Wave stress subctracted
378            utau(:,:) = utau(:,:)*tauoc_wave(:,:) 
379            vtau(:,:) = vtau(:,:)*tauoc_wave(:,:) 
380            taum(:,:) = taum(:,:)*tauoc_wave(:,:) 
381      !
382            SELECT CASE( nsbc ) 
383            CASE(  0,1,2,3,5,-1 )  ; 
384                IF(lwp .AND. kt == nit000 ) THEN
385                   write(numout,*)
386                   WRITE(numout,*) 'WARNING: You are subtracting the wave stress to the ocean. &
387                                                      & If not requested select ln_tauoc=.false' 
388                   write(numout,*)
389                END IF
390            END SELECT 
391      !
392      END IF
393
394      !                                            !==  Misc. Options  ==!
395     
396      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
397      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )                ! Ice-cover climatology ("Ice-if" model)
398      CASE(  2 )   ;         CALL sbc_ice_lim_2( kt, nsbc )          ! LIM-2 ice model
399      CASE(  3 )   ;         CALL sbc_ice_lim  ( kt, nsbc )          ! LIM-3 ice model
400      CASE(  4 )   ;         CALL sbc_ice_cice ( kt, nsbc )          ! CICE ice model
401      END SELECT                                             
402
403      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
404
405      IF( nn_isf   /= 0  )   CALL sbc_isf( kt )                    ! compute iceshelves
406
407      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
408 
409      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
410
411      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
412
413      IF( nn_closea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
414      !                                                           ! (update freshwater fluxes)
415!RBbug do not understand why see ticket 667
416!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
417      CALL lbc_lnk( emp, 'T', 1. )
418      !
419      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
420         !                                             ! ---------------------------------------- !
421         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
422            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
423            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
424            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
425            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
426            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
427            ! The 3D heat content due to qsr forcing is treated in traqsr
428            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  ) ! before     solar heat flux (T-point)
429            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b  )    ! before     freshwater flux (T-point)
430            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
431            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
432               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b )  ! before salt flux (T-point)
433            ELSE
434               sfx_b (:,:) = sfx(:,:)
435            ENDIF
436         ELSE                                                   !* no restart: set from nit000 values
437            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
438            utau_b(:,:) = utau(:,:) 
439            vtau_b(:,:) = vtau(:,:)
440            qns_b (:,:) = qns (:,:)
441            emp_b (:,:) = emp(:,:)
442            sfx_b (:,:) = sfx(:,:)
443         ENDIF
444      ENDIF
445      !                                                ! ---------------------------------------- !
446      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
447         !                                             ! ---------------------------------------- !
448         IF(lwp) WRITE(numout,*)
449         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
450            &                    'at it= ', kt,' date= ', ndastp
451         IF(lwp) WRITE(numout,*) '~~~~'
452         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
453         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
454         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
455         ! The 3D heat content due to qsr forcing is treated in traqsr
456         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
457         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
458         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx  )
459      ENDIF
460
461      !                                                ! ---------------------------------------- !
462      !                                                !        Outputs and control print         !
463      !                                                ! ---------------------------------------- !
464      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
465         CALL iom_put( "empmr" , emp  - rnf )                   ! upward water flux
466         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux 
467                                                                ! (includes virtual salt flux beneath ice
468                                                                ! in linear free surface case)
469         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
470         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
471         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
472         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
473         IF( nn_ice > 0 .OR. nn_components == jp_iam_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
474         CALL iom_put( "taum"  , taum       )                   ! wind stress module
475         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
476      ENDIF
477      !
478      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
479      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
480      !
481      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
482         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i     - : ', mask1=tmask, ovlap=1 )
483         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 )
484         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf  - : ', mask1=tmask, ovlap=1 )
485         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
486         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
487         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
488         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
489         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
490         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
491            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
492      ENDIF
493
494      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
495      !
496      IF( nn_timing == 1 )  CALL timing_stop('sbc')
497      !
498   END SUBROUTINE sbc
499
500
501   SUBROUTINE sbc_final
502      !!---------------------------------------------------------------------
503      !!                    ***  ROUTINE sbc_final  ***
504      !!
505      !! ** Purpose :   Finalize CICE (if used)
506      !!---------------------------------------------------------------------
507      !
508      IF( nn_ice == 4 )   CALL cice_sbc_final
509      !
510   END SUBROUTINE sbc_final
511
512   !!======================================================================
513END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.