New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domvvl.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/DOM/domvvl.F90 @ 2679

Last change on this file since 2679 was 2679, checked in by rfurner, 13 years ago

small bug fixes for bdy and vvl
  • Property svn:keywords set to Id
File size: 10.0 KB
Line 
1MODULE domvvl
2   !!======================================================================
3   !!                       ***  MODULE domvvl   ***
4   !! Ocean :
5   !!======================================================================
6   !! History :  2.0  !  2006-06  (B. Levier, L. Marie)  original code
7   !!            3.1  !  2009-02  (G. Madec, M. Leclair, R. Benshila)  pure z* coordinate
8   !!----------------------------------------------------------------------
9#if defined key_vvl
10   !!----------------------------------------------------------------------
11   !!   'key_vvl'                              variable volume
12   !!----------------------------------------------------------------------
13   !!   dom_vvl     : defined coefficients to distribute ssh on each layers
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE sbc_oce         ! surface boundary condition: ocean
18   USE phycst          ! physical constants
19   USE in_out_manager  ! I/O manager
20   USE lib_mpp         ! distributed memory computing library
21   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   dom_vvl       ! called by domain.F90
27   PUBLIC   dom_vvl_alloc ! called by nemogcm.F90
28
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ee_t, ee_u, ee_v, ee_f   !: ???
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mut , muu , muv , muf    !: ???
31
32   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:)     ::   r2dt   ! vertical profile time-step, = 2 rdttra
33      !                                                              ! except at nit000 (=rdttra) if neuler=0
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
40   !! $Id$
41   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS       
44
45   INTEGER FUNCTION dom_vvl_alloc()
46      !!----------------------------------------------------------------------
47      !!                ***  ROUTINE dom_vvl_alloc  ***
48      !!----------------------------------------------------------------------
49      !
50      ALLOCATE( mut (jpi,jpj,jpk) , muu (jpi,jpj,jpk) , muv (jpi,jpj,jpk) , muf (jpi,jpj,jpk) ,    &
51         &      ee_t(jpi,jpj)     , ee_u(jpi,jpj)     , ee_v(jpi,jpj)     , ee_f(jpi,jpj)     ,    &
52         &      r2dt(jpk)                                                                     , STAT=dom_vvl_alloc)
53         !
54      IF( lk_mpp             )   CALL mpp_sum ( dom_vvl_alloc )
55      IF( dom_vvl_alloc /= 0 )   CALL ctl_warn('dom_vvl_alloc: failed to allocate arrays')
56      !
57   END FUNCTION dom_vvl_alloc
58
59
60   SUBROUTINE dom_vvl
61      !!----------------------------------------------------------------------
62      !!                ***  ROUTINE dom_vvl  ***
63      !!                   
64      !! ** Purpose :  compute coefficients muX at T-U-V-F points to spread
65      !!               ssh over the whole water column (scale factors)
66      !!----------------------------------------------------------------------
67      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
68      USE wrk_nemo, ONLY:   zs_t   => wrk_2d_1, zs_u_1 => wrk_2d_2
69      USE wrk_nemo, ONLY:   zs_v_1 => wrk_2d_3
70      !!
71      INTEGER  ::   ji, jj, jk
72      REAL(wp) ::   zcoefu , zcoefv   , zcoeff                   ! local scalars
73      REAL(wp) ::   zv_t_ij, zv_t_ip1j, zv_t_ijp1, zv_t_ip1jp1   !   -      -
74      !!----------------------------------------------------------------------
75
76      IF(wrk_in_use(2, 1,2,3))THEN
77         CALL ctl_stop('dom_vvl: ERROR - requested workspace arrays unavailable.')   ;   RETURN
78      END IF
79
80      IF(lwp) THEN
81         WRITE(numout,*)
82         WRITE(numout,*) 'dom_vvl : Variable volume initialization'
83         WRITE(numout,*) '~~~~~~~~  compute coef. used to spread ssh over each layers'
84      ENDIF
85     
86      IF( dom_vvl_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'dom_vvl : unable to allocate arrays' )
87
88      fsdept(:,:,:) = gdept (:,:,:)
89      fsdepw(:,:,:) = gdepw (:,:,:)
90      fsde3w(:,:,:) = gdep3w(:,:,:)
91      fse3t (:,:,:) = e3t   (:,:,:)
92      fse3u (:,:,:) = e3u   (:,:,:)
93      fse3v (:,:,:) = e3v   (:,:,:)
94      fse3f (:,:,:) = e3f   (:,:,:)
95      fse3w (:,:,:) = e3w   (:,:,:)
96      fse3uw(:,:,:) = e3uw  (:,:,:)
97      fse3vw(:,:,:) = e3vw  (:,:,:)
98
99      !                                 !==  mu computation  ==!
100      ee_t(:,:) = fse3t_0(:,:,1)                ! Lower bound : thickness of the first model level
101      ee_u(:,:) = fse3u_0(:,:,1)
102      ee_v(:,:) = fse3v_0(:,:,1)
103      ee_f(:,:) = fse3f_0(:,:,1)
104      DO jk = 2, jpkm1                          ! Sum of the masked vertical scale factors
105         ee_t(:,:) = ee_t(:,:) + fse3t_0(:,:,jk) * tmask(:,:,jk)
106         ee_u(:,:) = ee_u(:,:) + fse3u_0(:,:,jk) * umask(:,:,jk)
107         ee_v(:,:) = ee_v(:,:) + fse3v_0(:,:,jk) * vmask(:,:,jk)
108         DO jj = 1, jpjm1                      ! f-point : fmask=shlat at coasts, use the product of umask
109            ee_f(:,jj) = ee_f(:,jj) + fse3f_0(:,jj,jk) *  umask(:,jj,jk) * umask(:,jj+1,jk)
110         END DO
111      END DO 
112      !                                         ! Compute and mask the inverse of the local depth at T, U, V and F points
113      ee_t(:,:) = 1. / ee_t(:,:) * tmask(:,:,1)
114      ee_u(:,:) = 1. / ee_u(:,:) * umask(:,:,1)
115      ee_v(:,:) = 1. / ee_v(:,:) * vmask(:,:,1)
116      DO jj = 1, jpjm1                               ! f-point case fmask cannot be used
117         ee_f(:,jj) = 1. / ee_f(:,jj) * umask(:,jj,1) * umask(:,jj+1,1)
118      END DO
119      CALL lbc_lnk( ee_f, 'F', 1. )                  ! lateral boundary condition on ee_f
120      !
121      DO jk = 1, jpk                            ! mu coefficients
122         mut(:,:,jk) = ee_t(:,:) * tmask(:,:,jk)     ! T-point at T levels
123         muu(:,:,jk) = ee_u(:,:) * umask(:,:,jk)     ! U-point at T levels
124         muv(:,:,jk) = ee_v(:,:) * vmask(:,:,jk)     ! V-point at T levels
125      END DO
126      DO jk = 1, jpk                                 ! F-point : fmask=shlat at coasts, use the product of umask
127         DO jj = 1, jpjm1
128               muf(:,jj,jk) = ee_f(:,jj) * umask(:,jj,jk) * umask(:,jj+1,jk)   ! at T levels
129         END DO
130         muf(:,jpj,jk) = 0.e0
131      END DO
132      CALL lbc_lnk( muf, 'F', 1. )                   ! lateral boundary condition
133
134
135      hu_0(:,:) = 0.e0                          ! Reference ocean depth at U- and V-points
136      hv_0(:,:) = 0.e0
137      DO jk = 1, jpk
138         hu_0(:,:) = hu_0(:,:) + fse3u_0(:,:,jk) * umask(:,:,jk)
139         hv_0(:,:) = hv_0(:,:) + fse3v_0(:,:,jk) * vmask(:,:,jk)
140      END DO
141     
142      ! surface at t-points and inverse surface at (u/v)-points used in surface averaging computations
143      ! for ssh and scale factors
144      zs_t  (:,:) =       e1t(:,:) * e2t(:,:)
145      zs_u_1(:,:) = 0.5 / e1u(:,:) * e2u(:,:)
146      zs_v_1(:,:) = 0.5 / e1v(:,:) * e2v(:,:)
147
148      DO jj = 1, jpjm1                          ! initialise before and now Sea Surface Height at u-, v-, f-points
149         DO ji = 1, jpim1   ! NO vector opt.
150            zcoefu = umask(ji,jj,1) * zs_u_1(ji,jj)
151            zcoefv = vmask(ji,jj,1) * zs_v_1(ji,jj)
152            zcoeff = 0.5 * umask(ji,jj,1) * umask(ji,jj+1,1) / ( e1f(ji,jj) * e2f(ji,jj) )
153            ! before fields
154            zv_t_ij       = zs_t(ji  ,jj  ) * sshb(ji  ,jj  )
155            zv_t_ip1j     = zs_t(ji+1,jj  ) * sshb(ji+1,jj  )
156            zv_t_ijp1     = zs_t(ji  ,jj+1) * sshb(ji  ,jj+1)
157            sshu_b(ji,jj) = zcoefu * ( zv_t_ij + zv_t_ip1j )
158            sshv_b(ji,jj) = zcoefv * ( zv_t_ij + zv_t_ijp1 )
159            ! now fields
160            zv_t_ij       = zs_t(ji  ,jj  ) * sshn(ji  ,jj  )
161            zv_t_ip1j     = zs_t(ji+1,jj  ) * sshn(ji+1,jj  )
162            zv_t_ijp1     = zs_t(ji  ,jj+1) * sshn(ji  ,jj+1)
163            zv_t_ip1jp1   = zs_t(ji  ,jj+1) * sshn(ji  ,jj+1)
164            sshu_n(ji,jj) = zcoefu * ( zv_t_ij + zv_t_ip1j )
165            sshv_n(ji,jj) = zcoefv * ( zv_t_ij + zv_t_ijp1 )
166            sshf_n(ji,jj) = zcoeff * ( zv_t_ij + zv_t_ip1j + zv_t_ijp1 + zv_t_ip1jp1 )
167         END DO
168      END DO
169      CALL lbc_lnk( sshu_n, 'U', 1. )   ;   CALL lbc_lnk( sshu_b, 'U', 1. )      ! lateral boundary conditions
170      CALL lbc_lnk( sshv_n, 'V', 1. )   ;   CALL lbc_lnk( sshv_b, 'V', 1. )
171      CALL lbc_lnk( sshf_n, 'F', 1. )
172
173                                                ! initialise before scale factors at (u/v)-points
174      ! Scale factor anomaly at (u/v)-points: surface averaging of scale factor at t-points
175      DO jk = 1, jpkm1
176         DO jj = 1, jpjm1
177            DO ji = 1, jpim1
178               zv_t_ij           = zs_t(ji  ,jj  ) * fse3t_b(ji  ,jj  ,jk)
179               zv_t_ip1j         = zs_t(ji+1,jj  ) * fse3t_b(ji+1,jj  ,jk)
180               zv_t_ijp1         = zs_t(ji  ,jj+1) * fse3t_b(ji  ,jj+1,jk)
181               fse3u_b(ji,jj,jk) = umask(ji,jj,jk) * ( zs_u_1(ji,jj) * ( zv_t_ij + zv_t_ip1j ) - fse3u_0(ji,jj,jk) )
182               fse3v_b(ji,jj,jk) = vmask(ji,jj,jk) * ( zs_v_1(ji,jj) * ( zv_t_ij + zv_t_ijp1 ) - fse3v_0(ji,jj,jk) )
183            END DO
184         END DO
185      END DO
186      CALL lbc_lnk( fse3u_b(:,:,:), 'U', 1. )               ! lateral boundary conditions
187      CALL lbc_lnk( fse3v_b(:,:,:), 'V', 1. )
188      ! Add initial scale factor to scale factor anomaly
189      fse3u_b(:,:,:) = fse3u_b(:,:,:) + fse3u_0(:,:,:)
190      fse3v_b(:,:,:) = fse3v_b(:,:,:) + fse3v_0(:,:,:)
191      !
192      IF(wrk_not_released(2, 1,2,3))THEN
193         CALL ctl_stop('dom_vvl: ERROR - failed to release workspace arrays.')
194      END IF
195      !
196   END SUBROUTINE dom_vvl
197
198#else
199   !!----------------------------------------------------------------------
200   !!   Default option :                                      Empty routine
201   !!----------------------------------------------------------------------
202CONTAINS
203   SUBROUTINE dom_vvl
204   END SUBROUTINE dom_vvl
205#endif
206
207   !!======================================================================
208END MODULE domvvl
Note: See TracBrowser for help on using the repository browser.