New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcrnf.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 2257

Last change on this file since 2257 was 2257, checked in by cetlod, 14 years ago
Apply the modified leap-frog scheme on runoff & correct a bug on time stepping for hpg implicit case
Property svn:keywords set to `Id`
File size: 25.5 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!!----------------------------------------------------------------------
11
12	!!----------------------------------------------------------------------
13	!! sbc_rnf : monthly runoffs read in a NetCDF file
14	!! sbc_rnf_init : runoffs initialisation
15	!! rnf_mouth : set river mouth mask
16	!!----------------------------------------------------------------------
17	USE dom_oce ! ocean space and time domain
18	USE phycst ! physical constants
19	USE sbc_oce ! surface boundary condition variables
20	USE fldread ! ???
21	USE in_out_manager ! I/O manager
22	USE iom ! I/O module
23
24	IMPLICIT NONE
25	PRIVATE
26
27	PUBLIC sbc_rnf ! routine call in sbcmod module
28	PUBLIC sbc_rnf_div ! routine called in sshwzv module
29
30	! !!* namsbc_rnf namelist *
31	CHARACTER(len=100), PUBLIC :: cn_dir = './' !: Root directory for location of ssr files
32	LOGICAL , PUBLIC :: ln_rnf_depth = .false. !: depth river runoffs attribute specified in a file
33	LOGICAL , PUBLIC :: ln_rnf_tem = .false. !: temperature river runoffs attribute specified in a file
34	LOGICAL , PUBLIC :: ln_rnf_sal = .false. !: salinity river runoffs attribute specified in a file
35	LOGICAL , PUBLIC :: ln_rnf_emp = .false. !: runoffs into a file to be read or already into precipitation
36	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
37	TYPE(FLD_N) , PUBLIC :: sn_cnf !: information about the runoff mouth file to be read
38	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
39	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
40	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
41	LOGICAL , PUBLIC :: ln_rnf_mouth = .false. !: specific treatment in mouths vicinity
42	REAL(wp) , PUBLIC :: rn_hrnf = 0.e0 !: runoffs, depth over which enhanced vertical mixing is used
43	REAL(wp) , PUBLIC :: rn_avt_rnf = 0.e0 !: runoffs, value of the additional vertical mixing coef. [m2/s]
44	REAL(wp) , PUBLIC :: rn_rfact = 1.e0 !: multiplicative factor for runoff
45
46	INTEGER , PUBLIC :: nkrnf = 0 !: number of levels over which Kz is increased at river mouths
47	REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: rnfmsk !: river mouth mask (hori.)
48	REAL(wp), PUBLIC, DIMENSION(jpk) :: rnfmsk_z !: river mouth mask (vert.)
49
50	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf !: structure of input river runoff (file information, fields read)
51
52	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf !: structure of input river runoff salinity (file information, fields read)
53	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf !: structure of input river runoff temperature (file information, fields read)
54
55	REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: h_rnf !: depth of runoff in m
56	INTEGER, PUBLIC, DIMENSION(jpi,jpj) :: nk_rnf !: depth of runoff in model levels
57
58	REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpts) :: rnf_tsc_b, rnf_tsc !: before and now
59	! !: temp. & sal. content of river runoffs [K.m/s & PSU.m/s]
60
61	!! * Substitutions
62	# include "domzgr_substitute.h90"
63	!!----------------------------------------------------------------------
64	!! NEMO/OPA 3.2 , LOCEAN-IPSL (2009)
65	!! $Id$
66	!! Software governed by the CeCILL licence (NEMOGCM/License_CeCILL.txt)
67	!!----------------------------------------------------------------------
68
69	CONTAINS
70
71	SUBROUTINE sbc_rnf( kt )
72	!!----------------------------------------------------------------------
73	!! * ROUTINE sbc_rnf *
74	!!
75	!! ** Purpose : Introduce a climatological run off forcing
76	!!
77	!! ** Method : Set each river mouth with a monthly climatology
78	!! provided from different data.
79	!! CAUTION : upward water flux, runoff forced to be < 0
80	!!
81	!! ** Action : runoff updated runoff field at time-step kt
82	!!----------------------------------------------------------------------
83	INTEGER, INTENT(in) :: kt ! ocean time step
84	!!
85	INTEGER :: ji, jj ! dummy loop indices
86	REAL(wp) :: z1_rau0 ! local scalar
87	!!----------------------------------------------------------------------
88	!
89	IF( kt == nit000 ) CALL sbc_rnf_init ! Read namelist and allocate structures
90
91	! ! ---------------------------------------- !
92	IF( kt /= nit000 ) THEN ! Swap of forcing fields !
93	! ! ---------------------------------------- !
94	rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000
95	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine
96	!
97	ENDIF
98
99	! !-------------------!
100	IF( .NOT. ln_rnf_emp ) THEN ! Update runoff !
101	! !-------------------!
102	!
103	CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
104	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
105	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
106
107	! Runoff reduction only associated to the ORCA2_LIM configuration
108	! when reading the NetCDF file runoff_1m_nomask.nc
109	IF( cp_cfg == 'orca' .AND. jp_cfg == 2 ) THEN
110	DO jj = 1, jpj
111	DO ji = 1, jpi
112	IF( gphit(ji,jj) > 40 .AND. gphit(ji,jj) < 65 ) sf_rnf(1)%fnow(ji,jj,1) = 0.85 * sf_rnf(1)%fnow(ji,jj,1)
113	END DO
114	END DO
115	ENDIF
116
117	! C a u t i o n : runoff is negative and in kg/m2/s
118	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
119	rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) )
120	!
121	z1_rau0 = 1.e0 / rau0
122	! ! set temperature & salinity content of runoffs
123	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
124	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * z1_rau0
125	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999 ) ! if missing data value use SST as runoffs temperature
126	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * z1_rau0
127	ENDWHERE
128	ELSE ! use SST as runoffs temperature
129	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * z1_rau0
130	ENDIF
131	! ! use runoffs salinity data
132	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * z1_rau0
133	! ! else use S=0 for runoffs (done one for all in the init)
134	!
135	IF( ln_rnf_tem .OR. ln_rnf_sal ) THEN ! runoffs as outflow: use ocean SST and SSS
136	WHERE( rnf(:,:) < 0.e0 ) ! example baltic model when flow is out of domain
137	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * z1_rau0
138	rnf_tsc(:,:,jp_sal) = sss_m(:,:) * rnf(:,:) * z1_rau0
139	ENDWHERE
140	ENDIF
141	!
142	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
143	ENDIF
144	!
145	ENDIF
146	!
147	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
148	! ! ---------------------------------------- !
149	IF( ln_rstart .AND. & !* Restart: read in restart file
150	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
151	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
152	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff
153	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
154	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
155	ELSE !* no restart: set from nit000 values
156	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
157	rnf_b (:,: ) = rnf (:,: )
158	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
159	ENDIF
160	ENDIF
161	! ! ---------------------------------------- !
162	IF( lrst_oce ) THEN ! Write in the ocean restart file !
163	! ! ---------------------------------------- !
164	IF(lwp) WRITE(numout,*)
165	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
166	& 'at it= ', kt,' date= ', ndastp
167	IF(lwp) WRITE(numout,*) '~~~~'
168	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
169	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
170	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
171	ENDIF
172
173	!
174	END SUBROUTINE sbc_rnf
175
176	SUBROUTINE sbc_rnf_div( phdivn )
177	!!----------------------------------------------------------------------
178	!! * ROUTINE sbc_rnf *
179	!!
180	!! ** Purpose : update the horizontal divergence with the runoff inflow
181	!!
182	!! ** Method :
183	!! CAUTION : rnf is positive (inflow) decreasing the
184	!! divergence and expressed in m/s
185	!!
186	!! ** Action : phdivn decreased by the runoff inflow
187	!!----------------------------------------------------------------------
188	REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: phdivn ! horizontal divergence
189	!!
190	INTEGER :: ji, jj, jk ! dummy loop indices
191	REAL(wp) :: z1_rau0 ! local scalar
192	!!----------------------------------------------------------------------
193	!
194	z1_rau0 = 1.e0 / rau0
195	IF( ln_rnf_depth ) THEN !== runoff distributed over several levels ==!
196	IF( lk_vvl ) THEN ! variable volume case
197	DO jj = 1, jpj ! update the depth over which runoffs are distributed
198	DO ji = 1, jpi
199	h_rnf(ji,jj) = 0.e0
200	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
201	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box
202	END DO
203	! ! apply the runoff input flow
204	DO jk = 1, nk_rnf(ji,jj)
205	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - rnf(ji,jj) * z1_rau0 / h_rnf(ji,jj)
206	END DO
207	END DO
208	END DO
209	ELSE ! constant volume case : just apply the runoff input flow
210	DO jj = 1, jpj
211	DO ji = 1, jpi
212	DO jk = 1, nk_rnf(ji,jj)
213	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - rnf(ji,jj) * z1_rau0 / h_rnf(ji,jj)
214	END DO
215	END DO
216	END DO
217	ENDIF
218	ELSE !== runoff put only at the surface ==!
219	phdivn(:,:,1) = phdivn(:,:,1) - rnf(:,:) * z1_rau0 / fse3t(:,:,1)
220	ENDIF
221	!
222	END SUBROUTINE sbc_rnf_div
223
224
225	SUBROUTINE sbc_rnf_init
226	!!----------------------------------------------------------------------
227	!! * ROUTINE sbc_rnf_init *
228	!!
229	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
230	!!
231	!! ** Method : - read the runoff namsbc_rnf namelist
232	!!
233	!! ** Action : - read parameters
234	!!----------------------------------------------------------------------
235	CHARACTER(len=32) :: rn_dep_file ! runoff file name
236	INTEGER :: ji, jj, jk ! dummy loop indices
237	INTEGER :: ierror, inum ! temporary integer
238	!!
239	NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
240	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
241	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact
242	!!----------------------------------------------------------------------
243
244	! ! ============
245	! ! Namelist
246	! ! ============
247	! (NB: frequency positive => hours, negative => months)
248	! ! file ! frequency ! variable ! time intep ! clim ! 'yearly' or ! weights ! rotation !
249	! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs !
250	sn_rnf = FLD_N( 'runoffs', -1 , 'sorunoff' , .TRUE. , .true. , 'yearly' , '' , '' )
251	sn_cnf = FLD_N( 'runoffs', 0 , 'sorunoff' , .FALSE. , .true. , 'yearly' , '' , '' )
252
253	sn_s_rnf = FLD_N( 'runoffs', 24. , 'rosaline' , .TRUE. , .true. , 'yearly' , '' , '' )
254	sn_t_rnf = FLD_N( 'runoffs', 24. , 'rotemper' , .TRUE. , .true. , 'yearly' , '' , '' )
255	sn_dep_rnf = FLD_N( 'runoffs', 0. , 'rodepth' , .FALSE. , .true. , 'yearly' , '' , '' )
256	!
257	REWIND ( numnam ) ! Read Namelist namsbc_rnf
258	READ ( numnam, namsbc_rnf )
259
260	! ! Control print
261	IF(lwp) THEN
262	WRITE(numout,*)
263	WRITE(numout,*) 'sbc_rnf : runoff '
264	WRITE(numout,*) '~~~~~~~ '
265	WRITE(numout,*) ' Namelist namsbc_rnf'
266	WRITE(numout,*) ' runoff in a file to be read ln_rnf_emp = ', ln_rnf_emp
267	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
268	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
269	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
270	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
271	ENDIF
272
273	! ! ==================
274	! ! Type of runoff
275	! ! ==================
276	!
277	IF( ln_rnf_emp ) THEN !== runoffs directly provided in the precipitations ==!
278	IF(lwp) WRITE(numout,*)
279	IF(lwp) WRITE(numout,*) ' runoffs directly provided in the precipitations'
280	IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal ) THEN
281	CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' )
282	ln_rnf_depth = .FALSE. ; ln_rnf_tem = .FALSE. ; ln_rnf_sal = .FALSE.
283	ENDIF
284	!
285	ELSE !== runoffs read in a file : set sf_rnf structure ==!
286	!
287	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
288	IF(lwp) WRITE(numout,*)
289	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
290	IF( ierror > 0 ) THEN
291	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
292	ENDIF
293	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
294	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
295	! ! fill sf_rnf with the namelist (sn_rnf) and control print
296	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
297	!
298	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
299	IF(lwp) WRITE(numout,*)
300	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
301	ALLOCATE( sf_t_rnf(1), STAT=ierror )
302	IF( ierror > 0 ) THEN
303	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
304	ENDIF
305	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
306	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
307	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
308	ENDIF
309	!
310	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
311	IF(lwp) WRITE(numout,*)
312	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
313	ALLOCATE( sf_s_rnf(1), STAT=ierror )
314	IF( ierror > 0 ) THEN
315	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
316	ENDIF
317	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
318	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
319	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
320	ENDIF
321
322
323	IF ( ln_rnf_depth ) THEN ! depth of runoffs set from a file
324	IF(lwp) WRITE(numout,*)
325	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
326	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
327	CALL iom_open ( rn_dep_file, inum ) ! open file
328	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
329	CALL iom_close( inum ) ! close file
330
331	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
332	DO jj = 1, jpj
333	DO ji = 1, jpi
334	IF ( h_rnf(ji,jj) > 0.e0 ) THEN
335	jk = 2
336	DO WHILE ( jk /= ( mbathy(ji,jj) - 1 ) .AND. fsdept(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1 ; ENDDO
337	nk_rnf(ji,jj) = jk
338	ELSE IF ( h_rnf(ji,jj) == -1 ) THEN ; nk_rnf(ji,jj) = 1
339	ELSE IF ( h_rnf(ji,jj) == -999 ) THEN ; nk_rnf(ji,jj) = mbathy(ji,jj) - 1
340	ELSE IF ( h_rnf(ji,jj) /= 0 ) THEN
341	CALL ctl_stop( 'runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
342	WRITE(999,*) 'ji, jj, rnf(ji,jj) :', ji, jj, rnf(ji,jj)
343	ENDIF
344	ENDDO
345	ENDDO
346	DO jj = 1, jpj ! set the associated depth
347	DO ji = 1, jpi
348	h_rnf(ji,jj) = 0.e0
349	DO jk = 1, nk_rnf(ji,jj)
350	h_rnf(ji,jj) = h_rnf(ji,jj)+fse3t(ji,jj,jk)
351	ENDDO
352	ENDDO
353	ENDDO
354	ELSE ! runoffs applied at the surface
355	nk_rnf(:,:) = 1
356	h_rnf(:,:) = fse3t(:,:,1)
357	ENDIF
358	!
359	ENDIF
360
361	rnf_tsc(:,:,:) = 0.e0 ! runoffs temperature & salinty contents initilisation
362	! ! ========================
363	! ! River mouth vicinity
364	! ! ========================
365	!
366	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
367	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
368	! ! - set to zero SSS damping (ln_ssr=T)
369	! ! - mixed upstream-centered (ln_traadv_cen2=T)
370	!
371	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
372	& 'be spread through depth by ln_rnf_depth' )
373	!
374	nkrnf = 0 ! Number of level over which Kz increase
375	IF( rn_hrnf > 0.e0 ) THEN
376	nkrnf = 2
377	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_0(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1 ; END DO
378	IF( ln_sco ) &
379	CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
380	ENDIF
381	IF(lwp) WRITE(numout,*)
382	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
383	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
384	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
385	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
386	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
387	!
388	CALL rnf_mouth ! set river mouth mask
389	!
390	ELSE ! No treatment at river mouths
391	IF(lwp) WRITE(numout,*)
392	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
393	rnfmsk (:,:) = 0.e0
394	rnfmsk_z(:) = 0.e0
395	nkrnf = 0
396	ENDIF
397
398	END SUBROUTINE sbc_rnf_init
399
400
401	SUBROUTINE rnf_mouth
402	!!----------------------------------------------------------------------
403	!! * ROUTINE rnf_mouth *
404	!!
405	!! ** Purpose : define the river mouths mask
406	!!
407	!! ** Method : read the river mouth mask (=0/1) in the river runoff
408	!! climatological file. Defined a given vertical structure.
409	!! CAUTION, the vertical structure is hard coded on the
410	!! first 5 levels.
411	!! This fields can be used to:
412	!! - set an upstream advection scheme
413	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
414	!! - increase vertical on the top nn_krnf vertical levels
415	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
416	!! - set to zero SSS restoring flux at river mouth grid points
417	!!
418	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
419	!! rnfmsk_z vertical structure
420	!!----------------------------------------------------------------------
421	USE closea, ONLY : clo_rnf ! rnfmsk update routine
422	!
423	INTEGER :: inum ! temporary integers
424	CHARACTER(len=32) :: cl_rnfile ! runoff file name
425	!!----------------------------------------------------------------------
426	!
427	IF(lwp) WRITE(numout,*)
428	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
429	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
430
431	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
432	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
433	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
434	ENDIF
435
436	! horizontal mask (read in NetCDF file)
437	CALL iom_open ( cl_rnfile, inum ) ! open file
438	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
439	CALL iom_close( inum ) ! close file
440
441	IF( nclosea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
442
443	rnfmsk_z(:) = 0.e0 ! vertical structure
444	rnfmsk_z(1) = 1.0
445	rnfmsk_z(2) = 1.0 ! **********
446	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
447	rnfmsk_z(4) = 0.25 ! **********
448	rnfmsk_z(5) = 0.125
449	!
450	END SUBROUTINE rnf_mouth
451
452	!!======================================================================
453	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

Download in other formats: