New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/UKMO/v3_6_extra_CMIP6_diagnostics/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/v3_6_extra_CMIP6_diagnostics/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 6671

Last change on this file since 6671 was 6671, checked in by timgraham, 8 years ago

Added output of vertically integrated x and y fluxes from the TVD advection scheme
File size: 34.3 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd   : update the tracer trend with the 3D advection trends using a TVD scheme
20   !!   nonosc        : compute monotonic tracer fluxes by a non-oscillatory algorithm
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and active tracers
23   USE dom_oce        ! ocean space and time domain
24   USE trc_oce        ! share passive tracers/Ocean variables
25   USE trd_oce        ! trends: ocean variables
26   USE trdtra         ! tracers trends
27   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
28   USE diaptr         ! poleward transport diagnostics
29   !
30   USE lib_mpp        ! MPP library
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32   USE in_out_manager ! I/O manager
33   USE wrk_nemo       ! Memory Allocation
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
36   USE iom
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   tra_adv_tvd        ! routine called by traadv.F90
42   PUBLIC   tra_adv_tvd_zts    ! routine called by traadv.F90
43
44   LOGICAL ::   l_trd   ! flag to compute trends
45   LOGICAL ::   l_trans   ! flag to output vertically integrated transports
46
47   !! * Substitutions
48#  include "domzgr_substitute.h90"
49#  include "vectopt_loop_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
52   !! $Id$
53   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
54   !!----------------------------------------------------------------------
55CONTAINS
56
57   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
58      &                                       ptb, ptn, pta, kjpt )
59      !!----------------------------------------------------------------------
60      !!                  ***  ROUTINE tra_adv_tvd  ***
61      !!
62      !! **  Purpose :   Compute the now trend due to total advection of
63      !!       tracers and add it to the general trend of tracer equations
64      !!
65      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
66      !!       corrected flux (monotonic correction)
67      !!       note: - this advection scheme needs a leap-frog time scheme
68      !!
69      !! ** Action : - update (pta) with the now advective tracer trends
70      !!             - save the trends
71      !!----------------------------------------------------------------------
72      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
73      !
74      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
75      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
76      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
77      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
78      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
79      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
80      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
81      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
82      !
83      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices
84      INTEGER  ::   ik 
85      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
86      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
87      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
88      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz
89      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz, z2d, zptry
90      REAL(wp), POINTER, DIMENSION(:,:)   :: z2d
91      !!----------------------------------------------------------------------
92      !
93      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
94      !
95      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz )
96      !
97      IF( kt == kit000 )  THEN
98         IF(lwp) WRITE(numout,*)
99         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
100         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
101         !
102         l_trd = .FALSE.
103         l_trans = .FALSE.
104         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
105         IF( cdtype == 'TRA' .AND. (iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") ) ) l_trans = .TRUE.
106      ENDIF
107      !
108      IF( l_trd .OR. l_trans )  THEN
109         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
110         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
111         CALL wrk_alloc( jpi, jpj, z2d )
112      ENDIF
113      !
114      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
115         CALL wrk_alloc( jpi, jpj, jpk, zptry )
116         zptry(:,:,:) = 0._wp
117      ENDIF
118      !
119      zwi(:,:,:) = 0.e0 ; 
120      !
121      !                                                          ! ===========
122      DO jn = 1, kjpt                                            ! tracer loop
123         !                                                       ! ===========
124         ! 1. Bottom and k=1 value : flux set to zero
125         ! ----------------------------------
126         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
127         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
128         
129         zwz(:,:,1  ) = 0._wp
130         ! 2. upstream advection with initial mass fluxes & intermediate update
131         ! --------------------------------------------------------------------
132         ! upstream tracer flux in the i and j direction
133         DO jk = 1, jpkm1
134            DO jj = 1, jpjm1
135               DO ji = 1, fs_jpim1   ! vector opt.
136                  ! upstream scheme
137                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
138                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
139                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
140                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
141                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
142                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
143               END DO
144            END DO
145         END DO
146
147         ! upstream tracer flux in the k direction
148         ! Interior value
149         DO jk = 2, jpkm1
150            DO jj = 1, jpj
151               DO ji = 1, jpi
152                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
153                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
154                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
155               END DO
156            END DO
157         END DO
158         ! Surface value
159         IF( lk_vvl ) THEN   
160            IF ( ln_isfcav ) THEN
161               DO jj = 1, jpj
162                  DO ji = 1, jpi
163                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable
164                  END DO
165               END DO
166            ELSE
167               zwz(:,:,1) = 0.e0          ! volume variable
168            END IF
169         ELSE               
170            IF ( ln_isfcav ) THEN
171               DO jj = 1, jpj
172                  DO ji = 1, jpi
173                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
174                  END DO
175               END DO   
176            ELSE
177               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
178            END IF
179         ENDIF
180
181         ! total advective trend
182         DO jk = 1, jpkm1
183            z2dtt = p2dt(jk)
184            DO jj = 2, jpjm1
185               DO ji = fs_2, fs_jpim1   ! vector opt.
186                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
187                  ! total intermediate advective trends
188                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
189                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
190                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
191                  ! update and guess with monotonic sheme
192                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra   * tmask(ji,jj,jk)
193                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
194               END DO
195            END DO
196         END DO
197         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
198         CALL lbc_lnk( zwi, 'T', 1. ) 
199
200         !                                 ! trend diagnostics (contribution of upstream fluxes)
201         IF( l_trd .OR. l_trans )  THEN 
202            ! store intermediate advective trends
203            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
204         END IF
205         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
206         IF( cdtype == 'TRA' .AND. ln_diaptr )    zptry(:,:,:) = zwy(:,:,:) 
207
208         ! 3. antidiffusive flux : high order minus low order
209         ! --------------------------------------------------
210         ! antidiffusive flux on i and j
211         DO jk = 1, jpkm1
212            DO jj = 1, jpjm1
213               DO ji = 1, fs_jpim1   ! vector opt.
214                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
215                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
216               END DO
217            END DO
218         END DO
219     
220         ! antidiffusive flux on k
221         ! Interior value
222         DO jk = 2, jpkm1                   
223            DO jj = 1, jpj
224               DO ji = 1, jpi
225                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
226               END DO
227            END DO
228         END DO
229         ! surface value
230         IF ( ln_isfcav ) THEN
231            DO jj = 1, jpj
232               DO ji = 1, jpi
233                  zwz(ji,jj,mikt(ji,jj)) = 0.e0
234               END DO
235            END DO
236         ELSE
237            zwz(:,:,1) = 0.e0
238         END IF
239         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
240         CALL lbc_lnk( zwz, 'W',  1. )
241
242         ! 4. monotonicity algorithm
243         ! -------------------------
244         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
245
246
247         ! 5. final trend with corrected fluxes
248         ! ------------------------------------
249         DO jk = 1, jpkm1
250            DO jj = 2, jpjm1
251               DO ji = fs_2, fs_jpim1   ! vector opt. 
252                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
253                  ! total advective trends
254                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
255                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
256                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
257                  ! add them to the general tracer trends
258                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra * tmask(ji,jj,jk)
259               END DO
260            END DO
261         END DO
262
263         !                                 ! trend diagnostics (contribution of upstream fluxes)
264         IF( l_trd .OR. l_trans )  THEN
265            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
266            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
267            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
268         ENDIF
269         
270         IF( l_trd ) THEN
271            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
272            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
273            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
274         END IF
275
276         IF( l_trans .AND. jn==jp_tem ) THEN
277            z2d(:,:) = 0._wp 
278            DO jk = 1, jpkm1
279               DO jj = 2, jpjm1
280                  DO ji = fs_2, fs_jpim1   ! vector opt.
281                     z2d(ji,jj) = z2d(ji,jj) + ztrdx(ji,jj,jk) 
282                  END DO
283               END DO
284            END DO
285            CALL lbc_lnk( z2d, 'U', -1. )
286            CALL iom_put( "uadv_heattr", rau0_rcp * z2d )       ! heat transport in i-direction
287              !
288            z2d(:,:) = 0._wp 
289            DO jk = 1, jpkm1
290               DO jj = 2, jpjm1
291                  DO ji = fs_2, fs_jpim1   ! vector opt.
292                     z2d(ji,jj) = z2d(ji,jj) + ztrdy(ji,jj,jk) 
293                  END DO
294               END DO
295            END DO
296            CALL lbc_lnk( z2d, 'V', -1. )
297            CALL iom_put( "vadv_heattr", rau0_rcp * z2d )       ! heat transport in j-direction
298         ENDIF
299         ! "Poleward" heat and salt transports (contribution of upstream fluxes)
300         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
301            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
302            CALL dia_ptr_ohst_components( jn, 'adv', zptry(:,:,:) )
303         ENDIF
304         !
305      END DO
306      !
307      CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz )
308      IF( l_trd .OR. l_trans )  THEN
309         CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
310         CALL wrk_dealloc( jpi, jpj, z2d )
311      ENDIF
312      IF( cdtype == 'TRA' .AND. ln_diaptr ) CALL wrk_dealloc( jpi, jpj, jpk, zptry )
313      !
314      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
315      !
316   END SUBROUTINE tra_adv_tvd
317
318   SUBROUTINE tra_adv_tvd_zts ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
319      &                                       ptb, ptn, pta, kjpt )
320      !!----------------------------------------------------------------------
321      !!                  ***  ROUTINE tra_adv_tvd_zts  ***
322      !!
323      !! **  Purpose :   Compute the now trend due to total advection of
324      !!       tracers and add it to the general trend of tracer equations
325      !!
326      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
327      !!       corrected flux (monotonic correction). This version use sub-
328      !!       timestepping for the vertical advection which increases stability
329      !!       when vertical metrics are small.
330      !!       note: - this advection scheme needs a leap-frog time scheme
331      !!
332      !! ** Action : - update (pta) with the now advective tracer trends
333      !!             - save the trends
334      !!----------------------------------------------------------------------
335      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
336      !
337      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
338      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
339      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
340      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
341      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
342      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
343      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
344      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
345      !
346      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
347      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
348      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
349      INTEGER  ::   jnzts = 5       ! number of sub-timesteps for vertical advection
350      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
351      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
352      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
353      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
354      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
355      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
356      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwx_sav , zwy_sav
357      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz, zhdiv, zwz_sav, zwzts
358      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
359      REAL(wp), POINTER, DIMENSION(:,:,:) :: zptry
360      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrs
361      !!----------------------------------------------------------------------
362      !
363      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd_zts')
364      !
365      CALL wrk_alloc( jpi, jpj, zwx_sav, zwy_sav )
366      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz , zhdiv, zwz_sav, zwzts )
367      CALL wrk_alloc( jpi, jpj, jpk, kjpt+1, ztrs )
368      !
369      IF( kt == kit000 )  THEN
370         IF(lwp) WRITE(numout,*)
371         IF(lwp) WRITE(numout,*) 'tra_adv_tvd_zts : TVD ZTS advection scheme on ', cdtype
372         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
373      ENDIF
374      !
375      l_trd = .FALSE.
376      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
377      !
378      IF( l_trd )  THEN
379         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
380         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
381      ENDIF
382      !
383      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
384         CALL wrk_alloc( jpi, jpj,jpk, zptry )
385         zptry(:,:,:) = 0._wp
386      ENDIF
387      !
388      zwi(:,:,:) = 0._wp
389      z_rzts = 1._wp / REAL( jnzts, wp )
390      zr_p2dt(:) = 1._wp / p2dt(:)
391      !
392      !                                                          ! ===========
393      DO jn = 1, kjpt                                            ! tracer loop
394         !                                                       ! ===========
395         ! 1. Bottom value : flux set to zero
396         ! ----------------------------------
397         zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
398         zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
399
400         ! 2. upstream advection with initial mass fluxes & intermediate update
401         ! --------------------------------------------------------------------
402         ! upstream tracer flux in the i and j direction
403         DO jk = 1, jpkm1
404            DO jj = 1, jpjm1
405               DO ji = 1, fs_jpim1   ! vector opt.
406                  ! upstream scheme
407                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
408                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
409                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
410                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
411                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
412                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
413               END DO
414            END DO
415         END DO
416
417         ! upstream tracer flux in the k direction
418         ! Interior value
419         DO jk = 2, jpkm1
420            DO jj = 1, jpj
421               DO ji = 1, jpi
422                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
423                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
424                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
425               END DO
426            END DO
427         END DO
428         ! Surface value
429         IF( lk_vvl ) THEN
430            IF ( ln_isfcav ) THEN
431               DO jj = 1, jpj
432                  DO ji = 1, jpi
433                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable +    isf
434                  END DO
435               END DO
436            ELSE
437               zwz(:,:,1) = 0.e0                              ! volume variable + no isf
438            END IF
439         ELSE
440            IF ( ln_isfcav ) THEN
441               DO jj = 1, jpj
442                  DO ji = 1, jpi
443                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface +    isf
444                  END DO
445               END DO
446            ELSE
447               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)                                               ! linear free surface + no isf
448            END IF
449         ENDIF
450
451         ! total advective trend
452         DO jk = 1, jpkm1
453            z2dtt = p2dt(jk)
454            DO jj = 2, jpjm1
455               DO ji = fs_2, fs_jpim1   ! vector opt.
456                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
457                  ! total intermediate advective trends
458                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
459                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
460                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
461                  ! update and guess with monotonic sheme
462                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
463                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
464               END DO
465            END DO
466         END DO
467         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
468         CALL lbc_lnk( zwi, 'T', 1. ) 
469
470         !                                 ! trend diagnostics (contribution of upstream fluxes)
471         IF( l_trd )  THEN 
472            ! store intermediate advective trends
473            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
474         END IF
475         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
476         IF( cdtype == 'TRA' .AND. ln_diaptr )  zptry(:,:,:) = zwy(:,:,:)
477
478         ! 3. antidiffusive flux : high order minus low order
479         ! --------------------------------------------------
480         ! antidiffusive flux on i and j
481
482
483         DO jk = 1, jpkm1
484
485            DO jj = 1, jpjm1
486               DO ji = 1, fs_jpim1   ! vector opt.
487                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
488                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
489
490                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
491                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
492               END DO
493            END DO
494
495            DO jj = 2, jpjm1         ! partial horizontal divergence
496               DO ji = fs_2, fs_jpim1
497                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
498                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
499               END DO
500            END DO
501
502            DO jj = 1, jpjm1
503               DO ji = 1, fs_jpim1   ! vector opt.
504                  zwx(ji,jj,jk) = zwx(ji,jj,jk)  - zwx_sav(ji,jj)
505                  zwy(ji,jj,jk) = zwy(ji,jj,jk)  - zwy_sav(ji,jj)
506               END DO
507            END DO
508         END DO
509     
510         ! antidiffusive flux on k
511         zwz(:,:,1) = 0._wp        ! Surface value
512         zwz_sav(:,:,:) = zwz(:,:,:)
513         !
514         ztrs(:,:,:,1) = ptb(:,:,:,jn)
515         zwzts(:,:,:) = 0._wp
516
517         DO jl = 1, jnzts                   ! Start of sub timestepping loop
518
519            IF( jl == 1 ) THEN              ! Euler forward to kick things off
520              jtb = 1   ;   jtn = 1   ;   jta = 2
521              zts(:) = p2dt(:) * z_rzts
522              jtaken = MOD( jnzts + 1 , 2)  ! Toggle to collect every second flux
523                                            ! starting at jl =1 if jnzts is odd;
524                                            ! starting at jl =2 otherwise
525            ELSEIF( jl == 2 ) THEN          ! First leapfrog step
526              jtb = 1   ;   jtn = 2   ;   jta = 3
527              zts(:) = 2._wp * p2dt(:) * z_rzts
528            ELSE                            ! Shuffle pointers for subsequent leapfrog steps
529              jtb = MOD(jtb,3) + 1
530              jtn = MOD(jtn,3) + 1
531              jta = MOD(jta,3) + 1
532            ENDIF
533            DO jk = 2, jpkm1          ! Interior value
534               DO jj = 2, jpjm1
535                  DO ji = fs_2, fs_jpim1
536                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) )
537                     IF( jtaken == 0 ) zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk)*zts(jk)           ! Accumulate time-weighted vertcal flux
538                  END DO
539               END DO
540            END DO
541
542            jtaken = MOD( jtaken + 1 , 2 )
543
544            DO jk = 2, jpkm1          ! Interior value
545               DO jj = 2, jpjm1
546                  DO ji = fs_2, fs_jpim1
547                     zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
548                     ! total advective trends
549                     ztra = - zbtr * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
550                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb) + zts(jk) * ztra
551                  END DO
552               END DO
553            END DO
554
555         END DO
556
557         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
558            DO jj = 2, jpjm1
559               DO ji = fs_2, fs_jpim1
560                  zwz(ji,jj,jk) = zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk)
561               END DO
562            END DO
563         END DO
564         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
565         CALL lbc_lnk( zwz, 'W',  1. )
566
567         ! 4. monotonicity algorithm
568         ! -------------------------
569         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
570
571
572         ! 5. final trend with corrected fluxes
573         ! ------------------------------------
574         DO jk = 1, jpkm1
575            DO jj = 2, jpjm1
576               DO ji = fs_2, fs_jpim1   ! vector opt. 
577                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
578                  ! total advective trends
579                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
580                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
581                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
582                  ! add them to the general tracer trends
583                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
584               END DO
585            END DO
586         END DO
587
588         !                                 ! trend diagnostics (contribution of upstream fluxes)
589         IF( l_trd )  THEN
590            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
591            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
592            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
593           
594            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
595            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
596            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
597         END IF
598         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
599         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
600            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:) 
601            CALL dia_ptr_ohst_components( jn, 'adv', zptry(:,:,:) )
602         ENDIF
603         !
604      END DO
605      !
606                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz, zhdiv, zwz_sav, zwzts )
607                   CALL wrk_dealloc( jpi, jpj, jpk, kjpt+1, ztrs )
608                   CALL wrk_dealloc( jpi, jpj, zwx_sav, zwy_sav )
609      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
610      IF( cdtype == 'TRA' .AND. ln_diaptr ) CALL wrk_dealloc( jpi, jpj, jpk, zptry )
611      !
612      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd_zts')
613      !
614   END SUBROUTINE tra_adv_tvd_zts
615
616   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
617      !!---------------------------------------------------------------------
618      !!                    ***  ROUTINE nonosc  ***
619      !!     
620      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
621      !!       scheme and the before field by a nonoscillatory algorithm
622      !!
623      !! **  Method  :   ... ???
624      !!       warning : pbef and paft must be masked, but the boundaries
625      !!       conditions on the fluxes are not necessary zalezak (1979)
626      !!       drange (1995) multi-dimensional forward-in-time and upstream-
627      !!       in-space based differencing for fluid
628      !!----------------------------------------------------------------------
629      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
630      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
631      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
632      !
633      INTEGER  ::   ji, jj, jk   ! dummy loop indices
634      INTEGER  ::   ikm1         ! local integer
635      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
636      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
637      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
638      !!----------------------------------------------------------------------
639      !
640      IF( nn_timing == 1 )  CALL timing_start('nonosc')
641      !
642      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
643      !
644      zbig  = 1.e+40_wp
645      zrtrn = 1.e-15_wp
646      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
647
648      ! Search local extrema
649      ! --------------------
650      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
651      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
652         &        paft * tmask - zbig * ( 1._wp - tmask )  )
653      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
654         &        paft * tmask + zbig * ( 1._wp - tmask )  )
655
656      DO jk = 1, jpkm1
657         ikm1 = MAX(jk-1,1)
658         z2dtt = p2dt(jk)
659         DO jj = 2, jpjm1
660            DO ji = fs_2, fs_jpim1   ! vector opt.
661
662               ! search maximum in neighbourhood
663               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
664                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
665                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
666                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
667
668               ! search minimum in neighbourhood
669               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
670                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
671                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
672                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
673
674               ! positive part of the flux
675               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
676                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
677                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
678
679               ! negative part of the flux
680               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
681                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
682                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
683
684               ! up & down beta terms
685               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
686               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
687               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
688            END DO
689         END DO
690      END DO
691      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
692
693      ! 3. monotonic flux in the i & j direction (paa & pbb)
694      ! ----------------------------------------
695      DO jk = 1, jpkm1
696         DO jj = 2, jpjm1
697            DO ji = fs_2, fs_jpim1   ! vector opt.
698               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
699               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
700               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
701               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
702
703               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
704               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
705               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
706               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
707
708      ! monotonic flux in the k direction, i.e. pcc
709      ! -------------------------------------------
710               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
711               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
712               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
713               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
714            END DO
715         END DO
716      END DO
717      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
718      !
719      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
720      !
721      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
722      !
723   END SUBROUTINE nonosc
724
725   !!======================================================================
726END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.