New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_bilap.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_bilap.F90 @ 2636

Last change on this file since 2636 was 2636, checked in by gm, 13 years ago

dynamic mem: #785 ; move ctl_stop & warn in lib_mpp to avoid a circular dependency + ctl_stop improvment
  • Property svn:keywords set to Id
File size: 9.3 KB
Line 
1MODULE traldf_bilap
2   !!==============================================================================
3   !!                   ***  MODULE  traldf_bilap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  1991-11  (G. Madec)  Original code
7   !!                 !  1993-03  (M. Guyon)  symetrical conditions
8   !!                 !  1995-11  (G. Madec)  suppress volumetric scale factors
9   !!                 !  1996-01  (G. Madec)  statement function for e3
10   !!                 !  1996-01  (M. Imbard)  mpp exchange
11   !!                 !  1997-07  (G. Madec)  optimization, and ahtt
12   !!            8.5  !  2002-08  (G. Madec)  F90: Free form and module
13   !!   NEMO     1.0  !  2004-08  (C. Talandier) New trends organization
14   !!             -   !  2005-11  (G. Madec)  zps or sco as default option
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
16   !!==============================================================================
17
18   !!----------------------------------------------------------------------
19   !!   tra_ldf_bilap : update the tracer trend with the horizontal diffusion
20   !!                   using a iso-level biharmonic operator
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and active tracers
23   USE dom_oce         ! ocean space and time domain
24   USE ldftra_oce      ! ocean tracer   lateral physics
25   USE in_out_manager  ! I/O manager
26   USE ldfslp          ! iso-neutral slopes
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28   USE diaptr          ! poleward transport diagnostics
29   USE trc_oce         ! share passive tracers/Ocean variables
30   USE lib_mpp         ! MPP library
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   tra_ldf_bilap   ! routine called by step.F90
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "ldftra_substitute.h90"
40#  include "ldfeiv_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48 
49   SUBROUTINE tra_ldf_bilap( kt, cdtype, pgu, pgv,      &
50      &                                  ptb, pta, kjpt ) 
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_ldf_bilap  ***
53      !!
54      !! ** Purpose :   Compute the before horizontal tracer diffusive
55      !!      trend and add it to the general trend of tracer equation.
56      !!
57      !! ** Method  :   4th order diffusive operator along model level surfaces
58      !!      evaluated using before fields (forward time scheme). The hor.
59      !!      diffusive trends  is given by:
60      !!      Laplacian of tb:
61      !!         zlt   = 1/(e1t*e2t*e3t) {  di-1[ e2u*e3u/e1u di(tb) ]
62      !!                                  + dj-1[ e1v*e3v/e2v dj(tb) ]  }
63      !!      Multiply by the eddy diffusivity coef. and insure lateral bc:
64      !!        zlt   = ahtt * zlt
65      !!        call to lbc_lnk
66      !!      Bilaplacian (laplacian of zlt):
67      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ e2u*e3u/e1u di(zlt) ]
68      !!                                  + dj-1[ e1v*e3v/e2v dj(zlt) ]  }
69      !!
70      !!      Add this trend to the general trend
71      !!         (pta) = (pta) + ( difft )
72      !!
73      !! ** Action : - Update pta arrays with the before iso-level
74      !!               biharmonic mixing trend.
75      !!----------------------------------------------------------------------
76      USE oce         , ztu => ua   ! use ua as workspace
77      USE oce         , ztv => va   ! use va as workspace
78      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
79      USE wrk_nemo, ONLY: zeeu => wrk_2d_1, zeev => wrk_2d_2, zlt => wrk_2d_3
80      !!
81      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
82      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
83      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
84      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
85      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
86      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
87      !!
88      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
89      REAL(wp) ::  zbtr, ztra       ! local scalars
90      !!----------------------------------------------------------------------
91
92      IF(wrk_in_use(2, 1,2,3))THEN
93         CALL ctl_stop('tra_ldf_bilap: requested workspace arrays unavailable.')
94         RETURN
95      END IF
96
97      IF( kt == nit000 )  THEN
98         IF(lwp) WRITE(numout,*)
99         IF(lwp) WRITE(numout,*) 'tra_ldf_bilap : iso-level biharmonic operator on ', cdtype
100         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
101      ENDIF
102      !                                                          ! ===========
103      DO jn = 1, kjpt                                            ! tracer loop
104         !                                                       ! ===========
105         !                                               
106         DO jk = 1, jpkm1                                        ! Horizontal slab
107            !                                             
108            !                          !==  Initialization of metric arrays (for z- or s-coordinates)  ==!
109            DO jj = 1, jpjm1
110               DO ji = 1, fs_jpim1   ! vector opt.
111                  zeeu(ji,jj) = e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj) * umask(ji,jj,jk)
112                  zeev(ji,jj) = e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj) * vmask(ji,jj,jk)
113               END DO
114            END DO
115
116            !                          !==  Laplacian  ==!
117            !
118            DO jj = 1, jpjm1                 ! First derivative (gradient)
119               DO ji = 1, fs_jpim1   ! vector opt.
120                  ztu(ji,jj,jk) = zeeu(ji,jj) * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
121                  ztv(ji,jj,jk) = zeev(ji,jj) * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
122               END DO
123            END DO
124            IF( ln_zps ) THEN                ! set gradient at partial step level (last ocean level)
125               DO jj = 1, jpjm1
126                  DO ji = 1, jpim1
127                     IF( mbku(ji,jj) == jk )  ztu(ji,jj,jk) = zeeu(ji,jj) * pgu(ji,jj,jn)
128                     IF( mbkv(ji,jj) == jk )  ztv(ji,jj,jk) = zeev(ji,jj) * pgv(ji,jj,jn)
129                  END DO
130               END DO
131            ENDIF
132            DO jj = 2, jpjm1                 ! Second derivative (divergence) time the eddy diffusivity coefficient
133               DO ji = fs_2, fs_jpim1   ! vector opt.
134                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
135                  zlt(ji,jj) = fsahtt(ji,jj,jk) * zbtr * (   ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
136                     &                                     + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)   )
137               END DO
138            END DO
139            CALL lbc_lnk( zlt, 'T', 1. )     ! Lateral boundary conditions (unchanged sgn)
140
141            !                          !==  Bilaplacian  ==!
142            !
143            DO jj = 1, jpjm1                 ! third derivative (gradient)
144               DO ji = 1, fs_jpim1   ! vector opt.
145                  ztu(ji,jj,jk) = zeeu(ji,jj) * ( zlt(ji+1,jj  ) - zlt(ji,jj) )
146                  ztv(ji,jj,jk) = zeev(ji,jj) * ( zlt(ji  ,jj+1) - zlt(ji,jj) )
147               END DO
148            END DO
149            DO jj = 2, jpjm1                 ! fourth derivative (divergence) and add to the general tracer trend
150               DO ji = fs_2, fs_jpim1   ! vector opt.
151                  ! horizontal diffusive trends
152                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
153                  ztra = zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
154                  ! add it to the general tracer trends
155                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
156               END DO
157            END DO
158            !                                             
159         END DO                                           ! Horizontal slab
160         !                                               
161         ! "zonal" mean lateral diffusive heat and salt transport
162         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
163           IF( jn == jp_tem )  htr_ldf(:) = ptr_vj( ztv(:,:,:) )
164           IF( jn == jp_sal )  str_ldf(:) = ptr_vj( ztv(:,:,:) )
165         ENDIF
166         !                                                ! ===========
167      END DO                                              ! tracer loop
168      !                                                   ! ===========
169      IF( wrk_not_released(2, 1,2,3) )   CALL ctl_stop('tra_ldf_bilap: failed to release workspace arrays')
170      !
171   END SUBROUTINE tra_ldf_bilap
172
173   !!==============================================================================
174END MODULE traldf_bilap
Note: See TracBrowser for help on using the repository browser.