1 | MODULE traldf_iso_zps |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE traldf_iso_zps *** |
---|
4 | !! Ocean active tracers: horizontal component of the lateral tracer mixing trend |
---|
5 | !!============================================================================== |
---|
6 | #if ( defined key_ldfslp && defined key_partial_steps ) || defined key_esopa |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | !! 'key_ldfslp' slope of the lateral diffusive direction |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | !! tra_ldf_iso_zps : update the tracer trend with the horizontal |
---|
11 | !! component of a iso-neutral laplacian operator |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! * Modules used |
---|
14 | USE oce ! ocean dynamics and active tracers |
---|
15 | USE dom_oce ! ocean space and time domain |
---|
16 | USE ldftra_oce ! ocean active tracers: lateral physics |
---|
17 | USE trdmod ! ocean active tracers trends |
---|
18 | USE trdmod_oce ! ocean variables trends |
---|
19 | USE zdf_oce ! ocean vertical physics |
---|
20 | USE in_out_manager ! I/O manager |
---|
21 | USE ldfslp ! iso-neutral slopes |
---|
22 | USE diaptr ! poleward transport diagnostics |
---|
23 | |
---|
24 | |
---|
25 | IMPLICIT NONE |
---|
26 | PRIVATE |
---|
27 | |
---|
28 | !! * Accessibility |
---|
29 | PUBLIC tra_ldf_iso_zps ! routine called by step.F90 |
---|
30 | |
---|
31 | !! * Substitutions |
---|
32 | # include "domzgr_substitute.h90" |
---|
33 | # include "ldftra_substitute.h90" |
---|
34 | # include "ldfeiv_substitute.h90" |
---|
35 | # include "vectopt_loop_substitute.h90" |
---|
36 | !!---------------------------------------------------------------------- |
---|
37 | !! OPA 9.0 , LOCEAN-IPSL (2005) |
---|
38 | !! $Header$ |
---|
39 | !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt |
---|
40 | !!---------------------------------------------------------------------- |
---|
41 | |
---|
42 | CONTAINS |
---|
43 | |
---|
44 | SUBROUTINE tra_ldf_iso_zps( kt ) |
---|
45 | !!---------------------------------------------------------------------- |
---|
46 | !! *** ROUTINE tra_ldf_iso_zps *** |
---|
47 | !! |
---|
48 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
---|
49 | !! trend and add it to the general trend of tracer equation. |
---|
50 | !! |
---|
51 | !! ** Method : The horizontal component of the lateral diffusive trends |
---|
52 | !! is provided by a 2nd order operator rotated along neural or geopo- |
---|
53 | !! tential surfaces to which an eddy induced advection can be added |
---|
54 | !! It is computed using before fields (forward in time) and isopyc- |
---|
55 | !! nal or geopotential slopes computed in routine ldfslp. |
---|
56 | !! |
---|
57 | !! horizontal fluxes associated with the rotated lateral mixing: |
---|
58 | !! zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ] |
---|
59 | !! - aht e2u*uslp dk[ mi(mk(tb)) ] |
---|
60 | !! zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ] |
---|
61 | !! - aht e2u*vslp dk[ mj(mk(tb)) ] |
---|
62 | !! add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T): |
---|
63 | !! zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb ) |
---|
64 | !! zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb ) |
---|
65 | !! take the horizontal divergence of the fluxes: |
---|
66 | !! difft = 1/(e1t*e2t*e3t) { di-1[ zftu ] + dj-1[ zftv ] } |
---|
67 | !! Add this trend to the general trend (ta,sa): |
---|
68 | !! ta = ta + difft |
---|
69 | !! |
---|
70 | !! 'key_trdtra' defined: the trend is saved for diagnostics. |
---|
71 | !! |
---|
72 | !! macro-tasked on horizontal slab (jk-loop). |
---|
73 | !! |
---|
74 | !! ** Action : |
---|
75 | !! Update (ta,sa) arrays with the before along level biharmonic |
---|
76 | !! mixing trend. |
---|
77 | !! Save in (ztdta,ztdsa) arrays the trends if 'key_trdtra' defined |
---|
78 | !! |
---|
79 | !! History : |
---|
80 | !! ! 94-08 (G. Madec, M. Imbard) |
---|
81 | !! ! 97-05 (G. Madec) split into traldf and trazdf |
---|
82 | !! 8.5 ! 02-08 (G. Madec) Free form, F90 |
---|
83 | !! 9.0 ! 04-08 (C. Talandier) New trends organization |
---|
84 | !!---------------------------------------------------------------------- |
---|
85 | !! * Modules used |
---|
86 | USE oce , zftu => ua, & ! use ua as workspace |
---|
87 | & zfsu => va ! use va as workspace |
---|
88 | |
---|
89 | !! * Arguments |
---|
90 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
---|
91 | |
---|
92 | !! * Local declarations |
---|
93 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
94 | INTEGER :: iku, ikv ! temporary integer |
---|
95 | REAL(wp) :: & |
---|
96 | zabe1, zabe2, zcof1, zcof2, & ! temporary scalars |
---|
97 | zmsku, zmskv, zbtr, zta, zsa ! " " |
---|
98 | REAL(wp), DIMENSION(jpi,jpj) :: & ! temporary workspace |
---|
99 | zdkt , zdk1t, zdks , zdk1s ! " " |
---|
100 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: & |
---|
101 | zftv, zgtbu, zgtbv, & ! temporary workspace |
---|
102 | zfsv, zgsbu, zgsbv, & ! " " |
---|
103 | ztdta, ztdsa |
---|
104 | |
---|
105 | #if defined key_traldf_eiv |
---|
106 | REAL(wp) :: & |
---|
107 | zcg1, zcg2, zuwk, zvwk, & ! temporary scalars |
---|
108 | zuwk1, zvwk1 ! " " |
---|
109 | REAL(wp), DIMENSION(jpi,jpj) :: & ! temporary workspace |
---|
110 | zftug, zftvg, zfsug, zfsvg ! " " |
---|
111 | #endif |
---|
112 | !!---------------------------------------------------------------------- |
---|
113 | |
---|
114 | IF( kt == nit000 ) THEN |
---|
115 | IF(lwp) WRITE(numout,*) |
---|
116 | IF(lwp) WRITE(numout,*) 'tra_ldf_iso_zps : iso neutral laplacian diffusion in ' |
---|
117 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~ z-coordinates with partial steps' |
---|
118 | #if defined key_diaeiv |
---|
119 | u_eiv(:,:,:) = 0.e0 |
---|
120 | v_eiv(:,:,:) = 0.e0 |
---|
121 | #endif |
---|
122 | ENDIF |
---|
123 | |
---|
124 | ! Save ta and sa trends |
---|
125 | IF( l_trdtra ) THEN |
---|
126 | ztdta(:,:,:) = ta(:,:,:) |
---|
127 | ztdsa(:,:,:) = sa(:,:,:) |
---|
128 | ENDIF |
---|
129 | |
---|
130 | ! Horizontal temperature and salinity gradient |
---|
131 | DO jk = 1, jpk |
---|
132 | DO jj = 1, jpj-1 |
---|
133 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
134 | zgtbu(ji,jj,jk) = tmask(ji,jj,jk) * ( tb(ji+1,jj ,jk) - tb(ji,jj,jk) ) |
---|
135 | zgsbu(ji,jj,jk) = tmask(ji,jj,jk) * ( sb(ji+1,jj ,jk) - sb(ji,jj,jk) ) |
---|
136 | zgtbv(ji,jj,jk) = tmask(ji,jj,jk) * ( tb(ji ,jj+1,jk) - tb(ji,jj,jk) ) |
---|
137 | zgsbv(ji,jj,jk) = tmask(ji,jj,jk) * ( sb(ji ,jj+1,jk) - sb(ji,jj,jk) ) |
---|
138 | END DO |
---|
139 | END DO |
---|
140 | END DO |
---|
141 | ! partial steps correction at the last level |
---|
142 | DO jj = 1, jpj-1 |
---|
143 | DO ji = 1, jpi-1 |
---|
144 | ! last level |
---|
145 | iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj ) ) - 1 |
---|
146 | ikv = MIN( mbathy(ji,jj), mbathy(ji ,jj+1) ) - 1 |
---|
147 | zgtbu(ji,jj,iku) = gtu(ji,jj) |
---|
148 | zgsbu(ji,jj,iku) = gsu(ji,jj) |
---|
149 | zgtbv(ji,jj,ikv) = gtv(ji,jj) |
---|
150 | zgsbv(ji,jj,ikv) = gsv(ji,jj) |
---|
151 | END DO |
---|
152 | END DO |
---|
153 | |
---|
154 | ! ! =============== |
---|
155 | DO jk = 1, jpkm1 ! Horizontal slab |
---|
156 | ! ! =============== |
---|
157 | ! 1. Vertical tracer gradient at level jk and jk+1 |
---|
158 | ! ------------------------------------------------ |
---|
159 | ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2) |
---|
160 | |
---|
161 | zdk1t(:,:) = ( tb(:,:,jk) - tb(:,:,jk+1) ) * tmask(:,:,jk+1) |
---|
162 | zdk1s(:,:) = ( sb(:,:,jk) - sb(:,:,jk+1) ) * tmask(:,:,jk+1) |
---|
163 | |
---|
164 | IF( jk == 1 ) THEN |
---|
165 | zdkt(:,:) = zdk1t(:,:) |
---|
166 | zdks(:,:) = zdk1s(:,:) |
---|
167 | ELSE |
---|
168 | zdkt(:,:) = ( tb(:,:,jk-1) - tb(:,:,jk) ) * tmask(:,:,jk) |
---|
169 | zdks(:,:) = ( sb(:,:,jk-1) - sb(:,:,jk) ) * tmask(:,:,jk) |
---|
170 | ENDIF |
---|
171 | |
---|
172 | |
---|
173 | ! 2. Horizontal fluxes |
---|
174 | ! -------------------- |
---|
175 | |
---|
176 | DO jj = 1 , jpjm1 |
---|
177 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
178 | zabe1 = ( fsahtu(ji,jj,jk) + ahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj) |
---|
179 | zabe2 = ( fsahtv(ji,jj,jk) + ahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj) |
---|
180 | |
---|
181 | zmsku = 1. / MAX( tmask(ji+1,jj,jk ) + tmask(ji,jj,jk+1) & |
---|
182 | + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk ), 1. ) |
---|
183 | |
---|
184 | zmskv = 1. / MAX( tmask(ji,jj+1,jk ) + tmask(ji,jj,jk+1) & |
---|
185 | + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk ), 1. ) |
---|
186 | |
---|
187 | zcof1 = -fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku |
---|
188 | zcof2 = -fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv |
---|
189 | |
---|
190 | zftu(ji,jj,jk) = umask(ji,jj,jk) * ( zabe1 * zgtbu(ji,jj,jk) & |
---|
191 | & + zcof1 * ( zdkt (ji+1,jj) + zdk1t(ji,jj) & |
---|
192 | & + zdk1t(ji+1,jj) + zdkt (ji,jj) ) ) |
---|
193 | zftv(ji,jj,jk) = vmask(ji,jj,jk) * ( zabe2 * zgtbv(ji,jj,jk) & |
---|
194 | & + zcof2 * ( zdkt (ji,jj+1) + zdk1t(ji,jj) & |
---|
195 | & + zdk1t(ji,jj+1) + zdkt (ji,jj) ) ) |
---|
196 | zfsu(ji,jj,jk) = umask(ji,jj,jk) * ( zabe1 * zgsbu(ji,jj,jk) & |
---|
197 | & + zcof1 * ( zdks (ji+1,jj) + zdk1s(ji,jj) & |
---|
198 | & + zdk1s(ji+1,jj) + zdks (ji,jj) ) ) |
---|
199 | zfsv(ji,jj,jk) = vmask(ji,jj,jk) * ( zabe2 * zgsbv(ji,jj,jk) & |
---|
200 | & + zcof2 * ( zdks (ji,jj+1) + zdk1s(ji,jj) & |
---|
201 | & + zdk1s(ji,jj+1) + zdks (ji,jj) ) ) |
---|
202 | END DO |
---|
203 | END DO |
---|
204 | |
---|
205 | #if defined key_traldf_eiv |
---|
206 | ! ---------------------------------------! |
---|
207 | ! Eddy induced vertical advective fluxes ! |
---|
208 | ! ---------------------------------------! |
---|
209 | DO jj = 1, jpjm1 |
---|
210 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
211 | zuwk = ( wslpi(ji,jj,jk ) + wslpi(ji+1,jj ,jk ) ) * fsaeiu(ji,jj,jk ) * umask(ji,jj,jk ) |
---|
212 | zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj ,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1) |
---|
213 | zvwk = ( wslpj(ji,jj,jk ) + wslpj(ji ,jj+1,jk ) ) * fsaeiv(ji,jj,jk ) * vmask(ji,jj,jk ) |
---|
214 | zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji ,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1) |
---|
215 | |
---|
216 | zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 ) |
---|
217 | zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 ) |
---|
218 | |
---|
219 | zftug(ji,jj) = zcg1 * ( tb(ji+1,jj,jk) + tb(ji,jj,jk) ) |
---|
220 | zftvg(ji,jj) = zcg2 * ( tb(ji,jj+1,jk) + tb(ji,jj,jk) ) |
---|
221 | zfsug(ji,jj) = zcg1 * ( sb(ji+1,jj,jk) + sb(ji,jj,jk) ) |
---|
222 | zfsvg(ji,jj) = zcg2 * ( sb(ji,jj+1,jk) + sb(ji,jj,jk) ) |
---|
223 | |
---|
224 | zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj) |
---|
225 | zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj) |
---|
226 | zfsu(ji,jj,jk) = zfsu(ji,jj,jk) + zfsug(ji,jj) |
---|
227 | zfsv(ji,jj,jk) = zfsv(ji,jj,jk) + zfsvg(ji,jj) |
---|
228 | # if defined key_diaeiv |
---|
229 | u_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) ) |
---|
230 | v_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) ) |
---|
231 | # endif |
---|
232 | END DO |
---|
233 | END DO |
---|
234 | #endif |
---|
235 | |
---|
236 | ! II.4 Second derivative (divergence) and add to the general trend |
---|
237 | ! ---------------------------------------------------------------- |
---|
238 | |
---|
239 | DO jj = 2 , jpjm1 |
---|
240 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
241 | zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) ) |
---|
242 | zta = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk) ) |
---|
243 | zsa = zbtr * ( zfsu(ji,jj,jk) - zfsu(ji-1,jj,jk) + zfsv(ji,jj,jk) - zfsv(ji,jj-1,jk) ) |
---|
244 | ta (ji,jj,jk) = ta (ji,jj,jk) + zta |
---|
245 | sa (ji,jj,jk) = sa (ji,jj,jk) + zsa |
---|
246 | END DO |
---|
247 | END DO |
---|
248 | ! ! =============== |
---|
249 | END DO ! End of slab |
---|
250 | ! ! =============== |
---|
251 | |
---|
252 | ! save the trends for diagnostic |
---|
253 | ! save the horizontal diffusive trends |
---|
254 | IF( l_trdtra ) THEN |
---|
255 | # if defined key_traldf_eiv |
---|
256 | DO jk = 1 , jpkm1 |
---|
257 | DO jj = 2 , jpjm1 |
---|
258 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
259 | zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) ) |
---|
260 | tladi(ji,jj,jk) = ( zftug(ji,jj) - zftug(ji-1,jj ) ) * zbtr |
---|
261 | tladj(ji,jj,jk) = ( zftvg(ji,jj) - zftvg(ji ,jj-1) ) * zbtr |
---|
262 | sladi(ji,jj,jk) = ( zfsug(ji,jj) - zfsug(ji-1,jj ) ) * zbtr |
---|
263 | sladj(ji,jj,jk) = ( zfsvg(ji,jj) - zfsvg(ji ,jj-1) ) * zbtr |
---|
264 | END DO |
---|
265 | END DO |
---|
266 | END DO |
---|
267 | # else |
---|
268 | tladi(:,:,:) = 0.e0 |
---|
269 | tladj(:,:,:) = 0.e0 |
---|
270 | sladi(:,:,:) = 0.e0 |
---|
271 | sladj(:,:,:) = 0.e0 |
---|
272 | # endif |
---|
273 | |
---|
274 | ! Substract the eddy induced velocity for T/S |
---|
275 | ztdta(:,:,:) = ta(:,:,:) - ztdta(:,:,:) - tladi(:,:,:) - tladj(:,:,:) |
---|
276 | ztdsa(:,:,:) = sa(:,:,:) - ztdsa(:,:,:) - sladi(:,:,:) - sladj(:,:,:) |
---|
277 | |
---|
278 | CALL trd_mod(ztdta, ztdsa, jpttdldf, 'TRA', kt) |
---|
279 | ENDIF |
---|
280 | |
---|
281 | IF(l_ctl) THEN ! print mean trends (used for debugging) |
---|
282 | zta = SUM( ta(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) ) |
---|
283 | zsa = SUM( sa(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) ) |
---|
284 | WRITE(numout,*) ' ldf - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl |
---|
285 | t_ctl = zta ; s_ctl = zsa |
---|
286 | ENDIF |
---|
287 | |
---|
288 | |
---|
289 | !!bug no separation of diff iso and eiv |
---|
290 | IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN |
---|
291 | ! "zonal" mean lateral diffusive heat and salt transports |
---|
292 | pht_ldf(:) = ptr_vj( zftv(:,:,:) ) |
---|
293 | pst_ldf(:) = ptr_vj( zfsv(:,:,:) ) |
---|
294 | ! "zonal" mean lateral eddy induced velocity heat and salt transports |
---|
295 | pht_eiv(:) = ptr_vj( zftv(:,:,:) ) |
---|
296 | pst_eiv(:) = ptr_vj( zfsv(:,:,:) ) |
---|
297 | ENDIF |
---|
298 | |
---|
299 | END SUBROUTINE tra_ldf_iso_zps |
---|
300 | |
---|
301 | #else |
---|
302 | !!---------------------------------------------------------------------- |
---|
303 | !! default option : Dummy code NO rotation of the diffusive tensor |
---|
304 | !!---------------------------------------------------------------------- |
---|
305 | CONTAINS |
---|
306 | SUBROUTINE tra_ldf_iso_zps( kt ) ! Empty routine |
---|
307 | WRITE(*,*) 'tra_ldf_iso_zps: You should not have seen this print! error?', kt |
---|
308 | END SUBROUTINE tra_ldf_iso_zps |
---|
309 | #endif |
---|
310 | |
---|
311 | !!============================================================================== |
---|
312 | END MODULE traldf_iso_zps |
---|