| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! sbc_init : read namsbc namelist |
|---|
| 16 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE oce ! ocean dynamics and tracers |
|---|
| 19 | USE dom_oce ! ocean space and time domain |
|---|
| 20 | USE phycst ! physical constants |
|---|
| 21 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 22 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 23 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 24 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 25 | USE sbcana ! surface boundary condition: analytical formulation |
|---|
| 26 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 27 | USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO |
|---|
| 28 | USE sbcblk_core ! surface boundary condition: bulk formulation : CORE |
|---|
| 29 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 30 | USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model |
|---|
| 31 | USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model |
|---|
| 32 | USE sbccpl ! surface boundary condition: coupled florulation |
|---|
| 33 | USE cpl_oasis3, ONLY:lk_cpl ! are we in coupled mode? |
|---|
| 34 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 35 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 36 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 37 | USE closea ! closed sea |
|---|
| 38 | USE bdy_par ! unstructured open boundary data variables |
|---|
| 39 | USE bdyice ! unstructured open boundary data (bdy_ice_frs routine) |
|---|
| 40 | |
|---|
| 41 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 42 | USE restart ! ocean restart |
|---|
| 43 | USE iom ! IOM library |
|---|
| 44 | USE in_out_manager ! I/O manager |
|---|
| 45 | |
|---|
| 46 | IMPLICIT NONE |
|---|
| 47 | PRIVATE |
|---|
| 48 | |
|---|
| 49 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 50 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 51 | |
|---|
| 52 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 53 | |
|---|
| 54 | !! * Substitutions |
|---|
| 55 | # include "domzgr_substitute.h90" |
|---|
| 56 | !!---------------------------------------------------------------------- |
|---|
| 57 | !! NEMO/OPA 3.3 , NEMO-consortium (2010) |
|---|
| 58 | !! $Id$ |
|---|
| 59 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | CONTAINS |
|---|
| 62 | |
|---|
| 63 | SUBROUTINE sbc_init |
|---|
| 64 | !!--------------------------------------------------------------------- |
|---|
| 65 | !! *** ROUTINE sbc_init *** |
|---|
| 66 | !! |
|---|
| 67 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 68 | !! |
|---|
| 69 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 70 | !! |
|---|
| 71 | !! ** Action : - read namsbc parameters |
|---|
| 72 | !! - nsbc: type of sbc |
|---|
| 73 | !!---------------------------------------------------------------------- |
|---|
| 74 | INTEGER :: icpt ! temporary integer |
|---|
| 75 | !! |
|---|
| 76 | NAMELIST/namsbc/ nn_fsbc, ln_ana , ln_flx, ln_blk_clio, ln_blk_core, ln_cpl , & |
|---|
| 77 | & nn_ice , ln_dm2dc, ln_rnf, ln_ssr , nn_fwb |
|---|
| 78 | !!---------------------------------------------------------------------- |
|---|
| 79 | |
|---|
| 80 | IF(lwp) THEN |
|---|
| 81 | WRITE(numout,*) |
|---|
| 82 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 83 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 84 | ENDIF |
|---|
| 85 | |
|---|
| 86 | REWIND( numnam ) ! Read Namelist namsbc |
|---|
| 87 | READ ( numnam, namsbc ) |
|---|
| 88 | |
|---|
| 89 | ! ! overwrite namelist parameter using CPP key information |
|---|
| 90 | IF( Agrif_Root() ) THEN ! AGRIF zoom |
|---|
| 91 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 92 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 93 | ENDIF |
|---|
| 94 | IF( cp_cfg == 'gyre' ) THEN ! GYRE configuration |
|---|
| 95 | ln_ana = .TRUE. |
|---|
| 96 | nn_ice = 0 |
|---|
| 97 | ENDIF |
|---|
| 98 | |
|---|
| 99 | IF(lwp) THEN ! Control print |
|---|
| 100 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 101 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 102 | WRITE(numout,*) ' Type of sbc : ' |
|---|
| 103 | WRITE(numout,*) ' analytical formulation ln_ana = ', ln_ana |
|---|
| 104 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 105 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio |
|---|
| 106 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_core = ', ln_blk_core |
|---|
| 107 | WRITE(numout,*) ' coupled formulation (T if key_sbc_cpl) ln_cpl = ', ln_cpl |
|---|
| 108 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 109 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 110 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 111 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 112 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 113 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 114 | WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea |
|---|
| 115 | ENDIF |
|---|
| 116 | |
|---|
| 117 | ! ! Checks: |
|---|
| 118 | IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths |
|---|
| 119 | ln_rnf_mouth = .false. |
|---|
| 120 | nkrnf = 0 |
|---|
| 121 | rnf (:,:) = 0.e0 |
|---|
| 122 | rnfmsk (:,:) = 0.e0 |
|---|
| 123 | rnfmsk_z(:) = 0.e0 |
|---|
| 124 | ENDIF |
|---|
| 125 | IF( nn_ice == 0 ) fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero |
|---|
| 126 | |
|---|
| 127 | ! ! restartability |
|---|
| 128 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. & |
|---|
| 129 | MOD( nstock , nn_fsbc) /= 0 ) THEN |
|---|
| 130 | WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, & |
|---|
| 131 | & ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 132 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 133 | ENDIF |
|---|
| 134 | ! |
|---|
| 135 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 136 | & CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 137 | ! |
|---|
| 138 | IF( nn_ice == 2 .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 139 | & CALL ctl_stop( 'sea-ice model requires a bulk formulation or coupled configuration' ) |
|---|
| 140 | |
|---|
| 141 | IF( ln_dm2dc ) nday_qsr = -1 ! initialisation flag |
|---|
| 142 | |
|---|
| 143 | IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) ) & |
|---|
| 144 | & CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' ) |
|---|
| 145 | |
|---|
| 146 | IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) ) < 8 ) ) & |
|---|
| 147 | & CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 148 | |
|---|
| 149 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 150 | icpt = 0 |
|---|
| 151 | IF( ln_ana ) THEN ; nsbc = 1 ; icpt = icpt + 1 ; ENDIF ! analytical formulation |
|---|
| 152 | IF( ln_flx ) THEN ; nsbc = 2 ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 153 | IF( ln_blk_clio ) THEN ; nsbc = 3 ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation |
|---|
| 154 | IF( ln_blk_core ) THEN ; nsbc = 4 ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation |
|---|
| 155 | IF( ln_cpl ) THEN ; nsbc = 5 ; icpt = icpt + 1 ; ENDIF ! Coupled formulation |
|---|
| 156 | IF( cp_cfg == 'gyre') THEN ; nsbc = 0 ; ENDIF ! GYRE analytical formulation |
|---|
| 157 | IF( lk_esopa ) nsbc = -1 ! esopa test, ALL formulations |
|---|
| 158 | ! |
|---|
| 159 | IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN |
|---|
| 160 | WRITE(numout,*) |
|---|
| 161 | WRITE(numout,*) ' E R R O R in setting the sbc, one and only one namelist/CPP key option ' |
|---|
| 162 | WRITE(numout,*) ' must be choosen. You choose ', icpt, ' option(s)' |
|---|
| 163 | WRITE(numout,*) ' We stop' |
|---|
| 164 | nstop = nstop + 1 |
|---|
| 165 | ENDIF |
|---|
| 166 | IF(lwp) THEN |
|---|
| 167 | WRITE(numout,*) |
|---|
| 168 | IF( nsbc == -1 ) WRITE(numout,*) ' ESOPA test All surface boundary conditions' |
|---|
| 169 | IF( nsbc == 0 ) WRITE(numout,*) ' GYRE analytical formulation' |
|---|
| 170 | IF( nsbc == 1 ) WRITE(numout,*) ' analytical formulation' |
|---|
| 171 | IF( nsbc == 2 ) WRITE(numout,*) ' flux formulation' |
|---|
| 172 | IF( nsbc == 3 ) WRITE(numout,*) ' CLIO bulk formulation' |
|---|
| 173 | IF( nsbc == 4 ) WRITE(numout,*) ' CORE bulk formulation' |
|---|
| 174 | IF( nsbc == 5 ) WRITE(numout,*) ' coupled formulation' |
|---|
| 175 | ENDIF |
|---|
| 176 | ! |
|---|
| 177 | END SUBROUTINE sbc_init |
|---|
| 178 | |
|---|
| 179 | |
|---|
| 180 | SUBROUTINE sbc( kt ) |
|---|
| 181 | !!--------------------------------------------------------------------- |
|---|
| 182 | !! *** ROUTINE sbc *** |
|---|
| 183 | !! |
|---|
| 184 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 185 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 186 | !! |
|---|
| 187 | !! ** Method : blah blah to be written ????????? |
|---|
| 188 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 189 | !! |
|---|
| 190 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 191 | !! time step, i.e. |
|---|
| 192 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, emps_b, qrp_b, erp_b |
|---|
| 193 | !! utau , vtau , qns , qsr , emp , emps , qrp , erp |
|---|
| 194 | !! - updte the ice fraction : fr_i |
|---|
| 195 | !!---------------------------------------------------------------------- |
|---|
| 196 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 197 | !!--------------------------------------------------------------------- |
|---|
| 198 | |
|---|
| 199 | ! ! ---------------------------------------- ! |
|---|
| 200 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 201 | ! ! ---------------------------------------- ! |
|---|
| 202 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 203 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 204 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 205 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 206 | ! qsr_b (:,:) = qsr (:,:) |
|---|
| 207 | emp_b (:,:) = emp (:,:) |
|---|
| 208 | emps_b(:,:) = emps(:,:) |
|---|
| 209 | ENDIF |
|---|
| 210 | ! ! ---------------------------------------- ! |
|---|
| 211 | ! ! forcing field computation ! |
|---|
| 212 | ! ! ---------------------------------------- ! |
|---|
| 213 | |
|---|
| 214 | CALL iom_setkt( kt + nn_fsbc - 1 ) ! in sbc, iom_put is called every nn_fsbc time step |
|---|
| 215 | ! |
|---|
| 216 | CALL sbc_ssm( kt ) ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 217 | ! ! averaged over nf_sbc time-step |
|---|
| 218 | |
|---|
| 219 | !== sbc formulation ==! |
|---|
| 220 | |
|---|
| 221 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 222 | ! ! (i.e. utau,vtau, qns, qsr, emp, emps) |
|---|
| 223 | CASE( 0 ) ; CALL sbc_gyre ( kt ) ! analytical formulation : GYRE configuration |
|---|
| 224 | CASE( 1 ) ; CALL sbc_ana ( kt ) ! analytical formulation : uniform sbc |
|---|
| 225 | CASE( 2 ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 226 | CASE( 3 ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean |
|---|
| 227 | CASE( 4 ) ; CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean |
|---|
| 228 | CASE( 5 ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! coupled formulation |
|---|
| 229 | CASE( -1 ) |
|---|
| 230 | CALL sbc_ana ( kt ) ! ESOPA, test ALL the formulations |
|---|
| 231 | CALL sbc_gyre ( kt ) ! |
|---|
| 232 | CALL sbc_flx ( kt ) ! |
|---|
| 233 | CALL sbc_blk_clio( kt ) ! |
|---|
| 234 | CALL sbc_blk_core( kt ) ! |
|---|
| 235 | CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! |
|---|
| 236 | END SELECT |
|---|
| 237 | |
|---|
| 238 | ! !== Misc. Options ==! |
|---|
| 239 | |
|---|
| 240 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 241 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 242 | ! |
|---|
| 243 | CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model |
|---|
| 244 | IF( lk_bdy ) CALL bdy_ice_frs ( kt ) ! BDY boundary condition |
|---|
| 245 | ! |
|---|
| 246 | CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model |
|---|
| 247 | END SELECT |
|---|
| 248 | |
|---|
| 249 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 250 | |
|---|
| 251 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 252 | |
|---|
| 253 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 254 | |
|---|
| 255 | IF( nclosea == 1 ) CALL sbc_clo( kt ) ! treatment of closed sea in the model domain |
|---|
| 256 | ! ! (update freshwater fluxes) |
|---|
| 257 | ! |
|---|
| 258 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 259 | ! ! ---------------------------------------- ! |
|---|
| 260 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 261 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 262 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 263 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b ) ! before i-stress (U-point) |
|---|
| 264 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b ) ! before j-stress (V-point) |
|---|
| 265 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b ) ! before non solar heat flux (T-point) |
|---|
| 266 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 267 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b ) ! before solar heat flux (T-point) |
|---|
| 268 | CALL iom_get( numror, jpdom_autoglo, 'emp_b' , emp_b ) ! before freshwater flux (T-point) |
|---|
| 269 | CALL iom_get( numror, jpdom_autoglo, 'emps_b', emps_b ) ! before C/D freshwater flux (T-point) |
|---|
| 270 | ELSE !* no restart: set from nit000 values |
|---|
| 271 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 272 | utau_b(:,:) = utau(:,:) |
|---|
| 273 | vtau_b(:,:) = vtau(:,:) |
|---|
| 274 | qns_b (:,:) = qns (:,:) |
|---|
| 275 | ! qsr_b (:,:) = qsr (:,:) |
|---|
| 276 | emp_b (:,:) = emp (:,:) |
|---|
| 277 | emps_b(:,:) = emps(:,:) |
|---|
| 278 | ENDIF |
|---|
| 279 | ENDIF |
|---|
| 280 | ! ! ---------------------------------------- ! |
|---|
| 281 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 282 | ! ! ---------------------------------------- ! |
|---|
| 283 | IF(lwp) WRITE(numout,*) |
|---|
| 284 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 285 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 286 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 287 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau ) |
|---|
| 288 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau ) |
|---|
| 289 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns ) |
|---|
| 290 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 291 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 292 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp ) |
|---|
| 293 | CALL iom_rstput( kt, nitrst, numrow, 'emps_b' , emps ) |
|---|
| 294 | ENDIF |
|---|
| 295 | |
|---|
| 296 | ! ! ---------------------------------------- ! |
|---|
| 297 | ! ! Outputs and control print ! |
|---|
| 298 | ! ! ---------------------------------------- ! |
|---|
| 299 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 300 | CALL iom_put( "emp-rnf" , emp - rnf ) ! upward water flux |
|---|
| 301 | CALL iom_put( "emps-rnf", emps - rnf ) ! c/d water flux |
|---|
| 302 | CALL iom_put( "qns+qsr" , qns + qsr ) ! total heat flux |
|---|
| 303 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 304 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 305 | IF( nn_ice > 0 ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 306 | ENDIF |
|---|
| 307 | ! |
|---|
| 308 | CALL iom_setkt( kt ) ! iom_put outside of sbc is called at every time step |
|---|
| 309 | ! |
|---|
| 310 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at |
|---|
| 311 | CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice) |
|---|
| 312 | CALL iom_put( "taum", taum ) ! wind stress module |
|---|
| 313 | CALL iom_put( "wspd", wndm ) ! wind speed module |
|---|
| 314 | ! |
|---|
| 315 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 316 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 ) |
|---|
| 317 | CALL prt_ctl(tab2d_1=(emp-rnf) , clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 318 | CALL prt_ctl(tab2d_1=(emps-rnf), clinfo1=' emps-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 319 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 ) |
|---|
| 320 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 ) |
|---|
| 321 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk ) |
|---|
| 322 | CALL prt_ctl(tab3d_1=tn , clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 323 | CALL prt_ctl(tab3d_1=sn , clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 324 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 325 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 ) |
|---|
| 326 | ENDIF |
|---|
| 327 | ! |
|---|
| 328 | END SUBROUTINE sbc |
|---|
| 329 | |
|---|
| 330 | !!====================================================================== |
|---|
| 331 | END MODULE sbcmod |
|---|
