New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_grif.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso_grif.F90 @ 2590

Last change on this file since 2590 was 2590, checked in by trackstand2, 13 years ago

Merge branch 'dynamic_memory' into master-svn-dyn
  • Property svn:keywords set to Id
File size: 18.3 KB
Line 
1MODULE traldf_iso_grif
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso_grif  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History : 3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec) 
7   !!                !          Griffies operator version adapted from traldf_iso.F90
8   !!----------------------------------------------------------------------
9#if   defined key_ldfslp   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_ldfslp'               slope of the lateral diffusive direction
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso_grif  : update the tracer trend with the horizontal component 
14   !!                       of the Griffies iso-neutral laplacian operator
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE trc_oce         ! share passive tracers/Ocean variables
19   USE zdf_oce         ! ocean vertical physics
20   USE ldftra_oce      ! ocean active tracers: lateral physics
21   USE ldfslp          ! iso-neutral slopes
22   USE diaptr          ! poleward transport diagnostics
23   USE in_out_manager  ! I/O manager
24   USE iom             ! I/O library
25#if defined key_diaar5
26   USE phycst          ! physical constants
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28#endif
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC tra_ldf_iso_grif   ! routine called by traldf.F90
34
35   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE ::   psix_eiv
36   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE ::   psiy_eiv
37   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE ::   ah_wslp2
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "ldftra_substitute.h90"
42#  include "vectopt_loop_substitute.h90"
43#  include "ldfeiv_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51  SUBROUTINE tra_ldf_iso_grif( kt, cdtype, pgu, pgv,              &
52       &                                   ptb, pta, kjpt, pahtb0 )
53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE tra_ldf_iso_grif  ***
55      !!
56      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
57      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
58      !!      add it to the general trend of tracer equation.
59      !!
60      !! ** Method  :   The horizontal component of the lateral diffusive trends
61      !!      is provided by a 2nd order operator rotated along neural or geopo-
62      !!      tential surfaces to which an eddy induced advection can be added
63      !!      It is computed using before fields (forward in time) and isopyc-
64      !!      nal or geopotential slopes computed in routine ldfslp.
65      !!
66      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
67      !!      ========    with partial cell update if ln_zps=T.
68      !!
69      !!      2nd part :  horizontal fluxes of the lateral mixing operator
70      !!      ========   
71      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
72      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
73      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
74      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
75      !!      take the horizontal divergence of the fluxes:
76      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
77      !!      Add this trend to the general trend (ta,sa):
78      !!         ta = ta + difft
79      !!
80      !!      3rd part: vertical trends of the lateral mixing operator
81      !!      ========  (excluding the vertical flux proportional to dk[t] )
82      !!      vertical fluxes associated with the rotated lateral mixing:
83      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
84      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
85      !!      take the horizontal divergence of the fluxes:
86      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
87      !!      Add this trend to the general trend (ta,sa):
88      !!         pta = pta + difft
89      !!
90      !! ** Action :   Update pta arrays with the before rotated diffusion
91      !!----------------------------------------------------------------------
92      USE oce,   zftu => ua   ! use ua as workspace
93      USE oce,   zftv => va   ! use va as workspace
94      USE wrk_nemo, ONLY: wrk_use, wrk_release
95      USE wrk_nemo, ONLY: zdit => wrk_3d_1, zdjt => wrk_3d_2, ztfw => wrk_3d_3
96      USE wrk_nemo, ONLY: wrk_3d_4 ! For 2D+1 workspace
97      USE wrk_nemo, ONLY: z2d => wrk_2d_1 ! Only used if key_diaar5 defined
98      !!
99      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
100      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
101      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
102      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
103      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
104      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
105      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
106      !!
107      INTEGER  ::  ji, jj, jk,jn   ! dummy loop indices
108      INTEGER  ::  ip,jp,kp        ! dummy loop indices
109      INTEGER  ::  ierr            ! temporary integer
110      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
111      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
112      REAL(wp) ::  zcoef0, zbtr                  !   -      -
113      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdkt           ! 2D+1 workspace
114      !
115      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
116      REAL(wp) ::   ze1ur, zdxt, ze2vr, ze3wr, zdyt, zdzt
117      REAL(wp) ::   zah, zah_slp, zaei_slp
118#if defined key_diaar5
119      REAL(wp)                         ::   zztmp              ! local scalar
120#endif
121      !!----------------------------------------------------------------------
122
123      ! Check that workspace arrays are free for use and set-up pointer into
124      ! sub-array of a 3D workspace
125      IF( (.NOT. wrk_use(3, 1,2,3,4)) .OR. (.NOT. wrk_use(2, 1)))THEN
126         CALL ctl_stop('tra_ldf_iso_grif : requested workspace arrays unavailable.')
127         RETURN
128      END IF
129      zdkt(1:jpi,1:jpj,0:1) => wrk_3d_4(:,:,1:2)
130
131      IF( kt == nit000 )  THEN
132         IF(lwp) WRITE(numout,*)
133         IF(lwp) WRITE(numout,*) 'tra_ldf_iso_grif : rotated laplacian diffusion operator on ', cdtype
134         IF(lwp) WRITE(numout,*) '                   WARNING: STILL UNDER TEST, NOT RECOMMENDED. USE AT YOUR OWN PERIL'
135         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
136         ALLOCATE( ah_wslp2(jpi,jpj,jpk) , STAT=ierr )
137         IF( ierr > 0 ) THEN
138            CALL ctl_stop( 'tra_ldf_iso_grif : unable to allocate Griffies operator ah_wslp2 ' )   ;   RETURN
139         ENDIF
140         IF( ln_traldf_gdia ) THEN
141            ALLOCATE( psix_eiv(jpi,jpj,jpk) , psiy_eiv(jpi,jpj,jpk) , STAT=ierr )
142            IF( ierr > 0 ) THEN
143               CALL ctl_stop( 'tra_ldf_iso_grif : unable to allocate Griffies operator diagnostics ' )   ;   RETURN
144            ENDIF
145         ENDIF
146      ENDIF
147
148      !!----------------------------------------------------------------------
149      !!   0 - calculate  ah_wslp2, psix_eiv, psiy_eiv
150      !!----------------------------------------------------------------------
151
152!!gm Future development: consider using Ah defined at T-points and attached to the 4 t-point triads
153
154      ah_wslp2(:,:,:) = 0._wp
155      IF( ln_traldf_gdia ) THEN
156         psix_eiv(:,:,:) = 0._wp
157         psiy_eiv(:,:,:) = 0._wp
158      ENDIF
159
160      DO ip = 0, 1
161         DO kp = 0, 1
162            DO jk = 1, jpkm1
163               DO jj = 1, jpjm1
164                  DO ji = 1, fs_jpim1
165                     ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
166                     zbu   = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
167                     zah   = fsahtu(ji,jj,jk)                                  !  fsaht(ji+ip,jj,jk)
168                     zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
169                     zslope2 = zslope_skew - ( fsdept(ji+1,jj,jk) - fsdept(ji ,jj ,jk) ) * ze1ur * umask(ji,jj,jk+kp)
170                     zslope2 = zslope2 *zslope2
171                     ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp)    &
172                        &                     + zah * ( zbu * ze3wr / ( e1t(ji+ip,jj) * e2t(ji+ip,jj) ) ) * zslope2
173                     IF( ln_traldf_gdia ) THEN
174                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew        !fsaeit(ji+ip,jj,jk)*zslope_skew
175                        psix_eiv(ji,jj,jk+kp) = psix_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
176                     ENDIF
177                  END DO
178               END DO
179            END DO
180         END DO
181      END DO
182      !
183      DO jp = 0, 1
184         DO kp = 0, 1
185            DO jk = 1, jpkm1
186               DO jj = 1, jpjm1
187                  DO ji=1,fs_jpim1
188                     ze3wr = 1.0_wp / fse3w(ji,jj+jp,jk+kp)
189                     zbv   = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
190                     zah   = fsahtu(ji,jj,jk)                                       !fsaht(ji,jj+jp,jk)
191                     zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
192                     zslope2 = zslope_skew - ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) * ze2vr * vmask(ji,jj,jk+kp)
193                     zslope2 = zslope2 * zslope2
194                     ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp)   &
195                        &                     + zah * ( zbv * ze3wr / ( e1t(ji,jj+jp) * e2t(ji,jj+jp) ) ) * zslope2
196                     IF( ln_traldf_gdia ) THEN
197                        zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew     !fsaeit(ji,jj+jp,jk)*zslope_skew
198                        psiy_eiv(ji,jj,jk+kp) = psiy_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
199                     ENDIF
200                  END DO
201               END DO
202            END DO
203         END DO
204      END DO
205      !
206      !                                                          ! ===========
207      DO jn = 1, kjpt                                            ! tracer loop
208         !                                                       ! ===========
209         ! Zero fluxes for each tracer
210         ztfw(:,:,:) = 0._wp
211         zftu(:,:,:) = 0._wp
212         zftv(:,:,:) = 0._wp
213         !                                               
214         DO jk = 1, jpkm1                          !==  before lateral T & S gradients at T-level jk  ==!
215            DO jj = 1, jpjm1
216               DO ji = 1, fs_jpim1   ! vector opt.
217                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
218                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
219               END DO
220            END DO
221         END DO
222         IF( ln_zps ) THEN                               ! partial steps: correction at the last level
223# if defined key_vectopt_loop
224            DO jj = 1, 1
225               DO ji = 1, jpij-jpi   ! vector opt. (forced unrolling)
226# else
227            DO jj = 1, jpjm1
228               DO ji = 1, jpim1
229# endif
230                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
231                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)     
232               END DO
233            END DO
234         ENDIF
235
236         !!----------------------------------------------------------------------
237         !!   II - horizontal trend  (full)
238         !!----------------------------------------------------------------------
239         !
240         DO jk = 1, jpkm1
241            !
242            !                    !==  Vertical tracer gradient at level jk and jk+1
243            zdkt(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
244            !
245            !                          ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
246            IF( jk == 1 ) THEN   ;   zdkt(:,:,0) = zdkt(:,:,1)
247            ELSE                 ;   zdkt(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
248            ENDIF
249
250            IF( .NOT. l_triad_iso ) THEN
251               triadi = triadi_g
252               triadj = triadj_g
253            ENDIF
254
255            DO ip = 0, 1              !==  Horizontal & vertical fluxes
256               DO kp = 0, 1
257                  DO jj = 1, jpjm1
258                     DO ji = 1, fs_jpim1
259                        ze1ur = 1._wp / e1u(ji,jj)
260                        zdxt = zdit(ji,jj,jk) * ze1ur
261                        ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
262                        zdzt  = zdkt(ji+ip,jj,kp) * ze3wr
263                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
264                        zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
265
266                        zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
267                        zah = fsahtu(ji,jj,jk)   !*umask(ji,jj,jk+kp)         !fsaht(ji+ip,jj,jk)           ===>>  ????
268                        zah_slp  = zah * zslope_iso
269                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew    !fsaeit(ji+ip,jj,jk)*zslope_skew
270                        zftu(ji,jj,jk) = zftu(ji,jj,jk) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
271                        ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
272                     END DO
273                  END DO
274               END DO
275            END DO
276
277            DO jp = 0, 1
278               DO kp = 0, 1
279                  DO jj = 1, jpjm1
280                     DO ji = 1, fs_jpim1
281                        ze2vr = 1._wp / e2v(ji,jj)
282                        zdyt = zdjt(ji,jj,jk) * ze2vr
283                        ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp)
284                        zdzt = zdkt(ji,jj+jp,kp) * ze3wr
285                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
286                        zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
287                        zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
288                        zah = fsahtv(ji,jj,jk)        !*vmask(ji,jj,jk+kp)         !fsaht(ji,jj+jp,jk)
289                        zah_slp = zah * zslope_iso
290                        zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew    !fsaeit(ji,jj+jp,jk)*zslope_skew
291                        zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
292                        ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
293                     END DO
294                  END DO
295               END DO
296            END DO
297
298            !                        !==  divergence and add to the general trend  ==!
299            DO jj = 2 , jpjm1
300               DO ji = fs_2, fs_jpim1   ! vector opt.
301                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
302                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (   zftu(ji-1,jj,jk) - zftu(ji,jj,jk)   &
303                     &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )
304               END DO
305            END DO
306            !
307         END DO
308         !
309         DO jk = 1, jpkm1            !== Divergence of vertical fluxes added to the general tracer trend
310            DO jj = 2, jpjm1
311               DO ji = fs_2, fs_jpim1   ! vector opt.
312                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
313                     &                                / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
314               END DO
315            END DO
316         END DO
317         !
318         !                            ! "Poleward" diffusive heat or salt transports (T-S case only)
319         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
320            IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( zftv(:,:,:) )        ! 3.3  names
321            IF( jn == jp_sal)   str_ldf(:) = ptr_vj( zftv(:,:,:) )
322         ENDIF
323
324#if defined key_diaar5
325         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
326            z2d(:,:) = 0._wp 
327            zztmp = rau0 * rcp 
328            DO jk = 1, jpkm1
329               DO jj = 2, jpjm1
330                  DO ji = fs_2, fs_jpim1   ! vector opt.
331                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
332                  END DO
333               END DO
334            END DO
335            z2d(:,:) = zztmp * z2d(:,:)
336            CALL lbc_lnk( z2d, 'U', -1. )
337            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
338            z2d(:,:) = 0._wp 
339            DO jk = 1, jpkm1
340               DO jj = 2, jpjm1
341                  DO ji = fs_2, fs_jpim1   ! vector opt.
342                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
343                  END DO
344               END DO
345            END DO
346            z2d(:,:) = zztmp * z2d(:,:)
347            CALL lbc_lnk( z2d, 'V', -1. )
348            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
349         END IF
350#endif
351         !
352      END DO
353      !
354      IF( (.NOT. wrk_release(3, 1,2,3,4)) .OR. (.NOT. wrk_release(2, 1)))THEN
355         CALL ctl_stop('tra_ldf_iso_grif : failed to release workspace arrays.')
356      END IF
357      !
358  END SUBROUTINE tra_ldf_iso_grif
359
360#else
361   !!----------------------------------------------------------------------
362   !!   default option :   Dummy code   NO rotation of the diffusive tensor
363   !!----------------------------------------------------------------------
364CONTAINS
365   SUBROUTINE tra_ldf_iso_grif( kt, cdtype, pgu, pgv, ptb, pta, kjpt, pahtb0 )      ! Empty routine
366      CHARACTER(len=3) ::   cdtype
367      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
368      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
369      WRITE(*,*) 'tra_ldf_iso_grif: You should not have seen this print! error?', kt, cdtype,    &
370         &                  pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
371   END SUBROUTINE tra_ldf_iso_grif
372#endif
373
374   !!==============================================================================
375END MODULE traldf_iso_grif
Note: See TracBrowser for help on using the repository browser.