New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcrnf.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 2370

Last change on this file since 2370 was 2370, checked in by gm, 13 years ago
v3.3beta: ice-ocean stress at kt with VP & EVP (LIM-2 and -3)
Property svn:keywords set to `Id`
File size: 25.8 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! sbc_rnf : monthly runoffs read in a NetCDF file
15	!! sbc_rnf_init : runoffs initialisation
16	!! rnf_mouth : set river mouth mask
17	!!----------------------------------------------------------------------
18	USE dom_oce ! ocean space and time domain
19	USE phycst ! physical constants
20	USE sbc_oce ! surface boundary condition variables
21	USE fldread ! ???
22	USE in_out_manager ! I/O manager
23	USE iom ! I/O module
24	USE restart ! restart
25
26	IMPLICIT NONE
27	PRIVATE
28
29	PUBLIC sbc_rnf ! routine call in sbcmod module
30	PUBLIC sbc_rnf_div ! routine called in sshwzv module
31
32	! !!* namsbc_rnf namelist *
33	CHARACTER(len=100), PUBLIC :: cn_dir = './' !: Root directory for location of ssr files
34	LOGICAL , PUBLIC :: ln_rnf_depth = .false. !: depth river runoffs attribute specified in a file
35	LOGICAL , PUBLIC :: ln_rnf_tem = .false. !: temperature river runoffs attribute specified in a file
36	LOGICAL , PUBLIC :: ln_rnf_sal = .false. !: salinity river runoffs attribute specified in a file
37	LOGICAL , PUBLIC :: ln_rnf_emp = .false. !: runoffs into a file to be read or already into precipitation
38	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
39	TYPE(FLD_N) , PUBLIC :: sn_cnf !: information about the runoff mouth file to be read
40	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
41	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
42	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
43	LOGICAL , PUBLIC :: ln_rnf_mouth = .false. !: specific treatment in mouths vicinity
44	REAL(wp) , PUBLIC :: rn_hrnf = 0.e0 !: runoffs, depth over which enhanced vertical mixing is used
45	REAL(wp) , PUBLIC :: rn_avt_rnf = 0.e0 !: runoffs, value of the additional vertical mixing coef. [m2/s]
46	REAL(wp) , PUBLIC :: rn_rfact = 1.e0 !: multiplicative factor for runoff
47
48	INTEGER , PUBLIC :: nkrnf = 0 !: number of levels over which Kz is increased at river mouths
49	REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: rnfmsk !: river mouth mask (hori.)
50	REAL(wp), PUBLIC, DIMENSION(jpk) :: rnfmsk_z !: river mouth mask (vert.)
51
52	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf !: structure: river runoff (file information, fields read)
53
54	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf !: structure: river runoff salinity (file information, fields read)
55	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf !: structure: river runoff temperature (file information, fields read)
56
57	REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: h_rnf !: depth of runoff in m
58	INTEGER, PUBLIC, DIMENSION(jpi,jpj) :: nk_rnf !: depth of runoff in model levels
59
60	REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpts) :: rnf_tsc_b, rnf_tsc !: before and now T & S contents of runoffs [K.m/s & PSU.m/s]
61
62	!! * Substitutions
63	# include "domzgr_substitute.h90"
64	!!----------------------------------------------------------------------
65	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
66	!! $Id$
67	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
68	!!----------------------------------------------------------------------
69	CONTAINS
70
71	SUBROUTINE sbc_rnf( kt )
72	!!----------------------------------------------------------------------
73	!! * ROUTINE sbc_rnf *
74	!!
75	!! ** Purpose : Introduce a climatological run off forcing
76	!!
77	!! ** Method : Set each river mouth with a monthly climatology
78	!! provided from different data.
79	!! CAUTION : upward water flux, runoff forced to be < 0
80	!!
81	!! ** Action : runoff updated runoff field at time-step kt
82	!!----------------------------------------------------------------------
83	INTEGER, INTENT(in) :: kt ! ocean time step
84	!!
85	INTEGER :: ji, jj ! dummy loop indices
86	REAL(wp) :: z1_rau0 ! local scalar
87	!!----------------------------------------------------------------------
88	!
89	IF( kt == nit000 ) CALL sbc_rnf_init ! Read namelist and allocate structures
90
91	! ! ---------------------------------------- !
92	IF( kt /= nit000 ) THEN ! Swap of forcing fields !
93	! ! ---------------------------------------- !
94	rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000
95	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine
96	!
97	ENDIF
98
99	! !-------------------!
100	IF( .NOT. ln_rnf_emp ) THEN ! Update runoff !
101	! !-------------------!
102	!
103	CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
104	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
105	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
106
107	! Runoff reduction only associated to the ORCA2_LIM configuration
108	! when reading the NetCDF file runoff_1m_nomask.nc
109	IF( cp_cfg == 'orca' .AND. jp_cfg == 2 ) THEN
110	DO jj = 1, jpj
111	DO ji = 1, jpi
112	IF( gphit(ji,jj) > 40 .AND. gphit(ji,jj) < 65 ) sf_rnf(1)%fnow(ji,jj,1) = 0.85 * sf_rnf(1)%fnow(ji,jj,1)
113	END DO
114	END DO
115	ENDIF
116
117	! C a u t i o n : runoff is negative and in kg/m2/s
118	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
119	rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) )
120	!
121	z1_rau0 = 1.e0 / rau0
122	! ! set temperature & salinity content of runoffs
123	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
124	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * z1_rau0
125	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999 ) ! if missing data value use SST as runoffs temperature
126	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * z1_rau0
127	ENDWHERE
128	ELSE ! use SST as runoffs temperature
129	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * z1_rau0
130	ENDIF
131	! ! use runoffs salinity data
132	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * z1_rau0
133	! ! else use S=0 for runoffs (done one for all in the init)
134	!
135	IF( ln_rnf_tem .OR. ln_rnf_sal ) THEN ! runoffs as outflow: use ocean SST and SSS
136	WHERE( rnf(:,:) < 0.e0 ) ! example baltic model when flow is out of domain
137	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * z1_rau0
138	rnf_tsc(:,:,jp_sal) = sss_m(:,:) * rnf(:,:) * z1_rau0
139	ENDWHERE
140	ENDIF
141	!
142	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
143	ENDIF
144	!
145	ENDIF
146	!
147	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
148	! ! ---------------------------------------- !
149	IF( ln_rstart .AND. & !* Restart: read in restart file
150	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
151	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
152	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff
153	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
154	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
155	ELSE !* no restart: set from nit000 values
156	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
157	rnf_b (:,: ) = rnf (:,: )
158	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
159	ENDIF
160	ENDIF
161	! ! ---------------------------------------- !
162	IF( lrst_oce ) THEN ! Write in the ocean restart file !
163	! ! ---------------------------------------- !
164	IF(lwp) WRITE(numout,*)
165	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
166	& 'at it= ', kt,' date= ', ndastp
167	IF(lwp) WRITE(numout,*) '~~~~'
168	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
169	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
170	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
171	ENDIF
172	!
173	END SUBROUTINE sbc_rnf
174
175
176	SUBROUTINE sbc_rnf_div( phdivn )
177	!!----------------------------------------------------------------------
178	!! * ROUTINE sbc_rnf *
179	!!
180	!! ** Purpose : update the horizontal divergence with the runoff inflow
181	!!
182	!! ** Method :
183	!! CAUTION : rnf is positive (inflow) decreasing the
184	!! divergence and expressed in m/s
185	!!
186	!! ** Action : phdivn decreased by the runoff inflow
187	!!----------------------------------------------------------------------
188	REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: phdivn ! horizontal divergence
189	!!
190	INTEGER :: ji, jj, jk ! dummy loop indices
191	REAL(wp) :: z1_rau0 ! local scalar
192	REAL(wp) :: zfact ! local scalar
193	!!----------------------------------------------------------------------
194	!
195	zfact = 0.5e0
196	!
197	z1_rau0 = 1.e0 / rau0
198	IF( ln_rnf_depth ) THEN !== runoff distributed over several levels ==!
199	IF( lk_vvl ) THEN ! variable volume case
200	DO jj = 1, jpj ! update the depth over which runoffs are distributed
201	DO ji = 1, jpi
202	h_rnf(ji,jj) = 0.e0
203	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
204	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box
205	END DO
206	! ! apply the runoff input flow
207	DO jk = 1, nk_rnf(ji,jj)
208	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * z1_rau0 / h_rnf(ji,jj)
209	END DO
210	END DO
211	END DO
212	ELSE ! constant volume case : just apply the runoff input flow
213	DO jj = 1, jpj
214	DO ji = 1, jpi
215	DO jk = 1, nk_rnf(ji,jj)
216	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * z1_rau0 / h_rnf(ji,jj)
217	END DO
218	END DO
219	END DO
220	ENDIF
221	ELSE !== runoff put only at the surface ==!
222	IF( lk_vvl ) THEN ! variable volume case
223	h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box
224	ENDIF
225	phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * z1_rau0 / fse3t(:,:,1)
226	ENDIF
227	!
228	END SUBROUTINE sbc_rnf_div
229
230
231	SUBROUTINE sbc_rnf_init
232	!!----------------------------------------------------------------------
233	!! * ROUTINE sbc_rnf_init *
234	!!
235	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
236	!!
237	!! ** Method : - read the runoff namsbc_rnf namelist
238	!!
239	!! ** Action : - read parameters
240	!!----------------------------------------------------------------------
241	CHARACTER(len=32) :: rn_dep_file ! runoff file name
242	INTEGER :: ji, jj, jk ! dummy loop indices
243	INTEGER :: ierror, inum ! temporary integer
244	!!
245	NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
246	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
247	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact
248	!!----------------------------------------------------------------------
249
250	! ! ============
251	! ! Namelist
252	! ! ============
253	! (NB: frequency positive => hours, negative => months)
254	! ! file ! frequency ! variable ! time intep ! clim ! 'yearly' or ! weights ! rotation !
255	! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs !
256	sn_rnf = FLD_N( 'runoffs', -1 , 'sorunoff' , .TRUE. , .true. , 'yearly' , '' , '' )
257	sn_cnf = FLD_N( 'runoffs', 0 , 'sorunoff' , .FALSE. , .true. , 'yearly' , '' , '' )
258
259	sn_s_rnf = FLD_N( 'runoffs', 24. , 'rosaline' , .TRUE. , .true. , 'yearly' , '' , '' )
260	sn_t_rnf = FLD_N( 'runoffs', 24. , 'rotemper' , .TRUE. , .true. , 'yearly' , '' , '' )
261	sn_dep_rnf = FLD_N( 'runoffs', 0. , 'rodepth' , .FALSE. , .true. , 'yearly' , '' , '' )
262	!
263	REWIND ( numnam ) ! Read Namelist namsbc_rnf
264	READ ( numnam, namsbc_rnf )
265
266	! ! Control print
267	IF(lwp) THEN
268	WRITE(numout,*)
269	WRITE(numout,*) 'sbc_rnf : runoff '
270	WRITE(numout,*) '~~~~~~~ '
271	WRITE(numout,*) ' Namelist namsbc_rnf'
272	WRITE(numout,*) ' runoff in a file to be read ln_rnf_emp = ', ln_rnf_emp
273	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
274	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
275	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
276	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
277	ENDIF
278
279	! ! ==================
280	! ! Type of runoff
281	! ! ==================
282	!
283	IF( ln_rnf_emp ) THEN !== runoffs directly provided in the precipitations ==!
284	IF(lwp) WRITE(numout,*)
285	IF(lwp) WRITE(numout,*) ' runoffs directly provided in the precipitations'
286	IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal ) THEN
287	CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' )
288	ln_rnf_depth = .FALSE. ; ln_rnf_tem = .FALSE. ; ln_rnf_sal = .FALSE.
289	ENDIF
290	!
291	ELSE !== runoffs read in a file : set sf_rnf structure ==!
292	!
293	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
294	IF(lwp) WRITE(numout,*)
295	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
296	IF( ierror > 0 ) THEN
297	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
298	ENDIF
299	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
300	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
301	! ! fill sf_rnf with the namelist (sn_rnf) and control print
302	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
303	!
304	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
305	IF(lwp) WRITE(numout,*)
306	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
307	ALLOCATE( sf_t_rnf(1), STAT=ierror )
308	IF( ierror > 0 ) THEN
309	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
310	ENDIF
311	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
312	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
313	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
314	ENDIF
315	!
316	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
317	IF(lwp) WRITE(numout,*)
318	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
319	ALLOCATE( sf_s_rnf(1), STAT=ierror )
320	IF( ierror > 0 ) THEN
321	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
322	ENDIF
323	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
324	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
325	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
326	ENDIF
327
328
329	IF ( ln_rnf_depth ) THEN ! depth of runoffs set from a file
330	IF(lwp) WRITE(numout,*)
331	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
332	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
333	CALL iom_open ( rn_dep_file, inum ) ! open file
334	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
335	CALL iom_close( inum ) ! close file
336
337	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
338	DO jj = 1, jpj
339	DO ji = 1, jpi
340	IF ( h_rnf(ji,jj) > 0.e0 ) THEN
341	jk = 2
342	DO WHILE ( jk /= ( mbathy(ji,jj) - 1 ) .AND. fsdept(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1 ; ENDDO
343	nk_rnf(ji,jj) = jk
344	ELSE IF ( h_rnf(ji,jj) == -1 ) THEN ; nk_rnf(ji,jj) = 1
345	ELSE IF ( h_rnf(ji,jj) == -999 ) THEN ; nk_rnf(ji,jj) = mbathy(ji,jj) - 1
346	ELSE IF ( h_rnf(ji,jj) /= 0 ) THEN
347	CALL ctl_stop( 'runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
348	WRITE(999,*) 'ji, jj, rnf(ji,jj) :', ji, jj, rnf(ji,jj)
349	ENDIF
350	ENDDO
351	ENDDO
352	DO jj = 1, jpj ! set the associated depth
353	DO ji = 1, jpi
354	h_rnf(ji,jj) = 0.e0
355	DO jk = 1, nk_rnf(ji,jj)
356	h_rnf(ji,jj) = h_rnf(ji,jj)+fse3t(ji,jj,jk)
357	ENDDO
358	ENDDO
359	ENDDO
360	ELSE ! runoffs applied at the surface
361	nk_rnf(:,:) = 1
362	h_rnf(:,:) = fse3t(:,:,1)
363	ENDIF
364	!
365	ENDIF
366
367	rnf_tsc(:,:,:) = 0.e0 ! runoffs temperature & salinty contents initilisation
368	! ! ========================
369	! ! River mouth vicinity
370	! ! ========================
371	!
372	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
373	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
374	! ! - set to zero SSS damping (ln_ssr=T)
375	! ! - mixed upstream-centered (ln_traadv_cen2=T)
376	!
377	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
378	& 'be spread through depth by ln_rnf_depth' )
379	!
380	nkrnf = 0 ! Number of level over which Kz increase
381	IF( rn_hrnf > 0.e0 ) THEN
382	nkrnf = 2
383	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_0(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1 ; END DO
384	IF( ln_sco ) &
385	CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
386	ENDIF
387	IF(lwp) WRITE(numout,*)
388	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
389	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
390	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
391	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
392	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
393	!
394	CALL rnf_mouth ! set river mouth mask
395	!
396	ELSE ! No treatment at river mouths
397	IF(lwp) WRITE(numout,*)
398	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
399	rnfmsk (:,:) = 0.e0
400	rnfmsk_z(:) = 0.e0
401	nkrnf = 0
402	ENDIF
403
404	END SUBROUTINE sbc_rnf_init
405
406
407	SUBROUTINE rnf_mouth
408	!!----------------------------------------------------------------------
409	!! * ROUTINE rnf_mouth *
410	!!
411	!! ** Purpose : define the river mouths mask
412	!!
413	!! ** Method : read the river mouth mask (=0/1) in the river runoff
414	!! climatological file. Defined a given vertical structure.
415	!! CAUTION, the vertical structure is hard coded on the
416	!! first 5 levels.
417	!! This fields can be used to:
418	!! - set an upstream advection scheme
419	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
420	!! - increase vertical on the top nn_krnf vertical levels
421	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
422	!! - set to zero SSS restoring flux at river mouth grid points
423	!!
424	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
425	!! rnfmsk_z vertical structure
426	!!----------------------------------------------------------------------
427	USE closea, ONLY : clo_rnf ! rnfmsk update routine
428	!
429	INTEGER :: inum ! temporary integers
430	CHARACTER(len=32) :: cl_rnfile ! runoff file name
431	!!----------------------------------------------------------------------
432	!
433	IF(lwp) WRITE(numout,*)
434	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
435	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
436
437	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
438	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
439	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
440	ENDIF
441
442	! horizontal mask (read in NetCDF file)
443	CALL iom_open ( cl_rnfile, inum ) ! open file
444	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
445	CALL iom_close( inum ) ! close file
446
447	IF( nclosea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
448
449	rnfmsk_z(:) = 0.e0 ! vertical structure
450	rnfmsk_z(1) = 1.0
451	rnfmsk_z(2) = 1.0 ! **********
452	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
453	rnfmsk_z(4) = 0.25 ! **********
454	rnfmsk_z(5) = 0.125
455	!
456	END SUBROUTINE rnf_mouth
457
458	!!======================================================================
459	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

Download in other formats: