New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 216

Last change on this file since 216 was 216, checked in by opalod, 19 years ago

CT : UPDATE151 : New trends organization
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 13.0 KB
Line 
1MODULE traldf_iso
2   !!==============================================================================
3   !!                    ***  MODULE  traldf_iso  ***
4   !! Ocean active tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if defined key_ldfslp   ||   defined key_esopa
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'                  rotation of the lateral mixing tensor
9   !!----------------------------------------------------------------------
10   !!   tra_ldf_iso : update the tracer trend with the horizontal component
11   !!                 of iso neutral laplacian operator or horizontal
12   !!                 laplacian operator in s-coordinate
13   !!----------------------------------------------------------------------
14   !! * Modules used
15   USE oce             ! ocean dynamics and tracers variables
16   USE dom_oce         ! ocean space and time domain variables
17   USE ldftra_oce      ! ocean active tracers: lateral physics
18   USE trdmod          ! ocean active tracers trends
19   USE trdmod_oce      ! ocean variables trends
20   USE in_out_manager  ! I/O manager
21   USE ldfslp          ! iso-neutral slopes
22   USE diaptr          ! poleward transport diagnostics
23
24   IMPLICIT NONE
25   PRIVATE
26
27   !! * Routine accessibility
28   PUBLIC tra_ldf_iso  ! routine called by step.F90
29
30   !! * Substitutions
31#  include "domzgr_substitute.h90"
32#  include "ldftra_substitute.h90"
33#  include "ldfeiv_substitute.h90"
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36
37CONTAINS
38
39   SUBROUTINE tra_ldf_iso( kt )
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE tra_ldf_iso  ***
42      !!
43      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
44      !!      trend and add it to the general trend of tracer equation.
45      !!
46      !! ** Method  :   The horizontal component of the lateral diffusive trends
47      !!      is provided by a 2nd order operator rotated along neural or geopo-
48      !!      tential surfaces to which an eddy induced advection can be added
49      !!      It is computed using before fields (forward in time) and isopyc-
50      !!      nal or geopotential slopes computed in routine ldfslp.
51      !!
52      !!      horizontal fluxes associated with the rotated lateral mixing:
53      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
54      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
55      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
56      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
57      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
58      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb )
59      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb )
60      !!      take the horizontal divergence of the fluxes:
61      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
62      !!      Add this trend to the general trend (ta,sa):
63      !!         ta = ta + difft
64      !!
65      !! ** Action  : - Update (ta,sa) arrays with the before isopycnal or
66      !!                geopotential s-coord harmonic mixing trend.
67      !!              - Save the trends in (ztdta,ztdsa) ('key_trdtra')
68      !!
69      !! History :
70      !!        !  94-08  (G. Madec, M. Imbard)
71      !!        !  97-05  (G. Madec)  split into traldf and trazdf
72      !!   8.5  !  02-08  (G. Madec)  Free form, F90
73      !!   9.0  !  04-08  (C. Talandier) New trends organization
74      !!----------------------------------------------------------------------
75      !! * Modules used
76      USE oce           , zftu => ua,  &  ! use ua as workspace
77         &                zfsu => va      ! use va as workspace
78
79      !! * Arguments
80      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
81
82      !! * Local declarations
83      INTEGER ::   ji, jj, jk             ! dummy loop indices
84      REAL(wp) ::   &
85         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
86#if defined key_traldf_eiv
87         zcg1, zcg2, zuwk, zvwk,       &
88         zuwk1, zvwk1,                 &
89#endif
90         zmsku, zmskv, zbtr, zta, zsa
91      REAL(wp), DIMENSION(jpi,jpj) ::   &
92         zdkt, zdk1t,      &  ! workspace
93         zdks, zdk1s
94#if defined key_traldf_eiv
95      REAL(wp), DIMENSION(jpi,jpj) ::   &
96         zftug, zftvg,                  &
97         zfsug, zfsvg
98#endif
99      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
100         zftv, zfsv,                        &  ! workspace
101         ztdta, ztdsa
102      !!----------------------------------------------------------------------
103
104      IF( kt == nit000 ) THEN
105         IF(lwp) WRITE(numout,*)
106         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : iso neutral lateral diffusion or'
107         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   horizontal laplacian diffusion in s-coordinate'
108#if defined key_diaeiv
109         u_eiv(:,:,:) = 0.e0
110         v_eiv(:,:,:) = 0.e0
111#endif
112      ENDIF
113
114      ! Save ta and sa trends
115      IF( l_trdtra )   THEN
116         ztdta(:,:,:) = ta(:,:,:) 
117         ztdsa(:,:,:) = sa(:,:,:) 
118      ENDIF
119
120      !                                                ! ===============
121      DO jk = 1, jpkm1                                 ! Horizontal slab
122         !                                             ! ===============
123         ! 1. Vertical tracer gradient at level jk and jk+1
124         ! ------------------------------------------------
125         ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
126
127         zdk1t(:,:) = ( tb(:,:,jk) - tb(:,:,jk+1) ) * tmask(:,:,jk+1)
128         zdk1s(:,:) = ( sb(:,:,jk) - sb(:,:,jk+1) ) * tmask(:,:,jk+1)
129
130         IF( jk == 1 ) THEN
131            zdkt(:,:) = zdk1t(:,:)
132            zdks(:,:) = zdk1s(:,:)
133         ELSE
134            zdkt(:,:) = ( tb(:,:,jk-1) - tb(:,:,jk) ) * tmask(:,:,jk)
135            zdks(:,:) = ( sb(:,:,jk-1) - sb(:,:,jk) ) * tmask(:,:,jk)
136         ENDIF
137
138
139         ! 2. Horizontal fluxes
140         ! --------------------
141
142         DO jj = 1 , jpjm1
143            DO ji = 1, fs_jpim1   ! vector opt.
144               zabe1 = ( fsahtu(ji,jj,jk) + ahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
145               zabe2 = ( fsahtv(ji,jj,jk) + ahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
146
147               zmsku = 1. / MAX(   tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
148                                 + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
149
150               zmskv = 1. / MAX(   tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
151                                 + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
152
153               zcof1 = -fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
154               zcof2 = -fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
155
156               zftu(ji,jj,jk) = umask(ji,jj,jk) * (   zabe1 * (   tb(ji+1,jj,jk) - tb(ji,jj,jk)  )   &
157                  &                              + zcof1 * (   zdkt (ji+1,jj) + zdk1t(ji,jj)      &
158                  &                                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
159
160               zftv(ji,jj,jk) = vmask(ji,jj,jk) * (   zabe2 * (   tb(ji,jj+1,jk) - tb(ji,jj,jk)  )   &
161                  &                              + zcof2 * (   zdkt (ji,jj+1) + zdk1t(ji,jj)      &
162                  &                                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
163
164               zfsu(ji,jj,jk) = umask(ji,jj,jk) * (   zabe1 * (   sb(ji+1,jj,jk) - sb(ji,jj,jk)  )   &
165                  &                              + zcof1 * (   zdks (ji+1,jj) + zdk1s(ji,jj)      &
166                  &                              + zdk1s(ji+1,jj) + zdks (ji,jj)  )  )
167
168               zfsv(ji,jj,jk) = vmask(ji,jj,jk) * (   zabe2 * (   sb(ji,jj+1,jk) - sb(ji,jj,jk)  )   &
169                  &                              + zcof2 * (   zdks (ji,jj+1) + zdk1s(ji,jj)      &
170                  &                              + zdk1s(ji,jj+1) + zdks (ji,jj)  )  )
171            END DO
172         END DO
173
174#   if defined key_traldf_eiv
175         !                              ! ---------------------------------------!
176         !                              ! Eddy induced vertical advective fluxes !
177         !                              ! ---------------------------------------!
178            DO jj = 1, jpjm1
179               DO ji = 1, fs_jpim1   ! vector opt.
180                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
181                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
182                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
183                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
184   
185                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
186                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
187   
188                  zftug(ji,jj) = zcg1 * ( tb(ji+1,jj,jk) + tb(ji,jj,jk) )
189                  zftvg(ji,jj) = zcg2 * ( tb(ji,jj+1,jk) + tb(ji,jj,jk) )
190                  zfsug(ji,jj) = zcg1 * ( sb(ji+1,jj,jk) + sb(ji,jj,jk) )
191                  zfsvg(ji,jj) = zcg2 * ( sb(ji,jj+1,jk) + sb(ji,jj,jk) )
192   
193                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
194                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
195                  zfsu(ji,jj,jk) = zfsu(ji,jj,jk) + zfsug(ji,jj)
196                  zfsv(ji,jj,jk) = zfsv(ji,jj,jk) + zfsvg(ji,jj)
197#   if defined key_diaeiv
198                  u_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
199                  v_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
200#   endif
201               END DO
202            END DO
203#   endif
204
205         ! II.4 Second derivative (divergence) and add to the general trend
206         ! ----------------------------------------------------------------
207
208         DO jj = 2 , jpjm1
209            DO ji = fs_2, fs_jpim1   ! vector opt.
210               zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
211               zta = zbtr * (  zftu(ji,jj,jk) - zftu(ji-1,jj  ,jk)   &
212                  &          + zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk)  )
213               zsa = zbtr * (  zfsu(ji,jj,jk) - zfsu(ji-1,jj  ,jk)   &
214                  &          + zfsv(ji,jj,jk) - zfsv(ji  ,jj-1,jk)  )
215               ta (ji,jj,jk) = ta (ji,jj,jk) + zta
216               sa (ji,jj,jk) = sa (ji,jj,jk) + zsa
217            END DO
218         END DO
219         !                                          ! ===============
220      END DO                                        !   End of slab 
221      !                                             ! ===============
222
223      ! save the trends for diagnostic
224      ! save the horizontal diffusive trends
225      IF( l_trdtra )   THEN
226#   if defined key_traldf_eiv
227         DO jk = 1 , jpkm1
228            DO jj = 2 , jpjm1
229               DO ji = fs_2, fs_jpim1   ! vector opt.
230                  zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
231                  tladi(ji,jj,jk) = ( zftug(ji,jj) - zftug(ji-1,jj  ) ) * zbtr
232                  tladj(ji,jj,jk) = ( zftvg(ji,jj) - zftvg(ji  ,jj-1) ) * zbtr
233                  sladi(ji,jj,jk) = ( zfsug(ji,jj) - zfsug(ji-1,jj  ) ) * zbtr
234                  sladj(ji,jj,jk) = ( zfsvg(ji,jj) - zfsvg(ji  ,jj-1) ) * zbtr
235               END DO
236            END DO
237         END DO
238#   else
239         tladi(:,:,:) = 0.e0
240         tladj(:,:,:) = 0.e0
241         sladi(:,:,:) = 0.e0
242         sladj(:,:,:) = 0.e0
243#   endif
244       
245         ! Substract the eddy induced velocity for T/S
246         ztdta(:,:,:) = ta(:,:,:) - ztdta(:,:,:) - tladi(:,:,:) - tladj(:,:,:) 
247         ztdsa(:,:,:) = sa(:,:,:) - ztdsa(:,:,:) - sladi(:,:,:) - sladj(:,:,:) 
248
249         CALL trd_mod(ztdta, ztdsa, jpttdldf, 'TRA', kt)
250      ENDIF
251
252      IF(l_ctl) THEN         ! print mean trends (used for debugging)
253         zta = SUM( ta(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
254         zsa = SUM( sa(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
255         WRITE(numout,*) ' ldf  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl
256         t_ctl = zta   ;   s_ctl = zsa
257      ENDIF
258
259      !!bug  no separation of diff iso and eiv
260      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
261         ! "zonal" mean lateral diffusive heat and salt transports
262         pht_ldf(:) = ptr_vj( zftv(:,:,:) )
263         pst_ldf(:) = ptr_vj( zfsv(:,:,:) )
264         ! "zonal" mean lateral eddy induced velocity heat and salt transports
265         pht_eiv(:) = ptr_vj( zftv(:,:,:) )
266         pst_eiv(:) = ptr_vj( zfsv(:,:,:) )
267      ENDIF
268
269   END SUBROUTINE tra_ldf_iso
270
271#else
272   !!----------------------------------------------------------------------
273   !!   Dummy module :             No rotation of the lateral mixing tensor
274   !!----------------------------------------------------------------------
275CONTAINS
276   SUBROUTINE tra_ldf_iso( kt )               ! Empty routine
277      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt
278   END SUBROUTINE tra_ldf_iso
279#endif
280
281   !!==============================================================================
282END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.