New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_grif.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso_grif.F90 @ 2594

Last change on this file since 2594 was 2594, checked in by trackstand2, 13 years ago

Removed F2003-only bounds-remapping and added _alloc routine instead
  • Property svn:keywords set to Id
File size: 19.3 KB
Line 
1MODULE traldf_iso_grif
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso_grif  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History : 3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec) 
7   !!                !          Griffies operator version adapted from traldf_iso.F90
8   !!----------------------------------------------------------------------
9#if   defined key_ldfslp   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_ldfslp'               slope of the lateral diffusive direction
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso_grif  : update the tracer trend with the horizontal component 
14   !!                       of the Griffies iso-neutral laplacian operator
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE trc_oce         ! share passive tracers/Ocean variables
19   USE zdf_oce         ! ocean vertical physics
20   USE ldftra_oce      ! ocean active tracers: lateral physics
21   USE ldfslp          ! iso-neutral slopes
22   USE diaptr          ! poleward transport diagnostics
23   USE in_out_manager  ! I/O manager
24   USE iom             ! I/O library
25#if defined key_diaar5
26   USE phycst          ! physical constants
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28#endif
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC tra_ldf_iso_grif       ! routine called by traldf.F90
34   PUBLIC tra_ldf_iso_grif_alloc ! routine called by nemogcm.F90
35
36   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE       ::   psix_eiv
37   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE       ::   psiy_eiv
38   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE       ::   ah_wslp2
39   REAL(wp),         DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   zdkt  ! 2D+1 workspace
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "ldftra_substitute.h90"
44#  include "vectopt_loop_substitute.h90"
45#  include "ldfeiv_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53  FUNCTION tra_ldf_iso_grif_alloc()
54      !!----------------------------------------------------------------------
55      !!                ***  ROUTINE tra_ldf_iso_grif_alloc  ***
56      !!----------------------------------------------------------------------
57      INTEGER :: tra_ldf_iso_grif_alloc
58      !!----------------------------------------------------------------------
59
60      ALLOCATE(zdkt(jpi,jpj,0:1), Stat=tra_ldf_iso_grif_alloc)
61
62      IF(tra_ldf_iso_grif_alloc /= 0)THEN
63         CALL ctl_warn('tra_ldf_iso_grif_alloc : allocation of arrays failed.')
64      END IF
65
66  END FUNCTION tra_ldf_iso_grif_alloc
67
68
69  SUBROUTINE tra_ldf_iso_grif( kt, cdtype, pgu, pgv,              &
70       &                                   ptb, pta, kjpt, pahtb0 )
71      !!----------------------------------------------------------------------
72      !!                  ***  ROUTINE tra_ldf_iso_grif  ***
73      !!
74      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
75      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
76      !!      add it to the general trend of tracer equation.
77      !!
78      !! ** Method  :   The horizontal component of the lateral diffusive trends
79      !!      is provided by a 2nd order operator rotated along neural or geopo-
80      !!      tential surfaces to which an eddy induced advection can be added
81      !!      It is computed using before fields (forward in time) and isopyc-
82      !!      nal or geopotential slopes computed in routine ldfslp.
83      !!
84      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
85      !!      ========    with partial cell update if ln_zps=T.
86      !!
87      !!      2nd part :  horizontal fluxes of the lateral mixing operator
88      !!      ========   
89      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
90      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
91      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
92      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
93      !!      take the horizontal divergence of the fluxes:
94      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
95      !!      Add this trend to the general trend (ta,sa):
96      !!         ta = ta + difft
97      !!
98      !!      3rd part: vertical trends of the lateral mixing operator
99      !!      ========  (excluding the vertical flux proportional to dk[t] )
100      !!      vertical fluxes associated with the rotated lateral mixing:
101      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
102      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
103      !!      take the horizontal divergence of the fluxes:
104      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
105      !!      Add this trend to the general trend (ta,sa):
106      !!         pta = pta + difft
107      !!
108      !! ** Action :   Update pta arrays with the before rotated diffusion
109      !!----------------------------------------------------------------------
110      USE oce,   zftu => ua   ! use ua as workspace
111      USE oce,   zftv => va   ! use va as workspace
112      USE wrk_nemo, ONLY: wrk_use, wrk_release
113      USE wrk_nemo, ONLY: zdit => wrk_3d_1, zdjt => wrk_3d_2, ztfw => wrk_3d_3
114      !USE wrk_nemo, ONLY: wrk_3d_4 ! For 2D+1 workspace
115      USE wrk_nemo, ONLY: z2d => wrk_2d_1 ! Only used if key_diaar5 defined
116      !!
117      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
118      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
119      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
120      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
121      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
122      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
123      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
124      !!
125      INTEGER  ::  ji, jj, jk,jn   ! dummy loop indices
126      INTEGER  ::  ip,jp,kp        ! dummy loop indices
127      INTEGER  ::  ierr            ! temporary integer
128      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
129      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
130      REAL(wp) ::  zcoef0, zbtr                  !   -      -
131      !REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdkt           ! 2D+1 workspace
132      !
133      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
134      REAL(wp) ::   ze1ur, zdxt, ze2vr, ze3wr, zdyt, zdzt
135      REAL(wp) ::   zah, zah_slp, zaei_slp
136#if defined key_diaar5
137      REAL(wp)                         ::   zztmp              ! local scalar
138#endif
139      !!----------------------------------------------------------------------
140
141      ! Check that workspace arrays are free for use
142      IF( (.NOT. wrk_use(3, 1,2,3)) .OR. (.NOT. wrk_use(2, 1)))THEN
143         CALL ctl_stop('tra_ldf_iso_grif : requested workspace arrays unavailable.')
144         RETURN
145      END IF
146      ! ARP - line below uses 'bounds re-mapping' which is only defined in
147      ! Fortran 2003 and up. We would be OK if code was written to use
148      ! zdkt(:,:,1:2) instead as then wouldn't need to re-map bounds.
149      ! As it is, we make zdkt a module array and allocate it in _alloc().
150      !zdkt(1:jpi,1:jpj,0:1) => wrk_3d_4(:,:,1:2)
151
152      IF( kt == nit000 )  THEN
153         IF(lwp) WRITE(numout,*)
154         IF(lwp) WRITE(numout,*) 'tra_ldf_iso_grif : rotated laplacian diffusion operator on ', cdtype
155         IF(lwp) WRITE(numout,*) '                   WARNING: STILL UNDER TEST, NOT RECOMMENDED. USE AT YOUR OWN PERIL'
156         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
157         ALLOCATE( ah_wslp2(jpi,jpj,jpk) , STAT=ierr )
158         IF( ierr > 0 ) THEN
159            CALL ctl_stop( 'tra_ldf_iso_grif : unable to allocate Griffies operator ah_wslp2 ' )   ;   RETURN
160         ENDIF
161         IF( ln_traldf_gdia ) THEN
162            ALLOCATE( psix_eiv(jpi,jpj,jpk) , psiy_eiv(jpi,jpj,jpk) , STAT=ierr )
163            IF( ierr > 0 ) THEN
164               CALL ctl_stop( 'tra_ldf_iso_grif : unable to allocate Griffies operator diagnostics ' )   ;   RETURN
165            ENDIF
166         ENDIF
167      ENDIF
168
169      !!----------------------------------------------------------------------
170      !!   0 - calculate  ah_wslp2, psix_eiv, psiy_eiv
171      !!----------------------------------------------------------------------
172
173!!gm Future development: consider using Ah defined at T-points and attached to the 4 t-point triads
174
175      ah_wslp2(:,:,:) = 0._wp
176      IF( ln_traldf_gdia ) THEN
177         psix_eiv(:,:,:) = 0._wp
178         psiy_eiv(:,:,:) = 0._wp
179      ENDIF
180
181      DO ip = 0, 1
182         DO kp = 0, 1
183            DO jk = 1, jpkm1
184               DO jj = 1, jpjm1
185                  DO ji = 1, fs_jpim1
186                     ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
187                     zbu   = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
188                     zah   = fsahtu(ji,jj,jk)                                  !  fsaht(ji+ip,jj,jk)
189                     zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
190                     zslope2 = zslope_skew - ( fsdept(ji+1,jj,jk) - fsdept(ji ,jj ,jk) ) * ze1ur * umask(ji,jj,jk+kp)
191                     zslope2 = zslope2 *zslope2
192                     ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp)    &
193                        &                     + zah * ( zbu * ze3wr / ( e1t(ji+ip,jj) * e2t(ji+ip,jj) ) ) * zslope2
194                     IF( ln_traldf_gdia ) THEN
195                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew        !fsaeit(ji+ip,jj,jk)*zslope_skew
196                        psix_eiv(ji,jj,jk+kp) = psix_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
197                     ENDIF
198                  END DO
199               END DO
200            END DO
201         END DO
202      END DO
203      !
204      DO jp = 0, 1
205         DO kp = 0, 1
206            DO jk = 1, jpkm1
207               DO jj = 1, jpjm1
208                  DO ji=1,fs_jpim1
209                     ze3wr = 1.0_wp / fse3w(ji,jj+jp,jk+kp)
210                     zbv   = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
211                     zah   = fsahtu(ji,jj,jk)                                       !fsaht(ji,jj+jp,jk)
212                     zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
213                     zslope2 = zslope_skew - ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) * ze2vr * vmask(ji,jj,jk+kp)
214                     zslope2 = zslope2 * zslope2
215                     ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp)   &
216                        &                     + zah * ( zbv * ze3wr / ( e1t(ji,jj+jp) * e2t(ji,jj+jp) ) ) * zslope2
217                     IF( ln_traldf_gdia ) THEN
218                        zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew     !fsaeit(ji,jj+jp,jk)*zslope_skew
219                        psiy_eiv(ji,jj,jk+kp) = psiy_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
220                     ENDIF
221                  END DO
222               END DO
223            END DO
224         END DO
225      END DO
226      !
227      !                                                          ! ===========
228      DO jn = 1, kjpt                                            ! tracer loop
229         !                                                       ! ===========
230         ! Zero fluxes for each tracer
231         ztfw(:,:,:) = 0._wp
232         zftu(:,:,:) = 0._wp
233         zftv(:,:,:) = 0._wp
234         !                                               
235         DO jk = 1, jpkm1                          !==  before lateral T & S gradients at T-level jk  ==!
236            DO jj = 1, jpjm1
237               DO ji = 1, fs_jpim1   ! vector opt.
238                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
239                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
240               END DO
241            END DO
242         END DO
243         IF( ln_zps ) THEN                               ! partial steps: correction at the last level
244# if defined key_vectopt_loop
245            DO jj = 1, 1
246               DO ji = 1, jpij-jpi   ! vector opt. (forced unrolling)
247# else
248            DO jj = 1, jpjm1
249               DO ji = 1, jpim1
250# endif
251                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
252                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)     
253               END DO
254            END DO
255         ENDIF
256
257         !!----------------------------------------------------------------------
258         !!   II - horizontal trend  (full)
259         !!----------------------------------------------------------------------
260         !
261         DO jk = 1, jpkm1
262            !
263            !                    !==  Vertical tracer gradient at level jk and jk+1
264            zdkt(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
265            !
266            !                          ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
267            IF( jk == 1 ) THEN   ;   zdkt(:,:,0) = zdkt(:,:,1)
268            ELSE                 ;   zdkt(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
269            ENDIF
270
271            IF( .NOT. l_triad_iso ) THEN
272               triadi = triadi_g
273               triadj = triadj_g
274            ENDIF
275
276            DO ip = 0, 1              !==  Horizontal & vertical fluxes
277               DO kp = 0, 1
278                  DO jj = 1, jpjm1
279                     DO ji = 1, fs_jpim1
280                        ze1ur = 1._wp / e1u(ji,jj)
281                        zdxt = zdit(ji,jj,jk) * ze1ur
282                        ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
283                        zdzt  = zdkt(ji+ip,jj,kp) * ze3wr
284                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
285                        zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
286
287                        zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
288                        zah = fsahtu(ji,jj,jk)   !*umask(ji,jj,jk+kp)         !fsaht(ji+ip,jj,jk)           ===>>  ????
289                        zah_slp  = zah * zslope_iso
290                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew    !fsaeit(ji+ip,jj,jk)*zslope_skew
291                        zftu(ji,jj,jk) = zftu(ji,jj,jk) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
292                        ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
293                     END DO
294                  END DO
295               END DO
296            END DO
297
298            DO jp = 0, 1
299               DO kp = 0, 1
300                  DO jj = 1, jpjm1
301                     DO ji = 1, fs_jpim1
302                        ze2vr = 1._wp / e2v(ji,jj)
303                        zdyt = zdjt(ji,jj,jk) * ze2vr
304                        ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp)
305                        zdzt = zdkt(ji,jj+jp,kp) * ze3wr
306                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
307                        zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
308                        zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
309                        zah = fsahtv(ji,jj,jk)        !*vmask(ji,jj,jk+kp)         !fsaht(ji,jj+jp,jk)
310                        zah_slp = zah * zslope_iso
311                        zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew    !fsaeit(ji,jj+jp,jk)*zslope_skew
312                        zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
313                        ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
314                     END DO
315                  END DO
316               END DO
317            END DO
318
319            !                        !==  divergence and add to the general trend  ==!
320            DO jj = 2 , jpjm1
321               DO ji = fs_2, fs_jpim1   ! vector opt.
322                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
323                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (   zftu(ji-1,jj,jk) - zftu(ji,jj,jk)   &
324                     &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )
325               END DO
326            END DO
327            !
328         END DO
329         !
330         DO jk = 1, jpkm1            !== Divergence of vertical fluxes added to the general tracer trend
331            DO jj = 2, jpjm1
332               DO ji = fs_2, fs_jpim1   ! vector opt.
333                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
334                     &                                / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
335               END DO
336            END DO
337         END DO
338         !
339         !                            ! "Poleward" diffusive heat or salt transports (T-S case only)
340         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
341            IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( zftv(:,:,:) )        ! 3.3  names
342            IF( jn == jp_sal)   str_ldf(:) = ptr_vj( zftv(:,:,:) )
343         ENDIF
344
345#if defined key_diaar5
346         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
347            z2d(:,:) = 0._wp 
348            zztmp = rau0 * rcp 
349            DO jk = 1, jpkm1
350               DO jj = 2, jpjm1
351                  DO ji = fs_2, fs_jpim1   ! vector opt.
352                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
353                  END DO
354               END DO
355            END DO
356            z2d(:,:) = zztmp * z2d(:,:)
357            CALL lbc_lnk( z2d, 'U', -1. )
358            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
359            z2d(:,:) = 0._wp 
360            DO jk = 1, jpkm1
361               DO jj = 2, jpjm1
362                  DO ji = fs_2, fs_jpim1   ! vector opt.
363                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
364                  END DO
365               END DO
366            END DO
367            z2d(:,:) = zztmp * z2d(:,:)
368            CALL lbc_lnk( z2d, 'V', -1. )
369            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
370         END IF
371#endif
372         !
373      END DO
374      !
375      IF( (.NOT. wrk_release(3, 1,2,3,4)) .OR. (.NOT. wrk_release(2, 1)))THEN
376         CALL ctl_stop('tra_ldf_iso_grif : failed to release workspace arrays.')
377      END IF
378      !
379  END SUBROUTINE tra_ldf_iso_grif
380
381#else
382   !!----------------------------------------------------------------------
383   !!   default option :   Dummy code   NO rotation of the diffusive tensor
384   !!----------------------------------------------------------------------
385CONTAINS
386   SUBROUTINE tra_ldf_iso_grif( kt, cdtype, pgu, pgv, ptb, pta, kjpt, pahtb0 )      ! Empty routine
387      CHARACTER(len=3) ::   cdtype
388      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
389      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
390      WRITE(*,*) 'tra_ldf_iso_grif: You should not have seen this print! error?', kt, cdtype,    &
391         &                  pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
392   END SUBROUTINE tra_ldf_iso_grif
393#endif
394
395   !!==============================================================================
396END MODULE traldf_iso_grif
Note: See TracBrowser for help on using the repository browser.