| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! sbc_init : read namsbc namelist |
|---|
| 17 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | USE oce ! ocean dynamics and tracers |
|---|
| 20 | USE dom_oce ! ocean space and time domain |
|---|
| 21 | USE phycst ! physical constants |
|---|
| 22 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 23 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 24 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 25 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 26 | USE sbcapr ! surface boundary condition: atmospheric pressure |
|---|
| 27 | USE sbcana ! surface boundary condition: analytical formulation |
|---|
| 28 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 29 | USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO |
|---|
| 30 | USE sbcblk_core ! surface boundary condition: bulk formulation : CORE |
|---|
| 31 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 32 | USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model |
|---|
| 33 | USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model |
|---|
| 34 | USE sbccpl ! surface boundary condition: coupled florulation |
|---|
| 35 | USE cpl_oasis3, ONLY:lk_cpl ! are we in coupled mode? |
|---|
| 36 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 37 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 38 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 39 | USE closea ! closed sea |
|---|
| 40 | USE bdy_par ! unstructured open boundary data variables |
|---|
| 41 | USE bdyice ! unstructured open boundary data (bdy_ice_frs routine) |
|---|
| 42 | |
|---|
| 43 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 44 | USE restart ! ocean restart |
|---|
| 45 | USE iom ! IOM library |
|---|
| 46 | USE in_out_manager ! I/O manager |
|---|
| 47 | |
|---|
| 48 | IMPLICIT NONE |
|---|
| 49 | PRIVATE |
|---|
| 50 | |
|---|
| 51 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 52 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 53 | |
|---|
| 54 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 55 | |
|---|
| 56 | !! * Substitutions |
|---|
| 57 | # include "domzgr_substitute.h90" |
|---|
| 58 | !!---------------------------------------------------------------------- |
|---|
| 59 | !! NEMO/OPA 3.3 , NEMO-consortium (2010) |
|---|
| 60 | !! $Id$ |
|---|
| 61 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 62 | !!---------------------------------------------------------------------- |
|---|
| 63 | CONTAINS |
|---|
| 64 | |
|---|
| 65 | SUBROUTINE sbc_init |
|---|
| 66 | !!--------------------------------------------------------------------- |
|---|
| 67 | !! *** ROUTINE sbc_init *** |
|---|
| 68 | !! |
|---|
| 69 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 70 | !! |
|---|
| 71 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 72 | !! |
|---|
| 73 | !! ** Action : - read namsbc parameters |
|---|
| 74 | !! - nsbc: type of sbc |
|---|
| 75 | !!---------------------------------------------------------------------- |
|---|
| 76 | INTEGER :: icpt ! temporary integer |
|---|
| 77 | !! |
|---|
| 78 | NAMELIST/namsbc/ nn_fsbc, ln_ana , ln_flx, ln_blk_clio, ln_blk_core, ln_cpl , & |
|---|
| 79 | & ln_apr_dyn, nn_ice , ln_dm2dc, ln_rnf, ln_ssr , nn_fwb |
|---|
| 80 | !!---------------------------------------------------------------------- |
|---|
| 81 | |
|---|
| 82 | IF(lwp) THEN |
|---|
| 83 | WRITE(numout,*) |
|---|
| 84 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 85 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 86 | ENDIF |
|---|
| 87 | |
|---|
| 88 | REWIND( numnam ) ! Read Namelist namsbc |
|---|
| 89 | READ ( numnam, namsbc ) |
|---|
| 90 | |
|---|
| 91 | ! ! overwrite namelist parameter using CPP key information |
|---|
| 92 | IF( Agrif_Root() ) THEN ! AGRIF zoom |
|---|
| 93 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 94 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 95 | ENDIF |
|---|
| 96 | IF( cp_cfg == 'gyre' ) THEN ! GYRE configuration |
|---|
| 97 | ln_ana = .TRUE. |
|---|
| 98 | nn_ice = 0 |
|---|
| 99 | ENDIF |
|---|
| 100 | |
|---|
| 101 | IF(lwp) THEN ! Control print |
|---|
| 102 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 103 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 104 | WRITE(numout,*) ' Type of sbc : ' |
|---|
| 105 | WRITE(numout,*) ' analytical formulation ln_ana = ', ln_ana |
|---|
| 106 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 107 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio |
|---|
| 108 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_core = ', ln_blk_core |
|---|
| 109 | WRITE(numout,*) ' coupled formulation (T if key_sbc_cpl) ln_cpl = ', ln_cpl |
|---|
| 110 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 111 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 112 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 113 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 114 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 115 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 116 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 117 | WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea |
|---|
| 118 | ENDIF |
|---|
| 119 | |
|---|
| 120 | ! ! Checks: |
|---|
| 121 | IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths |
|---|
| 122 | ln_rnf_mouth = .false. |
|---|
| 123 | nkrnf = 0 |
|---|
| 124 | rnf (:,:) = 0.e0 |
|---|
| 125 | rnfmsk (:,:) = 0.e0 |
|---|
| 126 | rnfmsk_z(:) = 0.e0 |
|---|
| 127 | ENDIF |
|---|
| 128 | IF( nn_ice == 0 ) fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero |
|---|
| 129 | |
|---|
| 130 | ! ! restartability |
|---|
| 131 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. & |
|---|
| 132 | MOD( nstock , nn_fsbc) /= 0 ) THEN |
|---|
| 133 | WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, & |
|---|
| 134 | & ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 135 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 136 | ENDIF |
|---|
| 137 | ! |
|---|
| 138 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 139 | & CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 140 | ! |
|---|
| 141 | IF( nn_ice == 2 .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 142 | & CALL ctl_stop( 'sea-ice model requires a bulk formulation or coupled configuration' ) |
|---|
| 143 | |
|---|
| 144 | IF( ln_dm2dc ) nday_qsr = -1 ! initialisation flag |
|---|
| 145 | |
|---|
| 146 | IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) ) & |
|---|
| 147 | & CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' ) |
|---|
| 148 | |
|---|
| 149 | IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) ) < 8 ) ) & |
|---|
| 150 | & CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 151 | |
|---|
| 152 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 153 | icpt = 0 |
|---|
| 154 | IF( ln_ana ) THEN ; nsbc = 1 ; icpt = icpt + 1 ; ENDIF ! analytical formulation |
|---|
| 155 | IF( ln_flx ) THEN ; nsbc = 2 ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 156 | IF( ln_blk_clio ) THEN ; nsbc = 3 ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation |
|---|
| 157 | IF( ln_blk_core ) THEN ; nsbc = 4 ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation |
|---|
| 158 | IF( ln_cpl ) THEN ; nsbc = 5 ; icpt = icpt + 1 ; ENDIF ! Coupled formulation |
|---|
| 159 | IF( cp_cfg == 'gyre') THEN ; nsbc = 0 ; ENDIF ! GYRE analytical formulation |
|---|
| 160 | IF( lk_esopa ) nsbc = -1 ! esopa test, ALL formulations |
|---|
| 161 | ! |
|---|
| 162 | IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN |
|---|
| 163 | WRITE(numout,*) |
|---|
| 164 | WRITE(numout,*) ' E R R O R in setting the sbc, one and only one namelist/CPP key option ' |
|---|
| 165 | WRITE(numout,*) ' must be choosen. You choose ', icpt, ' option(s)' |
|---|
| 166 | WRITE(numout,*) ' We stop' |
|---|
| 167 | nstop = nstop + 1 |
|---|
| 168 | ENDIF |
|---|
| 169 | IF(lwp) THEN |
|---|
| 170 | WRITE(numout,*) |
|---|
| 171 | IF( nsbc == -1 ) WRITE(numout,*) ' ESOPA test All surface boundary conditions' |
|---|
| 172 | IF( nsbc == 0 ) WRITE(numout,*) ' GYRE analytical formulation' |
|---|
| 173 | IF( nsbc == 1 ) WRITE(numout,*) ' analytical formulation' |
|---|
| 174 | IF( nsbc == 2 ) WRITE(numout,*) ' flux formulation' |
|---|
| 175 | IF( nsbc == 3 ) WRITE(numout,*) ' CLIO bulk formulation' |
|---|
| 176 | IF( nsbc == 4 ) WRITE(numout,*) ' CORE bulk formulation' |
|---|
| 177 | IF( nsbc == 5 ) WRITE(numout,*) ' coupled formulation' |
|---|
| 178 | ENDIF |
|---|
| 179 | ! |
|---|
| 180 | END SUBROUTINE sbc_init |
|---|
| 181 | |
|---|
| 182 | |
|---|
| 183 | SUBROUTINE sbc( kt ) |
|---|
| 184 | !!--------------------------------------------------------------------- |
|---|
| 185 | !! *** ROUTINE sbc *** |
|---|
| 186 | !! |
|---|
| 187 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 188 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 189 | !! |
|---|
| 190 | !! ** Method : blah blah to be written ????????? |
|---|
| 191 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 192 | !! |
|---|
| 193 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 194 | !! time step, i.e. |
|---|
| 195 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, emps_b, qrp_b, erp_b |
|---|
| 196 | !! utau , vtau , qns , qsr , emp , emps , qrp , erp |
|---|
| 197 | !! - updte the ice fraction : fr_i |
|---|
| 198 | !!---------------------------------------------------------------------- |
|---|
| 199 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 200 | !!--------------------------------------------------------------------- |
|---|
| 201 | |
|---|
| 202 | ! ! ---------------------------------------- ! |
|---|
| 203 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 204 | ! ! ---------------------------------------- ! |
|---|
| 205 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 206 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 207 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 208 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 209 | ! qsr_b (:,:) = qsr (:,:) |
|---|
| 210 | emp_b (:,:) = emp (:,:) |
|---|
| 211 | emps_b(:,:) = emps(:,:) |
|---|
| 212 | ENDIF |
|---|
| 213 | ! ! ---------------------------------------- ! |
|---|
| 214 | ! ! forcing field computation ! |
|---|
| 215 | ! ! ---------------------------------------- ! |
|---|
| 216 | |
|---|
| 217 | CALL iom_setkt( kt + nn_fsbc - 1 ) ! in sbc, iom_put is called every nn_fsbc time step |
|---|
| 218 | ! |
|---|
| 219 | IF( ln_apr_dyn ) CALL sbc_apr( kt ) ! atmospheric pressure provided at kt+0.5*nn_fsbc |
|---|
| 220 | ! (caution called before sbc_ssm) |
|---|
| 221 | ! |
|---|
| 222 | CALL sbc_ssm( kt ) ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 223 | ! ! averaged over nf_sbc time-step |
|---|
| 224 | |
|---|
| 225 | !== sbc formulation ==! |
|---|
| 226 | |
|---|
| 227 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 228 | ! ! (i.e. utau,vtau, qns, qsr, emp, emps) |
|---|
| 229 | CASE( 0 ) ; CALL sbc_gyre ( kt ) ! analytical formulation : GYRE configuration |
|---|
| 230 | CASE( 1 ) ; CALL sbc_ana ( kt ) ! analytical formulation : uniform sbc |
|---|
| 231 | CASE( 2 ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 232 | CASE( 3 ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean |
|---|
| 233 | CASE( 4 ) ; CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean |
|---|
| 234 | CASE( 5 ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! coupled formulation |
|---|
| 235 | CASE( -1 ) |
|---|
| 236 | CALL sbc_ana ( kt ) ! ESOPA, test ALL the formulations |
|---|
| 237 | CALL sbc_gyre ( kt ) ! |
|---|
| 238 | CALL sbc_flx ( kt ) ! |
|---|
| 239 | CALL sbc_blk_clio( kt ) ! |
|---|
| 240 | CALL sbc_blk_core( kt ) ! |
|---|
| 241 | CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! |
|---|
| 242 | END SELECT |
|---|
| 243 | |
|---|
| 244 | ! !== Misc. Options ==! |
|---|
| 245 | |
|---|
| 246 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 247 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 248 | ! |
|---|
| 249 | CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model |
|---|
| 250 | IF( lk_bdy ) CALL bdy_ice_frs ( kt ) ! BDY boundary condition |
|---|
| 251 | ! |
|---|
| 252 | CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model |
|---|
| 253 | END SELECT |
|---|
| 254 | |
|---|
| 255 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 256 | |
|---|
| 257 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 258 | |
|---|
| 259 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 260 | |
|---|
| 261 | IF( nclosea == 1 ) CALL sbc_clo( kt ) ! treatment of closed sea in the model domain |
|---|
| 262 | ! ! (update freshwater fluxes) |
|---|
| 263 | ! |
|---|
| 264 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 265 | ! ! ---------------------------------------- ! |
|---|
| 266 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 267 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 268 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 269 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b ) ! before i-stress (U-point) |
|---|
| 270 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b ) ! before j-stress (V-point) |
|---|
| 271 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b ) ! before non solar heat flux (T-point) |
|---|
| 272 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 273 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b ) ! before solar heat flux (T-point) |
|---|
| 274 | CALL iom_get( numror, jpdom_autoglo, 'emp_b' , emp_b ) ! before freshwater flux (T-point) |
|---|
| 275 | CALL iom_get( numror, jpdom_autoglo, 'emps_b', emps_b ) ! before C/D freshwater flux (T-point) |
|---|
| 276 | ELSE !* no restart: set from nit000 values |
|---|
| 277 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 278 | utau_b(:,:) = utau(:,:) |
|---|
| 279 | vtau_b(:,:) = vtau(:,:) |
|---|
| 280 | qns_b (:,:) = qns (:,:) |
|---|
| 281 | ! qsr_b (:,:) = qsr (:,:) |
|---|
| 282 | emp_b (:,:) = emp (:,:) |
|---|
| 283 | emps_b(:,:) = emps(:,:) |
|---|
| 284 | ENDIF |
|---|
| 285 | ENDIF |
|---|
| 286 | ! ! ---------------------------------------- ! |
|---|
| 287 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 288 | ! ! ---------------------------------------- ! |
|---|
| 289 | IF(lwp) WRITE(numout,*) |
|---|
| 290 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 291 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 292 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 293 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau ) |
|---|
| 294 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau ) |
|---|
| 295 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns ) |
|---|
| 296 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 297 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 298 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp ) |
|---|
| 299 | CALL iom_rstput( kt, nitrst, numrow, 'emps_b' , emps ) |
|---|
| 300 | ENDIF |
|---|
| 301 | |
|---|
| 302 | ! ! ---------------------------------------- ! |
|---|
| 303 | ! ! Outputs and control print ! |
|---|
| 304 | ! ! ---------------------------------------- ! |
|---|
| 305 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 306 | CALL iom_put( "emp-rnf" , emp - rnf ) ! upward water flux |
|---|
| 307 | CALL iom_put( "emps-rnf", emps - rnf ) ! c/d water flux |
|---|
| 308 | CALL iom_put( "qns+qsr" , qns + qsr ) ! total heat flux |
|---|
| 309 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 310 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 311 | IF( nn_ice > 0 ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 312 | ENDIF |
|---|
| 313 | ! |
|---|
| 314 | CALL iom_setkt( kt ) ! iom_put outside of sbc is called at every time step |
|---|
| 315 | ! |
|---|
| 316 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at |
|---|
| 317 | CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice) |
|---|
| 318 | CALL iom_put( "taum", taum ) ! wind stress module |
|---|
| 319 | CALL iom_put( "wspd", wndm ) ! wind speed module |
|---|
| 320 | ! |
|---|
| 321 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 322 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 ) |
|---|
| 323 | CALL prt_ctl(tab2d_1=(emp-rnf) , clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 324 | CALL prt_ctl(tab2d_1=(emps-rnf), clinfo1=' emps-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 325 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 ) |
|---|
| 326 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 ) |
|---|
| 327 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk ) |
|---|
| 328 | CALL prt_ctl(tab3d_1=tn , clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 329 | CALL prt_ctl(tab3d_1=sn , clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 330 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 331 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 ) |
|---|
| 332 | ENDIF |
|---|
| 333 | ! |
|---|
| 334 | END SUBROUTINE sbc |
|---|
| 335 | |
|---|
| 336 | !!====================================================================== |
|---|
| 337 | END MODULE sbcmod |
|---|
