New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_bilap.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_bilap.F90 @ 2633

Last change on this file since 2633 was 2633, checked in by trackstand2, 13 years ago

Renamed wrk_use => wrk_in_use and wrk_release => wrk_not_released
  • Property svn:keywords set to Id
File size: 9.2 KB
Line 
1MODULE traldf_bilap
2   !!==============================================================================
3   !!                   ***  MODULE  traldf_bilap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  1991-11  (G. Madec)  Original code
7   !!                 !  1993-03  (M. Guyon)  symetrical conditions
8   !!                 !  1995-11  (G. Madec)  suppress volumetric scale factors
9   !!                 !  1996-01  (G. Madec)  statement function for e3
10   !!                 !  1996-01  (M. Imbard)  mpp exchange
11   !!                 !  1997-07  (G. Madec)  optimization, and ahtt
12   !!            8.5  !  2002-08  (G. Madec)  F90: Free form and module
13   !!   NEMO     1.0  !  2004-08  (C. Talandier) New trends organization
14   !!             -   !  2005-11  (G. Madec)  zps or sco as default option
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
16   !!==============================================================================
17
18   !!----------------------------------------------------------------------
19   !!   tra_ldf_bilap : update the tracer trend with the horizontal diffusion
20   !!                   using a iso-level biharmonic operator
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and active tracers
23   USE dom_oce         ! ocean space and time domain
24   USE ldftra_oce      ! ocean tracer   lateral physics
25   USE in_out_manager  ! I/O manager
26   USE ldfslp          ! iso-neutral slopes
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28   USE diaptr          ! poleward transport diagnostics
29   USE trc_oce         ! share passive tracers/Ocean variables
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_ldf_bilap   ! routine called by step.F90
35
36   !! * Substitutions
37#  include "domzgr_substitute.h90"
38#  include "ldftra_substitute.h90"
39#  include "ldfeiv_substitute.h90"
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47 
48   SUBROUTINE tra_ldf_bilap( kt, cdtype, pgu, pgv,      &
49      &                                  ptb, pta, kjpt ) 
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE tra_ldf_bilap  ***
52      !!
53      !! ** Purpose :   Compute the before horizontal tracer diffusive
54      !!      trend and add it to the general trend of tracer equation.
55      !!
56      !! ** Method  :   4th order diffusive operator along model level surfaces
57      !!      evaluated using before fields (forward time scheme). The hor.
58      !!      diffusive trends  is given by:
59      !!      Laplacian of tb:
60      !!         zlt   = 1/(e1t*e2t*e3t) {  di-1[ e2u*e3u/e1u di(tb) ]
61      !!                                  + dj-1[ e1v*e3v/e2v dj(tb) ]  }
62      !!      Multiply by the eddy diffusivity coef. and insure lateral bc:
63      !!        zlt   = ahtt * zlt
64      !!        call to lbc_lnk
65      !!      Bilaplacian (laplacian of zlt):
66      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ e2u*e3u/e1u di(zlt) ]
67      !!                                  + dj-1[ e1v*e3v/e2v dj(zlt) ]  }
68      !!
69      !!      Add this trend to the general trend
70      !!         (pta) = (pta) + ( difft )
71      !!
72      !! ** Action : - Update pta arrays with the before iso-level
73      !!               biharmonic mixing trend.
74      !!----------------------------------------------------------------------
75      USE oce         , ztu => ua   ! use ua as workspace
76      USE oce         , ztv => va   ! use va as workspace
77      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
78      USE wrk_nemo, ONLY: zeeu => wrk_2d_1, zeev => wrk_2d_2, zlt => wrk_2d_3
79      !!
80      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
81      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
82      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
83      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
85      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
86      !!
87      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
88      REAL(wp) ::  zbtr, ztra       ! local scalars
89      !!----------------------------------------------------------------------
90
91      IF(wrk_in_use(2, 1,2,3))THEN
92         CALL ctl_stop('tra_ldf_bilap: requested workspace arrays unavailable.')
93         RETURN
94      END IF
95
96      IF( kt == nit000 )  THEN
97         IF(lwp) WRITE(numout,*)
98         IF(lwp) WRITE(numout,*) 'tra_ldf_bilap : iso-level biharmonic operator on ', cdtype
99         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
100      ENDIF
101      !                                                          ! ===========
102      DO jn = 1, kjpt                                            ! tracer loop
103         !                                                       ! ===========
104         !                                               
105         DO jk = 1, jpkm1                                        ! Horizontal slab
106            !                                             
107            !                          !==  Initialization of metric arrays (for z- or s-coordinates)  ==!
108            DO jj = 1, jpjm1
109               DO ji = 1, fs_jpim1   ! vector opt.
110                  zeeu(ji,jj) = e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj) * umask(ji,jj,jk)
111                  zeev(ji,jj) = e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj) * vmask(ji,jj,jk)
112               END DO
113            END DO
114
115            !                          !==  Laplacian  ==!
116            !
117            DO jj = 1, jpjm1                 ! First derivative (gradient)
118               DO ji = 1, fs_jpim1   ! vector opt.
119                  ztu(ji,jj,jk) = zeeu(ji,jj) * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
120                  ztv(ji,jj,jk) = zeev(ji,jj) * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
121               END DO
122            END DO
123            IF( ln_zps ) THEN                ! set gradient at partial step level (last ocean level)
124               DO jj = 1, jpjm1
125                  DO ji = 1, jpim1
126                     IF( mbku(ji,jj) == jk )  ztu(ji,jj,jk) = zeeu(ji,jj) * pgu(ji,jj,jn)
127                     IF( mbkv(ji,jj) == jk )  ztv(ji,jj,jk) = zeev(ji,jj) * pgv(ji,jj,jn)
128                  END DO
129               END DO
130            ENDIF
131            DO jj = 2, jpjm1                 ! Second derivative (divergence) time the eddy diffusivity coefficient
132               DO ji = fs_2, fs_jpim1   ! vector opt.
133                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
134                  zlt(ji,jj) = fsahtt(ji,jj,jk) * zbtr * (   ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
135                     &                                     + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)   )
136               END DO
137            END DO
138            CALL lbc_lnk( zlt, 'T', 1. )     ! Lateral boundary conditions (unchanged sgn)
139
140            !                          !==  Bilaplacian  ==!
141            !
142            DO jj = 1, jpjm1                 ! third derivative (gradient)
143               DO ji = 1, fs_jpim1   ! vector opt.
144                  ztu(ji,jj,jk) = zeeu(ji,jj) * ( zlt(ji+1,jj  ) - zlt(ji,jj) )
145                  ztv(ji,jj,jk) = zeev(ji,jj) * ( zlt(ji  ,jj+1) - zlt(ji,jj) )
146               END DO
147            END DO
148            DO jj = 2, jpjm1                 ! fourth derivative (divergence) and add to the general tracer trend
149               DO ji = fs_2, fs_jpim1   ! vector opt.
150                  ! horizontal diffusive trends
151                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
152                  ztra = zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
153                  ! add it to the general tracer trends
154                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
155               END DO
156            END DO
157            !                                             
158         END DO                                           ! Horizontal slab
159         !                                               
160         ! "zonal" mean lateral diffusive heat and salt transport
161         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
162           IF( jn == jp_tem )  htr_ldf(:) = ptr_vj( ztv(:,:,:) )
163           IF( jn == jp_sal )  str_ldf(:) = ptr_vj( ztv(:,:,:) )
164         ENDIF
165         !                                                ! ===========
166      END DO                                              ! tracer loop
167      !                                                   ! ===========
168      IF(wrk_not_released(2, 1,2,3))THEN
169         CALL ctl_stop('tra_ldf_bilap: failed to release workspace arrays.')
170      END IF
171      !
172   END SUBROUTINE tra_ldf_bilap
173
174   !!==============================================================================
175END MODULE traldf_bilap
Note: See TracBrowser for help on using the repository browser.