New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf_iso.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcldf_iso.F90 @ 1193

Last change on this file since 1193 was 1193, checked in by cetlod, 16 years ago

Correction of transport module to ensure reproductibility for TOP configurations, see ticket:253
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 15.5 KB
Line 
1MODULE trcldf_iso
2   !!==============================================================================
3   !!                    ***  MODULE  trcldf_iso  ***
4   !!======================================================================
5   !! Ocean passive tracers:  horizontal component of the lateral tracer mixing trend
6   !! History :
7   !!        !  94-08  (G. Madec, M. Imbard)
8   !!        !  97-05  (G. Madec)  split into traldf and trazdf
9   !!        !  98-03  (L. Bopp, MA Foujols) passive tracer generalisation
10   !!        !  00-10  (MA Foujols E Kestenare) USE passive tracer coefficient
11   !!   8.5  !  02-08  (G. Madec)  Free form, F90
12   !!   9.0  !  04-03  (C. Ethe)  Free form, F90
13   !!        !  06-08  (C. Deltel) Diagnose ML trends for passive tracers
14   !!----------------------------------------------------------------------
15#if key_top && defined key_ldfslp 
16   !!----------------------------------------------------------------------
17   !!   'key_ldfslp'                  rotation of the lateral mixing tensor
18   !!----------------------------------------------------------------------
19   !!   trc_ldf_iso : update the tracer trend with the horizontal component
20   !!                 of iso neutral laplacian operator or horizontal
21   !!                 laplacian operator in s-coordinate
22   !!----------------------------------------------------------------------
23   USE oce_trc      ! ocean dynamics and tracers variables
24   USE trp_trc      ! ocean passive tracers variables
25   USE prtctl_trc   ! Print control for debbuging
26   USE trdmld_trc
27   USE trdmld_trc_oce     
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC trc_ldf_iso  ! routine called by step.F90
33
34   !! * Substitutions
35#  include "top_substitute.h90"
36   !!----------------------------------------------------------------------
37   !!   TOP 1.0 , LOCEAN-IPSL (2005)
38   !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcldf_iso.F90,v 1.9 2006/04/10 15:38:54 opalod Exp $
39   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41
42CONTAINS
43
44   SUBROUTINE trc_ldf_iso( kt )
45      !!----------------------------------------------------------------------
46      !!                  ***  ROUTINE trc_ldf_iso  ***
47      !!
48      !! ** Purpose :   Compute the before horizontal tracer  diffusive
49      !!      trend and add it to the general trend of tracer equation.
50      !!
51      !! ** Method  :   The horizontal component of the lateral diffusive trends
52      !!      is provided by a 2nd order operator rotated along neural or geopo-
53      !!      tential surfaces to which an eddy induced advection can be added
54      !!      It is computed using before fields (forward in time) and isopyc-
55      !!      nal or geopotential slopes computed in routine ldfslp.
56      !!
57      !!      horizontal fluxes associated with the rotated lateral mixing:
58      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
59      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
60      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
61      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
62      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
63      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb )
64      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb )
65      !!      take the horizontal divergence of the fluxes:
66      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
67      !!      Add this trend to the general trend tra :
68      !!         tra = tra + difft
69      !!
70      !! ** Action  : - Update tra arrays with the before isopycnal or
71      !!                geopotential s-coord harmonic mixing trend.
72      !!              - Save the trends ('key_trdmld_trc')
73      !!----------------------------------------------------------------------
74      USE oce_trc       , zftu => ua,  &  ! use ua as workspace
75         &                zfsu => va      ! use va as workspace
76      !!
77      INTEGER, INTENT( in ) ::   kt                             ! ocean time-step index
78      !!                                                 
79      INTEGER ::   ji, jj, jk, jn                               ! dummy loop indices
80      REAL(wp) ::   zabe1, zabe2, zcof1, zcof2                  ! temporary scalars
81      REAL(wp) ::   zmsku, zmskv, zbtr, ztra
82#if defined key_trcldf_eiv
83      REAL(wp) ::   zcg1, zcg2, zuwk, zvwk, zuwk1, zvwk1
84      REAL(wp) ::   z_hdivn_x, z_hdivn_y
85#endif
86      REAL(wp), DIMENSION(jpi,jpj) ::   zdkt, zdk1t             ! workspace
87#if defined key_trcldf_eiv
88      REAL(wp), DIMENSION(jpi,jpj) ::   zftug, zftvg
89#endif
90      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zftv                ! workspace
91      CHARACTER (len=22) :: charout
92      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd       ! trends arrays
93#   if defined key_trcldf_eiv
94      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd_xei
95      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd_yei
96#endif
97      !!----------------------------------------------------------------------
98
99      IF( kt == nittrc000 ) THEN
100         IF(lwp) WRITE(numout,*)
101         IF(lwp) WRITE(numout,*) 'trc_ldf_iso : iso neutral lateral diffusion or'
102         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   horizontal laplacian diffusion in s-coordinate'
103#if defined key_trcldf_eiv && defined key_diaeiv
104         u_trc_eiv(:,:,:) = 0.e0
105         v_trc_eiv(:,:,:) = 0.e0
106#endif
107      ENDIF
108
109      IF( l_trdtrc ) THEN
110         ALLOCATE( ztrtrd(jpi,jpj,jpk) )
111#   if defined key_trcldf_eiv
112         ALLOCATE( ztrtrd_xei(jpi,jpj,jpk) )
113         ALLOCATE( ztrtrd_yei(jpi,jpj,jpk) )
114#   endif
115      ENDIF
116
117      !                                                          ! ===========
118      DO jn = 1, jptra                                           ! tracer loop
119         !                                                       ! ===========
120
121         IF( l_trdtrc ) ztrtrd(:,:,:) = tra(:,:,:,jn)
122
123         !                                                ! ===============
124         DO jk = 1, jpkm1                                 ! Horizontal slab
125            !                                             ! ===============
126            ! 1. Vertical tracer gradient at level jk and jk+1
127            ! ------------------------------------------------
128            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
129
130            zdk1t(:,:) = ( trb(:,:,jk,jn) - trb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
131
132            IF( jk == 1 ) THEN
133               zdkt(:,:) = zdk1t(:,:)
134            ELSE
135               zdkt(:,:) = ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) ) * tmask(:,:,jk)
136            ENDIF
137
138
139            ! 2. Horizontal fluxes
140            ! --------------------
141
142            DO jj = 1 , jpjm1
143               DO ji = 1, fs_jpim1   ! vector opt.
144                  zabe1 = ( fsahtru(ji,jj,jk) + ahtrb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
145                  zabe2 = ( fsahtrv(ji,jj,jk) + ahtrb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
146
147                  zmsku = 1. / MAX(   tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
148                     + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
149
150                  zmskv = 1. / MAX(   tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
151                     + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
152
153                  zcof1 = -fsahtru(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
154                  zcof2 = -fsahtrv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
155
156                  zftu(ji,jj,jk) = umask(ji,jj,jk) * (   zabe1 * (   trb(ji+1,jj,jk,jn) - trb(ji,jj,jk,jn)  )   &
157                     &                              + zcof1 * (   zdkt (ji+1,jj) + zdk1t(ji,jj)      &
158                     &                                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
159
160                  zftv(ji,jj,jk) = vmask(ji,jj,jk) * (   zabe2 * (   trb(ji,jj+1,jk,jn) - trb(ji,jj,jk,jn)  )   &
161                     &                              + zcof2 * (   zdkt (ji,jj+1) + zdk1t(ji,jj)      &
162                     &                                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
163
164               END DO
165            END DO
166
167#   if defined key_trcldf_eiv
168            !                              ! ---------------------------------------!
169            !                              ! Eddy induced vertical advective fluxes !
170            !                              ! ---------------------------------------!
171            DO jj = 1, jpjm1
172               DO ji = 1, fs_jpim1   ! vector opt.
173                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
174                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
175                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
176                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
177
178                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
179                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
180
181                  zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
182                  zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
183
184                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
185                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
186
187#   if defined key_diaeiv
188                  u_trc_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
189                  v_trc_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
190#   endif
191               END DO
192            END DO
193#   endif
194
195            ! 3. Second derivative (divergence) and add to the general trend
196            ! --------------------------------------------------------------
197
198            DO jj = 2 , jpjm1
199               DO ji = fs_2, fs_jpim1   ! vector opt.
200                  zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
201                  ztra = zbtr * (  zftu(ji,jj,jk) - zftu(ji-1,jj  ,jk)   &
202                       &         + zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk)  )
203                  tra (ji,jj,jk,jn) = tra (ji,jj,jk,jn) + ztra
204#if defined key_trc_diatrd
205                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),4) = ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk  ) ) * zbtr
206                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),5) = ( zftv(ji,jj,jk) - zftv(ji,jj-1,jk  ) ) * zbtr
207#endif
208
209               END DO
210            END DO
211            !                                          ! ===============
212         END DO                                        !   End of slab 
213         !                                             ! ===============
214
215         ! 4. Save the trends for diagnostic
216         ! ---------------------------------
217
218         IF( l_trdtrc ) THEN
219#   if defined key_trcldf_eiv
220
221            ! 4.1) Compute the eiv ZONAL & MERIDIONAL advective trends
222                                                          ! ===============
223            DO jk = 1, jpkm1                              ! Horizontal slab
224                                                          ! ===============
225               DO jj = 1, jpjm1
226                  DO ji = 1, fs_jpim1   ! vector opt.
227                     zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
228                     zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
229                     zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
230                     zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
231                     
232                     zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
233                     zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
234                     
235                     zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
236                     zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
237                  END DO
238               END DO
239               
240               DO jj = 2 , jpjm1
241                  DO ji = fs_2, fs_jpim1   ! vector opt.
242                     zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
243                     
244                     !-- Compute zonal & meridional divergences of the eiv field :
245                     !     d_x[u_trc_eiv] = 1/(e1t*e2t*e3t) ( di[e2u*e3u u_trc_eiv] )
246                     !     d_y[v_trc_eiv] = 1/(e1t*e2t*e3t) ( dj[e1v*e3v v_trc_eiv] )
247                     !   N.B.  This is only possible if key_diaeiv is switched on.
248#       if defined key_diaeiv
249                     z_hdivn_x = (  e2u(ji  ,jj) * fse3u(ji  ,jj,jk) * u_trc_eiv(ji  ,jj  ,jk)  &
250                          &       - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * u_trc_eiv(ji-1,jj  ,jk) ) * zbtr
251                     z_hdivn_y = (  e1v(ji,  jj) * fse3v(ji,jj  ,jk) * v_trc_eiv(ji,  jj  ,jk)  &
252                          &       - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * v_trc_eiv(ji  ,jj-1,jk) ) * zbtr
253#       else
254                     z_hdivn_x = 0.e0   ;   z_hdivn_y = 0.e0 
255#       endif
256                     !-- Compute the zonal advective trends associated with eiv
257                     ztrtrd_xei(ji,jj,jk) =  zbtr * ( zftug(ji,jj) - zftug(ji-1,jj  ) )          &
258                          &                 - trn(ji,jj,jk,jn) * z_hdivn_x
259                     
260                     !-- Compute the merid. advective trends associated with eiv
261                     ztrtrd_yei(ji,jj,jk) =  zbtr * ( zftvg(ji,jj) - zftvg(ji  ,jj-1) )          &
262                          &                 - trn(ji,jj,jk,jn) * z_hdivn_y
263                  END DO
264               END DO
265                                                          ! ===============
266            END DO                                        !   End of slab 
267                                                          ! ===============
268            ! 4.2) Deduce the trend
269            ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:) - ztrtrd_xei(:,:,:) - ztrtrd_yei(:,:,:)
270#   else
271            ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:)
272#   endif
273           
274            ! 4.3) save the trends for diagnostic
275            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd    , jn, jptrc_trd_ldf, kt ) 
276#   if defined key_trcldf_eiv
277            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd_xei, jn, jptrc_trd_xei, kt )
278            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd_yei, jn, jptrc_trd_yei, kt )
279#   endif
280         ENDIF
281         !                                                    ! ===========
282      END DO                                                  ! tracer loop
283      !                                                       ! ===========
284
285      IF( l_trdtrc ) THEN
286         DEALLOCATE( ztrtrd )
287#   if defined key_trcldf_eiv
288         DEALLOCATE( ztrtrd_xei )
289         DEALLOCATE( ztrtrd_yei )
290#   endif
291      ENDIF
292
293      IF( ln_ctl ) THEN        ! print mean trends (used for debugging)
294         WRITE(charout, FMT="('ldf - iso')")
295         CALL prt_ctl_trc_info(charout)
296         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
297      ENDIF
298
299   END SUBROUTINE trc_ldf_iso
300
301#else
302   !!----------------------------------------------------------------------
303   !!   Dummy module :             No rotation of the lateral mixing tensor
304   !!----------------------------------------------------------------------
305CONTAINS
306   SUBROUTINE trc_ldf_iso( kt )               ! Empty routine
307      INTEGER, INTENT(in) :: kt
308      WRITE(*,*) 'trc_ldf_iso: You should not have seen this print! error?', kt
309   END SUBROUTINE trc_ldf_iso
310#endif
311
312   !!==============================================================================
313END MODULE trcldf_iso
Note: See TracBrowser for help on using the repository browser.