New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in tags/nemo_dev_x5/NEMO/OPA_SRC/TRA – NEMO

source: tags/nemo_dev_x5/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 1792

Last change on this file since 1792 was 132, checked in by opalod, 20 years ago

CT : UPDATE082 : Finalization of the poleward transport diagnostics
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 12.4 KB
Line 
1MODULE traldf_iso
2   !!==============================================================================
3   !!                    ***  MODULE  traldf_iso  ***
4   !! Ocean active tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if defined key_ldfslp   ||   defined key_esopa
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'                  rotation of the lateral mixing tensor
9   !!----------------------------------------------------------------------
10   !!   tra_ldf_iso : update the tracer trend with the horizontal component
11   !!                 of iso neutral laplacian operator or horizontal
12   !!                 laplacian operator in s-coordinate
13   !!----------------------------------------------------------------------
14   !! * Modules used
15   USE oce             ! ocean dynamics and tracers variables
16   USE dom_oce         ! ocean space and time domain variables
17   USE ldftra_oce      ! ocean active tracers: lateral physics
18   USE trdtra_oce      ! ocean active tracers: trend variables
19   USE in_out_manager  ! I/O manager
20   USE ldfslp          ! iso-neutral slopes
21   USE diaptr          ! poleward transport diagnostics
22
23   IMPLICIT NONE
24   PRIVATE
25
26   !! * Routine accessibility
27   PUBLIC tra_ldf_iso  ! routine called by step.F90
28
29   !! * Substitutions
30#  include "domzgr_substitute.h90"
31#  include "ldftra_substitute.h90"
32#  include "ldfeiv_substitute.h90"
33#  include "vectopt_loop_substitute.h90"
34   !!----------------------------------------------------------------------
35
36CONTAINS
37
38   SUBROUTINE tra_ldf_iso( kt )
39      !!----------------------------------------------------------------------
40      !!                  ***  ROUTINE tra_ldf_iso  ***
41      !!
42      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
43      !!      trend and add it to the general trend of tracer equation.
44      !!
45      !! ** Method  :   The horizontal component of the lateral diffusive trends
46      !!      is provided by a 2nd order operator rotated along neural or geopo-
47      !!      tential surfaces to which an eddy induced advection can be added
48      !!      It is computed using before fields (forward in time) and isopyc-
49      !!      nal or geopotential slopes computed in routine ldfslp.
50      !!
51      !!      horizontal fluxes associated with the rotated lateral mixing:
52      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
53      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
54      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
55      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
56      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
57      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb )
58      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb )
59      !!      take the horizontal divergence of the fluxes:
60      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
61      !!      Add this trend to the general trend (ta,sa):
62      !!         ta = ta + difft
63      !!
64      !! ** Action  : - Update (ta,sa) arrays with the before isopycnal or
65      !!                geopotential s-coord harmonic mixing trend.
66      !!              - Save the trends in (ttrd,strd) ('key_diatrends')
67      !!
68      !! History :
69      !!        !  94-08  (G. Madec, M. Imbard)
70      !!        !  97-05  (G. Madec)  split into traldf and trazdf
71      !!   8.5  !  02-08  (G. Madec)  Free form, F90
72      !!----------------------------------------------------------------------
73      !! * Modules used
74      USE oce           , zftu => ua,  &  ! use ua as workspace
75         &                zfsu => va      ! use va as workspace
76
77      !! * Arguments
78      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
79
80      !! * Local declarations
81      INTEGER ::   ji, jj, jk             ! dummy loop indices
82      REAL(wp) ::   &
83         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
84         zmsku, zmskv, zbtr, zta, zsa, &
85#if defined key_traldf_eiv
86         zcg1, zcg2, zuwk, zvwk,       &
87         zuwk1, zvwk1,                 &
88#endif
89         ztagu, ztagv, zsagu, zsagv
90      REAL(wp), DIMENSION(jpi,jpj) ::   &
91         zdkt, zdk1t,      &  ! workspace
92         zdks, zdk1s
93#if defined key_traldf_eiv
94      REAL(wp), DIMENSION(jpi,jpj) ::   &
95         zftug, zftvg,                  &
96         zfsug, zfsvg
97#endif
98      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
99         zftv, zfsv                       ! workspace
100      !!----------------------------------------------------------------------
101
102      IF( kt == nit000 ) THEN
103         IF(lwp) WRITE(numout,*)
104         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : iso neutral lateral diffusion or'
105         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   horizontal laplacian diffusion in s-coordinate'
106#if defined key_diaeiv
107         u_eiv(:,:,:) = 0.e0
108         v_eiv(:,:,:) = 0.e0
109#endif
110      ENDIF
111
112      ztagu = 0.e0
113      ztagv = 0.e0
114      zsagu = 0.e0
115      zsagv = 0.e0
116
117      !                                                ! ===============
118      DO jk = 1, jpkm1                                 ! Horizontal slab
119         !                                             ! ===============
120         ! 1. Vertical tracer gradient at level jk and jk+1
121         ! ------------------------------------------------
122         ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
123
124         zdk1t(:,:) = ( tb(:,:,jk) - tb(:,:,jk+1) ) * tmask(:,:,jk+1)
125         zdk1s(:,:) = ( sb(:,:,jk) - sb(:,:,jk+1) ) * tmask(:,:,jk+1)
126
127         IF( jk == 1 ) THEN
128            zdkt(:,:) = zdk1t(:,:)
129            zdks(:,:) = zdk1s(:,:)
130         ELSE
131            zdkt(:,:) = ( tb(:,:,jk-1) - tb(:,:,jk) ) * tmask(:,:,jk)
132            zdks(:,:) = ( sb(:,:,jk-1) - sb(:,:,jk) ) * tmask(:,:,jk)
133         ENDIF
134
135
136         ! 2. Horizontal fluxes
137         ! --------------------
138
139         DO jj = 1 , jpjm1
140            DO ji = 1, fs_jpim1   ! vector opt.
141               zabe1 = ( fsahtu(ji,jj,jk) + ahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
142               zabe2 = ( fsahtv(ji,jj,jk) + ahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
143
144               zmsku = 1. / MAX(   tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
145                                 + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
146
147               zmskv = 1. / MAX(   tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
148                                 + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
149
150               zcof1 = -fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
151               zcof2 = -fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
152
153               zftu(ji,jj,jk) = umask(ji,jj,jk) * (   zabe1 * (   tb(ji+1,jj,jk) - tb(ji,jj,jk)  )   &
154                  &                              + zcof1 * (   zdkt (ji+1,jj) + zdk1t(ji,jj)      &
155                  &                                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
156
157               zftv(ji,jj,jk) = vmask(ji,jj,jk) * (   zabe2 * (   tb(ji,jj+1,jk) - tb(ji,jj,jk)  )   &
158                  &                              + zcof2 * (   zdkt (ji,jj+1) + zdk1t(ji,jj)      &
159                  &                                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
160
161               zfsu(ji,jj,jk) = umask(ji,jj,jk) * (   zabe1 * (   sb(ji+1,jj,jk) - sb(ji,jj,jk)  )   &
162                  &                              + zcof1 * (   zdks (ji+1,jj) + zdk1s(ji,jj)      &
163                  &                              + zdk1s(ji+1,jj) + zdks (ji,jj)  )  )
164
165               zfsv(ji,jj,jk) = vmask(ji,jj,jk) * (   zabe2 * (   sb(ji,jj+1,jk) - sb(ji,jj,jk)  )   &
166                  &                              + zcof2 * (   zdks (ji,jj+1) + zdk1s(ji,jj)      &
167                  &                              + zdk1s(ji,jj+1) + zdks (ji,jj)  )  )
168            END DO
169         END DO
170
171#   if defined key_traldf_eiv
172         !                              ! ---------------------------------------!
173         !                              ! Eddy induced vertical advective fluxes !
174         !                              ! ---------------------------------------!
175            DO jj = 1, jpjm1
176               DO ji = 1, fs_jpim1   ! vector opt.
177                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
178                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
179                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
180                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
181   
182                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
183                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
184   
185                  zftug(ji,jj) = zcg1 * ( tb(ji+1,jj,jk) + tb(ji,jj,jk) )
186                  zftvg(ji,jj) = zcg2 * ( tb(ji,jj+1,jk) + tb(ji,jj,jk) )
187                  zfsug(ji,jj) = zcg1 * ( sb(ji+1,jj,jk) + sb(ji,jj,jk) )
188                  zfsvg(ji,jj) = zcg2 * ( sb(ji,jj+1,jk) + sb(ji,jj,jk) )
189   
190                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
191                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
192                  zfsu(ji,jj,jk) = zfsu(ji,jj,jk) + zfsug(ji,jj)
193                  zfsv(ji,jj,jk) = zfsv(ji,jj,jk) + zfsvg(ji,jj)
194#   if defined key_diaeiv
195                  u_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
196                  v_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
197#   endif
198               END DO
199            END DO
200#   endif
201
202         ! II.4 Second derivative (divergence) and add to the general trend
203         ! ----------------------------------------------------------------
204
205         DO jj = 2 , jpjm1
206            DO ji = fs_2, fs_jpim1   ! vector opt.
207               zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
208               zta = zbtr * (  zftu(ji,jj,jk) - zftu(ji-1,jj  ,jk)   &
209                  &          + zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk)  )
210               zsa = zbtr * (  zfsu(ji,jj,jk) - zfsu(ji-1,jj  ,jk)   &
211                  &          + zfsv(ji,jj,jk) - zfsv(ji  ,jj-1,jk)  )
212               ta (ji,jj,jk) = ta (ji,jj,jk) + zta
213               sa (ji,jj,jk) = sa (ji,jj,jk) + zsa
214#if defined key_trdtra || defined key_trdmld
215#   if defined key_traldf_eiv
216               ztagu = ( zftug(ji,jj) - zftug(ji-1,jj  ) ) * zbtr
217               ztagv = ( zftvg(ji,jj) - zftvg(ji  ,jj-1) ) * zbtr
218               zsagu = ( zfsug(ji,jj) - zfsug(ji-1,jj  ) ) * zbtr
219               zsagv = ( zfsvg(ji,jj) - zfsvg(ji  ,jj-1) ) * zbtr
220               ttrdh(ji,jj,jk,3) = ztagu
221               ttrdh(ji,jj,jk,4) = ztagv
222               strdh(ji,jj,jk,3) = zsagu
223               strdh(ji,jj,jk,4) = zsagv
224#   endif
225               ttrd (ji,jj,jk,3) = zta - ztagu - ztagv
226               strd (ji,jj,jk,3) = zsa - zsagu - zsagv
227#endif
228            END DO
229         END DO
230         !                                          ! ===============
231      END DO                                        !   End of slab 
232      !                                             ! ===============
233
234      IF(l_ctl) THEN         ! print mean trends (used for debugging)
235         zta = SUM( ta(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
236         zsa = SUM( sa(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
237         WRITE(numout,*) ' ldf  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl
238         t_ctl = zta   ;   s_ctl = zsa
239      ENDIF
240
241      !!bug  no separation of diff iso and eiv
242      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
243         ! "zonal" mean lateral diffusive heat and salt transports
244         pht_ldf(:) = ptr_vj( zftv(:,:,:) )
245         pst_ldf(:) = ptr_vj( zfsv(:,:,:) )
246         ! "zonal" mean lateral eddy induced velocity heat and salt transports
247         pht_eiv(:) = ptr_vj( zftv(:,:,:) )
248         pst_eiv(:) = ptr_vj( zfsv(:,:,:) )
249      ENDIF
250
251   END SUBROUTINE tra_ldf_iso
252
253#else
254   !!----------------------------------------------------------------------
255   !!   Dummy module :             No rotation of the lateral mixing tensor
256   !!----------------------------------------------------------------------
257CONTAINS
258   SUBROUTINE tra_ldf_iso( kt )               ! Empty routine
259      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt
260   END SUBROUTINE tra_ldf_iso
261#endif
262
263   !!==============================================================================
264END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.