1 | MODULE trcldf_iso |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE trcldf_iso *** |
---|
4 | !!====================================================================== |
---|
5 | !! Ocean passive tracers: horizontal component of the lateral tracer mixing trend |
---|
6 | !! History : |
---|
7 | !! ! 94-08 (G. Madec, M. Imbard) |
---|
8 | !! ! 97-05 (G. Madec) split into traldf and trazdf |
---|
9 | !! ! 98-03 (L. Bopp, MA Foujols) passive tracer generalisation |
---|
10 | !! ! 00-10 (MA Foujols E Kestenare) USE passive tracer coefficient |
---|
11 | !! 8.5 ! 02-08 (G. Madec) Free form, F90 |
---|
12 | !! 9.0 ! 04-03 (C. Ethe) Free form, F90 |
---|
13 | !! ! 06-08 (C. Deltel) Diagnose ML trends for passive tracers |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | #if key_top && defined key_ldfslp |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | !! 'key_ldfslp' rotation of the lateral mixing tensor |
---|
18 | !!---------------------------------------------------------------------- |
---|
19 | !! trc_ldf_iso : update the tracer trend with the horizontal component |
---|
20 | !! of iso neutral laplacian operator or horizontal |
---|
21 | !! laplacian operator in s-coordinate |
---|
22 | !!---------------------------------------------------------------------- |
---|
23 | USE oce_trc ! ocean dynamics and tracers variables |
---|
24 | USE trp_trc ! ocean passive tracers variables |
---|
25 | USE prtctl_trc ! Print control for debbuging |
---|
26 | USE trdmld_trc |
---|
27 | USE trdmld_trc_oce |
---|
28 | |
---|
29 | IMPLICIT NONE |
---|
30 | PRIVATE |
---|
31 | |
---|
32 | PUBLIC trc_ldf_iso ! routine called by step.F90 |
---|
33 | |
---|
34 | !! * Substitutions |
---|
35 | # include "top_substitute.h90" |
---|
36 | !!---------------------------------------------------------------------- |
---|
37 | !! TOP 1.0 , LOCEAN-IPSL (2005) |
---|
38 | !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcldf_iso.F90,v 1.9 2006/04/10 15:38:54 opalod Exp $ |
---|
39 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
40 | !!---------------------------------------------------------------------- |
---|
41 | |
---|
42 | CONTAINS |
---|
43 | |
---|
44 | SUBROUTINE trc_ldf_iso( kt ) |
---|
45 | !!---------------------------------------------------------------------- |
---|
46 | !! *** ROUTINE trc_ldf_iso *** |
---|
47 | !! |
---|
48 | !! ** Purpose : Compute the before horizontal tracer diffusive |
---|
49 | !! trend and add it to the general trend of tracer equation. |
---|
50 | !! |
---|
51 | !! ** Method : The horizontal component of the lateral diffusive trends |
---|
52 | !! is provided by a 2nd order operator rotated along neural or geopo- |
---|
53 | !! tential surfaces to which an eddy induced advection can be added |
---|
54 | !! It is computed using before fields (forward in time) and isopyc- |
---|
55 | !! nal or geopotential slopes computed in routine ldfslp. |
---|
56 | !! |
---|
57 | !! horizontal fluxes associated with the rotated lateral mixing: |
---|
58 | !! zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ] |
---|
59 | !! - aht e2u*uslp dk[ mi(mk(tb)) ] |
---|
60 | !! zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ] |
---|
61 | !! - aht e2u*vslp dk[ mj(mk(tb)) ] |
---|
62 | !! add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T): |
---|
63 | !! zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb ) |
---|
64 | !! zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb ) |
---|
65 | !! take the horizontal divergence of the fluxes: |
---|
66 | !! difft = 1/(e1t*e2t*e3t) { di-1[ zftu ] + dj-1[ zftv ] } |
---|
67 | !! Add this trend to the general trend tra : |
---|
68 | !! tra = tra + difft |
---|
69 | !! |
---|
70 | !! ** Action : - Update tra arrays with the before isopycnal or |
---|
71 | !! geopotential s-coord harmonic mixing trend. |
---|
72 | !! - Save the trends ('key_trdmld_trc') |
---|
73 | !!---------------------------------------------------------------------- |
---|
74 | USE oce_trc , zftu => ua, & ! use ua as workspace |
---|
75 | & zftv => va ! use va as workspace |
---|
76 | !! |
---|
77 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
---|
78 | !! |
---|
79 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
---|
80 | REAL(wp) :: zabe1, zabe2, zcof1, zcof2 ! temporary scalars |
---|
81 | REAL(wp) :: zmsku, zmskv, zbtr, ztra |
---|
82 | #if defined key_trcldf_eiv |
---|
83 | REAL(wp) :: zcg1, zcg2, zuwk, zvwk, zuwk1, zvwk1 |
---|
84 | REAL(wp) :: z_hdivn_x, z_hdivn_y |
---|
85 | #endif |
---|
86 | REAL(wp), DIMENSION(jpi,jpj) :: zdkt, zdk1t ! workspace |
---|
87 | #if defined key_trcldf_eiv |
---|
88 | REAL(wp), DIMENSION(jpi,jpj) :: zftug, zftvg |
---|
89 | #endif |
---|
90 | CHARACTER (len=22) :: charout |
---|
91 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrtrd ! trends arrays |
---|
92 | # if defined key_trcldf_eiv |
---|
93 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrtrd_xei |
---|
94 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrtrd_yei |
---|
95 | #endif |
---|
96 | !!---------------------------------------------------------------------- |
---|
97 | |
---|
98 | IF( kt == nittrc000 ) THEN |
---|
99 | IF(lwp) WRITE(numout,*) |
---|
100 | IF(lwp) WRITE(numout,*) 'trc_ldf_iso : iso neutral lateral diffusion or' |
---|
101 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ horizontal laplacian diffusion in s-coordinate' |
---|
102 | #if defined key_trcldf_eiv && defined key_diaeiv |
---|
103 | u_trc_eiv(:,:,:) = 0.e0 |
---|
104 | v_trc_eiv(:,:,:) = 0.e0 |
---|
105 | #endif |
---|
106 | ENDIF |
---|
107 | |
---|
108 | IF( l_trdtrc ) THEN |
---|
109 | ALLOCATE( ztrtrd(jpi,jpj,jpk) ) |
---|
110 | # if defined key_trcldf_eiv |
---|
111 | ALLOCATE( ztrtrd_xei(jpi,jpj,jpk) ) |
---|
112 | ALLOCATE( ztrtrd_yei(jpi,jpj,jpk) ) |
---|
113 | # endif |
---|
114 | ENDIF |
---|
115 | |
---|
116 | ! ! =========== |
---|
117 | DO jn = 1, jptra ! tracer loop |
---|
118 | ! ! =========== |
---|
119 | |
---|
120 | IF( l_trdtrc ) ztrtrd(:,:,:) = tra(:,:,:,jn) |
---|
121 | |
---|
122 | ! ! =============== |
---|
123 | DO jk = 1, jpkm1 ! Horizontal slab |
---|
124 | ! ! =============== |
---|
125 | ! 1. Vertical tracer gradient at level jk and jk+1 |
---|
126 | ! ------------------------------------------------ |
---|
127 | ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2) |
---|
128 | |
---|
129 | zdk1t(:,:) = ( trb(:,:,jk,jn) - trb(:,:,jk+1,jn) ) * tmask(:,:,jk+1) |
---|
130 | |
---|
131 | IF( jk == 1 ) THEN |
---|
132 | zdkt(:,:) = zdk1t(:,:) |
---|
133 | ELSE |
---|
134 | zdkt(:,:) = ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) ) * tmask(:,:,jk) |
---|
135 | ENDIF |
---|
136 | |
---|
137 | |
---|
138 | ! 2. Horizontal fluxes |
---|
139 | ! -------------------- |
---|
140 | |
---|
141 | DO jj = 1 , jpjm1 |
---|
142 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
143 | zabe1 = ( fsahtru(ji,jj,jk) + ahtrb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj) |
---|
144 | zabe2 = ( fsahtrv(ji,jj,jk) + ahtrb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj) |
---|
145 | |
---|
146 | zmsku = 1. / MAX( tmask(ji+1,jj,jk ) + tmask(ji,jj,jk+1) & |
---|
147 | + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk ), 1. ) |
---|
148 | |
---|
149 | zmskv = 1. / MAX( tmask(ji,jj+1,jk ) + tmask(ji,jj,jk+1) & |
---|
150 | + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk ), 1. ) |
---|
151 | |
---|
152 | zcof1 = -fsahtru(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku |
---|
153 | zcof2 = -fsahtrv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv |
---|
154 | |
---|
155 | zftu(ji,jj,jk) = umask(ji,jj,jk) * ( zabe1 * ( trb(ji+1,jj,jk,jn) - trb(ji,jj,jk,jn) ) & |
---|
156 | & + zcof1 * ( zdkt (ji+1,jj) + zdk1t(ji,jj) & |
---|
157 | & + zdk1t(ji+1,jj) + zdkt (ji,jj) ) ) |
---|
158 | |
---|
159 | zftv(ji,jj,jk) = vmask(ji,jj,jk) * ( zabe2 * ( trb(ji,jj+1,jk,jn) - trb(ji,jj,jk,jn) ) & |
---|
160 | & + zcof2 * ( zdkt (ji,jj+1) + zdk1t(ji,jj) & |
---|
161 | & + zdk1t(ji,jj+1) + zdkt (ji,jj) ) ) |
---|
162 | |
---|
163 | END DO |
---|
164 | END DO |
---|
165 | |
---|
166 | # if defined key_trcldf_eiv |
---|
167 | ! ! ---------------------------------------! |
---|
168 | ! ! Eddy induced vertical advective fluxes ! |
---|
169 | ! ! ---------------------------------------! |
---|
170 | DO jj = 1, jpjm1 |
---|
171 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
172 | zuwk = ( wslpi(ji,jj,jk ) + wslpi(ji+1,jj,jk ) ) * fsaeitru(ji,jj,jk ) * umask(ji,jj,jk ) |
---|
173 | zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1) |
---|
174 | zvwk = ( wslpj(ji,jj,jk ) + wslpj(ji,jj+1,jk ) ) * fsaeitrv(ji,jj,jk ) * vmask(ji,jj,jk ) |
---|
175 | zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1) |
---|
176 | |
---|
177 | zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 ) |
---|
178 | zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 ) |
---|
179 | |
---|
180 | zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) ) |
---|
181 | zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) ) |
---|
182 | |
---|
183 | zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj) |
---|
184 | zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj) |
---|
185 | |
---|
186 | # if defined key_diaeiv |
---|
187 | u_trc_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) ) |
---|
188 | v_trc_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) ) |
---|
189 | # endif |
---|
190 | END DO |
---|
191 | END DO |
---|
192 | # endif |
---|
193 | |
---|
194 | ! 3. Second derivative (divergence) and add to the general trend |
---|
195 | ! -------------------------------------------------------------- |
---|
196 | |
---|
197 | DO jj = 2 , jpjm1 |
---|
198 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
199 | zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) ) |
---|
200 | ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj ,jk) & |
---|
201 | & + zftv(ji,jj,jk) - zftv(ji ,jj-1,jk) ) |
---|
202 | tra (ji,jj,jk,jn) = tra (ji,jj,jk,jn) + ztra |
---|
203 | #if defined key_trc_diatrd |
---|
204 | IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),4) = ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk ) ) * zbtr |
---|
205 | IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),5) = ( zftv(ji,jj,jk) - zftv(ji,jj-1,jk ) ) * zbtr |
---|
206 | #endif |
---|
207 | |
---|
208 | END DO |
---|
209 | END DO |
---|
210 | ! ! =============== |
---|
211 | END DO ! End of slab |
---|
212 | ! ! =============== |
---|
213 | |
---|
214 | ! 4. Save the trends for diagnostic |
---|
215 | ! --------------------------------- |
---|
216 | |
---|
217 | IF( l_trdtrc ) THEN |
---|
218 | # if defined key_trcldf_eiv |
---|
219 | |
---|
220 | ! 4.1) Compute the eiv ZONAL & MERIDIONAL advective trends |
---|
221 | ! =============== |
---|
222 | DO jk = 1, jpkm1 ! Horizontal slab |
---|
223 | ! =============== |
---|
224 | DO jj = 1, jpjm1 |
---|
225 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
226 | zuwk = ( wslpi(ji,jj,jk ) + wslpi(ji+1,jj,jk ) ) * fsaeitru(ji,jj,jk ) * umask(ji,jj,jk ) |
---|
227 | zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1) |
---|
228 | zvwk = ( wslpj(ji,jj,jk ) + wslpj(ji,jj+1,jk ) ) * fsaeitrv(ji,jj,jk ) * vmask(ji,jj,jk ) |
---|
229 | zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1) |
---|
230 | |
---|
231 | zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 ) |
---|
232 | zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 ) |
---|
233 | |
---|
234 | zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) ) |
---|
235 | zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) ) |
---|
236 | END DO |
---|
237 | END DO |
---|
238 | |
---|
239 | DO jj = 2 , jpjm1 |
---|
240 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
241 | zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) ) |
---|
242 | |
---|
243 | !-- Compute zonal & meridional divergences of the eiv field : |
---|
244 | ! d_x[u_trc_eiv] = 1/(e1t*e2t*e3t) ( di[e2u*e3u u_trc_eiv] ) |
---|
245 | ! d_y[v_trc_eiv] = 1/(e1t*e2t*e3t) ( dj[e1v*e3v v_trc_eiv] ) |
---|
246 | ! N.B. This is only possible if key_diaeiv is switched on. |
---|
247 | # if defined key_diaeiv |
---|
248 | z_hdivn_x = ( e2u(ji ,jj) * fse3u(ji ,jj,jk) * u_trc_eiv(ji ,jj ,jk) & |
---|
249 | & - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * u_trc_eiv(ji-1,jj ,jk) ) * zbtr |
---|
250 | z_hdivn_y = ( e1v(ji, jj) * fse3v(ji,jj ,jk) * v_trc_eiv(ji, jj ,jk) & |
---|
251 | & - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * v_trc_eiv(ji ,jj-1,jk) ) * zbtr |
---|
252 | # else |
---|
253 | z_hdivn_x = 0.e0 ; z_hdivn_y = 0.e0 |
---|
254 | # endif |
---|
255 | !-- Compute the zonal advective trends associated with eiv |
---|
256 | ztrtrd_xei(ji,jj,jk) = zbtr * ( zftug(ji,jj) - zftug(ji-1,jj ) ) & |
---|
257 | & - trn(ji,jj,jk,jn) * z_hdivn_x |
---|
258 | |
---|
259 | !-- Compute the merid. advective trends associated with eiv |
---|
260 | ztrtrd_yei(ji,jj,jk) = zbtr * ( zftvg(ji,jj) - zftvg(ji ,jj-1) ) & |
---|
261 | & - trn(ji,jj,jk,jn) * z_hdivn_y |
---|
262 | END DO |
---|
263 | END DO |
---|
264 | ! =============== |
---|
265 | END DO ! End of slab |
---|
266 | ! =============== |
---|
267 | ! 4.2) Deduce the trend |
---|
268 | ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:) - ztrtrd_xei(:,:,:) - ztrtrd_yei(:,:,:) |
---|
269 | # else |
---|
270 | ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:) |
---|
271 | # endif |
---|
272 | |
---|
273 | ! 4.3) save the trends for diagnostic |
---|
274 | IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd , jn, jptrc_trd_ldf, kt ) |
---|
275 | # if defined key_trcldf_eiv |
---|
276 | IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd_xei, jn, jptrc_trd_xei, kt ) |
---|
277 | IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd_yei, jn, jptrc_trd_yei, kt ) |
---|
278 | # endif |
---|
279 | ENDIF |
---|
280 | ! ! =========== |
---|
281 | END DO ! tracer loop |
---|
282 | ! ! =========== |
---|
283 | |
---|
284 | IF( l_trdtrc ) THEN |
---|
285 | DEALLOCATE( ztrtrd ) |
---|
286 | # if defined key_trcldf_eiv |
---|
287 | DEALLOCATE( ztrtrd_xei ) |
---|
288 | DEALLOCATE( ztrtrd_yei ) |
---|
289 | # endif |
---|
290 | ENDIF |
---|
291 | |
---|
292 | IF( ln_ctl ) THEN ! print mean trends (used for debugging) |
---|
293 | WRITE(charout, FMT="('ldf - iso')") |
---|
294 | CALL prt_ctl_trc_info(charout) |
---|
295 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd') |
---|
296 | ENDIF |
---|
297 | |
---|
298 | END SUBROUTINE trc_ldf_iso |
---|
299 | |
---|
300 | #else |
---|
301 | !!---------------------------------------------------------------------- |
---|
302 | !! Dummy module : No rotation of the lateral mixing tensor |
---|
303 | !!---------------------------------------------------------------------- |
---|
304 | CONTAINS |
---|
305 | SUBROUTINE trc_ldf_iso( kt ) ! Empty routine |
---|
306 | INTEGER, INTENT(in) :: kt |
---|
307 | WRITE(*,*) 'trc_ldf_iso: You should not have seen this print! error?', kt |
---|
308 | END SUBROUTINE trc_ldf_iso |
---|
309 | #endif |
---|
310 | |
---|
311 | !!============================================================================== |
---|
312 | END MODULE trcldf_iso |
---|