New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcrnf.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 2259

Last change on this file since 2259 was 2259, checked in by cetlod, 14 years ago
small bug correction
Property svn:keywords set to `Id`
File size: 25.5 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!!----------------------------------------------------------------------
11
12	!!----------------------------------------------------------------------
13	!! sbc_rnf : monthly runoffs read in a NetCDF file
14	!! sbc_rnf_init : runoffs initialisation
15	!! rnf_mouth : set river mouth mask
16	!!----------------------------------------------------------------------
17	USE dom_oce ! ocean space and time domain
18	USE phycst ! physical constants
19	USE sbc_oce ! surface boundary condition variables
20	USE fldread ! ???
21	USE in_out_manager ! I/O manager
22	USE iom ! I/O module
23	USE restart ! restart
24
25	IMPLICIT NONE
26	PRIVATE
27
28	PUBLIC sbc_rnf ! routine call in sbcmod module
29	PUBLIC sbc_rnf_div ! routine called in sshwzv module
30
31	! !!* namsbc_rnf namelist *
32	CHARACTER(len=100), PUBLIC :: cn_dir = './' !: Root directory for location of ssr files
33	LOGICAL , PUBLIC :: ln_rnf_depth = .false. !: depth river runoffs attribute specified in a file
34	LOGICAL , PUBLIC :: ln_rnf_tem = .false. !: temperature river runoffs attribute specified in a file
35	LOGICAL , PUBLIC :: ln_rnf_sal = .false. !: salinity river runoffs attribute specified in a file
36	LOGICAL , PUBLIC :: ln_rnf_emp = .false. !: runoffs into a file to be read or already into precipitation
37	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
38	TYPE(FLD_N) , PUBLIC :: sn_cnf !: information about the runoff mouth file to be read
39	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
40	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
41	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
42	LOGICAL , PUBLIC :: ln_rnf_mouth = .false. !: specific treatment in mouths vicinity
43	REAL(wp) , PUBLIC :: rn_hrnf = 0.e0 !: runoffs, depth over which enhanced vertical mixing is used
44	REAL(wp) , PUBLIC :: rn_avt_rnf = 0.e0 !: runoffs, value of the additional vertical mixing coef. [m2/s]
45	REAL(wp) , PUBLIC :: rn_rfact = 1.e0 !: multiplicative factor for runoff
46
47	INTEGER , PUBLIC :: nkrnf = 0 !: number of levels over which Kz is increased at river mouths
48	REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: rnfmsk !: river mouth mask (hori.)
49	REAL(wp), PUBLIC, DIMENSION(jpk) :: rnfmsk_z !: river mouth mask (vert.)
50
51	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf !: structure of input river runoff (file information, fields read)
52
53	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf !: structure of input river runoff salinity (file information, fields read)
54	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf !: structure of input river runoff temperature (file information, fields read)
55
56	REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: h_rnf !: depth of runoff in m
57	INTEGER, PUBLIC, DIMENSION(jpi,jpj) :: nk_rnf !: depth of runoff in model levels
58
59	REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpts) :: rnf_tsc_b, rnf_tsc !: before and now
60	! !: temp. & sal. content of river runoffs [K.m/s & PSU.m/s]
61
62	!! * Substitutions
63	# include "domzgr_substitute.h90"
64	!!----------------------------------------------------------------------
65	!! NEMO/OPA 3.2 , LOCEAN-IPSL (2009)
66	!! $Id$
67	!! Software governed by the CeCILL licence (NEMOGCM/License_CeCILL.txt)
68	!!----------------------------------------------------------------------
69
70	CONTAINS
71
72	SUBROUTINE sbc_rnf( kt )
73	!!----------------------------------------------------------------------
74	!! * ROUTINE sbc_rnf *
75	!!
76	!! ** Purpose : Introduce a climatological run off forcing
77	!!
78	!! ** Method : Set each river mouth with a monthly climatology
79	!! provided from different data.
80	!! CAUTION : upward water flux, runoff forced to be < 0
81	!!
82	!! ** Action : runoff updated runoff field at time-step kt
83	!!----------------------------------------------------------------------
84	INTEGER, INTENT(in) :: kt ! ocean time step
85	!!
86	INTEGER :: ji, jj ! dummy loop indices
87	REAL(wp) :: z1_rau0 ! local scalar
88	!!----------------------------------------------------------------------
89	!
90	IF( kt == nit000 ) CALL sbc_rnf_init ! Read namelist and allocate structures
91
92	! ! ---------------------------------------- !
93	IF( kt /= nit000 ) THEN ! Swap of forcing fields !
94	! ! ---------------------------------------- !
95	rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000
96	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine
97	!
98	ENDIF
99
100	! !-------------------!
101	IF( .NOT. ln_rnf_emp ) THEN ! Update runoff !
102	! !-------------------!
103	!
104	CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
105	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
106	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
107
108	! Runoff reduction only associated to the ORCA2_LIM configuration
109	! when reading the NetCDF file runoff_1m_nomask.nc
110	IF( cp_cfg == 'orca' .AND. jp_cfg == 2 ) THEN
111	DO jj = 1, jpj
112	DO ji = 1, jpi
113	IF( gphit(ji,jj) > 40 .AND. gphit(ji,jj) < 65 ) sf_rnf(1)%fnow(ji,jj,1) = 0.85 * sf_rnf(1)%fnow(ji,jj,1)
114	END DO
115	END DO
116	ENDIF
117
118	! C a u t i o n : runoff is negative and in kg/m2/s
119	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
120	rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) )
121	!
122	z1_rau0 = 1.e0 / rau0
123	! ! set temperature & salinity content of runoffs
124	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
125	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * z1_rau0
126	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999 ) ! if missing data value use SST as runoffs temperature
127	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * z1_rau0
128	ENDWHERE
129	ELSE ! use SST as runoffs temperature
130	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * z1_rau0
131	ENDIF
132	! ! use runoffs salinity data
133	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * z1_rau0
134	! ! else use S=0 for runoffs (done one for all in the init)
135	!
136	IF( ln_rnf_tem .OR. ln_rnf_sal ) THEN ! runoffs as outflow: use ocean SST and SSS
137	WHERE( rnf(:,:) < 0.e0 ) ! example baltic model when flow is out of domain
138	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * z1_rau0
139	rnf_tsc(:,:,jp_sal) = sss_m(:,:) * rnf(:,:) * z1_rau0
140	ENDWHERE
141	ENDIF
142	!
143	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
144	ENDIF
145	!
146	ENDIF
147	!
148	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
149	! ! ---------------------------------------- !
150	IF( ln_rstart .AND. & !* Restart: read in restart file
151	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
152	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
153	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff
154	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
155	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
156	ELSE !* no restart: set from nit000 values
157	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
158	rnf_b (:,: ) = rnf (:,: )
159	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
160	ENDIF
161	ENDIF
162	! ! ---------------------------------------- !
163	IF( lrst_oce ) THEN ! Write in the ocean restart file !
164	! ! ---------------------------------------- !
165	IF(lwp) WRITE(numout,*)
166	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
167	& 'at it= ', kt,' date= ', ndastp
168	IF(lwp) WRITE(numout,*) '~~~~'
169	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
170	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
171	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
172	ENDIF
173
174	!
175	END SUBROUTINE sbc_rnf
176
177	SUBROUTINE sbc_rnf_div( phdivn )
178	!!----------------------------------------------------------------------
179	!! * ROUTINE sbc_rnf *
180	!!
181	!! ** Purpose : update the horizontal divergence with the runoff inflow
182	!!
183	!! ** Method :
184	!! CAUTION : rnf is positive (inflow) decreasing the
185	!! divergence and expressed in m/s
186	!!
187	!! ** Action : phdivn decreased by the runoff inflow
188	!!----------------------------------------------------------------------
189	REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: phdivn ! horizontal divergence
190	!!
191	INTEGER :: ji, jj, jk ! dummy loop indices
192	REAL(wp) :: z1_rau0 ! local scalar
193	!!----------------------------------------------------------------------
194	!
195	z1_rau0 = 1.e0 / rau0
196	IF( ln_rnf_depth ) THEN !== runoff distributed over several levels ==!
197	IF( lk_vvl ) THEN ! variable volume case
198	DO jj = 1, jpj ! update the depth over which runoffs are distributed
199	DO ji = 1, jpi
200	h_rnf(ji,jj) = 0.e0
201	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
202	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box
203	END DO
204	! ! apply the runoff input flow
205	DO jk = 1, nk_rnf(ji,jj)
206	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - rnf(ji,jj) * z1_rau0 / h_rnf(ji,jj)
207	END DO
208	END DO
209	END DO
210	ELSE ! constant volume case : just apply the runoff input flow
211	DO jj = 1, jpj
212	DO ji = 1, jpi
213	DO jk = 1, nk_rnf(ji,jj)
214	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - rnf(ji,jj) * z1_rau0 / h_rnf(ji,jj)
215	END DO
216	END DO
217	END DO
218	ENDIF
219	ELSE !== runoff put only at the surface ==!
220	phdivn(:,:,1) = phdivn(:,:,1) - rnf(:,:) * z1_rau0 / fse3t(:,:,1)
221	ENDIF
222	!
223	END SUBROUTINE sbc_rnf_div
224
225
226	SUBROUTINE sbc_rnf_init
227	!!----------------------------------------------------------------------
228	!! * ROUTINE sbc_rnf_init *
229	!!
230	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
231	!!
232	!! ** Method : - read the runoff namsbc_rnf namelist
233	!!
234	!! ** Action : - read parameters
235	!!----------------------------------------------------------------------
236	CHARACTER(len=32) :: rn_dep_file ! runoff file name
237	INTEGER :: ji, jj, jk ! dummy loop indices
238	INTEGER :: ierror, inum ! temporary integer
239	!!
240	NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
241	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
242	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact
243	!!----------------------------------------------------------------------
244
245	! ! ============
246	! ! Namelist
247	! ! ============
248	! (NB: frequency positive => hours, negative => months)
249	! ! file ! frequency ! variable ! time intep ! clim ! 'yearly' or ! weights ! rotation !
250	! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs !
251	sn_rnf = FLD_N( 'runoffs', -1 , 'sorunoff' , .TRUE. , .true. , 'yearly' , '' , '' )
252	sn_cnf = FLD_N( 'runoffs', 0 , 'sorunoff' , .FALSE. , .true. , 'yearly' , '' , '' )
253
254	sn_s_rnf = FLD_N( 'runoffs', 24. , 'rosaline' , .TRUE. , .true. , 'yearly' , '' , '' )
255	sn_t_rnf = FLD_N( 'runoffs', 24. , 'rotemper' , .TRUE. , .true. , 'yearly' , '' , '' )
256	sn_dep_rnf = FLD_N( 'runoffs', 0. , 'rodepth' , .FALSE. , .true. , 'yearly' , '' , '' )
257	!
258	REWIND ( numnam ) ! Read Namelist namsbc_rnf
259	READ ( numnam, namsbc_rnf )
260
261	! ! Control print
262	IF(lwp) THEN
263	WRITE(numout,*)
264	WRITE(numout,*) 'sbc_rnf : runoff '
265	WRITE(numout,*) '~~~~~~~ '
266	WRITE(numout,*) ' Namelist namsbc_rnf'
267	WRITE(numout,*) ' runoff in a file to be read ln_rnf_emp = ', ln_rnf_emp
268	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
269	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
270	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
271	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
272	ENDIF
273
274	! ! ==================
275	! ! Type of runoff
276	! ! ==================
277	!
278	IF( ln_rnf_emp ) THEN !== runoffs directly provided in the precipitations ==!
279	IF(lwp) WRITE(numout,*)
280	IF(lwp) WRITE(numout,*) ' runoffs directly provided in the precipitations'
281	IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal ) THEN
282	CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' )
283	ln_rnf_depth = .FALSE. ; ln_rnf_tem = .FALSE. ; ln_rnf_sal = .FALSE.
284	ENDIF
285	!
286	ELSE !== runoffs read in a file : set sf_rnf structure ==!
287	!
288	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
289	IF(lwp) WRITE(numout,*)
290	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
291	IF( ierror > 0 ) THEN
292	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
293	ENDIF
294	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
295	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
296	! ! fill sf_rnf with the namelist (sn_rnf) and control print
297	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
298	!
299	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
300	IF(lwp) WRITE(numout,*)
301	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
302	ALLOCATE( sf_t_rnf(1), STAT=ierror )
303	IF( ierror > 0 ) THEN
304	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
305	ENDIF
306	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
307	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
308	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
309	ENDIF
310	!
311	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
312	IF(lwp) WRITE(numout,*)
313	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
314	ALLOCATE( sf_s_rnf(1), STAT=ierror )
315	IF( ierror > 0 ) THEN
316	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
317	ENDIF
318	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
319	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
320	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
321	ENDIF
322
323
324	IF ( ln_rnf_depth ) THEN ! depth of runoffs set from a file
325	IF(lwp) WRITE(numout,*)
326	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
327	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
328	CALL iom_open ( rn_dep_file, inum ) ! open file
329	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
330	CALL iom_close( inum ) ! close file
331
332	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
333	DO jj = 1, jpj
334	DO ji = 1, jpi
335	IF ( h_rnf(ji,jj) > 0.e0 ) THEN
336	jk = 2
337	DO WHILE ( jk /= ( mbathy(ji,jj) - 1 ) .AND. fsdept(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1 ; ENDDO
338	nk_rnf(ji,jj) = jk
339	ELSE IF ( h_rnf(ji,jj) == -1 ) THEN ; nk_rnf(ji,jj) = 1
340	ELSE IF ( h_rnf(ji,jj) == -999 ) THEN ; nk_rnf(ji,jj) = mbathy(ji,jj) - 1
341	ELSE IF ( h_rnf(ji,jj) /= 0 ) THEN
342	CALL ctl_stop( 'runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
343	WRITE(999,*) 'ji, jj, rnf(ji,jj) :', ji, jj, rnf(ji,jj)
344	ENDIF
345	ENDDO
346	ENDDO
347	DO jj = 1, jpj ! set the associated depth
348	DO ji = 1, jpi
349	h_rnf(ji,jj) = 0.e0
350	DO jk = 1, nk_rnf(ji,jj)
351	h_rnf(ji,jj) = h_rnf(ji,jj)+fse3t(ji,jj,jk)
352	ENDDO
353	ENDDO
354	ENDDO
355	ELSE ! runoffs applied at the surface
356	nk_rnf(:,:) = 1
357	h_rnf(:,:) = fse3t(:,:,1)
358	ENDIF
359	!
360	ENDIF
361
362	rnf_tsc(:,:,:) = 0.e0 ! runoffs temperature & salinty contents initilisation
363	! ! ========================
364	! ! River mouth vicinity
365	! ! ========================
366	!
367	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
368	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
369	! ! - set to zero SSS damping (ln_ssr=T)
370	! ! - mixed upstream-centered (ln_traadv_cen2=T)
371	!
372	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
373	& 'be spread through depth by ln_rnf_depth' )
374	!
375	nkrnf = 0 ! Number of level over which Kz increase
376	IF( rn_hrnf > 0.e0 ) THEN
377	nkrnf = 2
378	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_0(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1 ; END DO
379	IF( ln_sco ) &
380	CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
381	ENDIF
382	IF(lwp) WRITE(numout,*)
383	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
384	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
385	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
386	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
387	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
388	!
389	CALL rnf_mouth ! set river mouth mask
390	!
391	ELSE ! No treatment at river mouths
392	IF(lwp) WRITE(numout,*)
393	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
394	rnfmsk (:,:) = 0.e0
395	rnfmsk_z(:) = 0.e0
396	nkrnf = 0
397	ENDIF
398
399	END SUBROUTINE sbc_rnf_init
400
401
402	SUBROUTINE rnf_mouth
403	!!----------------------------------------------------------------------
404	!! * ROUTINE rnf_mouth *
405	!!
406	!! ** Purpose : define the river mouths mask
407	!!
408	!! ** Method : read the river mouth mask (=0/1) in the river runoff
409	!! climatological file. Defined a given vertical structure.
410	!! CAUTION, the vertical structure is hard coded on the
411	!! first 5 levels.
412	!! This fields can be used to:
413	!! - set an upstream advection scheme
414	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
415	!! - increase vertical on the top nn_krnf vertical levels
416	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
417	!! - set to zero SSS restoring flux at river mouth grid points
418	!!
419	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
420	!! rnfmsk_z vertical structure
421	!!----------------------------------------------------------------------
422	USE closea, ONLY : clo_rnf ! rnfmsk update routine
423	!
424	INTEGER :: inum ! temporary integers
425	CHARACTER(len=32) :: cl_rnfile ! runoff file name
426	!!----------------------------------------------------------------------
427	!
428	IF(lwp) WRITE(numout,*)
429	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
430	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
431
432	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
433	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
434	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
435	ENDIF
436
437	! horizontal mask (read in NetCDF file)
438	CALL iom_open ( cl_rnfile, inum ) ! open file
439	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
440	CALL iom_close( inum ) ! close file
441
442	IF( nclosea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
443
444	rnfmsk_z(:) = 0.e0 ! vertical structure
445	rnfmsk_z(1) = 1.0
446	rnfmsk_z(2) = 1.0 ! **********
447	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
448	rnfmsk_z(4) = 0.25 ! **********
449	rnfmsk_z(5) = 0.125
450	!
451	END SUBROUTINE rnf_mouth
452
453	!!======================================================================
454	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

Download in other formats: