1 | MODULE traldf_iso |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE traldf_iso *** |
---|
4 | !! Ocean tracers: horizontal component of the lateral tracer mixing trend |
---|
5 | !!====================================================================== |
---|
6 | !! History : OPA ! 1994-08 (G. Madec, M. Imbard) |
---|
7 | !! 8.0 ! 1997-05 (G. Madec) split into traldf and trazdf |
---|
8 | !! NEMO ! 2002-08 (G. Madec) Free form, F90 |
---|
9 | !! 1.0 ! 2005-11 (G. Madec) merge traldf and trazdf :-) |
---|
10 | !! 3.3 ! 2010-09 (C. Ethe, G. Madec) Merge TRA-TRC |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | #if defined key_ldfslp || defined key_esopa |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! 'key_ldfslp' slope of the lateral diffusive direction |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | !! tra_ldf_iso : update the tracer trend with the horizontal |
---|
17 | !! component of a iso-neutral laplacian operator |
---|
18 | !! and with the vertical part of |
---|
19 | !! the isopycnal or geopotential s-coord. operator |
---|
20 | !!---------------------------------------------------------------------- |
---|
21 | USE oce ! ocean dynamics and active tracers |
---|
22 | USE dom_oce ! ocean space and time domain |
---|
23 | USE ldftra_oce ! ocean active tracers: lateral physics |
---|
24 | USE zdf_oce ! ocean vertical physics |
---|
25 | USE in_out_manager ! I/O manager |
---|
26 | USE iom ! |
---|
27 | USE ldfslp ! iso-neutral slopes |
---|
28 | USE diaptr ! poleward transport diagnostics |
---|
29 | USE trc_oce ! share passive tracers/Ocean variables |
---|
30 | #if defined key_diaar5 |
---|
31 | USE phycst ! physical constants |
---|
32 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
33 | #endif |
---|
34 | |
---|
35 | IMPLICIT NONE |
---|
36 | PRIVATE |
---|
37 | |
---|
38 | PUBLIC tra_ldf_iso ! routine called by step.F90 |
---|
39 | |
---|
40 | !! * Substitutions |
---|
41 | # include "domzgr_substitute.h90" |
---|
42 | # include "ldftra_substitute.h90" |
---|
43 | # include "vectopt_loop_substitute.h90" |
---|
44 | !!---------------------------------------------------------------------- |
---|
45 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
46 | !! $Id$ |
---|
47 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
48 | !!---------------------------------------------------------------------- |
---|
49 | |
---|
50 | CONTAINS |
---|
51 | |
---|
52 | SUBROUTINE tra_ldf_iso( kt, cdtype, pgu, pgv, & |
---|
53 | & ptb, pta, kjpt, pahtb0 ) |
---|
54 | !!---------------------------------------------------------------------- |
---|
55 | !! *** ROUTINE tra_ldf_iso *** |
---|
56 | !! |
---|
57 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
---|
58 | !! trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and |
---|
59 | !! add it to the general trend of tracer equation. |
---|
60 | !! |
---|
61 | !! ** Method : The horizontal component of the lateral diffusive trends |
---|
62 | !! is provided by a 2nd order operator rotated along neural or geopo- |
---|
63 | !! tential surfaces to which an eddy induced advection can be added |
---|
64 | !! It is computed using before fields (forward in time) and isopyc- |
---|
65 | !! nal or geopotential slopes computed in routine ldfslp. |
---|
66 | !! |
---|
67 | !! 1st part : masked horizontal derivative of T ( di[ t ] ) |
---|
68 | !! ======== with partial cell update if ln_zps=T. |
---|
69 | !! |
---|
70 | !! 2nd part : horizontal fluxes of the lateral mixing operator |
---|
71 | !! ======== |
---|
72 | !! zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ] |
---|
73 | !! - aht e2u*uslp dk[ mi(mk(tb)) ] |
---|
74 | !! zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ] |
---|
75 | !! - aht e2u*vslp dk[ mj(mk(tb)) ] |
---|
76 | !! take the horizontal divergence of the fluxes: |
---|
77 | !! difft = 1/(e1t*e2t*e3t) { di-1[ zftu ] + dj-1[ zftv ] } |
---|
78 | !! Add this trend to the general trend (ta,sa): |
---|
79 | !! ta = ta + difft |
---|
80 | !! |
---|
81 | !! 3rd part: vertical trends of the lateral mixing operator |
---|
82 | !! ======== (excluding the vertical flux proportional to dk[t] ) |
---|
83 | !! vertical fluxes associated with the rotated lateral mixing: |
---|
84 | !! zftw =-aht { e2t*wslpi di[ mi(mk(tb)) ] |
---|
85 | !! + e1t*wslpj dj[ mj(mk(tb)) ] } |
---|
86 | !! take the horizontal divergence of the fluxes: |
---|
87 | !! difft = 1/(e1t*e2t*e3t) dk[ zftw ] |
---|
88 | !! Add this trend to the general trend (ta,sa): |
---|
89 | !! pta = pta + difft |
---|
90 | !! |
---|
91 | !! ** Action : Update pta arrays with the before rotated diffusion |
---|
92 | !!---------------------------------------------------------------------- |
---|
93 | USE oce , zftu => ua ! use ua as workspace |
---|
94 | USE oce , zftv => va ! use va as workspace |
---|
95 | !! |
---|
96 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
---|
97 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
---|
98 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
---|
99 | REAL(wp), DIMENSION(jpi,jpj ,kjpt), INTENT(in ) :: pgu, pgv ! tracer gradient at pstep levels |
---|
100 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptb ! before and now tracer fields |
---|
101 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) :: pta ! tracer trend |
---|
102 | REAL(wp) , INTENT(in ) :: pahtb0 ! background diffusion coef |
---|
103 | !! |
---|
104 | INTEGER :: ji, jj, jk,jn ! dummy loop indices |
---|
105 | INTEGER :: iku, ikv ! temporary integer |
---|
106 | REAL(wp) :: zmsku, zabe1, zcof1, zcoef3 ! local scalars |
---|
107 | REAL(wp) :: zmskv, zabe2, zcof2, zcoef4 ! - - |
---|
108 | REAL(wp) :: zcoef0, zbtr, ztra ! - - |
---|
109 | REAL(wp), DIMENSION(jpi,jpj) :: zdkt, zdk1t ! 2D workspace |
---|
110 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdit, zdjt, ztfw ! 3D workspace |
---|
111 | #if defined key_diaar5 |
---|
112 | REAL(wp), DIMENSION(jpi,jpj) :: z2d ! 2D workspace |
---|
113 | REAL(wp) :: zztmp ! local scalar |
---|
114 | #endif |
---|
115 | !!---------------------------------------------------------------------- |
---|
116 | |
---|
117 | IF( kt == nit000 ) THEN |
---|
118 | IF(lwp) WRITE(numout,*) |
---|
119 | IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype |
---|
120 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' |
---|
121 | ENDIF |
---|
122 | ! |
---|
123 | ! ! =========== |
---|
124 | DO jn = 1, kjpt ! tracer loop |
---|
125 | ! ! =========== |
---|
126 | ! |
---|
127 | !!---------------------------------------------------------------------- |
---|
128 | !! I - masked horizontal derivative |
---|
129 | !!---------------------------------------------------------------------- |
---|
130 | !!bug ajout.... why? ( 1,jpj,:) and (jpi,1,:) should be sufficient.... |
---|
131 | zdit (1,:,:) = 0.e0 ; zdit (jpi,:,:) = 0.e0 |
---|
132 | zdjt (1,:,:) = 0.e0 ; zdjt (jpi,:,:) = 0.e0 |
---|
133 | !!end |
---|
134 | |
---|
135 | ! Horizontal tracer gradient |
---|
136 | DO jk = 1, jpkm1 |
---|
137 | DO jj = 1, jpjm1 |
---|
138 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
139 | zdit(ji,jj,jk) = ( ptb(ji+1,jj ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk) |
---|
140 | zdjt(ji,jj,jk) = ( ptb(ji ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk) |
---|
141 | END DO |
---|
142 | END DO |
---|
143 | END DO |
---|
144 | IF( ln_zps ) THEN ! partial steps correction at the last level |
---|
145 | DO jj = 1, jpjm1 |
---|
146 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
147 | ! last level |
---|
148 | iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj ) ) - 1 |
---|
149 | ikv = MIN( mbathy(ji,jj), mbathy(ji ,jj+1) ) - 1 |
---|
150 | zdit(ji,jj,iku) = pgu(ji,jj,jn) |
---|
151 | zdjt(ji,jj,ikv) = pgv(ji,jj,jn) |
---|
152 | END DO |
---|
153 | END DO |
---|
154 | ENDIF |
---|
155 | |
---|
156 | !!---------------------------------------------------------------------- |
---|
157 | !! II - horizontal trend (full) |
---|
158 | !!---------------------------------------------------------------------- |
---|
159 | !CDIR PARALLEL DO PRIVATE( zdk1t ) |
---|
160 | ! ! =============== |
---|
161 | DO jk = 1, jpkm1 ! Horizontal slab |
---|
162 | ! ! =============== |
---|
163 | ! 1. Vertical tracer gradient at level jk and jk+1 |
---|
164 | ! ------------------------------------------------ |
---|
165 | ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2) |
---|
166 | zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1) |
---|
167 | ! |
---|
168 | IF( jk == 1 ) THEN ; zdkt(:,:) = zdk1t(:,:) |
---|
169 | ELSE ; zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk) |
---|
170 | ENDIF |
---|
171 | |
---|
172 | ! 2. Horizontal fluxes |
---|
173 | ! -------------------- |
---|
174 | DO jj = 1 , jpjm1 |
---|
175 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
176 | zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj) |
---|
177 | zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj) |
---|
178 | ! |
---|
179 | zmsku = 1. / MAX( tmask(ji+1,jj,jk ) + tmask(ji,jj,jk+1) & |
---|
180 | & + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk ), 1. ) |
---|
181 | ! |
---|
182 | zmskv = 1. / MAX( tmask(ji,jj+1,jk ) + tmask(ji,jj,jk+1) & |
---|
183 | & + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk ), 1. ) |
---|
184 | ! |
---|
185 | zcof1 = - fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku |
---|
186 | zcof2 = - fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv |
---|
187 | ! |
---|
188 | zftu(ji,jj,jk ) = ( zabe1 * zdit(ji,jj,jk) & |
---|
189 | & + zcof1 * ( zdkt (ji+1,jj) + zdk1t(ji,jj) & |
---|
190 | & + zdk1t(ji+1,jj) + zdkt (ji,jj) ) ) * umask(ji,jj,jk) |
---|
191 | zftv(ji,jj,jk) = ( zabe2 * zdjt(ji,jj,jk) & |
---|
192 | & + zcof2 * ( zdkt (ji,jj+1) + zdk1t(ji,jj) & |
---|
193 | & + zdk1t(ji,jj+1) + zdkt (ji,jj) ) ) * vmask(ji,jj,jk) |
---|
194 | END DO |
---|
195 | END DO |
---|
196 | |
---|
197 | ! II.4 Second derivative (divergence) and add to the general trend |
---|
198 | ! ---------------------------------------------------------------- |
---|
199 | DO jj = 2 , jpjm1 |
---|
200 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
201 | zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
202 | ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk) ) |
---|
203 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra |
---|
204 | END DO |
---|
205 | END DO |
---|
206 | ! ! =============== |
---|
207 | END DO ! End of slab |
---|
208 | ! ! =============== |
---|
209 | ! |
---|
210 | ! "Poleward" diffusive heat or salt transports (T-S case only) |
---|
211 | IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN |
---|
212 | IF( jn == jp_tem) pht_ldf(:) = ptr_vj( zftv(:,:,:) ) |
---|
213 | IF( jn == jp_sal) pst_ldf(:) = ptr_vj( zftv(:,:,:) ) |
---|
214 | ENDIF |
---|
215 | |
---|
216 | #if defined key_diaar5 |
---|
217 | IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN |
---|
218 | zztmp = 0.5 * rau0 * rcp |
---|
219 | z2d(:,:) = 0.e0 |
---|
220 | DO jk = 1, jpkm1 |
---|
221 | DO jj = 2, jpjm1 |
---|
222 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
223 | z2d(ji,jj) = z2d(ji,jj) + zztmp * zftu(ji,jj,jk) & |
---|
224 | & * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) * e1u(ji,jj) * fse3u(ji,jj,jk) |
---|
225 | END DO |
---|
226 | END DO |
---|
227 | END DO |
---|
228 | CALL lbc_lnk( z2d, 'U', -1. ) |
---|
229 | CALL iom_put( "udiff_heattr", z2d ) ! heat transport in i-direction |
---|
230 | z2d(:,:) = 0.e0 |
---|
231 | DO jk = 1, jpkm1 |
---|
232 | DO jj = 2, jpjm1 |
---|
233 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
234 | z2d(ji,jj) = z2d(ji,jj) + zztmp * zftv(ji,jj,jk) & |
---|
235 | & * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) * e2v(ji,jj) * fse3v(ji,jj,jk) |
---|
236 | END DO |
---|
237 | END DO |
---|
238 | END DO |
---|
239 | CALL lbc_lnk( z2d, 'V', -1. ) |
---|
240 | CALL iom_put( "vdiff_heattr", z2d ) ! heat transport in i-direction |
---|
241 | END IF |
---|
242 | #endif |
---|
243 | |
---|
244 | !!---------------------------------------------------------------------- |
---|
245 | !! III - vertical trend of T & S (extra diagonal terms only) |
---|
246 | !!---------------------------------------------------------------------- |
---|
247 | |
---|
248 | ! Local constant initialization |
---|
249 | ! ----------------------------- |
---|
250 | ztfw(1,:,:) = 0.e0 ; ztfw(jpi,:,:) = 0.e0 |
---|
251 | |
---|
252 | ! Vertical fluxes |
---|
253 | ! --------------- |
---|
254 | |
---|
255 | ! Surface and bottom vertical fluxes set to zero |
---|
256 | ztfw(:,:, 1 ) = 0.e0 ; ztfw(:,:,jpk) = 0.e0 |
---|
257 | |
---|
258 | ! interior (2=<jk=<jpk-1) |
---|
259 | DO jk = 2, jpkm1 |
---|
260 | DO jj = 2, jpjm1 |
---|
261 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
262 | zcoef0 = - fsahtw(ji,jj,jk) * tmask(ji,jj,jk) |
---|
263 | ! |
---|
264 | zmsku = 1./MAX( umask(ji ,jj,jk-1) + umask(ji-1,jj,jk) & |
---|
265 | & + umask(ji-1,jj,jk-1) + umask(ji ,jj,jk), 1. ) |
---|
266 | zmskv = 1./MAX( vmask(ji,jj ,jk-1) + vmask(ji,jj-1,jk) & |
---|
267 | & + vmask(ji,jj-1,jk-1) + vmask(ji,jj ,jk), 1. ) |
---|
268 | ! |
---|
269 | zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk) |
---|
270 | zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk) |
---|
271 | ! |
---|
272 | ztfw(ji,jj,jk) = zcoef3 * ( zdit(ji ,jj ,jk-1) + zdit(ji-1,jj ,jk) & |
---|
273 | & + zdit(ji-1,jj ,jk-1) + zdit(ji ,jj ,jk) ) & |
---|
274 | & + zcoef4 * ( zdjt(ji ,jj ,jk-1) + zdjt(ji ,jj-1,jk) & |
---|
275 | & + zdjt(ji ,jj-1,jk-1) + zdjt(ji ,jj ,jk) ) |
---|
276 | END DO |
---|
277 | END DO |
---|
278 | END DO |
---|
279 | |
---|
280 | |
---|
281 | ! I.5 Divergence of vertical fluxes added to the general tracer trend |
---|
282 | ! ------------------------------------------------------------------- |
---|
283 | DO jk = 1, jpkm1 |
---|
284 | DO jj = 2, jpjm1 |
---|
285 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
286 | zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
287 | ztra = ( ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1) ) * zbtr |
---|
288 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra |
---|
289 | END DO |
---|
290 | END DO |
---|
291 | END DO |
---|
292 | ! |
---|
293 | END DO |
---|
294 | ! |
---|
295 | END SUBROUTINE tra_ldf_iso |
---|
296 | |
---|
297 | #else |
---|
298 | !!---------------------------------------------------------------------- |
---|
299 | !! default option : Dummy code NO rotation of the diffusive tensor |
---|
300 | !!---------------------------------------------------------------------- |
---|
301 | CONTAINS |
---|
302 | SUBROUTINE tra_ldf_iso( kt ) ! Empty routine |
---|
303 | WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt |
---|
304 | END SUBROUTINE tra_ldf_iso |
---|
305 | #endif |
---|
306 | |
---|
307 | !!============================================================================== |
---|
308 | END MODULE traldf_iso |
---|